@sasjs/utils 2.48.2 → 2.49.1

package/macros/mp_tree.sas

@@ -0,0 +1,71 @@
+/**
+  @file
+  @brief Recursively scans a directory tree to get all subfolders and content
+  @details
+  Usage:
+
+      %mp_tree(dir=/tmp, outds=work.tree)
+
+  Credits:
+
+  Roger Deangelis:
+https://communities.sas.com/t5/SAS-Programming/listing-all-files-within-a-directory-and-subdirectories/m-p/332616/highlight/true#M74887
+
+  Tom:
+https://communities.sas.com/t5/SAS-Programming/listing-all-files-of-all-types-from-all-subdirectories/m-p/334113/highlight/true#M75419
+
+
+  @param dir= Directory to be scanned (default=/tmp)
+  @param outds= Dataset to create (default=work.mp_tree)
+
+  @returns outds contains the following variables:
+
+    - `dir`: a flag (1/0) to say whether it is a directory or not.  This is not
+      reliable - folders that you do not have permission to open will be flagged
+      as directories.
+    - `ext`: file extension
+    - `filename`: file name
+    - `dirname`: directory name
+    - `fullpath`: directory + file name
+
+  @version 9.2
+**/
+
+%macro mp_tree(dir=/tmp
+  ,outds=work.mp_tree
+)/*/STORE SOURCE*/;
+
+data &outds ;
+  length dir 8 ext filename dirname $256 fullpath $512 ;
+  call missing(of _all_);
+  fullpath = "&dir";
+run;
+
+%local sep;
+%if &sysscp=WIN or &SYSSCP eq DNTHOST %then %let sep=\;
+%else %let sep=/;
+
+data &outds ;
+  modify &outds ;
+  retain sep "&sep";
+  rc=filename('tmp',fullpath);
+  dir_id=dopen('tmp');
+  dir = (dir_id ne 0) ;
+  if dir then dirname=fullpath;
+  else do;
+    filename=scan(fullpath,-1,sep) ;
+    dirname =substrn(fullpath,1,length(fullpath)-length(filename));
+    if index(filename,'.')>1 then ext=scan(filename,-1,'.');
+  end;
+  replace;
+  if dir then do;
+    do i=1 to dnum(dir_id);
+      fullpath=cats(dirname,sep,dread(dir_id,i));
+      output;
+    end;
+    rc=dclose(dir_id);
+  end;
+  rc=filename('tmp');
+run;
+
+%mend mp_tree;

package/macros/mp_unzip.sas

@@ -0,0 +1,90 @@
+/**
+  @file mp_unzip.sas
+  @brief Unzips a zip file
+  @details Opens the zip file and copies all the contents to another directory.
+  It is not possible to retain permissions / timestamps, also the BOF marker
+  is lost so it cannot extract binary files.
+
+  Usage:
+
+      filename mc url
+        "https://raw.githubusercontent.com/sasjs/core/main/all.sas";
+      %inc mc;
+
+      %mp_unzip(ziploc="/some/file.zip",outdir=/some/folder)
+
+  More info:  https://blogs.sas.com/content/sasdummy/2015/05/11/using-filename-zip-to-unzip-and-read-data-files-in-sas/
+
+  @param ziploc= Fileref or quoted full path to zip file ("/path/to/file.zip")
+  @param outdir= (%sysfunc(pathname(work))) Directory in which to write the
+    outputs (created if non existant)
+
+  <h4> SAS Macros </h4>
+  @li mf_mkdir.sas
+  @li mf_getuniquefileref.sas
+  @li mp_binarycopy.sas
+
+  @version 9.4
+  @author Allan Bowe
+  @source https://github.com/sasjs/core
+
+**/
+
+%macro mp_unzip(
+  ziploc=
+  ,outdir=%sysfunc(pathname(work))
+)/*/STORE SOURCE*/;
+
+%local f1 f2 ;
+%let f1=%mf_getuniquefileref();
+%let f2=%mf_getuniquefileref();
+
+/* Macro variable &datazip would be read from the file */
+filename &f1 ZIP &ziploc;
+
+/* create target folder */
+%mf_mkdir(&outdir)
+
+/* Read the "members" (files) from the ZIP file */
+data _data_(keep=memname isFolder);
+  length memname $200 isFolder 8;
+  fid=dopen("&f1");
+  if fid=0 then stop;
+  memcount=dnum(fid);
+  do i=1 to memcount;
+    memname=dread(fid,i);
+    /* check for trailing / in folder name */
+    isFolder = (first(reverse(trim(memname)))='/');
+    output;
+  end;
+  rc=dclose(fid);
+run;
+
+filename &f2 temp;
+
+/* loop through each entry and either create the subfolder or extract member */
+data _null_;
+  set &syslast;
+  file &f2;
+  if isFolder then call execute('%mf_mkdir(&outdir/'!!memname!!')');
+  else do;
+    qname=quote(cats("&outdir/",memname));
+    bname=cats('(',memname,')');
+    put '/* hat tip: "data _null_" on SAS-L */';
+    put 'data _null_;';
+    put '  infile &f1 ' bname ' lrecl=256 recfm=F length=length eof=eof unbuf;';
+    put '  file ' qname ' lrecl=256 recfm=N;';
+    put '  input;';
+    put '  put _infile_ $varying256. length;';
+    put '  return;';
+    put 'eof:';
+    put '  stop;';
+    put 'run;';
+  end;
+run;
+
+%inc &f2/source2;
+
+filename &f2 clear;
+
+%mend mp_unzip;

