@sablier/devkit 1.0.0

package/.prettierrc.json

@@ -0,0 +1,13 @@
+{
+  "$schema": "https://json.schemastore.org/prettierrc",
+  "printWidth": 120,
+  "trailingComma": "all",
+  "overrides": [
+    {
+      "files": "*.md",
+      "options": {
+        "proseWrap": "always"
+      }
+    }
+  ]
+}

package/LICENSE.md

@@ -0,0 +1,16 @@
+MIT License
+
+Copyright (c) 2025 Sablier Labs Ltd
+
+Permission is hereby granted, free of charge, to any person obtaining a copy of this software and associated
+documentation files (the "Software"), to deal in the Software without restriction, including without limitation the
+rights to use, copy, modify, merge, publish, distribute, sublicense, and/or sell copies of the Software, and to permit
+persons to whom the Software is furnished to do so, subject to the following conditions:
+
+The above copyright notice and this permission notice shall be included in all copies or substantial portions of the
+Software.
+
+THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE
+WARRANTIES OF MERCHANTABILITY, FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT. IN NO EVENT SHALL THE AUTHORS OR
+COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR
+OTHERWISE, ARISING FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE USE OR OTHER DEALINGS IN THE SOFTWARE.

package/README.md

@@ -0,0 +1,34 @@
+# 🛠️ Sablier Devkit
+
+This repository contains configuration files and reusable scripts for various Sablier repositories.
+
+The files are meant to be extended and customized as needed.
+
+## ⚙️ Config Files
+
+| Tool            | Config File/Directory                 |
+| --------------- | :------------------------------------ |
+| 🔍 Biome        | [`biome.jsonc`](./biome.jsonc)        |
+| 📝 EditorConfig | [`.editorconfig`](./.editorconfig)    |
+| 🛠 Just          | [`just/`](./just/)                    |
+| ✨ Prettier     | [`prettier.json`](./.prettierrc.json) |
+| 📦 TSConfig     | [`tsconfig/`](./tsconfig/)            |
+
+## 🐈‍⬛ GitHub Actions
+
+The [setup](./actions/setup/) GitHub Actions workflow is used to setup the requisite dependencies in a GitHub CI
+workflow.
+
+## 🚀 Setup Script
+
+This is meant to be run by Sablier Labs employees and staff.
+
+See [`setup.sh`](./shell/setup.sh) for details.
+
+## 📦 VSCode Settings
+
+See [`vscode/settings.json`](./vscode/settings.json).
+
+## 📄 License
+
+This project is licensed under MIT.

package/biome.jsonc

@@ -0,0 +1,62 @@
+// Sablier Devkit configuration for Biome v2: https://next.biomejs.dev
+{
+  "$schema": "https://biomejs.dev/schemas/latest/schema.json",
+  "assist": {
+    "enabled": true,
+    "actions": {
+      "source": {
+        "organizeImports": "on",
+        "useSortedKeys": "on"
+      }
+    }
+  },
+  "files": {
+    "maxSize": 5242880 // 5MB
+  },
+  "formatter": {
+    "enabled": true,
+    "formatWithErrors": true,
+    "indentStyle": "space",
+    "lineWidth": 120
+  },
+  "linter": {
+    "enabled": true,
+    "rules": {
+      "correctness": {
+        "noUnusedImports": "off",
+        "noUnusedVariables": "error",
+        "useExhaustiveDependencies": "error"
+      },
+      "nursery": {
+        "noFloatingPromises": "error"
+      },
+      "recommended": true,
+      "style": {
+        "useImportType": {
+          "level": "warn",
+          "options": {
+            "style": "separatedType"
+          }
+        },
+        "useTemplate": "off"
+      }
+    }
+  },
+  "overrides": [
+    {
+      "assist": {
+        "actions": {
+          "source": {
+            "useSortedKeys": "off"
+          }
+        }
+      },
+      "includes": ["**/*.{json,json5,jsonc}"]
+    }
+  ],
+  "vcs": {
+    "clientKind": "git",
+    "enabled": true,
+    "useIgnoreFile": true
+  }
+}

package/just/base.just

