@simonklee/opentui-tex-native-source 0.2.0

package/native/vendor/microtex/CMakeLists.txt

@@ -0,0 +1,110 @@
+cmake_minimum_required(VERSION 3.16)
+
+set(CMAKE_CXX_STANDARD 17)
+set(CMAKE_CXX_STANDARD_REQUIRED ON)
+set(CMAKE_CXX_EXTENSIONS OFF)
+
+project(
+    microtex
+    VERSION 1.0.0
+    DESCRIPTION "A micro, fast, cross-platform, and embeddable LaTeX rendering library"
+)
+
+# the API (and ABI) is compatible when MICROTEX_API_VERSION is the same
+set(MICROTEX_API_VERSION 1)
+
+if (MSVC) # MSVC Compat
+    add_compile_options("/utf-8")
+    # make binaries together
+    set(CMAKE_LIBRARY_OUTPUT_DIRECTORY ${CMAKE_BINARY_DIR})
+    set(CMAKE_RUNTIME_OUTPUT_DIRECTORY ${CMAKE_BINARY_DIR})
+endif ()
+
+####################
+#  compile option  #
+####################
+option(CAIRO "Build with CAIRO" OFF)
+option(BUILD_EXAMPLE_GTKMM "Build GTKMM example, only work with -DCAIRO=ON flag" OFF)
+option(GTK "Build with GTK" OFF)
+option(BUILD_EXAMPLE_GTKMM "Build GTK example, only work with -DCAIRO=ON and -DGTK=ON flag" OFF)
+option(QT "Build with Qt" OFF)
+option(BUILD_EXAMPLE_QT "Build Qt example, only work with -DQT=ON flag" OFF)
+option(BUILD_EXAMPLE_QTPNG "Build Qt png example, only work with -DQT=ON flag" OFF)
+option(GDI "Build with GDI" OFF)
+option(BUILD_EXAMPLE_WIN32 "Build Win32 GDI example, only work with -DGDI=ON flag" OFF)
+option(BUILD_EXAMPLE_MEMCHECK "Build memory check example" OFF)
+option(HAVE_LOG "If enable log" ON)
+if (HAVE_LOG)
+    add_definitions(-DHAVE_LOG)
+endif ()
+option(BUILD_STATIC "If build for static library" OFF)
+if (BUILD_STATIC)
+    set(_BUILD_STATIC ON)
+endif ()
+
+include(MicroTeXInstall.cmake)
+
+add_subdirectory(lib)
+
+file(COPY res DESTINATION .)
+
+#####################
+# optional features #
+#####################
+if (CAIRO)
+    add_subdirectory(platform/cairo)
+    if (BUILD_EXAMPLE_GTKMM)
+        add_subdirectory(example/gtkmm)
+    endif ()
+endif ()
+
+if (GTK)
+    if (CAIRO)
+        add_subdirectory(platform/gtk)
+        if (BUILD_EXAMPLE_GTK)
+            add_subdirectory(example/gtk)
+        endif ()
+    else ()
+        message(FATAL_ERROR "The GTK Widget requires CAIRO to be enabled")
+    endif ()
+endif ()
+
+if (QT)
+    add_subdirectory(platform/qt)
+    if (BUILD_EXAMPLE_QT)
+        add_subdirectory(example/qt)
+    endif ()
+    if (BUILD_EXAMPLE_QTPNG)
+        add_subdirectory(example/qtpng)
+    endif ()
+endif ()
+
+if (SKIA)
+    add_subdirectory(platform/skia)
+endif ()
+
+if (GDI)
+    add_subdirectory(platform/gdi_win)
+    if (BUILD_EXAMPLE_WIN32)
+        add_subdirectory(example/win32)
+    endif ()
+endif ()
+
+if (WASM)
+    add_subdirectory(platform/wasm)
+endif ()
+
+if (BUILD_EXAMPLE_MEMCHECK)
+    add_subdirectory(example/memcheck)
+endif ()
+
+################
+# installation #
+################
+
+# install resources
+install(DIRECTORY res/ DESTINATION share/microtex)
+
+# install prebuilt scripts
+install(FILES prebuilt/otf2clm.py DESTINATION bin)
+install(PROGRAMS prebuilt/otf2clm.sh DESTINATION bin RENAME otf2clm)

package/native/vendor/microtex/LICENSE

@@ -0,0 +1,21 @@
+ The MIT License (MIT)
+
+ Copyright (c) 2020 Nano Michael
+
+ Permission is hereby granted, free of charge, to any person obtaining a copy
+ of this software and associated documentation files (the "Software"), to deal
+ in the Software without restriction, including without limitation the rights
+ to use, copy, modify, merge, publish, distribute, sublicense, and/or sell
+ copies of the Software, and to permit persons to whom the Software is
+ furnished to do so, subject to the following conditions:
+
+ The above copyright notice and this permission notice shall be included in all
+ copies or substantial portions of the Software.
+
+ THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS OR
+ IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF MERCHANTABILITY,
+ FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT. IN NO EVENT SHALL THE
+ AUTHORS OR COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER
+ LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE, ARISING FROM,
+ OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE USE OR OTHER DEALINGS IN THE
+ SOFTWARE.

package/native/vendor/microtex/MicroTeXInstall.cmake

@@ -0,0 +1,42 @@
+function(MICROTEX_INSTALL_HEADERS TARGET)
+    cmake_parse_arguments(H " " "PREFIX" "HEADERS" ${ARGN})
+    foreach (X IN ITEMS ${H_HEADERS})
+        if (H_PREFIX)
+            set(_DST "include/${TARGET}/${H_PREFIX}")
+        else ()
+            set(_DST "include/${TARGET}")
+        endif ()
+        install(FILES ${X} DESTINATION ${_DST})
+    endforeach ()
+endfunction()
+
+function(MICROTEX_INSTALL_TARGET TARGET)
+    install(
+        TARGETS ${TARGET}
+        EXPORT ${TARGET}Targets
+        LIBRARY DESTINATION lib
+        ARCHIVE DESTINATION lib
+        RUNTIME DESTINATION bin
+    )
+    include(CMakePackageConfigHelpers)
+    write_basic_package_version_file(
+        ${TARGET}ConfigVersion.cmake
+        VERSION ${PROJECT_VERSION}
+        COMPATIBILITY SameMajorVersion
+    )
+    install(
+        EXPORT ${TARGET}Targets
+        FILE ${TARGET}Targets.cmake
+        NAMESPACE microtex::
+        DESTINATION lib/cmake/${TARGET}
+    )
+    configure_file(${TARGET}Config.cmake.in ${TARGET}Config.cmake @ONLY)
+    install(
+        FILES
+        "${CMAKE_CURRENT_BINARY_DIR}/${TARGET}Config.cmake"
+        "${CMAKE_CURRENT_BINARY_DIR}/${TARGET}ConfigVersion.cmake"
+        DESTINATION lib/cmake/${TARGET}
+    )
+endfunction()
+
+set(_HAS_MICROTEX_INSTALL TRUE)