package/macros/mp_updatevarlength.sas

@@ -0,0 +1,93 @@
+/**
+  @file mp_updatevarlength.sas
+  @brief Change the length of a variable
+  @details The library is assumed to be assigned.  Simple character updates
+  currently supported, numerics are more complicated and will follow.
+
+        data example;
+          a='1';
+          b='12';
+          c='123';
+        run;
+        %mp_updatevarlength(example,a,3)
+        %mp_updatevarlength(example,c,1)
+        proc sql;
+        describe table example;
+
+  @param libds the library.dataset to be modified
+  @param var The variable to modify
+  @param len The new length to apply
+
+  <h4> SAS Macros </h4>
+  @li mf_existds.sas
+  @li mp_abort.sas
+  @li mf_existvar.sas
+  @li mf_getvarlen.sas
+  @li mf_getvartype.sas
+  @li mf_getnobs.sas
+  @li mp_createconstraints.sas
+  @li mp_getconstraints.sas
+  @li mp_deleteconstraints.sas
+
+  @version 9.2
+  @author Allan Bowe
+
+**/
+
+%macro mp_updatevarlength(libds,var,len
+)/*/STORE SOURCE*/;
+
+%if %index(&libds,.)=0 %then %let libds=WORK.&libds;
+
+%mp_abort(iftrue=(%mf_existds(&libds)=0)
+  ,mac=&sysmacroname
+  ,msg=%str(Table &libds not found!)
+)
+
+%mp_abort(iftrue=(%mf_existvar(&libds,&var)=0)
+  ,mac=&sysmacroname
+  ,msg=%str(Variable &var not found on &libds!)
+)
+
+/* not possible to in-place modify a numeric length, to add later */
+%mp_abort(iftrue=(%mf_getvartype(&libds,&var)=0)
+  ,mac=&sysmacroname
+  ,msg=%str(Only character resizings are currently supported)
+)
+
+%local oldlen;
+%let oldlen=%mf_getvarlen(&libds,&var);
+%if  &oldlen=&len %then %do;
+  %put &sysmacroname: Old and new lengths (&len) match!;
+  %return;
+%end;
+
+%let libds=%upcase(&libds);
+
+
+data;run;
+%local dsconst; %let dsconst=&syslast;
+%mp_getconstraints(lib=%scan(&libds,1,.),ds=%scan(&libds,2,.),outds=&dsconst)
+
+%mp_abort(iftrue=(&syscc ne 0)
+  ,mac=&sysmacroname
+  ,msg=%str(syscc=&syscc)
+)
+
+%if %mf_getnobs(&dscont)=0 %then %do;
+  /* must use SQL as proc datasets does not support length changes */
+  proc sql;
+  alter table &libds modify &var char(&len);
+  %return;
+%end;
+
+/* we have constraints! */
+
+%mp_deleteconstraints(inds=&dsconst,outds=&dsconst._dropd,execute=YES)
+
+proc sql;
+alter table &libds modify &var char(&len);
+
+%mp_createconstraints(inds=&dsconst,outds=&dsconst._addd,execute=YES)
+
+%mend mp_updatevarlength;

