@shopify/react-native-skia 1.5.10 → 1.7.0

package/ios/RNSkia-iOS/SkiaMetalSurfaceFactory.h

@@ -1,128 +0,0 @@
-#pragma once
-
-#import <MetalKit/MetalKit.h>
-
-#include <memory>
-
-#include "RNSkLog.h"
-#include "WindowContext.h"
-
-#pragma clang diagnostic push
-#pragma clang diagnostic ignored "-Wdocumentation"
-
-#import "include/core/SkCanvas.h"
-#import "include/core/SkColorSpace.h"
-
-#import <CoreMedia/CMSampleBuffer.h>
-#import <CoreVideo/CVMetalTextureCache.h>
-
-#import <include/gpu/ganesh/GrBackendSurface.h>
-#import <include/gpu/ganesh/GrDirectContext.h>
-#import <include/gpu/ganesh/SkImageGanesh.h>
-#import <include/gpu/ganesh/SkSurfaceGanesh.h>
-#import <include/gpu/ganesh/mtl/GrMtlBackendContext.h>
-#import <include/gpu/ganesh/mtl/GrMtlBackendSurface.h>
-#import <include/gpu/ganesh/mtl/GrMtlDirectContext.h>
-#import <include/gpu/ganesh/mtl/SkSurfaceMetal.h>
-
-#pragma clang diagnostic pop
-
-using SkiaMetalContext = struct SkiaMetalContext {
-  id<MTLCommandQueue> commandQueue = nullptr;
-  sk_sp<GrDirectContext> skContext = nullptr;
-};
-
-class SkiaMetalSurfaceFactory {
-  friend class IOSSkiaContext;
-
-public:
-  static sk_sp<SkSurface> makeOffscreenSurface(id<MTLDevice> device,
-                                               SkiaMetalContext *context,
-                                               int width, int height);
-
-  static sk_sp<SkImage>
-  makeTextureFromCVPixelBuffer(SkiaMetalContext *context,
-                               CVPixelBufferRef pixelBuffer);
-
-  static std::unique_ptr<RNSkia::WindowContext>
-  makeContext(SkiaMetalContext *context, CALayer *texture, int width,
-              int height);
-};
-
-class IOSSkiaContext : public RNSkia::WindowContext {
-public:
-  IOSSkiaContext(SkiaMetalContext *context, CALayer *layer, int width,
-                 int height)
-      : _context(context) {
-#pragma clang diagnostic push
-#pragma clang diagnostic ignored "-Wunguarded-availability-new"
-    _layer = (CAMetalLayer *)layer;
-#pragma clang diagnostic pop
-    _layer.framebufferOnly = NO;
-    _layer.device = MTLCreateSystemDefaultDevice();
-    _layer.opaque = false;
-    _layer.contentsScale = [UIScreen mainScreen].scale;
-    _layer.pixelFormat = MTLPixelFormatBGRA8Unorm;
-    _layer.contentsGravity = kCAGravityBottomLeft;
-    _layer.drawableSize = CGSizeMake(width, height);
-  }
-
-  ~IOSSkiaContext() {}
-
-  sk_sp<SkSurface> getSurface() override {
-    if (_skSurface) {
-      return _skSurface;
-    }
-
-    // Get the next drawable from the CAMetalLayer
-    _currentDrawable = [_layer nextDrawable];
-    if (!_currentDrawable) {
-      RNSkia::RNSkLogger::logToConsole(
-          "Could not retrieve drawable from CAMetalLayer");
-      return nullptr;
-    }
-
-    // Get the texture from the drawable
-    GrMtlTextureInfo fbInfo;
-    fbInfo.fTexture.retain((__bridge void *)_currentDrawable.texture);
-
-    GrBackendRenderTarget backendRT = GrBackendRenderTargets::MakeMtl(
-        _layer.drawableSize.width, _layer.drawableSize.height, fbInfo);
-
-    _skSurface = SkSurfaces::WrapBackendRenderTarget(
-        _context->skContext.get(), backendRT, kTopLeft_GrSurfaceOrigin,
-        kBGRA_8888_SkColorType, nullptr, nullptr);
-
-    return _skSurface;
-  }
-
-  void present() override {
-    if (auto dContext = GrAsDirectContext(_skSurface->recordingContext())) {
-      dContext->flushAndSubmit();
-    }
-
-    id<MTLCommandBuffer> commandBuffer([_context->commandQueue commandBuffer]);
-    [commandBuffer presentDrawable:_currentDrawable];
-    [commandBuffer commit];
-    _skSurface = nullptr;
-  }
-
-  int getWidth() override {
-    return _layer.frame.size.width * _layer.contentsScale;
-  };
-
-  int getHeight() override {
-    return _layer.frame.size.height * _layer.contentsScale;
-  };
-
-  void resize(int width, int height) override { _skSurface = nullptr; }
-
-private:
-  SkiaMetalContext *_context;
-  sk_sp<SkSurface> _skSurface = nullptr;
-#pragma clang diagnostic push
-#pragma clang diagnostic ignored "-Wunguarded-availability-new"
-  CAMetalLayer *_layer;
-#pragma clang diagnostic pop
-  id<CAMetalDrawable> _currentDrawable = nil;
-};

