@sasjs/utils 2.49.0 → 2.49.2

package/macros/mf_nobs.sas

@@ -0,0 +1,26 @@
+/**
+  @file
+  @brief Returns number of logical (undeleted) observations.
+  @details Beware - will not work on external database tables!
+  Is just a convenience macro for calling <code> %mf_getattrn()</code>.
+
+        %put Number of observations=%mf_nobs(sashelp.class);
+
+  <h4> SAS Macros </h4>
+  @li mf_getattrn.sas
+
+  @param libds library.dataset
+
+  @return output returns result of the attrn value supplied, or log message
+    if err.
+
+
+  @version 9.2
+  @author Allan Bowe
+
+**/
+
+%macro mf_nobs(libds
+)/*/STORE SOURCE*/;
+  %mf_getattrn(&libds,NLOBS)
+%mend mf_nobs;

package/macros/mf_trimstr.sas

@@ -0,0 +1,50 @@
+/**
+  @file mf_trimstr.sas
+  @brief Removes character(s) from the end, if they exist
+  @details If the designated characters exist at the end of the string, they
+  are removed
+
+        %put %mf_trimstr(/blah/,/); * /blah;
+        %put %mf_trimstr(/blah/,h); * /blah/;
+        %put %mf_trimstr(/blah/,h/);* /bla;
+
+  <h4> SAS Macros </h4>
+
+
+  @param basestr The string to be modified
+  @param trimstr The string to be removed from the end of `basestr`, if it
+    exists
+
+  @return output returns result with the value of `trimstr` removed from the end
+
+
+  @version 9.2
+  @author Allan Bowe
+
+**/
+
+%macro mf_trimstr(basestr,trimstr);
+%local baselen trimlen trimval;
+
+/* return if basestr is shorter than trimstr (or 0) */
+%let baselen=%length(%superq(basestr));
+%let trimlen=%length(%superq(trimstr));
+%if &baselen < &trimlen or &baselen=0 %then %return;
+
+/* obtain the characters from the end of basestr */
+%let trimval=%qsubstr(%superq(basestr)
+  ,%length(%superq(basestr))-&trimlen+1
+  ,&trimlen);
+
+/* compare and if matching, chop it off! */
+%if %superq(basestr)=%superq(trimstr) %then %do;
+  %return;
+%end;
+%else %if %superq(trimval)=%superq(trimstr) %then %do;
+  %qsubstr(%superq(basestr),1,%length(%superq(basestr))-&trimlen)
+%end;
+%else %do;
+  &basestr
+%end;
+
+%mend mf_trimstr;

package/macros/mf_uid.sas

@@ -0,0 +1,21 @@
+/**
+  @file
+  @brief Creates a unique ID based on system time in friendly format
+  @details format = YYYYMMDD_HHMMSSmmm_<sysjobid>_<3randomDigits>
+
+        %put %mf_uid();
+
+  @version 9.3
+  @author Allan Bowe
+
+**/
+
+%macro mf_uid(
+)/*/STORE SOURCE*/;
+  %local today now;
+  %let today=%sysfunc(today(),yymmddn8.);
+  %let now=%sysfunc(compress(%sysfunc(time(),tod12.3),:.));
+
+  &today._&now._&sysjobid._%sysevalf(%sysfunc(ranuni(0))*999,CEIL)
+
+%mend mf_uid;

package/macros/mf_verifymacvars.sas