package/macros/mp_validatecol.sas

@@ -0,0 +1,97 @@
+/**
+  @file
+  @brief Used to validate variables in a dataset
+  @details Useful when sanitising inputs, to ensure that they arrive with a
+  certain pattern.
+  Usage:
+
+      data test;
+        infile datalines4 dsd;
+        input;
+        libds=_infile_;
+        %mp_validatecol(libds,LIBDS,is_libds)
+      datalines4;
+      some.libname
+      !lib.blah
+      %abort
+      definite.ok
+      not.ok!
+      nineletrs._
+      ;;;;
+      run;
+
+  For more examples, see mp_validatecol.test.sas
+
+  Tip - when contributing, use https://regex101.com to test the regex validity!
+
+  @param [in] incol The column to be validated
+  @param [in] rule The rule to apply.  Current rules:
+    @li ISINT - checks if the variable is an integer
+    @li ISNUM - checks if the variable is numeric
+    @li LIBDS - matches LIBREF.DATASET format
+    @li FORMAT - checks if the provided format is syntactically valid
+  @param [out] outcol The variable to create, with the results of the match
+
+  <h4> SAS Macros </h4>
+  @li mf_getuniquename.sas
+
+  <h4> Related Macros </h4>
+  @li mp_validatecol.test.sas
+
+  @version 9.3
+**/
+
+%macro mp_validatecol(incol,rule,outcol);
+
+/* tempcol is given a unique name with every invocation */
+%local tempcol;
+%let tempcol=%mf_getuniquename();
+
+%if &rule=ISINT %then %do;
+  &outcol=0;
+  if not missing(&incol) then do;
+    &tempcol=input(&incol,?? best32.);
+    if not missing(&tempcol) then if mod(&tempcol,1)=0 then &outcol=1;
+  end;
+  drop &tempcol;
+%end;
+%else %if &rule=ISNUM %then %do;
+  /*
+    credit SØREN LASSEN
+    https://sasmacro.blogspot.com/2009/06/welcome-isnum-macro.html
+  */
+  &tempcol=input(&incol,?? best32.);
+  if missing(&tempcol) then &outcol=0;
+  else &outcol=1;
+  drop &tempcol;
+%end;
+%else %if &rule=LIBDS %then %do;
+  /* match libref.dataset */
+  if _n_=1 then do;
+    retain &tempcol;
+    &tempcol=prxparse('/^[_a-z]\w{0,7}\.[_a-z]\w{0,31}$/i');
+    if missing(&tempcol) then do;
+      putlog "%str(ERR)OR: Invalid expression for LIBDS";
+      stop;
+    end;
+    drop &tempcol;
+  end;
+  if prxmatch(&tempcol, trim(&incol)) then &outcol=1;
+  else &outcol=0;
+%end;
+%else %if &rule=FORMAT %then %do;
+  /* match valid format - regex could probably be improved */
+  if _n_=1 then do;
+    retain &tempcol;
+    &tempcol=prxparse('/^[_a-z\$]\w{0,31}\.[0-9]*$/i');
+    if missing(&tempcol) then do;
+      putlog "%str(ERR)OR: Invalid expression for FORMAT";
+      stop;
+    end;
+    drop &tempcol;
+  end;
+  if prxmatch(&tempcol, trim(&incol)) then &outcol=1;
+  else &outcol=0;
+%end;
+
+%mend mp_validatecol;

package/macros/mp_wait4file.sas

