@zgsm/costrict-cli 0.0.8 → 0.0.9

package/bundle/assets/queries/tree-sitter-languages/ocaml_interface-tags.scm

@@ -1,98 +0,0 @@
-; Modules
-;--------
-
-(
-  (comment)? @doc .
-  (module_definition
-    (module_binding (module_name) @name) @definition.module
-  )
-  (#strip! @doc "^\\(\\*+\\s*|\\s*\\*+\\)$")
-)
-
-(module_path (module_name) @name) @reference.module
-(extended_module_path (module_name) @name) @reference.module
-
-(
-  (comment)? @doc .
-  (module_type_definition (module_type_name) @name) @definition.interface
-  (#strip! @doc "^\\(\\*+\\s*|\\s*\\*+\\)$")
-)
-
-(module_type_path (module_type_name) @name) @reference.implementation
-
-
-; Classes
-;--------
-
-(
-  (comment)? @doc .
-  [
-    (class_definition
-      (class_binding (class_name) @name) @definition.class
-    )
-    (class_type_definition
-      (class_type_binding (class_type_name) @name) @definition.class
-    )
-  ]
-  (#strip! @doc "^\\(\\*+\\s*|\\s*\\*+\\)$")
-)
-
-[
-  (class_path (class_name) @name)
-  (class_type_path (class_type_name) @name)
-] @reference.class
-
-(
-  (comment)? @doc .
-  (method_definition (method_name) @name) @definition.method
-  (#strip! @doc "^\\(\\*+\\s*|\\s*\\*+\\)$")
-)
-
-(method_invocation (method_name) @name) @reference.call
-
-
-; Types
-;------
-
-(
-  (comment)? @doc .
-  (type_definition
-    (type_binding
-      name: [
-        (type_constructor) @name
-        (type_constructor_path (type_constructor) @name)
-      ]
-    ) @definition.type
-  )
-  (#strip! @doc "^\\(\\*+\\s*|\\s*\\*+\\)$")
-)
-
-(type_constructor_path (type_constructor) @name) @reference.type
-
-[
-  (constructor_declaration (constructor_name) @name)
-  (tag_specification (tag) @name)
-] @definition.enum_variant
-
-[
-  (constructor_path (constructor_name) @name)
-  (tag) @name
-] @reference.enum_variant
-
-(field_declaration (field_name) @name) @definition.field
-
-(field_path (field_name) @name) @reference.field
-
-(
-  (comment)? @doc .
-  (external (value_name) @name) @definition.function
-  (#strip! @doc "^\\(\\*+\\s*|\\s*\\*+\\)$")
-)
-
-(
-  (comment)? @doc .
-  (value_specification
-    (value_name) @name.definition.function
-  ) @definition.function
-  (#strip! @doc "^\\(\\*+\\s*|\\s*\\*+\\)$")
-)

package/bundle/assets/queries/tree-sitter-languages/php-tags.scm

@@ -1,26 +0,0 @@
-(class_declaration
-  name: (name) @name.definition.class) @definition.class
-
-(function_definition
-  name: (name) @name.definition.function) @definition.function
-
-(method_declaration
-  name: (name) @name.definition.function) @definition.function
-
-(object_creation_expression
-  [
-    (qualified_name (name) @name.reference.class)
-    (variable_name (name) @name.reference.class)
-  ]) @reference.class
-
-(function_call_expression
-  function: [
-    (qualified_name (name) @name.reference.call)
-    (variable_name (name)) @name.reference.call
-  ]) @reference.call
-
-(scoped_call_expression
-  name: (name) @name.reference.call) @reference.call
-
-(member_call_expression
-  name: (name) @name.reference.call) @reference.call

package/bundle/assets/queries/tree-sitter-languages/python-tags.scm

@@ -1,12 +0,0 @@
-(class_definition
-  name: (identifier) @name.definition.class) @definition.class
-
-(function_definition
-  name: (identifier) @name.definition.function) @definition.function
-
-(call
-  function: [
-      (identifier) @name.reference.call
-      (attribute
-        attribute: (identifier) @name.reference.call)
-  ]) @reference.call

package/bundle/assets/queries/tree-sitter-languages/ql-tags.scm

@@ -1,26 +0,0 @@
-(classlessPredicate
-  name: (predicateName) @name.definition.function) @definition.function
-
-(memberPredicate
-  name: (predicateName) @name.definition.method) @definition.method
-
-(aritylessPredicateExpr
-  name: (literalId) @name.reference.call) @reference.call
-
-(module
-  name: (moduleName) @name.definition.module) @definition.module
-
-(dataclass
-  name: (className) @name.definition.class) @definition.class
-
-(datatype
-  name: (className) @name.definition.class) @definition.class
-
-(datatypeBranch
-  name: (className) @name.definition.class) @definition.class
-
-(qualifiedRhs
-  name: (predicateName) @name.reference.call) @reference.call
-
-(typeExpr
-  name: (className) @name.reference.type) @reference.type

package/bundle/assets/queries/tree-sitter-languages/ruby-tags.scm

@@ -1,64 +0,0 @@
-; Method definitions
-
-(
-  (comment)* @doc
-  .
-  [
-    (method
-      name: (_) @name.definition.method) @definition.method
-    (singleton_method
-      name: (_) @name.definition.method) @definition.method
-  ]
-  (#strip! @doc "^#\\s*")
-  (#select-adjacent! @doc @definition.method)
-)
-
-(alias
-  name: (_) @name.definition.method) @definition.method
-
-(setter
-  (identifier) @ignore)
-
-; Class definitions
-
-(
-  (comment)* @doc
-  .
-  [
-    (class
-      name: [
-        (constant) @name.definition.class
-        (scope_resolution
-          name: (_) @name.definition.class)
-      ]) @definition.class
-    (singleton_class
-      value: [
-        (constant) @name.definition.class
-        (scope_resolution
-          name: (_) @name.definition.class)
-      ]) @definition.class
-  ]
-  (#strip! @doc "^#\\s*")
-  (#select-adjacent! @doc @definition.class)
-)
-
-; Module definitions
-
-(
-  (module
-    name: [
-      (constant) @name.definition.module
-      (scope_resolution
-        name: (_) @name.definition.module)
-    ]) @definition.module
-)
-
-; Calls
-
-(call method: (identifier) @name.reference.call) @reference.call
-
-(
-  [(identifier) (constant)] @name.reference.call @reference.call
-  (#is-not? local)
-  (#not-match? @name.reference.call "^(lambda|load|require|require_relative|__FILE__|__LINE__)$")
-)

package/bundle/assets/queries/tree-sitter-languages/rust-tags.scm

@@ -1,60 +0,0 @@
-; ADT definitions
-
-(struct_item
-    name: (type_identifier) @name.definition.class) @definition.class
-
-(enum_item
-    name: (type_identifier) @name.definition.class) @definition.class
-
-(union_item
-    name: (type_identifier) @name.definition.class) @definition.class
-
-; type aliases
-
-(type_item
-    name: (type_identifier) @name.definition.class) @definition.class
-
-; method definitions
-
-(declaration_list
-    (function_item
-        name: (identifier) @name.definition.method)) @definition.method
-
-; function definitions
-
-(function_item
-    name: (identifier) @name.definition.function) @definition.function
-
-; trait definitions
-(trait_item
-    name: (type_identifier) @name.definition.interface) @definition.interface
-
-; module definitions
-(mod_item
-    name: (identifier) @name.definition.module) @definition.module
-
-; macro definitions
-
-(macro_definition
-    name: (identifier) @name.definition.macro) @definition.macro
-
-; references
-
-(call_expression
-    function: (identifier) @name.reference.call) @reference.call
-
-(call_expression
-    function: (field_expression
-        field: (field_identifier) @name.reference.call)) @reference.call
-
-(macro_invocation
-    macro: (identifier) @name.reference.call) @reference.call
-
-; implementations
-
-(impl_item
-    trait: (type_identifier) @name.reference.implementation) @reference.implementation
-
-(impl_item
-    type: (type_identifier) @name.reference.implementation
-    !trait) @reference.implementation

package/bundle/assets/queries/tree-sitter-languages/scala-tags.scm

@@ -1,65 +0,0 @@
-; Definitions
-
-(package_clause
-  name: (package_identifier) @name.definition.module) @definition.module
-
-(trait_definition
-  name: (identifier) @name.definition.interface) @definition.interface
-
-(enum_definition
-  name: (identifier) @name.definition.enum) @definition.enum
-
-(simple_enum_case
-  name: (identifier) @name.definition.class) @definition.class
-
-(full_enum_case
-  name: (identifier) @name.definition.class) @definition.class
-
-(class_definition
-  name: (identifier) @name.definition.class) @definition.class
-
-(object_definition
-  name: (identifier) @name.definition.object) @definition.object
-
-(function_definition
-  name: (identifier) @name.definition.function) @definition.function
-
-(val_definition
-  pattern: (identifier) @name.definition.variable) @definition.variable
-
-(given_definition
-  name: (identifier) @name.definition.variable) @definition.variable
-
-(var_definition
-  pattern: (identifier) @name.definition.variable) @definition.variable
-
-(val_declaration
-  name: (identifier) @name.definition.variable) @definition.variable
-
-(var_declaration
-  name: (identifier) @name.definition.variable) @definition.variable
-
-(type_definition
-  name: (type_identifier) @name.definition.type) @definition.type
-
-(class_parameter
-  name: (identifier) @name.definition.property) @definition.property
-
-; References
-
-(call_expression
-  (identifier) @name.reference.call) @reference.call
-
-(instance_expression
-  (type_identifier) @name.reference.interface) @reference.interface
-
-(instance_expression
-  (generic_type
-    (type_identifier) @name.reference.interface)) @reference.interface
-
-(extends_clause
-  (type_identifier) @name.reference.class) @reference.class
-
-(extends_clause
-  (generic_type
-    (type_identifier) @name.reference.class)) @reference.class

package/bundle/assets/queries/tree-sitter-languages/typescript-tags.scm

@@ -1,41 +0,0 @@
-(function_signature
-  name: (identifier) @name.definition.function) @definition.function
-
-(method_signature
-  name: (property_identifier) @name.definition.method) @definition.method
-
-(abstract_method_signature
-  name: (property_identifier) @name.definition.method) @definition.method
-
-(abstract_class_declaration
-  name: (type_identifier) @name.definition.class) @definition.class
-
-(module
-  name: (identifier) @name.definition.module) @definition.module
-
-(interface_declaration
-  name: (type_identifier) @name.definition.interface) @definition.interface
-
-(type_annotation
-  (type_identifier) @name.reference.type) @reference.type
-
-(new_expression
-  constructor: (identifier) @name.reference.class) @reference.class
-
-(function_declaration
-  name: (identifier) @name.definition.function) @definition.function
-
-(method_definition
-  name: (property_identifier) @name.definition.method) @definition.method
-
-(class_declaration
-  name: (type_identifier) @name.definition.class) @definition.class
-
-(interface_declaration
-  name: (type_identifier) @name.definition.class) @definition.class
-
-(type_alias_declaration
-  name: (type_identifier) @name.definition.type) @definition.type
-
-(enum_declaration
-  name: (identifier) @name.definition.enum) @definition.enum