@zoralabs/protocol-deployments 0.0.11 → 0.0.14-MINT.0

package/test/UpgradesTest.t.sol

@@ -1,222 +0,0 @@
-// SPDX-License-Identifier: MIT
-pragma solidity 0.8.17;
-
-import "forge-std/Test.sol";
-import {ZoraCreator1155FactoryImpl} from "@zoralabs/zora-1155-contracts/src/factory/ZoraCreator1155FactoryImpl.sol";
-import {ZoraCreator1155PremintExecutorImpl} from "@zoralabs/zora-1155-contracts/src/delegation/ZoraCreator1155PremintExecutorImpl.sol";
-import {ForkDeploymentConfig, Deployment, ChainConfig} from "../src/DeploymentConfig.sol";
-import {ZoraDeployerUtils} from "../src/ZoraDeployerUtils.sol";
-import {DeploymentTestingUtils} from "../src/DeploymentTestingUtils.sol";
-import {IZoraCreator1155PremintExecutor} from "@zoralabs/zora-1155-contracts/src/interfaces/IZoraCreator1155PremintExecutor.sol";
-
-contract UpgradesTest is ForkDeploymentConfig, DeploymentTestingUtils, Test {
-    /// @notice gets the chains to do fork tests on, by reading environment var FORK_TEST_CHAINS.
-    /// Chains are by name, and must match whats under `rpc_endpoints` in the foundry.toml
-    function getForkTestChains() private view returns (string[] memory result) {
-        try vm.envString("FORK_TEST_CHAINS", ",") returns (string[] memory forkTestChains) {
-            result = forkTestChains;
-        } catch {
-            console.log("could not get fork test chains - make sure the environment variable FORK_TEST_CHAINS is set");
-            result = new string[](0);
-        }
-    }
-
-    function determine1155Upgrade(Deployment memory deployment) private view returns (bool upgradeNeeded, address targetProxy, address targetImpl) {
-        targetProxy = deployment.factoryProxy;
-        targetImpl = deployment.factoryImpl;
-        address currentImplementation = ZoraCreator1155FactoryImpl(targetProxy).implementation();
-
-        upgradeNeeded = targetImpl != currentImplementation;
-    }
-
-    function determinePreminterUpgrade(Deployment memory deployment) private returns (bool upgradeNeeded, address targetProxy, address targetImpl) {
-        targetProxy = deployment.preminterProxy;
-        targetImpl = deployment.preminterImpl;
-
-        // right now we cannot call "implementation" on contract since it doesn't exist yet, so we check if deployed impl meets the v1 impl we know
-        address preminterV1ImplAddress = 0x6E2AbBcd82935bFC68A1d5d2c96372b13b65eD9C;
-
-        // if the target impl is still the v1 impl, it didnt have a method to check impl so we can't call it, also we know its still v1 impl so we don't need to upgrade
-        if (targetImpl == preminterV1ImplAddress) {
-            upgradeNeeded = false;
-        } else {
-            // if doesnt have implementation method, then we know upgrade is needed
-            (bool success, bytes memory data) = deployment.preminterProxy.call(abi.encodePacked(ZoraCreator1155PremintExecutorImpl.implementation.selector));
-
-            if (!success) {
-                upgradeNeeded = true;
-            } else {
-                address currentImplementation = abi.decode(data, (address));
-                upgradeNeeded = currentImplementation != targetImpl;
-            }
-        }
-    }
-
-    function _buildSafeUrl(address safe, address target, bytes memory cd) internal view returns (string memory) {
-        address[] memory targets = new address[](1);
-        targets[0] = target;
-
-        bytes[] memory calldatas = new bytes[](1);
-        calldatas[0] = cd;
-
-        return _buildBatchSafeUrl(safe, targets, calldatas);
-    }
-
-    // pipe delimiter is url encoded | which is %7C
-    string constant PIPE_DELIMITER = "%7C";
-
-    function _buildBatchSafeUrl(address safe, address[] memory targets, bytes[] memory cd) internal view returns (string memory) {
-        string memory targetsString = "";
-
-        for (uint256 i = 0; i < targets.length; i++) {
-            targetsString = string.concat(targetsString, vm.toString(targets[i]));
-
-            if (i < targets.length - 1) {
-                targetsString = string.concat(targetsString, PIPE_DELIMITER);
-            }
-        }
-
-        string memory calldataString = "";
-
-        for (uint256 i = 0; i < cd.length; i++) {
-            calldataString = string.concat(calldataString, vm.toString(cd[i]));
-
-            if (i < cd.length - 1) {
-                calldataString = string.concat(calldataString, PIPE_DELIMITER);
-            }
-        }
-
-        string memory valuesString = "";
-
-        for (uint256 i = 0; i < cd.length; i++) {
-            valuesString = string.concat(valuesString, "0");
-
-            if (i < cd.length - 1) {
-                valuesString = string.concat(valuesString, PIPE_DELIMITER);
-            }
-        }
-
-        // sample url: https://ourzora.github.io/smol-safe/${chainId}/${safeAddress}&target={pipeDelimitedTargets}&calldata={pipeDelimitedCalldata}&value={pipeDelimitedValues}
-        string memory targetUrl = "https://ourzora.github.io/smol-safe/#safe/";
-        targetUrl = string.concat(targetUrl, vm.toString(block.chainid));
-        targetUrl = string.concat(targetUrl, "/");
-        targetUrl = string.concat(targetUrl, vm.toString(safe));
-        targetUrl = string.concat(targetUrl, "/new");
-        targetUrl = string.concat(targetUrl, "?");
-        targetUrl = string.concat(targetUrl, "targets=");
-        targetUrl = string.concat(targetUrl, targetsString);
-        targetUrl = string.concat(targetUrl, "&calldatas=");
-        targetUrl = string.concat(targetUrl, calldataString);
-        targetUrl = string.concat(targetUrl, "&values=");
-        targetUrl = string.concat(targetUrl, valuesString);
-
-        return targetUrl;
-    }
-
-    /// @notice checks which chains need an upgrade, simulated the upgrade, and gets the upgrade calldata
-    function simulateUpgradeOnFork(string memory chainName) private {
-        // create and select the fork, which will be used for all subsequent calls
-        vm.createSelectFork(vm.rpcUrl(chainName));
-
-        Deployment memory deployment = getDeployment();
-
-        ChainConfig memory chainConfig = getChainConfig();
-
-        address creator = makeAddr("creator");
-
-        (bool is1155UpgradeNeeded, address targetProxy1155, address targetImpl1155) = determine1155Upgrade(deployment);
-        (bool preminterUpgradeNeeded, address targetPreminterProxy, address targetPremintImpl) = determinePreminterUpgrade(deployment);
-
-        if (!is1155UpgradeNeeded && !preminterUpgradeNeeded) {
-            return;
-        }
-
-        console2.log("====== upgrade needed ======");
-        console2.log("chain:", chainName);
-        console2.log("upgrade owner:", chainConfig.factoryOwner);
-
-        bytes memory factory1155UpgradeCalldata;
-
-        if (is1155UpgradeNeeded) {
-            console2.log("-- 1155 upgrade needed --");
-            vm.prank(chainConfig.factoryOwner);
-            factory1155UpgradeCalldata = ZoraDeployerUtils.simulateUpgrade(targetProxy1155, targetImpl1155);
-            vm.prank(creator);
-            ZoraDeployerUtils.deployTestContractForVerification(targetProxy1155, creator);
-
-            console2.log("1155 upgrade target:", targetProxy1155);
-            console2.log("upgrade calldata:");
-            console.logBytes(factory1155UpgradeCalldata);
-            {
-                console2.log("upgrade to address:", targetImpl1155);
-                console2.log("upgrade to version:", ZoraCreator1155FactoryImpl(targetImpl1155).contractVersion());
-                if (!preminterUpgradeNeeded) {
-                    console2.log("smol safe upgrade url: ", _buildSafeUrl(chainConfig.factoryOwner, targetProxy1155, factory1155UpgradeCalldata));
-                }
-                console2.log("------------------------");
-            }
-        }
-
-        address factoryOwner = chainConfig.factoryOwner;
-        bytes memory preminterUpgradeCalldata;
-
-        // hack - for now, only check on zora sepolia or goerli
-        if (preminterUpgradeNeeded) {
-            console2.log("-- preminter upgrade needed --");
-            console2.log("preminter upgrade target:", targetPreminterProxy);
-            vm.prank(factoryOwner);
-            preminterUpgradeCalldata = ZoraDeployerUtils.simulateUpgrade(deployment.preminterProxy, deployment.preminterImpl);
-
-            address collector = makeAddr("collector");
-            address mintReferral = makeAddr("referral");
-            vm.deal(collector, 10 ether);
-
-            address[] memory mintRewardsRecipients = new address[](1);
-            mintRewardsRecipients[0] = mintReferral;
-
-            IZoraCreator1155PremintExecutor.MintArguments memory mintArguments = IZoraCreator1155PremintExecutor.MintArguments({
-                mintRecipient: collector,
-                mintComment: "",
-                mintRewardsRecipients: mintRewardsRecipients
-            });
-
-            vm.startPrank(collector);
-            signAndExecutePremintV1(targetPreminterProxy, makeAddr("payoutRecipientA"), mintArguments);
-            signAndExecutePremintV2(targetPreminterProxy, makeAddr("payoutRecipientB"), mintArguments);
-
-            vm.stopPrank();
-
-            {
-                console2.log("upgrade calldata:");
-                console.logBytes(preminterUpgradeCalldata);
-                console2.log("upgrade to address:", targetPremintImpl);
-                if (!is1155UpgradeNeeded) {
-                    console2.log("smol safe upgrade url: ", _buildSafeUrl(factoryOwner, targetPreminterProxy, preminterUpgradeCalldata));
-                }
-                console2.log("------------------------");
-            }
-        }
-
-        // if both needed:
-        if (is1155UpgradeNeeded && preminterUpgradeNeeded) {
-            address[] memory targets = new address[](2);
-            targets[0] = targetProxy1155;
-            targets[1] = targetPreminterProxy;
-
-            bytes[] memory calldatas = new bytes[](2);
-            calldatas[0] = factory1155UpgradeCalldata;
-            calldatas[1] = preminterUpgradeCalldata;
-
-            console2.log("multi-upgrade smol safe upgrade url: ", _buildBatchSafeUrl(factoryOwner, targets, calldatas));
-        }
-
-        console2.log("=================\n");
-    }
-
-    function test_fork_simulateUpgrades() external {
-        string[] memory forkTestChains = getForkTestChains();
-        for (uint256 i = 0; i < forkTestChains.length; i++) {
-            simulateUpgradeOnFork(forkTestChains[i]);
-        }
-    }
-}