@@ -0,0 +1,35 @@
+/**
+  @file
+  @brief Wait until a file arrives before continuing execution
+  @details Loops with a `sleep()` command until a file arrives or the max wait
+  period expires.
+
+  Example: Wait 3 minutes OR for /tmp/flag.txt to appear
+
+    %mp_wait4file(/tmp/flag.txt , maxwait=60*3)
+
+  @param [in] file The file to wait for.  Must be provided.
+  @param [in] maxwait= (0) Number of seconds to wait.  If set to zero, will
+    loop indefinitely (to a maximum of 46 days, per SAS [documentation](
+      https://support.sas.com/documentation/cdl/en/lrdict/64316/HTML/default/viewer.htm#a001418809.htm
+    )).  Otherwise, execution will proceed upon sleep expiry.
+  @param [in] interval= (1) The wait period between sleeps, in seconds
+
+
+**/
+
+%macro mp_wait4file(file, maxwait=0, interval=1);
+
+%if %str(&file)=%str() %then %do;
+  %put %str(ERR)OR: file not provided;
+%end;
+
+data _null_;
+  maxwait=&maxwait;
+  if maxwait=0 then maxwait=60*60*24*46;
+  do until (fileexist("&file") or slept>maxwait );
+    slept=sum(slept,sleep(&interval,1));
+  end;
+run;
+
+%mend mp_wait4file;

package/macros/mp_webin.sas

@@ -0,0 +1,59 @@
+/**
+  @file
+  @brief Fix the `_WEBIN` variables provided to SAS web services
+  @details When uploading files to SAS Stored Processes or Viya Jobs a number
+  of global macro variables are automatically created - however there are some
+  differences in behaviour both between SAS 9 and Viya, and also between a
+  single file upload and a multi-file upload.
+
+  This macro "straightens" up the global macro variables to make it easier /
+  simpler to write code that works in both environments and with a variable
+  number of file inputs.
+
+  After running this macro, the following global variables will *always* exist:
+  @li `_WEBIN_FILE_COUNT`
+  @li `_WEBIN_FILENAME1`
+  @li `_WEBIN_FILEREF1`
+  @li `_WEBIN_NAME1`
+
+  Usage:
+
+    %mp_webin()
+
+  This was created as a macro procedure (over a macro function) as it will also
+  use the filename statement in Viya environments (where `_webin_fileuri` is
+  provided).
+
+  <h4> SAS Macros </h4>
+  @li mf_getplatform.sas
+  @li mf_getuniquefileref.sas
+
+**/
+
+%macro mp_webin();
+
+/* prepare global variables */
+%global _webin_file_count
+  _webin_filename _webin_filename1
+  _webin_fileref _webin_fileref1
+  _webin_fileuri _webin_fileuri1
+  _webin_name _webin_name1
+  ;
+
+/* create initial versions */
+%let _webin_file_count=%eval(&_webin_file_count+0);
+%let _webin_filename1=%sysfunc(coalescec(&_webin_filename1,&_webin_filename));
+%let _webin_fileref1=%sysfunc(coalescec(&_webin_fileref1,&_webin_fileref));
+%let _webin_fileuri1=%sysfunc(coalescec(&_webin_fileuri1,&_webin_fileuri));
+%let _webin_name1=%sysfunc(coalescec(&_webin_name1,&_webin_name));
+
+
+/* If Viya, create temporary fileref(s) */
+%local i;
+%if %mf_getplatform()=SASVIYA %then %do i=1 %to &_webin_file_count;
+  %let _webin_fileref&i=%mf_getuniquefileref();
+  filename &&_webin_fileref&i filesrvc "&&_webin_fileuri&i";
+%end;
+
+
+%mend mp_webin;

package/macros/mp_zip.sas