@@ -0,0 +1,72 @@
+/**
+  @file
+  @brief Checks if a set of macro variables exist AND contain values.
+  @details Writes ERROR to log if abortType is SOFT, else will call %mf_abort.
+  Usage:
+
+      %let var1=x;
+      %let var2=y;
+      %put %mf_verifymacvars(var1 var2);
+
+  Returns:
+  > 1
+
+  <h4> SAS Macros </h4>
+  @li mf_abort.sas
+
+  @param [in] verifyvars Space separated list of macro variable names
+  @param [in] makeupcase= (NO) Set to YES to convert all variable VALUES to
+    uppercase.
+  @param [in] mAbort= (SOFT) Abort Type.  When SOFT, simply writes an err
+    message to the log.
+    Set to any other value to call mf_abort (which can be configured to abort in
+    various fashions according to context).
+
+  @warning will not be able to verify the following variables due to
+    naming clash!
+      - verifyVars
+      - verifyVar
+      - verifyIterator
+      - makeUpcase
+
+  @version 9.2
+  @author Allan Bowe
+
+**/
+
+
+%macro mf_verifymacvars(
+    verifyVars  /* list of macro variable NAMES */
+    ,makeUpcase=NO  /* set to YES to make all the variable VALUES uppercase */
+    ,mAbort=SOFT
+)/*/STORE SOURCE*/;
+
+  %local verifyIterator verifyVar abortmsg;
+  %do verifyIterator=1 %to %sysfunc(countw(&verifyVars,%str( )));
+    %let verifyVar=%qscan(&verifyVars,&verifyIterator,%str( ));
+    %if not %symexist(&verifyvar) %then %do;
+      %let abortmsg= Variable &verifyVar is MISSING;
+      %goto exit_err;
+    %end;
+    %if %length(%trim(&&&verifyVar))=0 %then %do;
+      %let abortmsg= Variable &verifyVar is EMPTY;
+      %goto exit_err;
+    %end;
+    %if &makeupcase=YES %then %do;
+      %let &verifyVar=%upcase(&&&verifyvar);
+    %end;
+  %end;
+
+  %goto exit_success;
+  %exit_err:
+    %put &abortmsg;
+    %mf_abort(iftrue=(&mabort ne SOFT),
+      mac=mf_verifymacvars,
+      msg=%str(&abortmsg)
+    )
+    0
+    %return;
+  %exit_success:
+  1
+
+%mend mf_verifymacvars;

package/macros/mf_wordsinstr1andstr2.sas

@@ -0,0 +1,53 @@
+/**
+  @file
+  @brief Returns words that are in both string 1 and string 2
+  @details  Compares two space separated strings and returns the words that are
+  in both.
+  Usage:
+
+      %put %mf_wordsInStr1andStr2(
+        Str1=blah sss blaaah brah bram boo
+        ,Str2=   blah blaaah brah ssss
+      );
+
+  returns:
+  > blah blaaah brah
+
+  @param str1= string containing words to extract
+  @param str2= used to compare with the extract string
+
+  @warning CASE SENSITIVE!
+
+  @version 9.2
+  @author Allan Bowe
+
+**/
+
+%macro mf_wordsInStr1andStr2(
+  Str1= /* string containing words to extract */
+  ,Str2= /* used to compare with the extract string */
+)/*/STORE SOURCE*/;
+
+%local count_base count_extr i i2 extr_word base_word match outvar;
+%if %length(&str1)=0 or %length(&str2)=0 %then %do;
+  %put base string (str1)= &str1;
+  %put compare string (str2) = &str2;
+  %return;
+%end;
+%let count_base=%sysfunc(countw(&Str2));
+%let count_extr=%sysfunc(countw(&Str1));
+
+%do i=1 %to &count_extr;
+  %let extr_word=%scan(&Str1,&i,%str( ));
+  %let match=0;
+  %do i2=1 %to &count_base;
+    %let base_word=%scan(&Str2,&i2,%str( ));
+    %if &extr_word=&base_word %then %let match=1;
+  %end;
+  %if &match=1 %then %let outvar=&outvar &extr_word;
+%end;
+
+  &outvar
+
+%mend mf_wordsInStr1andStr2;
+

package/macros/mf_wordsinstr1butnotstr2.sas

