@sebastienrousseau/dotfiles 0.2.502 → 0.2.504

package/dot_config/zsh/rc.d/00-alias-shims.zsh

@@ -1,99 +0,0 @@
-# shellcheck shell=bash
-# Cognitive Shell Enhancements
-#
-# Carapace is deferred to first `preexec` (closes #862). The eager
-# `_cached_eval carapace ...` call previously cost ~15ms on every
-# interactive shell start even with the cache warm — that work is
-# only needed when the user invokes tab-completion, which happens
-# after the first command at the earliest. Opt out by setting
-# `DOTFILES_DEFER_CARAPACE=0` (rarely useful).
-if [[ -o interactive ]]; then
-  : ${DOTFILES_DEFER_CARAPACE:=1}
-
-  _dotfiles_carapace_init() {
-    if command -v carapace >/dev/null 2>&1; then
-      if typeset -f _cached_eval >/dev/null 2>&1; then
-        _cached_eval carapace carapace _carapace zsh
-      else
-        source <(carapace _zsh)
-      fi
-    fi
-  }
-
-  if [[ "${DOTFILES_DEFER_CARAPACE}" == "1" ]] && typeset -f _dotfiles_add_preexec >/dev/null 2>&1; then
-    _dotfiles_carapace_deferred() {
-      _dotfiles_del_preexec _dotfiles_carapace_deferred
-      _dotfiles_carapace_init
-    }
-    _dotfiles_add_preexec _dotfiles_carapace_deferred
-  else
-    # Fallback to eager init when preexec helpers aren't available
-    # (e.g., DOTFILES_FAST=1 paths that skip the zshrc helper block).
-    _dotfiles_carapace_init
-  fi
-
-  # thefuck — lazy-loaded to avoid ~200ms startup penalty
-  if command -v thefuck >/dev/null 2>&1; then
-    _lazy_load_thefuck() {
-      unset -f fuck _lazy_load_thefuck 2>/dev/null
-      _cached_eval "thefuck-alias" thefuck --alias
-    }
-    fuck() { _lazy_load_thefuck; fuck "$@"; }
-    alias fix='fuck'
-  fi
-fi
-
-# Fallback command shims for environments with aliases disabled.
-# These are lightweight functions to ensure core shortcuts still work.
-
-# Opt-out with: export DOTFILES_ALIAS_SHIMS=0
-if [[ "${DOTFILES_ALIAS_SHIMS:-1}" != "1" ]]; then
-  return 0
-fi
-
-# Avoid redefining if already present.
-if ! typeset -f c >/dev/null 2>&1; then
-  c() { clear; }
-fi
-if ! typeset -f q >/dev/null 2>&1; then
-  q() { exit; }
-fi
-if ! typeset -f e >/dev/null 2>&1; then
-  e() { "${EDITOR:-nano}" "$@"; }
-fi
-if ! typeset -f h >/dev/null 2>&1; then
-  h() { history; }
-fi
-if ! typeset -f l >/dev/null 2>&1; then
-  l() { command -v eza >/dev/null 2>&1 && eza --sort Name --icons --group-directories-first "$@" || command ls "$@"; }
-fi
-if ! typeset -f ll >/dev/null 2>&1; then
-  ll() { command -v eza >/dev/null 2>&1 && eza -alF --sort Name --icons --group-directories-first "$@" || command ls -lA "$@"; }
-fi
-if ! typeset -f la >/dev/null 2>&1; then
-  la() { command -v eza >/dev/null 2>&1 && eza -a --sort Name --icons --group-directories-first "$@" || command ls -a "$@"; }
-fi
-if ! typeset -f lt >/dev/null 2>&1; then
-  lt() { command -v eza >/dev/null 2>&1 && eza -aT --sort Name --icons --group-directories-first "$@" || command ls -R "$@"; }
-fi
-if ! typeset -f lr >/dev/null 2>&1; then
-  lr() { command -v eza >/dev/null 2>&1 && eza -alF --recurse --sort Name --icons --group-directories-first "$@" || command ls -lAR "$@"; }
-fi
-if ! typeset -f lra >/dev/null 2>&1; then
-  lra() { command -v eza >/dev/null 2>&1 && eza -alF --recurse --all --sort Name --icons --group-directories-first "$@" || command ls -lAR "$@"; }
-fi
-if ! typeset -f lta >/dev/null 2>&1; then
-  lta() { command -v eza >/dev/null 2>&1 && eza -aT --all --sort Name --icons --group-directories-first "$@" || command ls -aR "$@"; }
-fi
-if ! typeset -f d >/dev/null 2>&1; then
-  d() { command -v dot >/dev/null 2>&1 && dot "$@" || command -v docker >/dev/null 2>&1 && docker "$@"; }
-fi
-if ! typeset -f i >/dev/null 2>&1; then
-  i() { command -v epoch >/dev/null 2>&1 && epoch "$@"; }
-fi
-if ! typeset -f a >/dev/null 2>&1; then
-  a() { command -v ai_core >/dev/null 2>&1 && ai_core query "$@"; }
-fi
-if ! typeset -f _ >/dev/null 2>&1; then
-  _() { sudo "$@"; }
-fi