package/test/ZoraCreator1155Factory_Fork.t.sol

@@ -1,149 +0,0 @@
-// SPDX-License-Identifier: MIT
-pragma solidity 0.8.17;
-
-import "forge-std/Test.sol";
-import {IZoraCreator1155Factory} from "@zoralabs/zora-1155-contracts/src/interfaces/IZoraCreator1155Factory.sol";
-import {ZoraCreator1155FactoryImpl} from "@zoralabs/zora-1155-contracts/src/factory/ZoraCreator1155FactoryImpl.sol";
-import {IZoraCreator1155Errors} from "@zoralabs/zora-1155-contracts/src/interfaces/IZoraCreator1155Errors.sol";
-import {IZoraCreator1155} from "@zoralabs/zora-1155-contracts/src/interfaces/IZoraCreator1155.sol";
-import {ZoraCreator1155Impl} from "@zoralabs/zora-1155-contracts/src/nft/ZoraCreator1155Impl.sol";
-import {IMinter1155} from "@zoralabs/zora-1155-contracts/src/interfaces/IMinter1155.sol";
-import {IOwnable} from "@zoralabs/zora-1155-contracts/src/interfaces/IOwnable.sol";
-import {ICreatorRoyaltiesControl} from "@zoralabs/zora-1155-contracts/src/interfaces/ICreatorRoyaltiesControl.sol";
-import {Strings} from "@openzeppelin/contracts/utils/Strings.sol";
-import {ZoraCreatorFixedPriceSaleStrategy} from "@zoralabs/zora-1155-contracts/src/minters/fixed-price/ZoraCreatorFixedPriceSaleStrategy.sol";
-import {ForkDeploymentConfig, Deployment} from "../src/DeploymentConfig.sol";
-
-contract ZoraCreator1155FactoryForkTest is ForkDeploymentConfig, Test {
-    uint256 constant quantityToMint = 3;
-    uint256 constant tokenMaxSupply = 100;
-    uint32 constant royaltyMintSchedule = 10;
-    uint32 constant royaltyBPS = 100;
-    uint256 constant mintFee = 0.000777 ether;
-
-    address collector;
-    address creator;
-
-    uint256 public constant PERMISSION_BIT_MINTER = 2 ** 2;
-
-    function setUp() external {
-        creator = vm.addr(1);
-        collector = vm.addr(2);
-    }
-
-    /// @notice gets the chains to do fork tests on, by reading environment var FORK_TEST_CHAINS.
-    /// Chains are by name, and must match whats under `rpc_endpoints` in the foundry.toml
-    function getForkTestChains() private view returns (string[] memory result) {
-        try vm.envString("FORK_TEST_CHAINS", ",") returns (string[] memory forkTestChains) {
-            result = forkTestChains;
-        } catch {
-            console.log("could not get fork test chains - make sure the environment variable FORK_TEST_CHAINS is set");
-            result = new string[](0);
-        }
-    }
-
-    function _setupToken(IZoraCreator1155 target, IMinter1155 fixedPrice, uint96 tokenPrice) private returns (uint256 tokenId) {
-        string memory tokenURI = "ipfs://token";
-
-        tokenId = target.setupNewToken(tokenURI, tokenMaxSupply);
-
-        target.addPermission(tokenId, address(fixedPrice), PERMISSION_BIT_MINTER);
-
-        target.callSale(
-            tokenId,
-            fixedPrice,
-            abi.encodeWithSelector(
-                ZoraCreatorFixedPriceSaleStrategy.setSale.selector,
-                tokenId,
-                ZoraCreatorFixedPriceSaleStrategy.SalesConfig({
-                    pricePerToken: tokenPrice,
-                    saleStart: 0,
-                    saleEnd: type(uint64).max,
-                    maxTokensPerAddress: 0,
-                    fundsRecipient: address(0)
-                })
-            )
-        );
-    }
-
-    function _createErc1155Contract(IZoraCreator1155Factory factory) private returns (IZoraCreator1155 target) {
-        // create the contract, with no toekns
-        bytes[] memory initSetup = new bytes[](0);
-
-        address admin = creator;
-        string memory contractURI = "ipfs://asdfasdf";
-        string memory name = "Test";
-        address royaltyRecipient = creator;
-
-        address deployedAddress = factory.createContract(
-            contractURI,
-            name,
-            ICreatorRoyaltiesControl.RoyaltyConfiguration({
-                royaltyBPS: royaltyBPS,
-                royaltyRecipient: royaltyRecipient,
-                royaltyMintSchedule: royaltyMintSchedule
-            }),
-            payable(admin),
-            initSetup
-        );
-
-        target = IZoraCreator1155(deployedAddress);
-
-        // ** 2. Setup a new token with the fixed price sales strategy **
-    }
-
-    function mintTokenAtFork(IZoraCreator1155Factory factory) internal {
-        uint96 tokenPrice = 1 ether;
-        IMinter1155 fixedPrice = factory.defaultMinters()[0];
-        // now create a contract with the factory
-        vm.startPrank(creator);
-
-        // ** 1. Create the erc1155 contract **
-        IZoraCreator1155 target = _createErc1155Contract(factory);
-
-        // ** 2. Setup a new token with the fixed price sales strategy and the token price **
-        uint256 tokenId = _setupToken(target, fixedPrice, tokenPrice);
-
-        // ** 3. Mint on that contract **
-
-        // mint 3 tokens
-        uint256 valueToSend = quantityToMint * (tokenPrice + mintFee);
-
-        // mint the token
-        vm.deal(collector, valueToSend);
-        vm.startPrank(collector);
-        ZoraCreator1155Impl(payable(address(target))).mintWithRewards{value: valueToSend}(fixedPrice, tokenId, quantityToMint, abi.encode(collector), address(0));
-
-        uint256 balance = ZoraCreator1155Impl(payable(address(target))).balanceOf(collector, tokenId);
-
-        assertEq(balance, quantityToMint, "balance mismatch");
-    }
-
-    function testTheFork(string memory chainName) private {
-        console.log("testing on fork: ", chainName);
-
-        // create and select the fork, which will be used for all subsequent calls
-        // it will also affect the current block chain id based on the rpc url returned
-        vm.createSelectFork(vm.rpcUrl(chainName));
-
-        Deployment memory deployment = getDeployment();
-
-        address factoryAddress = deployment.factoryProxy;
-        ZoraCreator1155FactoryImpl factory = ZoraCreator1155FactoryImpl(factoryAddress);
-
-        assertEq(getChainConfig().factoryOwner, IOwnable(factoryAddress).owner(), string.concat("configured owner incorrect on: ", chainName));
-
-        // make sure that the address from the factory matches the stored fixed price address
-        // sanity check - check minters match config
-        assertEq(address(factory.merkleMinter()), deployment.merkleMintSaleStrategy, "merkle minter incorrect");
-        assertEq(address(factory.fixedPriceMinter()), deployment.fixedPriceSaleStrategy, "fixed priced minter incorrect");
-        assertEq(address(factory.redeemMinterFactory()), deployment.redeemMinterFactory, "redeem minter not correct");
-    }
-
-    function test_fork_canCreateContractAndMint() external {
-        string[] memory forkTestChains = getForkTestChains();
-        for (uint256 i = 0; i < forkTestChains.length; i++) {
-            testTheFork(forkTestChains[i]);
-        }
-    }
-}

