@zzz0350/ozon-listing-workbench 0.5.0 → 1.0.1

package/versions/0.5.0/_internal/_tk_data/ttk/fonts.tcl

@@ -1,154 +0,0 @@
-#
-# Font specifications.
-#
-# This file, [source]d at initialization time, sets up the following
-# symbolic fonts based on the current platform:
-#
-# TkDefaultFont	-- default for GUI items not otherwise specified
-# TkTextFont	-- font for user text (entry, listbox, others)
-# TkFixedFont	-- standard fixed width font
-# TkHeadingFont	-- headings (column headings, etc)
-# TkCaptionFont -- dialog captions (primary text in alert dialogs, etc.)
-# TkTooltipFont	-- font to use for tooltip windows
-# TkIconFont	-- font to use for icon captions
-# TkMenuFont	-- used to use for menu items
-#
-# In Tk 8.5, some of these fonts may be provided by the TIP#145 implementation
-# (On Windows and Mac OS X as of Oct 2007).
-#
-# +++ Platform notes:
-#
-# Windows:
-#	The default system font changed from "MS Sans Serif" to "Tahoma"
-# 	in Windows XP/Windows 2000.
-#
-#	MS documentation says to use "Tahoma 8" in Windows 2000/XP,
-#	although many MS programs still use "MS Sans Serif 8"
-#
-#	Should use SystemParametersInfo() instead.
-#
-# Mac OSX / Aqua:
-#	Quoth the Apple HIG:
-#	The _system font_ (Lucida Grande Regular 13 pt) is used for text
-#	in menus, dialogs, and full-size controls.
-#	[...] Use the _view font_ (Lucida Grande Regular 12pt) as the default
-#	font of text in lists and tables.
-#	[...] Use the _emphasized system font_ (Lucida Grande Bold 13 pt)
-#	sparingly. It is used for the message text in alerts.
-#	[...] The _small system font_ (Lucida Grande Regular 11 pt) [...]
-#	is also the default font for column headings in lists, for help tags,
-#	and for small controls.
-#
-#	Note that the font for column headings (TkHeadingFont) is
-#	_smaller_ than the default font.
-#
-#	There does not appear to be any recommendations for fixed-width fonts.
-#
-# X11:
-#	"Classic" look used Helvetica bold for everything except
-#	for entry widgets, which use Helvetica medium.
-#	Most other toolkits use medium weight for all UI elements,
-#	which is what we do now.
-#
-#	Font size specified in pixels on X11, not points.
-#	This is Theoretically Wrong, but in practice works better; using
-#	points leads to huge inconsistencies across different servers.
-#
-
-namespace eval ttk {
-
-variable tip145 [catch {font create TkDefaultFont}]
-catch {font create TkTextFont}
-catch {font create TkHeadingFont}
-catch {font create TkCaptionFont}
-catch {font create TkTooltipFont}
-catch {font create TkFixedFont}
-catch {font create TkIconFont}
-catch {font create TkMenuFont}
-catch {font create TkSmallCaptionFont}
-
-if {!$tip145} {
-variable F	;# miscellaneous platform-specific font parameters
-switch -- [tk windowingsystem] {
-    win32 {
-        # In safe interps there is no osVersion element.
-	if {[info exists tcl_platform(osVersion)]} {
-            if {$tcl_platform(osVersion) >= 5.0} {
-                set F(family) "Tahoma"
-            } else {
-                set F(family) "MS Sans Serif"
-            }
-        } else {
-            if {[lsearch -exact [font families] Tahoma] >= 0} {
-                set F(family) "Tahoma"
-            } else {
-                set F(family) "MS Sans Serif"
-            }
-        }
-	set F(size) 8
-
-	font configure TkDefaultFont -family $F(family) -size $F(size)
-	font configure TkTextFont    -family $F(family) -size $F(size)
-	font configure TkHeadingFont -family $F(family) -size $F(size)
-	font configure TkCaptionFont -family $F(family) -size $F(size) \
-	    -weight bold
-	font configure TkTooltipFont -family $F(family) -size $F(size)
-	font configure TkFixedFont   -family Courier -size 10
-	font configure TkIconFont    -family $F(family) -size $F(size)
-	font configure TkMenuFont    -family $F(family) -size $F(size)
-	font configure TkSmallCaptionFont -family $F(family) -size $F(size)
-    }
-    aqua {
-	set F(family) "Lucida Grande"
-	set F(fixed) "Monaco"
-	set F(menusize) 14
-	set F(size) 13
-	set F(viewsize) 12
-	set F(smallsize) 11
-	set F(labelsize) 10
-	set F(fixedsize) 11
-
-	font configure TkDefaultFont -family $F(family) -size $F(size)
-	font configure TkTextFont    -family $F(family) -size $F(size)
-	font configure TkHeadingFont -family $F(family) -size $F(smallsize)
-	font configure TkCaptionFont -family $F(family) -size $F(size) \
-					-weight bold
-	font configure TkTooltipFont -family $F(family) -size $F(smallsize)
-	font configure TkFixedFont   -family $F(fixed)  -size $F(fixedsize)
-	font configure TkIconFont    -family $F(family) -size $F(size)
-	font configure TkMenuFont    -family $F(family) -size $F(menusize)
-	font configure TkSmallCaptionFont -family $F(family) -size $F(labelsize)
-    }
-    default -
-    x11 {
-	if {![catch {tk::pkgconfig get fontsystem} F(fs)] && $F(fs) eq "xft"} {
-	    set F(family) "sans-serif"
-	    set F(fixed)  "monospace"
-	} else {
-	    set F(family) "Helvetica"
-	    set F(fixed)  "courier"
-	}
-	set F(size) -12
-	set F(ttsize) -10
-	set F(capsize) -14
-	set F(fixedsize) -12
-
-	font configure TkDefaultFont -family $F(family) -size $F(size)
-	font configure TkTextFont    -family $F(family) -size $F(size)
-	font configure TkHeadingFont -family $F(family) -size $F(size) \
-			-weight bold
-	font configure TkCaptionFont -family $F(family) -size $F(capsize) \
-			-weight bold
-	font configure TkTooltipFont -family $F(family) -size $F(ttsize)
-	font configure TkFixedFont   -family $F(fixed)  -size $F(fixedsize)
-	font configure TkIconFont    -family $F(family) -size $F(size)
-	font configure TkMenuFont    -family $F(family) -size $F(size)
-	font configure TkSmallCaptionFont -family $F(family) -size $F(ttsize)
-    }
-}
-unset -nocomplain F
-}
-
-}
-
-#*EOF*