package/ios/RNSkia-iOS/SkiaMetalSurfaceFactory.mm

@@ -1,92 +0,0 @@
-#import "RNSkLog.h"
-
-#import "SkiaCVPixelBufferUtils.h"
-#import "SkiaMetalSurfaceFactory.h"
-
-#pragma clang diagnostic push
-#pragma clang diagnostic ignored "-Wdocumentation"
-
-#import "include/core/SkCanvas.h"
-#import "include/core/SkColorSpace.h"
-#import "include/core/SkSurface.h"
-
-#import <include/gpu/ganesh/GrBackendSurface.h>
-#import <include/gpu/ganesh/GrDirectContext.h>
-#import <include/gpu/ganesh/SkImageGanesh.h>
-#import <include/gpu/ganesh/SkSurfaceGanesh.h>
-#import <include/gpu/ganesh/mtl/GrMtlBackendContext.h>
-#import <include/gpu/ganesh/mtl/GrMtlBackendSurface.h>
-#import <include/gpu/ganesh/mtl/GrMtlDirectContext.h>
-#import <include/gpu/ganesh/mtl/SkSurfaceMetal.h>
-
-#pragma clang diagnostic pop
-
-struct OffscreenRenderContext {
-  id<MTLTexture> texture;
-
-  OffscreenRenderContext(id<MTLDevice> device,
-                         sk_sp<GrDirectContext> skiaContext,
-                         id<MTLCommandQueue> commandQueue, int width,
-                         int height) {
-    // Create a Metal texture descriptor
-    MTLTextureDescriptor *textureDescriptor = [MTLTextureDescriptor
-        texture2DDescriptorWithPixelFormat:MTLPixelFormatBGRA8Unorm
-                                     width:width
-                                    height:height
-                                 mipmapped:NO];
-    textureDescriptor.usage =
-        MTLTextureUsageRenderTarget | MTLTextureUsageShaderRead;
-    texture = [device newTextureWithDescriptor:textureDescriptor];
-  }
-};
-
-std::unique_ptr<RNSkia::WindowContext>
-SkiaMetalSurfaceFactory::makeContext(SkiaMetalContext *context,
-                                     CALayer *texture, int width, int height) {
-  return std::make_unique<IOSSkiaContext>(context, texture, width, height);
-}
-
-sk_sp<SkSurface> SkiaMetalSurfaceFactory::makeOffscreenSurface(
-    id<MTLDevice> device, SkiaMetalContext *context, int width, int height) {
-
-  auto ctx = new OffscreenRenderContext(device, context->skContext,
-                                        context->commandQueue, width, height);
-
-  // Create a GrBackendTexture from the Metal texture
-  GrMtlTextureInfo info;
-  info.fTexture.retain((__bridge void *)ctx->texture);
-  GrBackendTexture backendTexture =
-      GrBackendTextures::MakeMtl(width, height, skgpu::Mipmapped::kNo, info);
-
-  // Create a SkSurface from the GrBackendTexture
-  auto surface = SkSurfaces::WrapBackendTexture(
-      context->skContext.get(), backendTexture, kTopLeft_GrSurfaceOrigin, 0,
-      kBGRA_8888_SkColorType, nullptr, nullptr,
-      [](void *addr) { delete (OffscreenRenderContext *)addr; }, ctx);
-
-  return surface;
-}
-
-sk_sp<SkImage> SkiaMetalSurfaceFactory::makeTextureFromCVPixelBuffer(
-    SkiaMetalContext *context, CVPixelBufferRef pixelBuffer) {
-  SkiaCVPixelBufferUtils::CVPixelBufferBaseFormat format =
-      SkiaCVPixelBufferUtils::getCVPixelBufferBaseFormat(pixelBuffer);
-  switch (format) {
-  case SkiaCVPixelBufferUtils::CVPixelBufferBaseFormat::rgb: {
-    // CVPixelBuffer is in any RGB format, single-plane
-    return SkiaCVPixelBufferUtils::RGB::makeSkImageFromCVPixelBuffer(
-        context->skContext.get(), pixelBuffer);
-  }
-  case SkiaCVPixelBufferUtils::CVPixelBufferBaseFormat::yuv: {
-    // CVPixelBuffer is in any YUV format, multi-plane
-    return SkiaCVPixelBufferUtils::YUV::makeSkImageFromCVPixelBuffer(
-        context->skContext.get(), pixelBuffer);
-  }
-  default:
-    [[unlikely]] {
-      throw std::runtime_error("Failed to convert NativeBuffer to SkImage - "
-                               "NativeBuffer has unsupported PixelFormat! " +
-                               std::to_string(static_cast<int>(format)));
-    }
-  }
-}