package/dot_config/zsh/rc.d/05-ssh-agent.zsh

@@ -1,18 +0,0 @@
-# YubiKey FIDO2/U2F security key helper
-if [[ -x /usr/lib/ssh/ssh-sk-helper ]]; then
-  export SSH_SK_HELPER=/usr/lib/ssh/ssh-sk-helper
-fi
-
-# SSH agent: auto-start if no agent is running (interactive only)
-if [[ -o interactive ]] && [[ -z "$SSH_AUTH_SOCK" ]]; then
-  eval "$(ssh-agent -s)" >/dev/null 2>&1
-
-  # Add default key with timeout guard (2s max) to prevent startup hangs
-  if [[ -f ~/.ssh/id_ed25519 ]]; then
-    if [[ "$OSTYPE" == darwin* ]]; then
-      timeout 2 ssh-add --apple-use-keychain ~/.ssh/id_ed25519 2>/dev/null || true
-    else
-      timeout 2 ssh-add ~/.ssh/id_ed25519 2>/dev/null || true
-    fi
-  fi
-fi

package/dot_config/zsh/rc.d/10-env.zsh.tmpl

@@ -1,28 +0,0 @@
-# Environment and core variables
-export HOSTNAME="${HOST}"
-export INPUTRC="${HOME}/.inputrc"
-export OS_ARCH='{{ output "uname" "-m" | trim }}'
-export OS_NAME='{{ output "uname" | trim }}'
-export OS_VERSION='{{ output "uname" "-r" | trim }}'
-export USER_LANGUAGE="en_GB.UTF-8"
-export ARCHFLAGS="-arch ${OS_ARCH}"
-export DOTFILES_VERSION='{{ .dotfiles_version }}'
-export DOTFILES="${HOME}/.dotfiles/lib"
-export LANG="${USER_LANGUAGE}"
-export LANGUAGE="${USER_LANGUAGE}"
-export LC_ALL="${USER_LANGUAGE}"
-export LC_CTYPE="${USER_LANGUAGE}"
-export TERM="xterm-256color"
-
-# fnm multishell path for environments without /run/user/... access
-if [[ -z "${XDG_RUNTIME_DIR:-}" ]]; then
-  export XDG_RUNTIME_DIR="${XDG_STATE_HOME:-$HOME/.local/state}/run"
-fi
-if [[ ! -d "${XDG_RUNTIME_DIR}" ]]; then
-  mkdir -p "${XDG_RUNTIME_DIR}" 2>/dev/null || true
-fi
-
-export FNM_MULTISHELL_PATH="${FNM_MULTISHELL_PATH:-${XDG_RUNTIME_DIR}/fnm_multishells}"
-if [[ ! -d "${FNM_MULTISHELL_PATH}" ]]; then
-  mkdir -p "${FNM_MULTISHELL_PATH}" 2>/dev/null || true
-fi