package/versions/0.5.0/_internal/_tk_data/ttk/menubutton.tcl

@@ -1,233 +0,0 @@
-#
-# Bindings for Menubuttons.
-#
-# Menubuttons have three interaction modes:
-#
-# Pulldown: Press menubutton, drag over menu, release to activate menu entry
-# Popdown: Click menubutton to post menu
-# Keyboard: <space> or accelerator key to post menu
-#
-# (In addition, when menu system is active, "dropdown" -- menu posts
-# on mouse-over.  Ttk menubuttons don't implement this).
-#
-# For keyboard and popdown mode, we hand off to tk_popup and let
-# the built-in Tk bindings handle the rest of the interaction.
-#
-# ON X11:
-#
-# Standard Tk menubuttons use a global grab on the menubutton.
-# This won't work for Ttk menubuttons in pulldown mode,
-# since we need to process the final <ButtonRelease> event,
-# and this might be delivered to the menu.  So instead we
-# rely on the passive grab that occurs on <Button> events,
-# and transition to popdown mode when the mouse is released
-# or dragged outside the menubutton.
-#
-# ON WINDOWS:
-#
-# I'm not sure what the hell is going on here.  [$menu post] apparently
-# sets up some kind of internal grab for native menus.
-# On this platform, just use [tk_popup] for all menu actions.
-#
-# ON MACOS:
-#
-# Same probably applies here.
-#
-
-namespace eval ttk {
-    namespace eval menubutton {
-	variable State
-	array set State {
-	    pulldown	0
-	    oldcursor	{}
-	}
-    }
-}
-
-bind TMenubutton <Enter>	{ %W instate !disabled {%W state active } }
-bind TMenubutton <Leave>	{ %W state !active }
-bind TMenubutton <space>	{ ttk::menubutton::Popdown %W }
-bind TMenubutton <<Invoke>> 	{ ttk::menubutton::Popdown %W }
-
-if {[tk windowingsystem] eq "x11"} {
-    bind TMenubutton <Button-1>  	{ ttk::menubutton::Pulldown %W }
-    bind TMenubutton <ButtonRelease-1>	{ ttk::menubutton::TransferGrab %W }
-    bind TMenubutton <B1-Leave> 	{ ttk::menubutton::TransferGrab %W }
-} else {
-    bind TMenubutton <Button-1>  \
-	{ %W state pressed ; ttk::menubutton::Popdown %W }
-    bind TMenubutton <ButtonRelease-1>  \
-	{ if {[winfo exists %W]} { %W state !pressed } }
-}
-
-# PostPosition --
-#	Returns x and y coordinates and a menu item index.
-#       If the index is not an empty string the menu should
-#       be posted so that the upper left corner of the indexed
-#       menu item is located at the point (x, y).  Otherwise
-#       the top left corner of the menu itself should be located
-#       at that point.
-#
-# TODO: adjust menu width to be at least as wide as the button
-#	for -direction above, below.
-#
-
-if {[tk windowingsystem] eq "aqua"} {
-    proc ::ttk::menubutton::PostPosition {mb menu} {
-	set menuPad 5
-	set buttonPad 1
-	set bevelPad 4
-	set mh [winfo reqheight $menu]
-	set bh [expr {[winfo height $mb]} + $buttonPad]
-	set bbh [expr {[winfo height $mb]} + $bevelPad]
-	set mw [winfo reqwidth $menu]
-	set bw [winfo width $mb]
-	set entry [::tk::MenuFindName $menu [$mb cget -text]]
-	if {$entry < 0} {
-	    set entry 0
-	}
-	set x [winfo rootx $mb]
-	set y [winfo rooty $mb]
-	switch [$mb cget -direction] {
-	    above {
-		set entry ""
-		incr y [expr {-$mh + 2 * $menuPad}]
-	    }
-	    below {
-		set entry ""
-		incr y $bh
-	    }
-	    left {
-		incr y $menuPad
-		incr x -$mw
-	    }
-	    right {
-		incr y $menuPad
-		incr x $bw
-	    }
-	    default {  # flush
-		incr y $bbh
-	    }
-	}
-	return [list $x $y $entry]
-    }
-} else {
-    proc ::ttk::menubutton::PostPosition {mb menu} {
-	set mh [expr {[winfo reqheight $menu]}]
-	set bh [expr {[winfo height $mb]}]
-	set mw [expr {[winfo reqwidth $menu]}]
-	set bw [expr {[winfo width $mb]}]
-	if {[tk windowingsystem] eq "win32"} {
-	    incr mh 6
-	    incr mw 16
-	}
-	set entry [::tk::MenuFindName $menu [$mb cget -text]]
-	if {$entry < 0} {
-	    set entry 0
-	}
-	set x [winfo rootx $mb]
-	set y [winfo rooty $mb]
-	switch [$mb cget -direction] {
-	    above {
-		set entry ""
-		incr y -$mh
-		# if we go offscreen to the top, show as 'below'
-		if {$y < [winfo vrooty $mb]} {
-		    set y [expr {[winfo vrooty $mb] + [winfo rooty $mb]\
-			    + [winfo reqheight $mb]}]
-		}
-	    }
-	    below {
-		set entry ""
-		incr y $bh
-		# if we go offscreen to the bottom, show as 'above'
-		if {($y + $mh) > ([winfo vrooty $mb] + [winfo vrootheight $mb])} {
-		    set y [expr {[winfo vrooty $mb] + [winfo rooty $mb] - $mh}]
-		}
-	    }
-	    left {
-		incr x -$mw
-	    }
-	    right {
-		incr x $bw
-	    }
-	    default {  # flush
-		incr x [expr {([winfo width $mb] - [winfo reqwidth $menu])/ 2}]
-	    }
-	}
-	return [list $x $y $entry]
-    }
-}
-
-# Popdown --
-#	Post the menu and set a grab on the menu.
-#
-proc ttk::menubutton::Popdown {mb} {
-    if {[$mb instate disabled] || [set menu [$mb cget -menu]] eq ""} {
-	return
-    }
-    foreach {x y entry} [PostPosition $mb $menu] { break }
-    tk_popup $menu $x $y $entry
-}
-
-# Pulldown (X11 only) --
-#	Called when Button1 is pressed on a menubutton.
-#	Posts the menu; a subsequent ButtonRelease
-#	or Leave event will set a grab on the menu.
-#
-proc ttk::menubutton::Pulldown {mb} {
-    variable State
-    if {[$mb instate disabled] || [set menu [$mb cget -menu]] eq ""} {
-	return
-    }
-    set State(pulldown) 1
-    set State(oldcursor) [$mb cget -cursor]
-
-    $mb state pressed
-    $mb configure -cursor [$menu cget -cursor]
-    foreach {x y entry} [PostPosition $mb $menu] { break }
-    if {$entry >= 0} {
-	$menu post $x $y $entry
-    } else {
-	$menu post $x $y
-    }
-    tk_menuSetFocus $menu
-}
-
-# TransferGrab (X11 only) --
-#	Switch from pulldown mode (menubutton has an implicit grab)
-#	to popdown mode (menu has an explicit grab).
-#
-proc ttk::menubutton::TransferGrab {mb} {
-    variable State
-    if {$State(pulldown)} {
-	$mb configure -cursor $State(oldcursor)
-	$mb state {!pressed !active}
-	set State(pulldown) 0
-
-	set menu [$mb cget -menu]
-	foreach {x y entry} [PostPosition $mb $menu] { break }
-    	tk_popup $menu [winfo rootx $menu] [winfo rooty $menu]
-    }
-}
-
-# FindMenuEntry --
-#	Hack to support tk_optionMenus.
-#	Returns the index of the menu entry with a matching -label,
-#	"" if not found.
-#
-proc ttk::menubutton::FindMenuEntry {menu s} {
-    set last [$menu index last]
-    if {$last eq "none" || $last < 0} {
-	return ""
-    }
-    for {set i 0} {$i <= $last} {incr i} {
-	if {![catch {$menu entrycget $i -label} label]
-	    && ($label eq $s)} {
-	    return $i
-	}
-    }
-    return ""
-}
-
-#*EOF*