@@ -0,0 +1,85 @@
+/**
+  @file
+  @brief Creates a zip file
+  @details For DIRECTORY usage, will ignore subfolders. For DATASET usage,
+  provide a column that contains the full file path to each file to be zipped.
+
+      %mp_zip(in=myzips,type=directory,outname=myDir)
+      %mp_zip(in=/my/file/path.txt,type=FILE,outname=myFile)
+      %mp_zip(in=SOMEDS,incol=FPATH,type=DATASET,outname=myFile)
+
+  If you are sending zipped output to the _webout destination as part of an STP
+  be sure that _debug is not set (else the SPWA will send non zipped content
+  as well).
+
+  <h4> SAS Macros </h4>
+  @li mp_dirlist.sas
+
+  @param in= unquoted filepath, dataset of files or directory to zip
+  @param type= (FILE) Valid values:
+    @li FILE - /full/path/and/filename.extension to a particular file
+    @li DATASET - a dataset containing a list of files to zip (see `incol`)
+    @li DIRECTORY - a directory to zip
+  @param outname= (FILE) Output file to create, _without_ .zip extension
+  @param outpath= (%sysfunc(pathname(WORK))) Parent folder for output zip file
+  @param incol= if DATASET input, say which column contains the filepath
+
+  <h4> Related Macros </h4>
+  @li mp_unzip.sas
+  @li mp_zip.test.sas
+
+  @version 9.2
+  @author Allan Bowe
+  @source https://github.com/sasjs/core
+
+**/
+
+%macro mp_zip(
+  in=
+  ,type=FILE
+  ,outname=FILE
+  ,outpath=%sysfunc(pathname(WORK))
+  ,incol=
+  ,debug=NO
+)/*/STORE SOURCE*/;
+
+%let type=%upcase(&type);
+%local ds;
+
+ods package open nopf;
+
+%if &type=FILE %then %do;
+  ods package add file="&in" mimetype="application/x-compress";
+%end;
+%else %if &type=DIRECTORY %then %do;
+  %mp_dirlist(path=&in,outds=_data_)
+  %let ds=&syslast;
+  data _null_;
+    set &ds;
+    length __command $4000;
+    if file_or_folder='file';
+    __command=cats('ods package add file="',filepath
+      ,'" mimetype="application/x-compress";');
+    call execute(__command);
+  run;
+  /* tidy up */
+  %if &debug=NO %then %do;
+    proc sql; drop table &ds;quit;
+  %end;
+%end;
+%else %if &type=DATASET %then %do;
+  data _null_;
+    set &in;
+    length __command $4000;
+    __command=cats('ods package add file="',&incol
+      ,'" mimetype="application/x-compress";');
+    call execute(__command);
+  run;
+%end;
+
+
+ods package publish archive properties
+  (archive_name="&outname..zip" archive_path="&outpath");
+ods package close;
+
+%mend mp_zip;

package/package.json

@@ -15,6 +15,8 @@
     "preinstall": "npm run nodeVersionMessage",
     "prebuild": "npm run nodeVersionMessage",
     "build": "rimraf build && tsc",
+    "postbuild": "npm run copy:macros",
+    "copy:macros": "ts-node ./scripts/copySASjsCore.ts",
     "prepublishOnly": "cp -r ./build/* . && rm -rf ./build && rm -rf ./src && rm jest.config.js && rm tsconfig.json",
     "postpublish": "git clean -fd",
     "package:lib": "npm run build && cp ./package.json build && cp README.md build && cd build && npm version \"5.0.0\" && npm pack",
@@ -34,7 +36,7 @@
   },
   "homepage": "https://github.com/sasjs/utils#readme",
   "devDependencies": {
-    "@sasjs/core": "3.10.0",
+    "@sasjs/core": "4.41.0",
     "@types/cli-table": "0.3.0",
     "@types/find": "0.2.1",
     "@types/jest": "27.4.0",
@@ -45,6 +47,7 @@
     "jest-extended": "1.1.0",
     "ts-jest": "27.1.3",
     "ts-loader": "9.2.6",
+    "ts-node": "10.9.1",
     "typescript": "4.5.4"
   },
   "dependencies": {
@@ -61,5 +64,5 @@
     "rimraf": "3.0.2",
     "valid-url": "1.0.9"
   },
-  "version": "2.48.2"
+  "version": "2.49.1"
 }

package/scripts/copySASjsCore.ts

@@ -0,0 +1,36 @@
+import path from 'path'
+import { asyncForEach, copy, createFolder, deleteFolder } from '../src'
+
+const root = path.join(__dirname, '..')
+
+const sasjsCorePath = path.join(root, 'node_modules', '@sasjs', 'core')
+
+export const macrosPath = path.join(root, 'build', 'macros')
+
+/**
+ * We need @sasjs/core macros at runtime for compilation of programs, but we
+ * can't directly import them like a javascript file.
+ * So, we have to read the macro files directly. For this we can't use the
+ * node_modules folder, as it will not always be available after the library is
+ * built / packed (eg in the VS Code extension)
+ * Therefore, we copy the macros to a folder in the post build step, so that we
+ * can read them at runtime.
+ *
+ * These macros are / will be used by the sasjs fs command / fs sync utilites
+ * as well as for general compilation of SAS Jobs, Services, and Tests.
+ */
+
+export const copySASjsCore = async () => {
+  await deleteFolder(macrosPath)
+  await createFolder(macrosPath)
+
+  const foldersToCopy = ['base']
+
+  await asyncForEach(foldersToCopy, async (coreSubFolder) => {
+    const coreSubFolderPath = path.join(sasjsCorePath, coreSubFolder)
+
+    await copy(coreSubFolderPath, macrosPath)
+  })
+}
+
+copySASjsCore()