package/test/ZoraCreator1155PremintExecutorForkTest.t.sol

@@ -1,205 +0,0 @@
-// SPDX-License-Identifier: MIT
-pragma solidity 0.8.17;
-
-import "forge-std/Test.sol";
-import {ForkDeploymentConfig} from "../src/DeploymentConfig.sol";
-import {ZoraCreator1155Attribution, ContractCreationConfig, PremintConfig, PremintConfigV2, TokenCreationConfig} from "@zoralabs/zora-1155-contracts/src/delegation/ZoraCreator1155Attribution.sol";
-import {ZoraCreator1155PremintExecutorImpl} from "@zoralabs/zora-1155-contracts/src/delegation/ZoraCreator1155PremintExecutorImpl.sol";
-import {ZoraCreator1155FactoryImpl} from "@zoralabs/zora-1155-contracts/src/factory/ZoraCreator1155FactoryImpl.sol";
-import {IZoraCreator1155PremintExecutor} from "@zoralabs/zora-1155-contracts/src/interfaces/IZoraCreator1155PremintExecutor.sol";
-import {Zora1155PremintFixtures} from "../src/Zora1155PremintFixtures.sol";
-
-contract ZoraCreator1155PreminterForkTest is ForkDeploymentConfig, Test {
-    ZoraCreator1155FactoryImpl factory;
-    ZoraCreator1155PremintExecutorImpl preminter;
-    uint256 mintFeeAmount = 0.000777 ether;
-    address creator;
-    uint256 creatorPrivateKey;
-    address payoutRecipient = makeAddr("payoutRecipient");
-    address minter = makeAddr("minter");
-
-    ContractCreationConfig contractConfig;
-    PremintConfig premintConfig;
-    PremintConfigV2 premintConfigV2;
-    address createReferral = makeAddr("creatReferral");
-
-    /// @notice gets the chains to do fork tests on, by reading environment var FORK_TEST_CHAINS.
-    /// Chains are by name, and must match whats under `rpc_endpoints` in the foundry.toml
-    function getForkTestChains() private view returns (string[] memory result) {
-        try vm.envString("FORK_TEST_CHAINS", ",") returns (string[] memory forkTestChains) {
-            result = forkTestChains;
-        } catch {
-            console.log("could not get fork test chains - make sure the environment variable FORK_TEST_CHAINS is set");
-            result = new string[](0);
-        }
-    }
-
-    function setupPremint() private {
-        // get contract hash, which is unique per contract creation config, and can be used
-        // retrieve the address created for a contract
-        address preminterAddress = getDeployment().preminterProxy;
-
-        // override local preminter to use the addresses from the chain
-        factory = ZoraCreator1155FactoryImpl(getDeployment().factoryProxy);
-        preminter = ZoraCreator1155PremintExecutorImpl(preminterAddress);
-
-        (creator, creatorPrivateKey) = makeAddrAndKey("creator");
-
-        contractConfig = Zora1155PremintFixtures.makeDefaultContractCreationConfig(creator);
-
-        premintConfig = Zora1155PremintFixtures.makeDefaultV1PremintConfig(factory.fixedPriceMinter(), payoutRecipient);
-        premintConfigV2 = Zora1155PremintFixtures.makeDefaultV2PremintConfig(factory.fixedPriceMinter(), payoutRecipient, createReferral);
-    }
-
-    function equals(string memory str1, string memory str2) public pure returns (bool) {
-        return keccak256(abi.encodePacked(str1)) == keccak256(abi.encodePacked(str2));
-    }
-
-    function test_fork_legacyPremint_successfullyMintsPremintTokens() external {
-        string[] memory forkTestChains = getForkTestChains();
-        for (uint256 i = 0; i < forkTestChains.length; i++) {
-            string memory chainName = forkTestChains[i];
-
-            console.log("testing on fork: ", chainName);
-
-            // create and select the fork, which will be used for all subsequent calls
-            // it will also affect the current block chain id based on the rpc url returned
-            vm.createSelectFork(vm.rpcUrl(chainName));
-
-            setupPremint();
-
-            _signAndExecutePremintLegacy(creatorPrivateKey, minter, 1, "test comment");
-        }
-    }
-
-    function test_fork_premintV1_successfullyMintsPremintTokens() external {
-        string[] memory forkTestChains = getForkTestChains();
-        for (uint256 i = 0; i < forkTestChains.length; i++) {
-            string memory chainName = forkTestChains[i];
-
-            if (!_chainSupportsPremintV2(chainName)) {
-                console.log("skipping chain, does not support v1 premint: ", chainName);
-                continue;
-            }
-
-            console.log("testing on fork: ", chainName);
-
-            // it will also affect the current block chain id based on the rpc url returned
-            vm.createSelectFork(vm.rpcUrl(chainName));
-
-            setupPremint();
-
-            _signAndExecutePremintV1(creatorPrivateKey, minter, 1, "test comment");
-        }
-    }
-
-    function test_fork_premintV2_successfullyMintsPremintTokens() external {
-        string[] memory forkTestChains = getForkTestChains();
-        for (uint256 i = 0; i < forkTestChains.length; i++) {
-            string memory chainName = forkTestChains[i];
-
-            if (!_chainSupportsPremintV2(chainName)) {
-                console.log("skipping chain, does not support v2 premint: ", chainName);
-                continue;
-            }
-
-            console.log("testing on fork: ", chainName);
-
-            // it will also affect the current block chain id based on the rpc url returned
-            vm.createSelectFork(vm.rpcUrl(chainName));
-
-            setupPremint();
-
-            _signAndExecutePremintV2(creatorPrivateKey, minter, 0, "test comment");
-        }
-    }
-
-    function _chainSupportsPremintV2(string memory chainName) private pure returns (bool) {
-        // for now we know that only goerli and sepolia have v2 premint deployed
-        return (equals(chainName, "zora_sepolia") || equals(chainName, "zora_goerli"));
-    }
-
-    function _signAndExecutePremintLegacy(
-        uint256 privateKey,
-        address executor,
-        uint256 quantityToMint,
-        string memory comment
-    ) private returns (uint256 newTokenId) {
-        bytes memory signature = _signPremintV1(preminter.getContractAddress(contractConfig), privateKey, block.chainid);
-
-        uint256 mintCost = mintFeeAmount * quantityToMint;
-        vm.deal(executor, mintCost);
-
-        // now call the premint function, using the same config that was used to generate the digest, and the signature
-        vm.prank(executor);
-        newTokenId = preminter.premint{value: mintCost}(contractConfig, premintConfig, signature, quantityToMint, comment);
-    }
-
-    function _signAndExecutePremintV1(uint256 privateKey, address executor, uint256 quantityToMint, string memory comment) private {
-        bytes memory signature = _signPremintV1(preminter.getContractAddress(contractConfig), privateKey, block.chainid);
-
-        uint256 mintCost = mintFeeAmount * quantityToMint;
-        vm.deal(executor, mintCost);
-
-        // now call the premint function, using the same config that was used to generate the digest, and the signature
-        vm.prank(executor);
-        preminter.premintV1{value: mintCost}(
-            contractConfig,
-            premintConfig,
-            signature,
-            quantityToMint,
-            IZoraCreator1155PremintExecutor.MintArguments({mintRecipient: executor, mintComment: comment, mintRewardsRecipients: new address[](0)})
-        );
-    }
-
-    function _signPremintV1(address contractAddress, uint256 privateKey, uint256 chainId) private view returns (bytes memory) {
-        bytes32 digest = ZoraCreator1155Attribution.premintHashedTypeDataV4(
-            ZoraCreator1155Attribution.hashPremint(premintConfig),
-            contractAddress,
-            ZoraCreator1155Attribution.HASHED_VERSION_1,
-            chainId
-        );
-
-        // 3. Sign the digest
-        // create a signature with the digest for the params
-        return _sign(privateKey, digest);
-    }
-
-    function _signAndExecutePremintV2(uint256 privateKey, address executor, uint256 quantityToMint, string memory comment) private {
-        bytes memory signature = _signPremintV2(preminter.getContractAddress(contractConfig), privateKey, block.chainid);
-
-        uint256 mintCost = mintFeeAmount * quantityToMint;
-        vm.deal(executor, mintCost);
-
-        // now call the premint function, using the same config that was used to generate the digest, and the signature
-        vm.prank(executor);
-        preminter.premintV2{value: mintCost}(
-            contractConfig,
-            premintConfigV2,
-            signature,
-            quantityToMint,
-            IZoraCreator1155PremintExecutor.MintArguments({mintRecipient: executor, mintComment: comment, mintRewardsRecipients: new address[](0)})
-        );
-    }
-
-    function _signPremintV2(address contractAddress, uint256 privateKey, uint256 chainId) private view returns (bytes memory) {
-        bytes32 digest = ZoraCreator1155Attribution.premintHashedTypeDataV4(
-            ZoraCreator1155Attribution.hashPremint(premintConfigV2),
-            contractAddress,
-            ZoraCreator1155Attribution.HASHED_VERSION_2,
-            chainId
-        );
-
-        // 3. Sign the digest
-        // create a signature with the digest for the params
-        return _sign(privateKey, digest);
-    }
-
-    function _sign(uint256 privateKey, bytes32 digest) private pure returns (bytes memory) {
-        // sign the message
-        (uint8 v, bytes32 r, bytes32 s) = vm.sign(privateKey, digest);
-
-        // combine into a single bytes array
-        return abi.encodePacked(r, s, v);
-    }
-}