@@ -0,0 +1,106 @@
+import "./settings.just"
+
+# ---------------------------------------------------------------------------- #
+#                                 DEPENDENCIES                                 #
+# ---------------------------------------------------------------------------- #
+
+# Ni: https://github.com/antfu-collective/ni
+na := require("na")
+ni := require("ni")
+nlx := require("nlx")
+
+# ---------------------------------------------------------------------------- #
+#                                   CONSTANTS                                  #
+# ---------------------------------------------------------------------------- #
+
+GLOBS_PRETTIER := "**/*.{md,mdx,yaml,yml}"
+
+# ---------------------------------------------------------------------------- #
+#                                    RECIPES                                   #
+# ---------------------------------------------------------------------------- #
+
+# Clean files
+[no-cd]
+clean +globs:
+    nlx del-cli "{{ globs }}"
+
+# Clear node_modules recursively
+[confirm("Are you sure you want to delete all node_modules, including in subdirectories? y/n")]
+[no-cd]
+clean-modules:
+    nlx del-cli "node_modules" "**/node_modules"
+
+# Install the Node.js dependencies; run with --frozen to install the dependencies with the frozen lockfile
+[no-cd]
+install *args:
+    ni {{ args }}
+
+# Build with TypeScript
+[no-cd]
+tsc-build:
+    na tsc -p tsconfig.build.json
+
+# ---------------------------------------------------------------------------- #
+#                                     CHECK                                    #
+# ---------------------------------------------------------------------------- #
+
+# Check code with Biome
+[group("checks")]
+[no-cd]
+biome-check paths=".":
+    na biome check {{ paths }}
+alias bc := biome-check
+
+# Fix code with Biome
+[group("checks")]
+[no-cd]
+biome-write paths=".":
+    na biome check --write {{ paths }}
+    na biome lint --unsafe --write --only correctness/noUnusedImports {{ paths }}
+alias bw := biome-write
+
+# Run all code checks
+[group("checks")]
+[no-cd]
+full-check: biome-check prettier-check tsc-check
+alias fc := full-check
+
+# Run all code fixes
+[group("checks")]
+[no-cd]
+full-write: biome-write prettier-write
+alias fw := full-write
+
+# Run knip checks
+[group("checks")]
+[no-cd]
+knip-check:
+    na knip
+alias kc := knip-check
+
+# Run knip fix
+[group("checks")]
+[no-cd]
+knip-write:
+    na knip --fix
+alias kw := knip-write
+
+# Check Prettier formatting
+[group("checks")]
+[no-cd]
+prettier-check globs=GLOBS_PRETTIER:
+    na prettier --check --cache "{{ globs }}"
+alias pc := prettier-check
+
+# Format using Prettier
+[group("checks")]
+[no-cd]
+prettier-write globs=GLOBS_PRETTIER:
+    na prettier --write --cache "{{ globs }}"
+alias pw := prettier-write
+
+# Type check with TypeScript
+[group("checks")]
+[no-cd]
+tsc-check:
+    na tsc --noEmit

package/just/evm.just