@@ -0,0 +1,54 @@
+/**
+  @file
+  @brief Returns words that are in string 1 but not in string 2
+  @details  Compares two space separated strings and returns the words that are
+  in the first but not in the second.
+
+  Note - case sensitive!
+
+  Usage:
+
+      %let x= %mf_wordsInStr1ButNotStr2(
+        Str1=blah sss blaaah brah bram boo
+        ,Str2=   blah blaaah brah ssss
+      );
+
+  returns:
+  > sss bram boo
+
+  @param [in] str1= string containing words to extract
+  @param [in] str2= used to compare with the extract string
+
+  @version 9.2
+  @author Allan Bowe
+
+**/
+
+%macro mf_wordsInStr1ButNotStr2(
+  Str1= /* string containing words to extract */
+  ,Str2= /* used to compare with the extract string */
+)/*/STORE SOURCE*/;
+
+%local count_base count_extr i i2 extr_word base_word match outvar;
+%if %length(&str1)=0 or %length(&str2)=0 %then %do;
+  %put base string (str1)= &str1;
+  %put compare string (str2) = &str2;
+  %return;
+%end;
+%let count_base=%sysfunc(countw(&Str2));
+%let count_extr=%sysfunc(countw(&Str1));
+
+%do i=1 %to &count_extr;
+  %let extr_word=%scan(&Str1,&i,%str( ));
+  %let match=0;
+  %do i2=1 %to &count_base;
+    %let base_word=%scan(&Str2,&i2,%str( ));
+    %if &extr_word=&base_word %then %let match=1;
+  %end;
+  %if &match=0 %then %let outvar=&outvar &extr_word;
+%end;
+
+  &outvar
+
+%mend mf_wordsInStr1ButNotStr2;
+

package/macros/mf_writefile.sas

@@ -0,0 +1,67 @@
+/**
+  @file
+  @brief Creates a text file using pure macro
+  @details Creates a text file of up to 10 lines.  If further lines are
+    desired, feel free to [create an issue](
+    https://github.com/sasjs/core/issues/new), or make a pull request!
+
+    The use of PARMBUFF was considered for this macro, but it would have made
+    things problematic for writing lines containing commas.
+
+    Usage:
+
+        %mf_writefile(&sasjswork/myfile.txt,l1=some content,l2=more content)
+        data _null_;
+          infile "&sasjswork/myfile.txt";
+          input;
+          list;
+        run;
+
+  @param [in] fpath Full path to file to be created or appended to
+  @param [in] mode= (O) Available options are A or O as follows:
+    @li A APPEND mode, writes new records after the current end of the file.
+    @li O OUTPUT mode, writes new records from the beginning of the file.
+  @param [in] l1= First line
+  @param [in] l2= Second line (etc through to l10)
+
+  <h4> Related Macros </h4>
+  @li mf_writefile.test.sas
+
+  @version 9.2
+  @author Allan Bowe
+**/
+/** @cond */
+
+%macro mf_writefile(fpath,mode=O,l1=,l2=,l3=,l4=,l5=,l6=,l7=,l8=,l9=,l10=
+)/*/STORE SOURCE*/;
+%local fref rc fid i total_lines;
+
+/* find number of lines by reference to first non-blank param */
+%do i=10 %to 1 %by -1;
+  %if %str(&&l&i) ne %str() %then %goto continue;
+%end;
+%continue:
+%let total_lines=&i;
+
+%if %sysfunc(filename(fref,&fpath)) ne 0 %then %do;
+  %put &=fref &=fpath;
+  %put %str(ERR)OR: %sysfunc(sysmsg());
+  %return;
+%end;
+
+%let fid=%sysfunc(fopen(&fref,&mode));
+
+%if &fid=0 %then %do;
+  %put %str(ERR)OR: %sysfunc(sysmsg());
+  %return;
+%end;
+
+%do i=1 %to &total_lines;
+  %let rc=%sysfunc(fput(&fid, &&l&i));
+  %let rc=%sysfunc(fwrite(&fid));
+%end;
+%let rc=%sysfunc(fclose(&fid));
+%let rc=%sysfunc(filename(&fref));
+
+%mend mf_writefile;
+/** @endcond */

package/macros/mp_abort.sas