package/dot_config/zsh/rc.d/20-zinit.zsh

@@ -1,65 +0,0 @@
-# Zinit plugin manager
-[[ "${DOTFILES_FAST:-0}" == "1" ]] && return 0
-[[ "${DOTFILES_ULTRA_FAST:-0}" == "1" ]] && return 0
-
-ZINIT_HOME="${XDG_DATA_HOME:-${HOME}/.local/share}/zinit/zinit.git"
-
-_dotfiles_zinit_git_policy() {
-  [[ -d "$ZINIT_HOME/.git" ]] || return 0
-  command git -C "$ZINIT_HOME" config --local merge.verifySignatures false >/dev/null 2>&1 || true
-}
-
-_dotfiles_zinit_init() {
-  if [[ ! -f "$ZINIT_HOME/zinit.zsh" ]]; then
-     print -P "%F{33}▓▒░ %F{220}Installing %F{33}ZDHARMA-CONTINUUM%F{220} Initiative Plugin Manager (%F{33}zdharma-continuum/zinit%F{220})…%f"
-     command mkdir -p "$(dirname "$ZINIT_HOME")" && command chmod g-rwX "$(dirname "$ZINIT_HOME")"
-     command git clone https://github.com/zdharma-continuum/zinit "$ZINIT_HOME" && \
-        print -P "%F{33}▓▒░ %F{34}Installation successful.%f%b" || \
-        print -P "%F{160}▓▒░ The clone has failed.%f%b"
-  fi
-
-  _dotfiles_zinit_git_policy
-
-  source "$ZINIT_HOME/zinit.zsh"
-  autoload -Uz _zinit
-  (( ${+_comps} )) && _comps[zinit]=_zinit
-
-  # Load Zsh Plugins (Turbo mode - deferred loading, pinned to stable releases)
-  zinit ice wait lucid ver"0.8.0"
-  zinit light zsh-users/zsh-syntax-highlighting
-  zinit ice wait lucid ver"v0.7.1" atload"_zsh_autosuggest_start"
-  zinit light zsh-users/zsh-autosuggestions
-  zinit ice wait lucid ver"0.35.0" blockf atpull"zinit creinstall -q ."
-  zinit light zsh-users/zsh-completions
-}
-
-# Defer Zinit init for faster first prompt (opt-out by setting DOTFILES_DEFER_ZINIT=0)
-: ${DOTFILES_DEFER_ZINIT:=1}
-: ${DOTFILES_DEFER_ZINIT_MODE:=preexec}
-
-if [[ "${DOTFILES_DEFER_ZINIT}" == "1" ]]; then
-  # Stub to auto-load zinit on first call (e.g. by topgrade)
-  zinit() {
-    unfunction zinit
-    _dotfiles_zinit_init
-    zinit "$@"
-  }
-
-  _dotfiles_zinit_deferred() {
-    if [[ "${DOTFILES_DEFER_ZINIT_MODE}" == "preexec" ]]; then
-      _dotfiles_del_preexec _dotfiles_zinit_deferred
-    else
-      _dotfiles_del_precmd _dotfiles_zinit_deferred
-    fi
-    # If zinit was already loaded via the stub, this is a no-op
-    (( ${+functions[zinit]} )) && [[ "$(whence -w zinit)" == "zinit: function" ]] || _dotfiles_zinit_init
-  }
-
-  if [[ "${DOTFILES_DEFER_ZINIT_MODE}" == "preexec" ]]; then
-    _dotfiles_add_preexec _dotfiles_zinit_deferred
-  else
-    _dotfiles_add_precmd _dotfiles_zinit_deferred
-  fi
-else
-  _dotfiles_zinit_init
-fi

package/dot_config/zsh/rc.d/30-options.zsh.tmpl