@@ -0,0 +1,167 @@
+import "./settings.just"
+
+# See https://just.systems/man/en/modules1190.html
+mod base
+
+
+# ---------------------------------------------------------------------------- #
+#                                 DEPENDENCIES                                 #
+# ---------------------------------------------------------------------------- #
+
+# Foundry: https://getfoundry.sh
+forge := require("forge")
+
+# Ni: https://github.com/antfu-collective/ni
+na := require("na")
+nlx := require("nlx")
+
+# ---------------------------------------------------------------------------- #
+#                                   CONSTANTS                                  #
+# ---------------------------------------------------------------------------- #
+
+GLOBS_CLEAN := ```
+    arr=(
+        "artifacts"
+        "artifacts-*"
+        "broadcast"
+        "cache"
+        "cache_hardhat-zk"
+        "coverage"
+        "docs"
+        "out"
+        "out-*"
+        "typechain-types"
+        "lcov.info"
+    )
+    echo "${arr[*]}"
+```
+GLOBS_PRETTIER := "**/*.{md,mdx,yaml,yml}"
+GLOBS_SOLIDITY := "{precompiles,scripts,src,tests}/**/*.sol"
+
+# ---------------------------------------------------------------------------- #
+#                                    RECIPES                                   #
+# ---------------------------------------------------------------------------- #
+
+# Clean directories and files
+clean globs=GLOBS_CLEAN:
+    nlx del-cli {{ globs }}
+alias c := clean
+
+# Clear node_modules recursively
+[confirm("Are you sure you want to delete all node_modules, including in subdirectories? y/n")]
+clean-modules:
+    just base::clean-modules
+
+# Run all code checks
+full-check: solhint-check fmt-check prettier-check
+alias fc := full-check
+
+# Run all code fixes
+full-write: solhint-write fmt-write prettier-write
+alias fw := full-write
+
+# Install the Node.js dependencies
+install *args:
+    just base::install {{ args }}
+alias i := install
+
+# Check Prettier formatting
+@prettier-check globs=GLOBS_PRETTIER:
+    just base::prettier-check "{{ globs }}"
+alias pc := prettier-check
+
+# Format using Prettier
+@prettier-write globs=GLOBS_PRETTIER:
+    just base::prettier-write "{{ globs }}"
+alias pw := prettier-write
+
+# Check code with Solhint
+solhint-check globs=GLOBS_SOLIDITY:
+    na solhint --cache "{{ globs }}"
+alias sc := solhint-check
+
+# Fix code with Solhint
+solhint-write globs=GLOBS_SOLIDITY:
+    na solhint --fix --noPrompt "{{ globs }}"
+alias sw := solhint-write
+
+# ---------------------------------------------------------------------------- #
+#                                    FOUNDRY                                   #
+# ---------------------------------------------------------------------------- #
+
+# Build contracts
+[group("foundry")]
+build:
+    forge build
+alias b := build
+
+# Build using optimized profile
+[group("foundry")]
+build-optimized:
+    FOUNDRY_PROFILE=optimized \
+        forge build
+alias bo := build-optimized
+
+# Build using optimized profile with optional arguments
+[group("foundry")]
+build-optimized *args:
+    FOUNDRY_PROFILE=optimized \
+        forge build --extra-output-files metadata {{ args }}
+
+# Dump code coverage to an html file
+[group("foundry")]
+[script]
+coverage:
+    if ! command -v genhtml >/dev/null 2>&1; then
+        echo "✗ genhtml CLI not found"
+        echo "Install it with Homebrew: https://formulae.brew.sh/formula/lcov"
+        exit 1
+    fi
+    forge coverage --report lcov
+    genhtml --branch-coverage --ignore-errors inconsistent --output-dir coverage lcov.info
+alias cov := coverage
+
+# Check code with Forge formatter
+[group("foundry")]
+fmt-check:
+    forge fmt --check
+
+# Fix code with Forge formatter
+[group("foundry")]
+fmt-write:
+    forge fmt
+
+# Performs a gas report
+[group("foundry")]
+gas-report:
+    forge test --gas-report
+alias gr := gas-report
+
+# Run tests with optional arguments
+[group("foundry")]
+test *args:
+    forge test {{ args }}
+alias t := test
+
+# Run Bulloak checks
+[group("foundry")]
+test-bulloak:
+    bulloak check --skip-modifiers "./tests/**/*.tree"
+alias tb := test-bulloak
+
+# Run tests using lite profile (skipping fork tests)
+[group("foundry")]
+test-lite:
+    FOUNDRY_PROFILE=lite forge test --nmt "testFork"
+alias tl := test-lite
+
+# Run tests using lite profile with optional arguments
+[group("foundry")]
+test-lite *args:
+    FOUNDRY_PROFILE=lite forge test {{ args }}
+
+# Run tests using optimized profile
+[group("foundry")]
+test-optimized: build-optimized
+    FOUNDRY_PROFILE=test-optimized forge test
+alias to := test-optimized

package/just/npm.just