package/types/hash.d.ts

@@ -0,0 +1,9 @@
+export interface HashedFile {
+    hash: string;
+    absolutePath: string;
+    relativePath: string;
+    isFile: boolean;
+}
+export interface HashedFolder extends HashedFile {
+    members: (HashedFile | HashedFolder)[];
+}

package/types/hash.js

@@ -0,0 +1,3 @@
+"use strict";
+Object.defineProperty(exports, "__esModule", { value: true });
+//# sourceMappingURL=hash.js.map

package/types/hash.js.map

@@ -0,0 +1 @@
+{"version":3,"file":"hash.js","sourceRoot":"","sources":["../../src/types/hash.ts"],"names":[],"mappings":""}

package/types/index.d.ts

@@ -3,6 +3,7 @@ export * from './configuration';
 export * from './decodedToken';
 export * from './extraResponseAttributes';
 export * from './fileTree';
+export * from './hash';
 export * from './httpsAgentOptions';
 export * from './macro';
 export * from './sasAuthResponse';

package/types/index.js

@@ -15,6 +15,7 @@ __exportStar(require("./configuration"), exports);
 __exportStar(require("./decodedToken"), exports);
 __exportStar(require("./extraResponseAttributes"), exports);
 __exportStar(require("./fileTree"), exports);
+__exportStar(require("./hash"), exports);
 __exportStar(require("./httpsAgentOptions"), exports);
 __exportStar(require("./macro"), exports);
 __exportStar(require("./sasAuthResponse"), exports);

package/types/index.js.map

@@ -1 +1 @@
-{"version":3,"file":"index.js","sourceRoot":"","sources":["../../src/types/index.ts"],"names":[],"mappings":";;;;;;;;;;;;AAAA,2CAAwB;AACxB,kDAA+B;AAC/B,iDAA8B;AAC9B,4DAAyC;AACzC,6CAA0B;AAC1B,sDAAmC;AACnC,0CAAuB;AACvB,oDAAiC;AACjC,kDAA+B;AAC/B,gDAA6B;AAC7B,+CAA4B;AAC5B,gDAA6B;AAC7B,2CAAwB"}
+{"version":3,"file":"index.js","sourceRoot":"","sources":["../../src/types/index.ts"],"names":[],"mappings":";;;;;;;;;;;;AAAA,2CAAwB;AACxB,kDAA+B;AAC/B,iDAA8B;AAC9B,4DAAyC;AACzC,6CAA0B;AAC1B,yCAAsB;AACtB,sDAAmC;AACnC,0CAAuB;AACvB,oDAAiC;AACjC,kDAA+B;AAC/B,gDAA6B;AAC7B,+CAA4B;AAC5B,gDAA6B;AAC7B,2CAAwB"}

package/utils/index.d.ts

@@ -1,4 +1,4 @@
-export { uuidv4, asyncForEach, uniqArray, isWindows, isLinux, escapeWinSlashes } from './utils';
+export { uuidv4, asyncForEach, uniqArray, isWindows, isLinux, escapeWinSlashes, getMacrosPath } from './utils';
 export * from './fileTree';
 export { urlOrigin } from './url';
 export { encodeToBase64, decodeFromBase64 } from './base64';

package/utils/index.js

@@ -10,7 +10,7 @@ var __exportStar = (this && this.__exportStar) || function(m, exports) {
     for (var p in m) if (p !== "default" && !Object.prototype.hasOwnProperty.call(exports, p)) __createBinding(exports, m, p);
 };
 Object.defineProperty(exports, "__esModule", { value: true });