@@ -1,214 +0,0 @@
-# Zsh history and options
-HISTFILE="${HOME}/.zsh_history"
-HISTSIZE=10000
-SAVEHIST=10000
-setopt HIST_IGNORE_ALL_DUPS
-setopt HIST_SAVE_NO_DUPS
-setopt HIST_EXPIRE_DUPS_FIRST
-setopt HIST_FIND_NO_DUPS
-setopt HIST_IGNORE_SPACE
-setopt HIST_REDUCE_BLANKS
-setopt EXTENDED_HISTORY
-setopt SHARE_HISTORY
-setopt APPEND_HISTORY
-setopt HIST_SAVE_BY_COPY
-setopt INTERACTIVE_COMMENTS
-
-setopt AUTO_CD
-setopt AUTO_PUSHD
-setopt PUSHD_IGNORE_DUPS
-setopt PUSHD_SILENT
-setopt NO_BEEP
-
-bindkey -v
-
-# Fix: prevent auto-indent when pasting multi-line content (vi mode)
-autoload -Uz bracketed-paste-magic
-zle -N bracketed-paste bracketed-paste-magic
-
-autoload -Uz up-line-or-beginning-search down-line-or-beginning-search
-zle -N up-line-or-beginning-search
-zle -N down-line-or-beginning-search
-bindkey -M viins "^[[A" up-line-or-beginning-search
-bindkey -M viins "^[[B" down-line-or-beginning-search
-bindkey -M viins "^P" up-line-or-beginning-search
-bindkey -M viins "^N" down-line-or-beginning-search
-
-ZSH_COMPLETIONS_DIR="${XDG_DATA_HOME:-${HOME}/.local/share}/zsh/completions"
-if [[ ! -d "${ZSH_COMPLETIONS_DIR}" ]]; then
-  command mkdir -p "${ZSH_COMPLETIONS_DIR}"
-fi
-if [[ -z ${fpath[(r)${ZSH_COMPLETIONS_DIR}]} ]]; then
-  fpath=("${ZSH_COMPLETIONS_DIR}" "${fpath[@]}")
-fi
-{{- /* Node.js version manager: configured via .chezmoidata.toml tools.node_manager */ -}}
-{{- $node_mgr := default "mise" .tools.node_manager -}}
-{{- if eq $node_mgr "fnm" }}
-# fnm (Fast Node Manager)
-# Initialize early so Node + corepack use the expected version.
-if [[ "${DOTFILES_FAST:-0}" != "1" ]] && [[ "${DOTFILES_ULTRA_FAST:-0}" != "1" ]] && command -v fnm >/dev/null; then
-  if [[ ! -f "${ZSH_COMPLETIONS_DIR}/_fnm" ]]; then
-    command fnm completions --shell zsh >| "${ZSH_COMPLETIONS_DIR}/_fnm"
-  fi
-  _lazy_load_fnm() {
-    unfunction node npm npx pnpm pnpx fnm _lazy_load_fnm 2>/dev/null
-    eval "$(command fnm env --use-on-cd --shell zsh --log-level quiet)"
-  }
-  fnm() { _lazy_load_fnm; command fnm "$@"; }
-  node() { _lazy_load_fnm; command node "$@"; }
-  npm() { _lazy_load_fnm; command npm "$@"; }
-  npx() { _lazy_load_fnm; command npx "$@"; }
-  pnpm() { _lazy_load_fnm; command pnpm "$@"; }
-  pnpx() { _lazy_load_fnm; command pnpx "$@"; }
-fi
-{{- end }}
-{{- /* When node_manager = "mise", Node.js is handled by mise activate in dot_zshrc.tmpl */}}
-
-# Completions: generated on-demand on first interactive shell and cached
-if [[ "${DOTFILES_FAST:-0}" != "1" ]] && [[ "${DOTFILES_ULTRA_FAST:-0}" != "1" ]]; then
-  [[ ! -f "${ZSH_COMPLETIONS_DIR}/_gh" ]] && command -v gh >/dev/null &&
-    command gh completion -s zsh >| "${ZSH_COMPLETIONS_DIR}/_gh"
-  [[ ! -f "${ZSH_COMPLETIONS_DIR}/_just" ]] && command -v just >/dev/null &&
-    command just --completions zsh >| "${ZSH_COMPLETIONS_DIR}/_just"
-  [[ ! -f "${ZSH_COMPLETIONS_DIR}/_chezmoi" ]] && command -v chezmoi >/dev/null &&
-    command chezmoi completion zsh >| "${ZSH_COMPLETIONS_DIR}/_chezmoi"
-  [[ ! -f "${ZSH_COMPLETIONS_DIR}/_kubectl" ]] && command -v kubectl >/dev/null &&
-    command kubectl completion zsh >| "${ZSH_COMPLETIONS_DIR}/_kubectl"
-  [[ ! -f "${ZSH_COMPLETIONS_DIR}/_atuin" ]] && command -v atuin >/dev/null &&
-    command atuin gen-completions --shell zsh --out-dir "${ZSH_COMPLETIONS_DIR}" 2>/dev/null
-  [[ ! -f "${ZSH_COMPLETIONS_DIR}/_mise" ]] && command -v mise >/dev/null &&
-    command mise completions zsh >| "${ZSH_COMPLETIONS_DIR}/_mise" 2>/dev/null
-fi
-
-{{- if eq $node_mgr "nvm" }}
-# Lazy-load NVM
-export NVM_DIR="${NVM_DIR:-$HOME/.nvm}"
-if [[ "${DOTFILES_FAST:-0}" != "1" ]] && [[ "${DOTFILES_ULTRA_FAST:-0}" != "1" ]]; then
-  if [[ -s "${NVM_DIR}/nvm.sh" ]]; then
-    _lazy_load_nvm() {
-      unfunction node npm npx nvm _lazy_load_nvm 2>/dev/null
-      # shellcheck disable=SC1090
-      . "${NVM_DIR}/nvm.sh"
-      if [[ -s "${NVM_DIR}/bash_completion" ]]; then
-        # shellcheck disable=SC1090
-        . "${NVM_DIR}/bash_completion"
-      fi
-    }
-    nvm() { _lazy_load_nvm; nvm "$@"; }
-    node() { _lazy_load_nvm; command node "$@"; }
-    npm() { _lazy_load_nvm; command npm "$@"; }
-    npx() { _lazy_load_nvm; command npx "$@"; }
-  fi
-fi
-{{- end }}
-
-# Lazy-load SDKMAN
-export SDKMAN_DIR="${SDKMAN_DIR:-$HOME/.sdkman}"
-if [[ "${DOTFILES_FAST:-0}" != "1" ]] && [[ "${DOTFILES_ULTRA_FAST:-0}" != "1" ]] && [[ -s "${SDKMAN_DIR}/bin/sdkman-init.sh" && -z "${functions[sdk]:-}" ]]; then
-  _lazy_load_sdkman() {
-    unfunction sdk _lazy_load_sdkman 2>/dev/null
-    # shellcheck disable=SC1090
-    . "${SDKMAN_DIR}/bin/sdkman-init.sh"
-  }
-  sdk() { _lazy_load_sdkman; sdk "$@"; }
-fi
-# Defer compinit to first prompt — opt-in for max performance.
-#
-# Cache lifecycle (closes #864):
-#   * dump path lives at $XDG_CACHE_HOME/zsh/zcompdump-$ZSH_VERSION so
-#     the user-state directory is clean (and zsh's own search picks up
-#     `.zwc` siblings automatically — non-laptop profiles get the
-#     benefit even without re-running compinit).
-#   * `compinit -C` (skip security-check, use the cached dump) is used
-#     when the dump is fresh (< 24 h); full `compinit` rebuilds when
-#     the dump is older.
-#   * The dump is `zcompile`d in the background after each rebuild so
-#     subsequent shells load the bytecode form directly.
-#   * The fpath corpus itself is precompiled at chezmoi-apply time by
-#     `run_onchange_after_zcompile-completions.sh.tmpl` — that runs
-#     once per fpath change, not per shell start.
-: ${DOTFILES_ENABLE_COMPINIT:=0}
-: ${DOTFILES_DEFER_COMPINIT:=1}
-
-_DOTFILES_ZCOMPDUMP="${XDG_CACHE_HOME:-${HOME}/.cache}/zsh/zcompdump-${ZSH_VERSION:-${ZSH_NAME:-unknown}}"
-
-if [[ "${DOTFILES_ENABLE_COMPINIT}" == "1" ]] && [[ "${DOTFILES_FAST:-0}" != "1" ]] && [[ "${DOTFILES_ULTRA_FAST:-0}" != "1" ]]; then
-  autoload -Uz compinit
-  [[ -d "${_DOTFILES_ZCOMPDUMP:h}" ]] || mkdir -p "${_DOTFILES_ZCOMPDUMP:h}"
-
-  _deferred_compinit() {
-    if [[ "${DOTFILES_DEFER_COMPINIT}" == "1" ]]; then
-      _dotfiles_del_preexec _deferred_compinit
-    else
-      _dotfiles_del_precmd _deferred_compinit
-    fi
-    # Fresh dump (< 24 h) → use cached fast path; otherwise rebuild.
-    if [[ -n ${_DOTFILES_ZCOMPDUMP}(#qN.mh+24) ]]; then
-      compinit -d "${_DOTFILES_ZCOMPDUMP}"
-    else
-      compinit -C -d "${_DOTFILES_ZCOMPDUMP}"
-    fi
-    # Compile to bytecode in background for faster subsequent loads
-    { [[ ! -f "${_DOTFILES_ZCOMPDUMP}.zwc" || "${_DOTFILES_ZCOMPDUMP}" -nt "${_DOTFILES_ZCOMPDUMP}.zwc" ]] && zcompile "${_DOTFILES_ZCOMPDUMP}" } &!
-  }
-  if [[ "${DOTFILES_DEFER_COMPINIT}" == "1" ]]; then
-    _dotfiles_add_preexec _deferred_compinit
-  else
-    _dotfiles_add_precmd _deferred_compinit
-  fi
-
-  zstyle ':completion:*' menu select
-  zstyle ':completion:*' matcher-list 'm:{a-zA-Z}={A-Za-z}'
-  zstyle ':completion:*' list-colors "${(s.:.)LS_COLORS}"
-  zstyle ':completion:*' special-dirs true
-  zstyle ':completion:*' verbose yes
-fi
-
-# Colors (opt-in; enables $fg/$bg variables)
-: ${DOTFILES_ENABLE_COLORS:=0}
-if [[ "${DOTFILES_ENABLE_COLORS}" == "1" ]]; then
-  : ${DOTFILES_DEFER_COLORS:=1}
-  if [[ "${DOTFILES_DEFER_COLORS}" == "1" ]]; then
-    _dotfiles_colors_zle_init() {
-      zle -D zle-line-init
-      # Skip when running -c (no prompt)
-      [[ -n "${ZSH_EXECUTION_STRING:-}" ]] && return 0
-      autoload -Uz colors && colors
-    }
-    zle -N zle-line-init _dotfiles_colors_zle_init
-  else
-    autoload -Uz colors && colors
-  fi
-fi
-unsetopt correct_all
-
-# fzf integration
-if [[ "${DOTFILES_FAST:-0}" != "1" ]] && [[ "${DOTFILES_ULTRA_FAST:-0}" != "1" ]]; then
-  if [[ -f "${HOME}/.config/fzf/fzf.zsh" ]]; then
-    source "${HOME}/.config/fzf/fzf.zsh"
-  elif [[ -f "${HOME}/.fzf.zsh" ]]; then
-    source "${HOME}/.fzf.zsh"
-  fi
-fi
-
-# Explicit fzf bindings (fallback if not already set by fzf)
-if [[ "${DOTFILES_FAST:-0}" != "1" ]] && [[ "${DOTFILES_ULTRA_FAST:-0}" != "1" ]] && command -v fzf >/dev/null; then
-  bindkey -M viins -s '^T' 'fzf^M'
-  bindkey -M viins -s '^R' 'fzf^M'
-fi
-
-# direnv (directory environments)
-if [[ "${DOTFILES_FAST:-0}" != "1" ]] && [[ "${DOTFILES_ULTRA_FAST:-0}" != "1" ]] && command -v direnv >/dev/null; then
-  # Custom quiet hook: suppress direnv status chatter on every prompt/chdir.
-  _dotfiles_direnv_hook() {
-    # Fast path: skip direnv in dotfiles unless flake mode is explicitly enabled.
-    if [[ "${PWD:A}" == "${HOME}/.dotfiles"* ]] && [[ "${DOTFILES_USE_FLAKE:-0}" != "1" ]] && [[ "${CI:-0}" != "1" ]]; then
-      return 0
-    fi
-    trap -- '' SIGINT
-    eval "$(direnv export zsh 2>/dev/null)"
-    trap - SIGINT
-  }
-  autoload -Uz add-zsh-hook
-  add-zsh-hook chpwd _dotfiles_direnv_hook
-fi

package/dot_config/zsh/rc.d/40-bell.zsh

@@ -1,20 +0,0 @@
-# Terminal bell (sound + visual)
-
-: ${DOTFILES_BELL_SOUND:=1}
-: ${DOTFILES_BELL_VISUAL:=1}
-
-if [[ "$DOTFILES_BELL_SOUND" == "1" ]]; then
-  unsetopt NO_BEEP
-  setopt BEEP
-else
-  setopt NO_BEEP
-fi
-
-# Some zsh builds don't include visualbell; guard to avoid startup errors.
-if (( $+options[visualbell] )); then
-  if [[ "$DOTFILES_BELL_VISUAL" == "1" ]]; then
-    setopt VISUALBELL
-  else
-    unsetopt VISUALBELL
-  fi
-fi

package/dot_config/zsh/rc.d/50-login-fortune.zsh

@@ -1,9 +0,0 @@
-# Login fortune (cowsay)
-
-: ${DOTFILES_LOGIN_FORTUNE:=1}
-
-if [[ -o login ]] && [[ "$DOTFILES_LOGIN_FORTUNE" == "1" ]]; then
-  if command -v fortune >/dev/null && command -v cowsay >/dev/null; then
-    fortune | cowsay
-  fi
-fi

package/dot_config/zsh/rc.d/99-alias-wrapper.zsh

@@ -1,32 +0,0 @@
-# Smart Alias Function (High-Fidelity TUI)
-alias_wrapper() {
-  if [[ $# -eq 0 ]]; then
-    # Find gum cmd dynamically if needed
-    local gum_cmd
-    gum_cmd=$(command -v gum 2>/dev/null || (command -v mise >/dev/null && mise which "aqua:charmbracelet/gum" 2>/dev/null))
-
-    if [[ -n "$gum_cmd" ]]; then
-      # Use printf to get a literal tab
-      local tab=$'\t'
-
-      # Extract aliases, format as Tab separated, ensure only 2 columns, and pipe to gum table
-      builtin alias | sed -E "s/^([^=]+)='?([^']*)'?$/\1${tab}\2/" |
-        while IFS=$tab read -r alias_name cmd_body; do
-          if [[ -n "$alias_name" && -n "$cmd_body" ]]; then
-            # Ensure no extra tabs in body and exactly one tab total
-            local clean_cmd="${cmd_body//$tab/ }"
-            printf "%s\t%s\n" "$alias_name" "$clean_cmd"
-          fi
-        done |
-        "$gum_cmd" table --separator "${tab}" --print --columns "Alias,Command" --widths 15,60 \
-          --border rounded --border.foreground 212 --header.foreground 212
-    elif command -v bat >/dev/null 2>&1; then
-      builtin alias | bat -l sh --style=plain
-    else
-      builtin alias
-    fi
-  else
-    builtin alias "$@"
-  fi
-}
-alias alias=alias_wrapper