package/versions/0.5.0/_internal/_tk_data/ttk/notebook.tcl

@@ -1,201 +0,0 @@
-#
-# Bindings for TNotebook widget
-#
-
-namespace eval ttk::notebook {
-    variable TLNotebooks ;# See enableTraversal
-}
-
-bind TNotebook <Button-1>		{ ttk::notebook::Press %W %x %y }
-bind TNotebook <Right>			{ ttk::notebook::CycleTab %W  1; break }
-bind TNotebook <Left>			{ ttk::notebook::CycleTab %W -1; break }
-bind TNotebook <Control-Tab>		{ ttk::notebook::CycleTab %W  1; break }
-bind TNotebook <Control-Shift-Tab>	{ ttk::notebook::CycleTab %W -1; break }
-catch {
-bind TNotebook <Control-ISO_Left_Tab>	{ ttk::notebook::CycleTab %W -1; break }
-}
-bind TNotebook <Destroy>		{ ttk::notebook::Cleanup %W }
-
-# ActivateTab $nb $tab --
-#	Select the specified tab and set focus.
-#
-#  Desired behavior:
-#	+ take focus when reselecting the currently-selected tab;
-#	+ keep focus if the notebook already has it;
-#	+ otherwise set focus to the first traversable widget
-#	  in the newly-selected tab;
-#	+ do not leave the focus in a deselected tab.
-#
-proc ttk::notebook::ActivateTab {w tab} {
-    set oldtab [$w select]
-    $w select $tab
-    set newtab [$w select] ;# NOTE: might not be $tab, if $tab is disabled
-
-    if {[focus] eq $w} { return }
-    if {$newtab eq $oldtab} { focus $w ; return }
-
-    update idletasks ;# needed so focus logic sees correct mapped states
-    if {[set f [ttk::focusFirst $newtab]] ne ""} {
-	ttk::traverseTo $f
-    } else {
-	focus $w
-    }
-}
-
-# Press $nb $x $y --
-#	Button-1 binding for notebook widgets.
-#	Activate the tab under the mouse cursor, if any.
-#
-proc ttk::notebook::Press {w x y} {
-    set index [$w index @$x,$y]
-    if {$index ne ""} {
-	ActivateTab $w $index
-    }
-}
-
-# CycleTab --
-#	Select the next/previous tab in the list.
-#
-proc ttk::notebook::CycleTab {w dir} {
-    set current [$w index current]
-    if {$current >= 0} {
-	set tabCount [$w index end]
-	set select [expr {($current + $dir) % $tabCount}]
-	set step [expr {$dir > 0 ? 1 : -1}]
-	while {[$w tab $select -state] ne "normal" && ($select != $current)} {
-	    set select [expr {($select + $step) % $tabCount}]
-	}
-	if {$select != $current} {
-	    ActivateTab $w $select
-	}
-    }
-}
-
-# MnemonicTab $nb $key --
-#	Scan all tabs in the specified notebook for one with the
-#	specified mnemonic. If found, returns path name of tab;
-#	otherwise returns ""
-#
-proc ttk::notebook::MnemonicTab {nb key} {
-    set key [string toupper $key]
-    foreach tab [$nb tabs] {
-	set label [$nb tab $tab -text]
-	set underline [$nb tab $tab -underline]
-	if {$underline >= 0} {
-	    set mnemonic [string toupper [string index $label $underline]]
-	    if {$mnemonic ne "" && $mnemonic eq $key} {
-		return $tab
-	    }
-	}
-    }
-    return ""
-}
-
-# +++ Toplevel keyboard traversal.
-#
-
-# enableTraversal --
-#	Enable keyboard traversal for a notebook widget
-#	by adding bindings to the containing toplevel window.
-#
-#	TLNotebooks($top) keeps track of the list of all traversal-enabled
-#	notebooks contained in the toplevel
-#
-proc ttk::notebook::enableTraversal {nb} {
-    variable TLNotebooks
-
-    set top [winfo toplevel $nb]
-
-    if {![info exists TLNotebooks($top)]} {
-	# Augment $top bindings:
-	#
-	bind $top <Control-Next>             {+ttk::notebook::TLCycleTab %W  1}
-	bind $top <Control-Prior>            {+ttk::notebook::TLCycleTab %W -1}
-	bind $top <Control-Tab> 	     {+ttk::notebook::TLCycleTab %W  1}
-	bind $top <Control-Shift-Tab>        {+ttk::notebook::TLCycleTab %W -1}
-	catch {
-	bind $top <Control-ISO_Left_Tab>     {+ttk::notebook::TLCycleTab %W -1}
-	}
-	if {[tk windowingsystem] eq "aqua"} {
-	    bind $top <Option-Key> \
-		+[list ttk::notebook::MnemonicActivation $top %K]
-	} else {
-	    bind $top <Alt-Key> \
-		+[list ttk::notebook::MnemonicActivation $top %K]
-	}
-	bind $top <Destroy> {+ttk::notebook::TLCleanup %W}
-    }
-
-    lappend TLNotebooks($top) $nb
-}
-
-# TLCleanup -- <Destroy> binding for traversal-enabled toplevels
-#
-proc ttk::notebook::TLCleanup {w} {
-    variable TLNotebooks
-    if {$w eq [winfo toplevel $w]} {
-	unset -nocomplain -please TLNotebooks($w)
-    }
-}
-
-# Cleanup -- <Destroy> binding for notebooks
-#
-proc ttk::notebook::Cleanup {nb} {
-    variable TLNotebooks
-    set top [winfo toplevel $nb]
-    if {[info exists TLNotebooks($top)]} {
-	set index [lsearch -exact $TLNotebooks($top) $nb]
-        set TLNotebooks($top) [lreplace $TLNotebooks($top) $index $index]
-    }
-}
-
-# EnclosingNotebook $w --
-#	Return the nearest traversal-enabled notebook widget
-#	that contains $w.
-#
-# BUGS: this only works properly for tabs that are direct children
-#	of the notebook widget.  This routine should follow the
-#	geometry manager hierarchy, not window ancestry, but that
-#	information is not available in Tk.
-#
-proc ttk::notebook::EnclosingNotebook {w} {
-    variable TLNotebooks
-
-    set top [winfo toplevel $w]
-    if {![info exists TLNotebooks($top)]} { return }
-
-    while {$w ne $top  && $w ne ""} {
-	if {[lsearch -exact $TLNotebooks($top) $w] >= 0} {
-	    return $w
-	}
-	set w [winfo parent $w]
-    }
-    return ""
-}
-
-# TLCycleTab --
-#	toplevel binding procedure for Control-Tab / Control-Shift-Tab
-#	Select the next/previous tab in the nearest ancestor notebook.
-#
-proc ttk::notebook::TLCycleTab {w dir} {
-    set nb [EnclosingNotebook $w]
-    if {$nb ne ""} {
-	CycleTab $nb $dir
-	return -code break
-    }
-}
-
-# MnemonicActivation $nb $key --
-#	Alt-Key binding procedure for mnemonic activation.
-#	Scan all notebooks in specified toplevel for a tab with the
-#	the specified mnemonic.  If found, activate it and return TCL_BREAK.
-#
-proc ttk::notebook::MnemonicActivation {top key} {
-    variable TLNotebooks
-    foreach nb $TLNotebooks($top) {
-	if {[set tab [MnemonicTab $nb $key]] ne ""} {
-	    ActivateTab $nb [$nb index $tab]
-	    return -code break
-	}
-    }
-}