@@ -0,0 +1,301 @@
+/**
+  @file
+  @brief abort gracefully according to context
+  @details Configures an abort mechanism according to site specific policies or
+    the particulars of an environment.  For instance, can stream custom
+    results back to the client in an STP Web App context, or completely stop
+    in the case of a batch run.  For STP sessions
+
+  The method used varies according to the context.  Important points:
+
+  @li should not use endsas or abort cancel in 9.4m3 WIN environments as this
+    can cause hung multibridge sessions and result in a frozen STP server
+  @li The use of endsas in 9.4m6+ windows environments for POST requests to the
+    STP server can result in an empty response body
+  @li should not use endsas in viya 3.5 as this destroys the session and cannot
+    fetch results (although both mv_getjoblog.sas and the @sasjs/adapter will
+    recognise this and fetch the log of the parent session instead)
+  @li STP environments must finish cleanly to avoid the log being sent to
+    _webout.  To assist with this, we also run stpsrvset('program error', 0)
+    and set SYSCC=0.
+    Where possible, we take a unique "soft abort" approach - we open a macro
+    but don't close it!  This works everywhere EXCEPT inside a \%include inside
+    a macro.  For that, we recommend you use mp_include.sas to perform the
+    include, and then call \%mp_abort(mode=INCLUDE) from the source program (ie,
+    OUTSIDE of the top-parent macro).
+    The soft abort has become ineffective in 9.4m6 WINDOWS environments.  We are
+    currently investigating approaches to deal with this.
+
+
+  @param mac= (mp_abort.sas) To contain the name of the calling macro. Do not
+    use &sysmacroname as this will always resolve to MP_ABORT.
+  @param msg= message to be returned
+  @param iftrue= (1=1) Supply a condition for which the macro should be executed
+  @param errds= (work.mp_abort_errds) There is no clean way to end a process
+    within a %include called within a macro.  Furthermore, there is no way to
+    test if a macro is called within a %include.  To handle this particular
+    scenario, the %include should be switched for the mp_include.sas macro.
+    This provides an indicator that we are running a macro within a \%include
+    (`_SYSINCLUDEFILEDEVICE`) and allows us to provide a dataset with the abort
+    values (msg, mac).
+    We can then run an abort cancel FILE to stop the include running, and pass
+    the dataset back to the calling program to run a regular \%mp_abort().
+    The dataset will contain the following fields:
+    @li iftrue (1=1)
+    @li msg (the message)
+    @li mac (the mac param)
+
+  @param mode= (REGULAR) If mode=INCLUDE then the &errds dataset is checked for
+    an abort status.
+    Valid values:
+    @li REGULAR (default)
+    @li INCLUDE
+
+  @version 9.4
+  @author Allan Bowe
+
+  <h4> Related Macros </h4>
+  @li mp_include.sas
+
+  @cond
+**/
+
+%macro mp_abort(mac=mp_abort.sas, type=, msg=, iftrue=%str(1=1)
+  , errds=work.mp_abort_errds
+  , mode=REGULAR
+)/*/STORE SOURCE*/;
+
+%global sysprocessmode sysprocessname sasjs_stpsrv_header_loc sasjsprocessmode;
+%local fref fid i;
+
+%if not(%eval(%unquote(&iftrue))) %then %return;
+
+%put NOTE: ///  mp_abort macro executing //;
+%if %length(&mac)>0 %then %put NOTE- called by &mac;
+%put NOTE - &msg;
+
+%if %symexist(_SYSINCLUDEFILEDEVICE)
+/* abort cancel FILE does not restart outside the INCLUDE on Viya 3.5 */
+and %superq(SYSPROCESSNAME) ne %str(Compute Server)
+%then %do;
+  %if "*&_SYSINCLUDEFILEDEVICE*" ne "**" %then %do;
+    data &errds;
+      iftrue='1=1';
+      length mac $100 msg $5000;
+      mac=symget('mac');
+      msg=symget('msg');
+    run;
+    data _null_;
+      abort cancel FILE;
+    run;
+    %return;
+  %end;
+%end;
+
+/* Web App Context */
+%if %symexist(_PROGRAM)
+  or %superq(SYSPROCESSNAME) = %str(Compute Server)
+  or &mode=INCLUDE
+%then %do;
+  options obs=max replace mprint;
+  %if "%substr(&sysver,1,1)" ne "4" and "%substr(&sysver,1,1)" ne "5"
+  %then %do;
+    options nosyntaxcheck;
+  %end;
+
+  %if &mode=INCLUDE %then %do;
+    %if %sysfunc(exist(&errds))=1 %then %do;
+      data _null_;
+        set &errds;
+        call symputx('iftrue',iftrue,'l');
+        call symputx('mac',mac,'l');
+        call symputx('msg',msg,'l');
+        putlog (_all_)(=);
+      run;
+      %if (&iftrue)=0 %then %return;
+    %end;
+    %else %do;
+      %put &sysmacroname: No include errors found;
+      %return;
+    %end;
+  %end;
+
+  /* extract log errs / warns, if exist */
+  %local logloc logline;
+  %global logmsg; /* capture global messages */
+  %if %symexist(SYSPRINTTOLOG) %then %let logloc=&SYSPRINTTOLOG;
+  %else %let logloc=%qsysfunc(getoption(LOG));
+  proc printto log=log;run;
+  %let logline=0;
+  %if %length(&logloc)>0 %then %do;
+    data _null_;
+      infile &logloc lrecl=5000;
+      input; putlog _infile_;
+      i=1;
+      retain logonce 0;
+      if (
+          _infile_=:"%str(WARN)ING" or _infile_=:"%str(ERR)OR"
+        ) and logonce=0 then
+      do;
+        call symputx('logline',_n_);
+        logonce+1;
+      end;
+    run;
+    /* capture log including lines BEFORE the err */
+    %if &logline>0 %then %do;
+      data _null_;
+        infile &logloc lrecl=5000;
+        input;
+        i=1;
+        stoploop=0;
+        if _n_ ge &logline-15 and stoploop=0 then do until (i>22);
+          call symputx('logmsg',catx('\n',symget('logmsg'),_infile_));
+          input;
+          i+1;
+          stoploop=1;
+        end;
+        if stoploop=1 then stop;
+      run;
+    %end;
+  %end;
+
+  %if %symexist(SYS_JES_JOB_URI) %then %do;
+    /* setup webout for Viya */
+    options nobomfile;
+    %if "X&SYS_JES_JOB_URI.X"="XX" %then %do;
+        filename _webout temp lrecl=999999 mod;
+    %end;
+    %else %do;
+      filename _webout filesrvc parenturi="&SYS_JES_JOB_URI"
+        name="_webout.json" lrecl=999999 mod;
+    %end;
+  %end;
+  %else %if %sysfunc(filename(fref,&sasjs_stpsrv_header_loc))=0 %then %do;
+    options nobomfile;
+    /* set up http header for SASjs Server */
+    %let fid=%sysfunc(fopen(&fref,A));
+    %if &fid=0 %then %do;
+      %put %str(ERR)OR: %sysfunc(sysmsg());
+      %return;
+    %end;
+    %let rc=%sysfunc(fput(&fid,%str(Content-Type: application/json)));
+    %let rc=%sysfunc(fwrite(&fid));
+    %let rc=%sysfunc(fclose(&fid));
+    %let rc=%sysfunc(filename(&fref));
+  %end;
+
+  /* send response in SASjs JSON format */
+  data _null_;
+    file _webout mod lrecl=32000 encoding='utf-8';
+    length msg syswarningtext syserrortext $32767 mode $10 ;
+    sasdatetime=datetime();
+    msg=symget('msg');
+  %if &logline>0 %then %do;
+    msg=cats(msg,'\n\nLog Extract:\n',symget('logmsg'));
+  %end;
+    /* escape the escapes */
+    msg=tranwrd(msg,'\','\\');
+    /* escape the quotes */
+    msg=tranwrd(msg,'"','\"');
+    /* ditch the CRLFs as chrome complains */
+    msg=compress(msg,,'kw');
+    /* quote without quoting the quotes (which are escaped instead) */
+    msg=cats('"',msg,'"');
+    if symexist('_debug') then debug=quote(trim(symget('_debug')));
+    else debug='""';
+    if symget('sasjsprocessmode')='Stored Program' then mode='SASJS';
+    if mode ne 'SASJS' then put '>>weboutBEGIN<<';
+    put '{"SYSDATE" : "' "&SYSDATE" '"';
+    put ',"SYSTIME" : "' "&SYSTIME" '"';
+    put ',"sasjsAbort" : [{';
+    put ' "MSG":' msg ;
+    put ' ,"MAC": "' "&mac" '"}]';
+    put ",""SYSUSERID"" : ""&sysuserid"" ";
+    put ',"_DEBUG":' debug ;
+    if symexist('_metauser') then do;
+      _METAUSER=quote(trim(symget('_METAUSER')));
+      put ",""_METAUSER"": " _METAUSER;
+      _METAPERSON=quote(trim(symget('_METAPERSON')));
+      put ',"_METAPERSON": ' _METAPERSON;
+    end;
+    if symexist('SYS_JES_JOB_URI') then do;
+      SYS_JES_JOB_URI=quote(trim(symget('SYS_JES_JOB_URI')));
+      put ',"SYS_JES_JOB_URI": ' SYS_JES_JOB_URI;
+    end;
+    _PROGRAM=quote(trim(resolve(symget('_PROGRAM'))));
+    put ',"_PROGRAM" : ' _PROGRAM ;
+    put ",""SYSCC"" : ""&syscc"" ";
+    syserrortext=cats('"',tranwrd(symget('syserrortext'),'"','\"'),'"');
+    put ",""SYSERRORTEXT"" : " syserrortext;
+    put ",""SYSHOSTNAME"" : ""&syshostname"" ";
+    put ",""SYSJOBID"" : ""&sysjobid"" ";
+    put ",""SYSSCPL"" : ""&sysscpl"" ";
+    put ",""SYSSITE"" : ""&syssite"" ";
+    sysvlong=quote(trim(symget('sysvlong')));
+    put ',"SYSVLONG" : ' sysvlong;
+    syswarningtext=cats('"',tranwrd(symget('syswarningtext'),'"','\"'),'"');
+    put ",""SYSWARNINGTEXT"" : " syswarningtext;
+    put ',"END_DTTM" : "' "%sysfunc(datetime(),E8601DT26.6)" '" ';
+    put "}" ;
+    if mode ne 'SASJS' then put '>>weboutEND<<';
+  run;
+
+  %put _all_;
+
+  %if "&sysprocessmode " = "SAS Stored Process Server " %then %do;
+    data _null_;
+      putlog 'stpsrvset program err and syscc';
+      rc=stpsrvset('program error', 0);
+      call symputx("syscc",0,"g");
+    run;
+    %if &sysscp=WIN
+    and 1=0 /* deprecating this logic until we figure out a consistent abort */
+    and "%substr(%str(&sysvlong         ),1,8)"="9.04.01M"
+    and "%substr(%str(&sysvlong         ),9,1)">"5" %then %do;
+      /* skip approach (below) does not work in windows m6+ envs */
+      endsas;
+    %end;
+    %else %do;
+      /**
+        * endsas kills 9.4m3 deployments by orphaning multibridges.
+        * Abort variants are ungraceful (non zero return code)
+        * This approach lets SAS run silently until the end :-)
+        * Caution - fails when called within a %include within a macro
+        * Use mp_include() to handle this.
+        */
+      filename skip temp;
+      data _null_;
+        file skip;
+        put '%macro skip();';
+        comment '%mend skip; -> fix lint ';
+        put '%macro skippy();';
+        comment '%mend skippy; -> fix lint ';
+      run;
+      %inc skip;
+    %end;
+  %end;
+  %else %if "&sysprocessmode " = "SAS Compute Server " %then %do;
+    /* endsas kills the session making it harder to fetch results */
+    data _null_;
+      syswarningtext=symget('syswarningtext');
+      syserrortext=symget('syserrortext');
+      abort_msg=symget('msg');
+      syscc=symget('syscc');
+      sysuserid=symget('sysuserid');
+      iftrue=symget('iftrue');
+      put (_all_)(/=);
+      call symputx('syscc',0);
+      abort cancel nolist;
+    run;
+  %end;
+  %else %do;
+    %abort cancel;
+  %end;
+%end;
+%else %do;
+  %put _all_;
+  %abort cancel;
+%end;
+%mend mp_abort;
+
+/** @endcond */