@sablier/bob 1.0.1

package/package.json

@@ -0,0 +1,68 @@
+{
+  "name": "@sablier/bob",
+  "description": "EVM smart contracts of the Sablier Bob and Sablier Escrow",
+  "license": "SEE LICENSE IN LICENSE",
+  "version": "1.0.1",
+  "author": {
+    "name": "Sablier Labs Ltd",
+    "url": "https://sablier.com"
+  },
+  "bugs": {
+    "url": "https://github.com/sablier-labs/evm-monorepo/issues"
+  },
+  "dependencies": {
+    "@chainlink/contracts": "1.3.0",
+    "@openzeppelin/contracts": "5.3.0",
+    "@prb/math": "4.1.0",
+    "@sablier/evm-utils": "2.0.1"
+  },
+  "overrides": {
+    "@openzeppelin/contracts-upgradeable": "5.3.0"
+  },
+  "devDependencies": {
+    "@sablier/devkit": "1",
+    "forge-std": "github:foundry-rs/forge-std#v1.10.0",
+    "lint-staged": "16.2.6",
+    "prettier": "3.6.2",
+    "solhint": "6.0.1"
+  },
+  "files": [
+    "artifacts",
+    "src",
+    "tests/utils",
+    "CHANGELOG.md",
+    "LICENSE.md",
+    "LICENSE-BUSL.md",
+    "LICENSE-GPL.md"
+  ],
+  "homepage": "https://github.com/sablier-labs/evm-monorepo#readme",
+  "keywords": [
+    "blockchain",
+    "defi",
+    "ethereum",
+    "evm",
+    "foundry",
+    "price-gated",
+    "sablier",
+    "smart-contracts",
+    "solidity",
+    "vault",
+    "web3",
+    "yield"
+  ],
+  "peerDependencies": {
+    "@prb/math": "4.1.0"
+  },
+  "publishConfig": {
+    "access": "public"
+  },
+  "repository": {
+    "type": "git",
+    "url": "https://github.com/sablier-labs/evm-monorepo.git",
+    "directory": "bob"
+  },
+  "scripts": {
+    "prepack": "../scripts/bash/publish-prepack.sh",
+    "postpack": "../scripts/bash/publish-postpack.sh"
+  }
+}

package/src/BobVaultShare.sol

@@ -0,0 +1,119 @@
+// SPDX-License-Identifier: GPL-3.0-or-later
+pragma solidity >=0.8.22;
+
+import { ERC20 } from "@openzeppelin/contracts/token/ERC20/ERC20.sol";
+import { IERC20Metadata } from "@openzeppelin/contracts/token/ERC20/extensions/IERC20Metadata.sol";
+
+import { IBobVaultShare } from "./interfaces/IBobVaultShare.sol";
+import { ISablierBob } from "./interfaces/ISablierBob.sol";
+import { Errors } from "./libraries/Errors.sol";
+
+/// @title BobVaultShare
+/// @notice ERC-20 token representing shares in a Bob vault.
+/// @dev Each vault has its own BobVaultShare deployed. Only the SablierBob contract can mint and burn tokens.
+/// When shares are transferred, wstETH attribution is updated proportionally via the adapter.
+contract BobVaultShare is ERC20, IBobVaultShare {
+    /*//////////////////////////////////////////////////////////////////////////
+                                     CONSTANTS
+    //////////////////////////////////////////////////////////////////////////*/
+
+    /// @inheritdoc IBobVaultShare
+    address public immutable override SABLIER_BOB;
+
+    /// @inheritdoc IBobVaultShare
+    uint256 public immutable override VAULT_ID;
+
+    /*//////////////////////////////////////////////////////////////////////////
+                                  INTERNAL STORAGE
+    //////////////////////////////////////////////////////////////////////////*/
+
+    /// @dev The number of decimals.
+    uint8 internal immutable _DECIMALS;
+
+    /*//////////////////////////////////////////////////////////////////////////
+                                     MODIFIERS
+    //////////////////////////////////////////////////////////////////////////*/
+
+    /// @dev Reverts if caller is not the Bob contract.
+    modifier onlySablierBob() {
+        if (msg.sender != SABLIER_BOB) {
+            revert Errors.BobVaultShare_OnlySablierBob(msg.sender, SABLIER_BOB);
+        }
+        _;
+    }
+
+    /// @dev Reverts if the vault ID is not equal to {VAULT_ID}.
+    modifier onlyVault(uint256 vaultId) {
+        if (vaultId != VAULT_ID) {
+            revert Errors.BobVaultShare_VaultIdMismatch(vaultId, VAULT_ID);
+        }
+        _;
+    }
+
+    /*//////////////////////////////////////////////////////////////////////////
+                                    CONSTRUCTOR
+    //////////////////////////////////////////////////////////////////////////*/
+
+    /// @notice Deploys the vault share token.
+    /// @param name_ The name of the token (e.g., "Sablier Bob WETH Vault #1").
+    /// @param symbol_ The symbol of the token (e.g., "WETH-500000000000-1792790393-1" with $5000 target price) with the
+    /// first number being the target price denominated in Chainlink's 8-decimal format, where 1e8 is $1.
+    /// @param decimals_ The number of decimals.
+    /// @param sablierBob The address of the SablierBob contract.
+    /// @param vaultId The ID of the vault this share token represents.
+    constructor(
+        string memory name_,
+        string memory symbol_,
+        uint8 decimals_,
+        address sablierBob,
+        uint256 vaultId
+    )
+        ERC20(name_, symbol_)
+    {
+        _DECIMALS = decimals_;
+        SABLIER_BOB = sablierBob;
+        VAULT_ID = vaultId;
+    }
+
+    /*//////////////////////////////////////////////////////////////////////////
+                          USER-FACING READ-ONLY FUNCTIONS
+    //////////////////////////////////////////////////////////////////////////*/
+
+    /// @notice Returns the number of decimals used by the token.
+    function decimals() public view override(ERC20, IERC20Metadata) returns (uint8) {
+        return _DECIMALS;
+    }
+
+    /*//////////////////////////////////////////////////////////////////////////
+                        USER-FACING STATE-CHANGING FUNCTIONS
+    //////////////////////////////////////////////////////////////////////////*/
+
+    /// @inheritdoc IBobVaultShare
+    function mint(uint256 vaultId, address to, uint256 amount) external override onlySablierBob onlyVault(vaultId) {
+        _mint(to, amount);
+    }
+
+    /// @inheritdoc IBobVaultShare
+    function burn(uint256 vaultId, address from, uint256 amount) external override onlySablierBob onlyVault(vaultId) {
+        _burn(from, amount);
+    }
+
+    /*//////////////////////////////////////////////////////////////////////////
+                            INTERNAL OVERRIDE FUNCTIONS
+    //////////////////////////////////////////////////////////////////////////*/
+
+    /// @dev Override to notify SablierBob when shares are transferred (not minted/burned).
+    /// This allows the adapter to update wstETH attribution proportionally.
+    function _update(address from, address to, uint256 amount) internal override {
+        // Get sender's balance before the transfer.
+        uint256 fromBalanceBefore = balanceOf(from);
+
+        // Perform the update.
+        super._update(from, to, amount);
+
+        // Notify SablierBob if the transfer is not a mint or burn.
+        if (from != address(0) && to != address(0)) {
+            ISablierBob(SABLIER_BOB).onShareTransfer(VAULT_ID, from, to, amount, fromBalanceBefore);
+        }
+    }
+}