@@ -0,0 +1,54 @@
+import "./settings.just"
+
+# ---------------------------------------------------------------------------- #
+#                                 DEPENDENCIES                                 #
+# ---------------------------------------------------------------------------- #
+
+# Jq
+jq := require("jq")
+
+# Npm
+npm := require("npm")
+
+# ---------------------------------------------------------------------------- #
+#                                    SCRIPTS                                   #
+# ---------------------------------------------------------------------------- #
+
+# Publish the npm package, e.g. v1.0.0
+[group("publish")]
+publish *args:
+  npm publish {{ args }}
+  @just tag $(jq -r '.version' package.json)
+
+# Publish using the `beta` tag, e.g. v1.0.0-beta.1
+[group("publish")]
+publish-beta *args:
+  @just check-beta-version
+  npm publish --tag beta {{ args }}
+
+# Tag the new version
+[group("publish")]
+tag *version:
+  git tag -am "{{ version }}" {{ version }}
+  git push origin --tags
+
+# ---------------------------------------------------------------------------- #
+#                                PRIVATE HELPERS                               #
+# ---------------------------------------------------------------------------- #
+
+
+# Check that package.json version includes -beta.x suffix
+[private]
+[script]
+@check-beta-version:
+  # Extract version from package.json using jq for reliable JSON parsing
+  version=$(jq -r '.version' package.json)
+
+  # Check if version contains -beta suffix
+  if [[ "$version" =~ -beta\.[0-9]+$ ]]; then
+    echo "✓ Version $version includes beta suffix"
+  else
+    echo "✗ Error: Version $version does not include -beta.x suffix"
+    echo "Please update package.json version to include -beta.x (e.g., 1.0.0-beta.1)"
+    exit 1
+  fi

package/just/settings.just

@@ -0,0 +1,5 @@
+# See https://just.systems/man/en/settings.html
+set allow-duplicate-recipes
+set allow-duplicate-variables
+set shell := ["bash", "-euo", "pipefail", "-c"]
+set unstable

package/package.json

@@ -0,0 +1,46 @@
+{
+  "name": "@sablier/devkit",
+  "description": "Configuration files and reusable scripts for Sablier repositories",
+  "version": "1.0.0",
+  "author": {
+    "name": "Sablier Labs Ltd",
+    "url": "https://sablier.com"
+  },
+  "bugs": {
+    "url": "https://github.com/sablier-labs/devkit/issues"
+  },
+  "exports": {
+    "./biome": "./biome.jsonc",
+    "./prettier": "./.prettierrc.json",
+    "./tsconfig/base": "./tsconfig/base.json",
+    "./tsconfig/build": "./tsconfig/build.json",
+    "./tsconfig/next": "./tsconfig/next.json"
+  },
+  "engines": {
+    "node": ">=20"
+  },
+  "files": [
+    "biome.jsonc",
+    ".prettierrc.json",
+    "just/",
+    "tsconfig/"
+  ],
+  "keywords": [
+    "biome",
+    "config",
+    "devkit",
+    "prettier",
+    "sablier",
+    "tsconfig",
+    "typescript"
+  ],
+  "license": "MIT",
+  "publishConfig": {
+    "access": "public"
+  },
+  "repository": {
+    "type": "git",
+    "url": "git+https://github.com/sablier-labs/devkit.git"
+  },
+  "type": "module"
+}

package/tsconfig/base.json

@@ -0,0 +1,17 @@
+{
+  "$schema": "https://json.schemastore.org/tsconfig",
+  "compilerOptions": {
+    "esModuleInterop": true,
+    "forceConsistentCasingInFileNames": true,
+    "lib": ["ESNext"],
+    "module": "NodeNext",
+    "moduleResolution": "NodeNext",
+    "noFallthroughCasesInSwitch": true,
+    "noImplicitReturns": true,
+    "resolveJsonModule": true,
+    "skipLibCheck": true,
+    "sourceMap": true,
+    "strict": true,
+    "target": "ESNext"
+  }
+}

package/tsconfig/build.json

@@ -0,0 +1,14 @@
+{
+  "$schema": "https://json.schemastore.org/tsconfig",
+  "extends": "./base.json",
+  "compilerOptions": {
+    "declaration": true,
+    "declarationMap": true,
+    "emitDecoratorMetadata": true,
+    "experimentalDecorators": true,
+    "forceConsistentCasingInFileNames": true,
+    "removeComments": true,
+    "skipLibCheck": true,
+    "stripInternal": true
+  }
+}

package/tsconfig/next.json

@@ -0,0 +1,19 @@
+{
+  "$schema": "https://json.schemastore.org/tsconfig",
+  "extends": "./base.json",
+  "compilerOptions": {
+    "allowJs": true,
+    "isolatedModules": true,
+    "noEmit": true,
+    "incremental": true,
+    "jsx": "preserve",
+    "lib": ["dom", "dom.iterable", "ESNext"],
+    "module": "ESNext",
+    "moduleResolution": "bundler",
+    "plugins": [
+      {
+        "name": "next"
+      }
+    ]
+  }
+}