@rezti/dsh-rez-suite 0.1.49 → 0.1.51

package/templates/shared/wecomcli-smartpage/references/formula/templates.md

@@ -0,0 +1,410 @@
+# 实用公式模板(本章节提供开箱即用的公式模板，推荐载入)
+
+> 实用公式模板涵盖9大推荐功能（排名、环比增长、重复值标记、进度跟踪、日期提取、工龄计算、逾期判断）、2个销售分析模板（累计营业额）、2个文本处理模板（人员并集/补集）、14+个其他实用功能（地址提取、邮箱提取、数字大写、跳转链接、人员列匹配等）。
+
+---
+
+#### 模板变量替换规则
+
+- **特殊变量**：`[当前表]` 表示当前数据表，也需要替换成 `[表名]` 格式
+
+### 推荐模板
+
+#### 1. 计算排名（连续排名）
+
+**功能描述**：从大到小计算数值字段的排名。
+
+**使用场景**：为销售额、分数等数值字段计算排名。
+
+**公式表达式**：
+
+// 数据表场景示例
+IF([销售表.销售额].ISBLANK(), "", [销售表].FILTER([Each].[销售额] >= [销售表.销售额]).[销售额].UNIQUE().COUNTA())
+
+// 或页面控件场景示例
+IF([销售页.销售额].ISBLANK(), "", [销售表].FILTER([Each].[销售额] >= [销售页.销售额]).[销售额].UNIQUE().COUNTA())
+
+
+---
+
+#### 2. 环比增长率
+
+**功能描述**：计算环比增长率 = 当前周期的数值 / 上一周期的数值 - 1
+
+**使用场景**：分析月度、季度销售增长情况。
+
+**公式表达式**：
+
+// 数据表场景示例
+IF(OR([销售表.月份].ISBLANK(), [销售表.月份] = [销售表.月份].MIN()), "", [销售表].FILTER([Each].[月份] = [销售表.月份]).[销售额] / [销售表].FILTER([Each].[月份] = ([销售表.月份] - 1)).[销售额] - 1)
+
+
+---
+
+#### 3. 标记重复值
+
+**功能描述**：整列重复的内容标记"❗️重复"。
+
+**使用场景**：检测产品名称、订单号等字段的重复值。
+
+**公式表达式**：
+
+// 数据表场景示例
+IF([产品表].FILTER([Each].[产品名称] = [其他表.产品名称]).[产品名称].COUNTA() > 1, "❗️重复", "")
+
+
+---
+
+#### 4. 进度跟踪
+
+**功能描述**：根据项目的计划完成时间和实际完成时间标记项目状态。
+
+**使用场景**：项目管理、任务跟踪。
+
+**公式表达式**：
+
+// 数据表场景示例
+IFS(
+  AND([项目表.计划完成日期] = "", [项目表.实际完成日期] = ""), "",
+  AND([项目表.计划完成日期] = "", [项目表.实际完成日期] < TODAY()), "❗️未完成",
+  AND([项目表.计划完成日期] != "", [项目表.实际完成日期] != "", [项目表.实际完成日期] <= [项目表.计划完成日期]), "✅完成",
+  AND([项目表.计划完成日期] != "", [项目表.实际完成日期] != "", [项目表.实际完成日期] > [项目表.计划完成日期]), "🚨延期",
+  AND([项目表.实际完成日期] = "", [项目表.计划完成日期] != ""), "❗️未完成"
+)
+
+
+---
+
+#### 5. 提取年月
+
+**功能描述**：从日期中提取年月信息。
+
+**使用场景**：将 `2026年3月18日` 转换为 `2026年3月`。
+
+**公式表达式**：
+
+// 数据表场景示例
+IF([订单表.订单日期].ISBLANK(), "", TEXT([订单表.订单日期], "yyyy年mm月"))
+
+
+---
+
+#### 6. 提取星期几
+
+**功能描述**：从日期中提取星期信息。
+
+**使用场景**：将 `2026年3月18日` 转换为 `星期三`。
+
+**公式表达式**：
+
+// 数据表场景示例
+IF([订单表.订单日期].ISBLANK(), "", TEXT([订单表.订单日期], "dddd"))
+
+
+---
+
+#### 7. 月度第几周
+
+**功能描述**：计算日期在当月是第几周。
+
+**使用场景**：将 `2026年3月18日` 转换为 `3月第4周`。
+
+**公式表达式**：
+
+// 数据表场景示例
+IF([订单表.订单日期] = "", "", CONCAT(MONTH([订单表.订单日期]).TEXT("00"), "月", "第", (WEEKNUM([订单表.订单日期], 2) - WEEKNUM(DATE(YEAR([订单表.订单日期]), MONTH([订单表.订单日期]), 1), 2) + 1).TEXT("00"), "周"))
+
+
+---
+
+#### 8. 计算工龄
+
+**功能描述**：根据入职日期计算工龄天数。
+
+**使用场景**：将 `2026年1月7日` 转换为 `n天`。
+
+**公式表达式**：
+
+// 数据表场景示例
+IF(OR([员工表.入职日期].ISBLANK(), [员工表.入职日期] > TODAY()), "", (TODAY() - [员工表.入职日期]) & "天")
+
+
+---
+
+#### 9. 是否逾期
+
+**功能描述**：根据预计完成时间判断任务是否逾期。
+
+**使用场景**：任务管理，将 `2026年5月6日` 标记为 `逾期`。
+
+**公式表达式**：
+
+// 数据表场景示例
+IF([任务表.完成日期].ISBLANK(), "", IF([任务表.完成日期] < TODAY(), "未逾期", "逾期"))
+
+
+---
+
+### 销售分析模板
+
+#### 1. 逐日累计营业额
+
+**功能描述**：计算从第一天到当前日期的累计营业额。
+
+**使用场景**：销售数据分析，追踪累计业绩。
+
+**公式表达式**：
+
+// 数据表场景示例
+[销售表].FILTER([Each].[销售日期] <= [销售表.销售日期]).[营业额].LISTCOMBINE().SUM()
+
+
+---
+
+#### 2. 当月累计营业额
+
+**功能描述**：计算当月截止到当前日期的累计营业额。
+
+**使用场景**：月度销售数据分析。
+
+**公式表达式**：
+
+// 数据表场景示例
+[销售表].FILTER([Each].[销售日期].MONTH() = [销售表.销售日期].MONTH()).FILTER([Each].[销售日期] <= [销售表.销售日期]).[营业额].LISTCOMBINE().SUM()
+
+
+---
+
+### 文本处理模板
+
+#### 1. 人员取并集
+
+**功能描述**：取两个人员列的并集（去重）。
+
+**使用场景**：合并项目成员和负责人列表，如 "张三,李四" 和 "张三,王五" 得到 "张三,李四,王五"。
+
+**公式表达式**：
+
+// 数据表场景示例
+LIST([项目表.项目成员], [项目表.项目负责人]).LISTCOMBINE().UNIQUE()
+
+// 或页面控件场景示例
+LIST([项目页.项目成员], [项目页.项目负责人]).LISTCOMBINE().UNIQUE()
+
+
+---
+
+#### 2. 人员取补集
+
+**功能描述**：取第一个字段相对第二个字段的补集。
+
+**使用场景**：找出只在第一个列表中的人员，如 "张三,李四" 和 "张三,王五" 得到 "李四"。
+
+**公式表达式**：
+
+// 数据表场景示例
+[项目表.项目成员].FILTER([Each].CONTAINS([项目表.项目负责人]).NOT())
+
+// 或页面控件场景示例
+[项目页.项目成员].FILTER([Each].CONTAINS([项目页.项目负责人]).NOT())
+
+
+---
+
+### 其他实用模板
+
+#### 1. 随机数生成
+
+**功能描述**：生成指定范围内的随机数（保留2位小数）。
+
+**使用场景**：生成测试数据、随机抽样。
+
+**公式表达式**：
+
+// 数据表场景示例（假设有一个"范围"字段存储最大值）
+(RAND() * [配置表.范围]).ROUND(2)
+
+// 或直接使用固定值
+(RAND() * 100).ROUND(2)
+
+
+---
+
+#### 2. 地址提取 - 省份
+
+**功能描述**：从地理位置字段中提取省份信息。
+
+**使用场景**：将 "广州塔，广东省广州市海珠区阅江西路222号" 提取为 "广东省"。
+
+**公式表达式**：
+
+// 数据表场景示例
+IF([客户表.客户地址].ISBLANK(), "", [客户表.客户地址].[省])
+
+// 或页面控件场景示例
+IF([客户页.客户地址].ISBLANK(), "", [客户页.客户地址].[省])
+
+
+---
+
+#### 3. 地址提取 - 市
+
+**功能描述**：从地理位置字段中提取城市信息。
+
+**公式表达式**：
+
+// 数据表场景示例
+IF([客户表.客户地址].ISBLANK(), "", [客户表.客户地址].[市])
+
+
+---
+
+#### 4. 地址提取 - 区
+
+**功能描述**：从地理位置字段中提取区域信息。
+
+**公式表达式**：
+
+// 数据表场景示例
+IF([客户表.客户地址].ISBLANK(), "", [客户表.客户地址].[区])
+
+
+---
+
+#### 5. 地址提取 - 街道
+
+**功能描述**：从地理位置字段中提取街道信息。
+
+**公式表达式**：
+
+// 数据表场景示例
+IF([客户表.客户地址].ISBLANK(), "", [客户表.客户地址].[街道])
+
+
+---
+
+#### 6. 地址提取 - 经纬度
+
+**功能描述**：从地理位置字段中提取经纬度坐标。
+
+**公式表达式**：
+
+// 数据表场景示例
+IF([客户表.客户地址].ISBLANK(), "", [客户表.客户地址].[经纬度])
+
+
+---
+
+#### 7. 提取邮箱账号
+
+**功能描述**：从邮箱地址中提取@符号前的账号部分。
+
+**使用场景**：将 `zhangsan@qq.com` 提取为 `zhangsan`。
+
+**公式表达式**：
+
+// 数据表场景示例
+IF([用户表.邮箱].ISBLANK(), "", MID([用户表.邮箱], 1, FIND("@", [用户表.邮箱]) - 1))
+
+// 或页面控件场景示例
+IF([用户页.邮箱].ISBLANK(), "", MID([用户页.邮箱], 1, FIND("@", [用户页.邮箱]) - 1))
+
+
+---
+
+#### 8. 提取邮箱域名
+
+**功能描述**：从邮箱地址中提取@符号后的域名部分。
+
+**使用场景**：将 `zhangsan@qq.com` 提取为 `qq.com`。
+
+**公式表达式**：
+// 数据表场景示例
+IF([用户表.邮箱].ISBLANK(), "", MID([用户表.邮箱], FIND("@", [用户表.邮箱], 1) + 1, LEN([用户表.邮箱]) - FIND("@", [用户表.邮箱], 1)))
+
+// 或页面控件场景示例
+IF([用户页.邮箱].ISBLANK(), "", MID([用户页.邮箱], FIND("@", [用户页.邮箱], 1) + 1, LEN([用户页.邮箱]) - FIND("@", [用户页.邮箱], 1)))
+
+---
+
+#### 9. 数字转中文大写
+
+**功能描述**：将数字转换为中文大写形式。
+
+**使用场景**：财务报表、票据打印，将 `1000` 转换为 `壹仟`。
+
+**公式表达式**：
+
+// 数据表场景示例
+IF([财务表.金额].ISBLANK(), "", TEXT([财务表.金额], "[DBNum2][$-804]General"))
+
+// 或页面控件场景示例
+IF([财务页.金额].ISBLANK(), "", TEXT([财务页.金额], "[DBNum2][$-804]General"))
+
+#### 10. 统计月份的数量
+
+[项目主表].FILTER(AND(YEAR([Each].[开始日期]) = LEFT([页面1.统计月份],4), MONTH([Each].[开始日期]) = RIGHT([页面1.统计月份],2))).[项目编号].COUNTA()
+
+> 说明：示例中的 `[页面1.统计月份]` 是页面控件引用（用户在页面上输入的"YYYYMM"字符串）；若改为公式字段所在表的字段，写作 `[Each].[统计月份]`，禁止使用裸字段 `[统计月份]`。
+
+#### 11. 按钮跳转外部链接
+
+// 跳转至百度链接
+OPENLINK("https://baidu.com")
+
+// 若你知道当前文档的 doc.weixin.qq.com 链接，需要跳转到其他页面，修改 p=<page_id> 参数为目标 page_id 即可
+// 假设当前页面为：https://doc.weixin.qq.com/smartpage/<docid>?p=<current_page_id>，或者末尾没有 p=<page_id>
+// 你需要跳转到另一个页面，page_id 为 <new_page_id>，则写为以下 URL 即可
+OPENLINK("https://doc.weixin.qq.com/smartpage/<docid>?p=<new_page_id>")
+---
+
+#### 12. 计算下个周六，以日期显示
+// 计算下个周六
+DATE(YEAR(TODAY()), MONTH(TODAY()), DAY(TODAY()) + (6 - WEEKDAY(TODAY(), 2)))
+
+// 计算下个周天
+DATE(YEAR(TODAY()), MONTH(TODAY()), DAY(TODAY()) + (7 - WEEKDAY(TODAY(), 2)))
+
+#### 13. 显示用户信息
+// 当前用户的姓名
+USER()
+
+// 当前用户的头像
+USER().[头像]
+
+// 当前用户的企业名称
+USER().[企业名称]
+
+#### 14. 修改数据表中的记录
+
+MODIFYRECORDS(目标记录集, 字段1, 值1, [字段2, 值2...])
+- 目标记录集：支持指定单条记录（如 [表].FIRST()），也**完全支持**通过 FILTER 函数动态查询出的多条记录集合（如 [表].FILTER(条件)）。
+配合条件语句等可以实现很复杂实用的数据表记录修改/新增功能。
+
+#### 15. 通过输入框匹配人员，写入记录到数据表
+
+**功能描述**：将人员列中的人员添加到数据表中。
+
+// 数据表场景示例
+ADDRECORD([投票表], [投票表.提名人员], [人员表.人员].FILTER([Each].CONTAINTEXT([页面1.输入框])).FIRST(), [投票表.投票人], USER())
+
+## 使用模板前必读
+
+所有模板中的公式遵循以下规范：
+
+1. **[Each] 规范**：
+   - 在 FILTER 中看到字段引用，前面都有 `[Each].`
+   - 例如：`[表名].FILTER([Each].[字段] = 值)`
+
+2. **逻辑运算规范**：
+   - 与运算使用 `AND(条件1, 条件2)`，而不是 `&&`
+   - 或运算使用 `OR(条件1, 条件2)`，而不是 `||`
+   - 非运算使用 `NOT(条件)`，而不是 `!`
+
+3. **引用格式规范**：
+   - 数据表字段：`[表名.字段名]`
+   - 页面控件：`[页面名.控件名]`
+   - 在公式字段中引用当前记录：`[字段名]`
+   - 在 FILTER 中引用：`[Each].[字段名]`
+
+模板变量替换时请严格保持这些格式。