package/versions/0.5.0/_internal/_tk_data/ttk/panedwindow.tcl

@@ -1,89 +0,0 @@
-#
-# Bindings for ttk::panedwindow widget.
-#
-
-namespace eval ttk::panedwindow {
-    variable State
-    array set State {
-	pressed 0
-    	pressX	-
-	pressY	-
-	sash 	-
-	sashPos -
-    }
-}
-
-## Bindings:
-#
-bind TPanedwindow <Button-1> 		{ ttk::panedwindow::Press %W %x %y }
-bind TPanedwindow <B1-Motion>		{ ttk::panedwindow::Drag %W %x %y }
-bind TPanedwindow <ButtonRelease-1> 	{ ttk::panedwindow::Release %W %x %y }
-
-bind TPanedwindow <Motion> 		{ ttk::panedwindow::SetCursor %W %x %y }
-bind TPanedwindow <Enter> 		{ ttk::panedwindow::SetCursor %W %x %y }
-bind TPanedwindow <Leave> 		{ ttk::panedwindow::ResetCursor %W }
-
-## Sash movement:
-#
-proc ttk::panedwindow::Press {w x y} {
-    variable State
-
-    set sash [$w identify $x $y]
-    if {$sash eq ""} {
-    	set State(pressed) 0
-	return
-    }
-    set State(pressed) 	1
-    set State(pressX) 	$x
-    set State(pressY) 	$y
-    set State(sash) 	$sash
-    set State(sashPos)	[$w sashpos $sash]
-}
-
-proc ttk::panedwindow::Drag {w x y} {
-    variable State
-    if {!$State(pressed)} { return }
-    switch -glob -- [$w cget -orient] {
-    	h*  { set delta [expr {$x - $State(pressX)}] }
-    	v*  { set delta [expr {$y - $State(pressY)}] }
-    }
-    $w sashpos $State(sash) [expr {$State(sashPos) + $delta}]
-}
-
-proc ttk::panedwindow::Release {w x y} {
-    variable State
-    set State(pressed) 0
-    SetCursor $w $x $y
-}
-
-## Cursor management:
-#
-proc ttk::panedwindow::ResetCursor {w} {
-    variable State
-
-    ttk::saveCursor $w State(userConfCursor) \
-            [list [ttk::cursor hresize] [ttk::cursor vresize]]
-
-    if {!$State(pressed)} {
-	ttk::setCursor $w $State(userConfCursor)
-    }
-}
-
-proc ttk::panedwindow::SetCursor {w x y} {
-    variable State
-
-    ttk::saveCursor $w State(userConfCursor) \
-            [list [ttk::cursor hresize] [ttk::cursor vresize]]
-
-    set cursor $State(userConfCursor)
-    if {[llength [$w identify $x $y]]} {
-    	# Assume we're over a sash.
-	switch -glob -- [$w cget -orient] {
-	    h*  { set cursor hresize }
-	    v*  { set cursor vresize }
-	}
-    }
-    ttk::setCursor $w $cursor
-}
-
-#*EOF*