-exports.chunk = exports.diff = exports.bytesToSize = exports.getExecutorPath = exports.decodeFromBase64 = exports.encodeToBase64 = exports.urlOrigin = exports.escapeWinSlashes = exports.isLinux = exports.isWindows = exports.uniqArray = exports.asyncForEach = exports.uuidv4 = void 0;
+exports.chunk = exports.diff = exports.bytesToSize = exports.getExecutorPath = exports.decodeFromBase64 = exports.encodeToBase64 = exports.urlOrigin = exports.getMacrosPath = exports.escapeWinSlashes = exports.isLinux = exports.isWindows = exports.uniqArray = exports.asyncForEach = exports.uuidv4 = void 0;
 var utils_1 = require("./utils");
 Object.defineProperty(exports, "uuidv4", { enumerable: true, get: function () { return utils_1.uuidv4; } });
 Object.defineProperty(exports, "asyncForEach", { enumerable: true, get: function () { return utils_1.asyncForEach; } });
@@ -18,6 +18,7 @@ Object.defineProperty(exports, "uniqArray", { enumerable: true, get: function ()
 Object.defineProperty(exports, "isWindows", { enumerable: true, get: function () { return utils_1.isWindows; } });
 Object.defineProperty(exports, "isLinux", { enumerable: true, get: function () { return utils_1.isLinux; } });
 Object.defineProperty(exports, "escapeWinSlashes", { enumerable: true, get: function () { return utils_1.escapeWinSlashes; } });
+Object.defineProperty(exports, "getMacrosPath", { enumerable: true, get: function () { return utils_1.getMacrosPath; } });
 __exportStar(require("./fileTree"), exports);
 var url_1 = require("./url");
 Object.defineProperty(exports, "urlOrigin", { enumerable: true, get: function () { return url_1.urlOrigin; } });

package/utils/index.js.map

@@ -1 +1 @@
-{"version":3,"file":"index.js","sourceRoot":"","sources":["../../src/utils/index.ts"],"names":[],"mappings":";;;;;;;;;;;;;AAAA,iCAOgB;AANd,+FAAA,MAAM,OAAA;AACN,qGAAA,YAAY,OAAA;AACZ,kGAAA,SAAS,OAAA;AACT,kGAAA,SAAS,OAAA;AACT,gGAAA,OAAO,OAAA;AACP,yGAAA,gBAAgB,OAAA;AAElB,6CAA0B;AAE1B,6BAAiC;AAAxB,gGAAA,SAAS,OAAA;AAElB,mCAA2D;AAAlD,wGAAA,cAAc,OAAA;AAAE,0GAAA,gBAAgB,OAAA;AAEzC,uCAA4C;AAAnC,2GAAA,eAAe,OAAA;AAExB,6CAA2C;AAAlC,0GAAA,WAAW,OAAA;AACpB,+BAA6B;AAApB,4FAAA,IAAI,OAAA;AACb,iCAA+B;AAAtB,8FAAA,KAAK,OAAA"}
+{"version":3,"file":"index.js","sourceRoot":"","sources":["../../src/utils/index.ts"],"names":[],"mappings":";;;;;;;;;;;;;AAAA,iCAQgB;AAPd,+FAAA,MAAM,OAAA;AACN,qGAAA,YAAY,OAAA;AACZ,kGAAA,SAAS,OAAA;AACT,kGAAA,SAAS,OAAA;AACT,gGAAA,OAAO,OAAA;AACP,yGAAA,gBAAgB,OAAA;AAChB,sGAAA,aAAa,OAAA;AAEf,6CAA0B;AAE1B,6BAAiC;AAAxB,gGAAA,SAAS,OAAA;AAElB,mCAA2D;AAAlD,wGAAA,cAAc,OAAA;AAAE,0GAAA,gBAAgB,OAAA;AAEzC,uCAA4C;AAAnC,2GAAA,eAAe,OAAA;AAExB,6CAA2C;AAAlC,0GAAA,WAAW,OAAA;AACpB,+BAA6B;AAApB,4FAAA,IAAI,OAAA;AACb,iCAA+B;AAAtB,8FAAA,KAAK,OAAA"}

package/utils/utils.d.ts

@@ -7,3 +7,4 @@ export declare const isLinux: () => boolean;
  * replace single backslash with double backslash
  */
 export declare const escapeWinSlashes: (path: string) => string;
+export declare const getMacrosPath: () => string;