@rev-net/core-v6 0.0.1

package/docs/src/src/structs/REVDescription.sol/struct.REVDescription.md

@@ -0,0 +1,23 @@
+# REVDescription
+[Git Source](https://github.com/rev-net/revnet-core-v5/blob/364afaae78a8f60af2b98252dc96af1c2e4760d3/src/structs/REVDescription.sol)
+
+**Notes:**
+- member: name The name of the ERC-20 token being create for the revnet.
+
+- member: ticker The ticker of the ERC-20 token being created for the revnet.
+
+- member: uri The metadata URI containing revnet's info.
+
+- member: salt Revnets deployed across chains by the same address with the same salt will have the same
+address.
+
+
+```solidity
+struct REVDescription {
+    string name;
+    string ticker;
+    string uri;
+    bytes32 salt;
+}
+```
+

package/docs/src/src/structs/REVLoan.sol/struct.REVLoan.md

@@ -0,0 +1,28 @@
+# REVLoan
+[Git Source](https://github.com/rev-net/revnet-core-v5/blob/364afaae78a8f60af2b98252dc96af1c2e4760d3/src/structs/REVLoan.sol)
+
+**Notes:**
+- member: borrowedAmount The amount that is being borrowed.
+
+- member: collateralTokenCount The number of collateral tokens currently accounted for.
+
+- member: createdAt The timestamp when the loan was created.
+
+- member: prepaidFeePercent The percentage of the loan's fees that were prepaid.
+
+- member: prepaidDuration The duration that the loan was prepaid for.
+
+- member: source The source of the loan.
+
+
+```solidity
+struct REVLoan {
+    uint112 amount;
+    uint112 collateral;
+    uint48 createdAt;
+    uint16 prepaidFeePercent;
+    uint32 prepaidDuration;
+    REVLoanSource source;
+}
+```
+

package/docs/src/src/structs/REVLoanSource.sol/struct.REVLoanSource.md

@@ -0,0 +1,16 @@
+# REVLoanSource
+[Git Source](https://github.com/rev-net/revnet-core-v5/blob/364afaae78a8f60af2b98252dc96af1c2e4760d3/src/structs/REVLoanSource.sol)
+
+**Notes:**
+- member: token The token that is being loaned.
+
+- member: terminal The terminal that the loan is being made from.
+
+
+```solidity
+struct REVLoanSource {
+    address token;
+    IJBPayoutTerminal terminal;
+}
+```
+

package/docs/src/src/structs/REVStageConfig.sol/struct.REVStageConfig.md

@@ -0,0 +1,44 @@
+# REVStageConfig
+[Git Source](https://github.com/rev-net/revnet-core-v5/blob/364afaae78a8f60af2b98252dc96af1c2e4760d3/src/structs/REVStageConfig.sol)
+
+**Notes:**
+- member: startsAtOrAfter The timestamp to start a stage at the given rate at or after.
+
+- member: autoIssuances The configurations of mints during this stage.
+
+- member: splitPercent The percentage of newly issued tokens that should be split with the operator, out
+of 10_000 (JBConstants.MAX_RESERVED_PERCENT).
+
+- member: splits The splits for the revnet.
+
+- member: initialIssuance The number of revnet tokens that one unit of the revnet's base currency will buy, as
+a fixed point number
+with 18 decimals.
+
+- member: issuanceCutFrequency The number of seconds between applied issuance decreases. This
+should be at least 24 hours.
+
+- member: issuanceCutPercent The percent that issuance should decrease over time. This percentage is out
+of 1_000_000_000 (JBConstants.MAX_CUT_PERCENT). 0% corresponds to no issuance increase.
+
+- member: cashOutTaxRate The factor determining how much each token can cash out from the revnet once
+cashed out. This rate is out of 10_000 (JBConstants.MAX_CASH_OUT_TAX_RATE). 0% corresponds to no tax when cashing
+out.
+
+- member: extraMetadata Extra info to attach set into this stage that may affect hooks.
+
+
+```solidity
+struct REVStageConfig {
+    uint48 startsAtOrAfter;
+    REVAutoIssuance[] autoIssuances;
+    uint16 splitPercent;
+    JBSplit[] splits;
+    uint112 initialIssuance;
+    uint32 issuanceCutFrequency;
+    uint32 issuanceCutPercent;
+    uint16 cashOutTaxRate;
+    uint16 extraMetadata;
+}
+```
+

package/docs/src/src/structs/REVSuckerDeploymentConfig.sol/struct.REVSuckerDeploymentConfig.md

@@ -0,0 +1,16 @@
+# REVSuckerDeploymentConfig
+[Git Source](https://github.com/rev-net/revnet-core-v5/blob/364afaae78a8f60af2b98252dc96af1c2e4760d3/src/structs/REVSuckerDeploymentConfig.sol)
+
+**Notes:**
+- member: deployerConfigurations The information for how to suck tokens to other chains.
+
+- member: salt The salt to use for creating suckers so that they use the same address across chains.
+
+
+```solidity
+struct REVSuckerDeploymentConfig {
+    JBSuckerDeployerConfig[] deployerConfigurations;
+    bytes32 salt;
+}
+```
+

package/foundry.lock

@@ -0,0 +1,11 @@
+{
+  "lib/forge-std": {
+    "rev": "83c5d212a01f8950727da4095cdfe2654baccb5b"
+  },
+  "lib/sphinx": {
+    "branch": {
+      "name": "v0.23.0",
+      "rev": "5fb24a825f46bd6ae0b5359fe0da1d2346126b09"
+    }
+  }
+}

package/foundry.toml

@@ -0,0 +1,23 @@
+[profile.default]
+solc = '0.8.23'
+evm_version = 'paris'
+optimizer_runs = 500
+libs = ["node_modules", "lib"]
+fs_permissions = [{ access = "read-write", path = "./"}]
+
+[profile.ci_sizes]
+optimizer_runs = 200
+via_ir = true
+
+[fuzz]
+runs = 4096
+
+[invariant]
+runs = 1024
+depth = 100
+fail_on_revert = false
+
+[fmt]
+number_underscore = "thousands"
+multiline_func_header = "all"
+wrap_comments = true

package/package.json

@@ -0,0 +1,31 @@
+{
+    "name": "@rev-net/core-v6",
+    "version": "0.0.1",
+    "license": "MIT",
+    "repository": {
+        "type": "git",
+        "url": "git+https://github.com/rev-net/revnet-core-v6"
+    },
+    "scripts": {
+        "test": "forge test",
+        "coverage:integration": "forge coverage --match-path \"./src/*.sol\" --report lcov --report summary",
+        "deploy:mainnets": "source ./.env && export START_TIME=$(date +%s) && npx sphinx propose ./script/Deploy.s.sol --networks mainnets",
+        "deploy:mainnets:1_1": "source ./.env && npx sphinx propose ./script/Deploy1_1.s.sol --networks mainnets",
+        "deploy:testnets": "source ./.env && export START_TIME=$(date +%s) && npx sphinx propose ./script/Deploy.s.sol --networks testnets",
+        "deploy:testnets:1_1": "source ./.env && npx sphinx propose ./script/Deploy1_1.s.sol --networks testnets",
+        "artifacts": "source ./.env && npx sphinx artifacts --org-id 'ea165b21-7cdc-4d7b-be59-ecdd4c26bee4' --project-name 'revnet-core-v6'"
+    },
+    "dependencies": {
+        "@bananapus/721-hook-v6": "^0.0.2",
+        "@bananapus/buyback-hook-v6": "^0.0.1",
+        "@bananapus/core-v6": "^0.0.3",
+        "@bananapus/permission-ids-v6": "^0.0.1",
+        "@bananapus/suckers-v6": "^0.0.1",
+        "@bananapus/swap-terminal-v6": "^0.0.2",
+        "@croptop/core-v6": "^0.0.3",
+        "@openzeppelin/contracts": "^5.2.0"
+    },
+    "devDependencies": {
+        "@sphinx-labs/plugins": "^0.33.1"
+    }
+}

package/remappings.txt

@@ -0,0 +1 @@
+@sphinx-labs/contracts/=node_modules/@sphinx-labs/contracts/contracts/foundry

package/script/Deploy.s.sol

@@ -0,0 +1,350 @@
+// SPDX-License-Identifier: MIT
+pragma solidity 0.8.23;
+
+import "@bananapus/721-hook-v6/script/helpers/Hook721DeploymentLib.sol";
+import "@bananapus/buyback-hook-v6/script/helpers/BuybackDeploymentLib.sol";
+import "@bananapus/core-v6/script/helpers/CoreDeploymentLib.sol";
+import "@bananapus/suckers-v6/script/helpers/SuckerDeploymentLib.sol";
+import "@bananapus/swap-terminal-v6/script/helpers/SwapTerminalDeploymentLib.sol";
+import "@croptop/core-v6/script/helpers/CroptopDeploymentLib.sol";
+
+import {Sphinx} from "@sphinx-labs/contracts/SphinxPlugin.sol";
+import {Script} from "forge-std/Script.sol";
+
+import {JBConstants} from "@bananapus/core-v6/src/libraries/JBConstants.sol";
+import {JBCurrencyIds} from "@bananapus/core-v6/src/libraries/JBCurrencyIds.sol";
+import {JBAccountingContext} from "@bananapus/core-v6/src/structs/JBAccountingContext.sol";
+import {JBTerminalConfig} from "@bananapus/core-v6/src/structs/JBTerminalConfig.sol";
+import {JBSuckerDeployerConfig} from "@bananapus/suckers-v6/src/structs/JBSuckerDeployerConfig.sol";
+import {JBTokenMapping} from "@bananapus/suckers-v6/src/structs/JBTokenMapping.sol";
+import {IPermit2} from "@uniswap/permit2/src/interfaces/IPermit2.sol";
+import {IJBSplitHook} from "@bananapus/core-v6/src/interfaces/IJBSplitHook.sol";
+import {IJBTerminal} from "@bananapus/core-v6/src/interfaces/IJBTerminal.sol";
+import {IJBRulesetDataHook} from "@bananapus/core-v6/src/interfaces/IJBRulesetDataHook.sol";
+import {JBSplit} from "@bananapus/core-v6/src/structs/JBSplit.sol";
+
+import {REVDeployer} from "./../src/REVDeployer.sol";
+import {REVAutoIssuance} from "../src/structs/REVAutoIssuance.sol";
+import {REVConfig} from "../src/structs/REVConfig.sol";
+import {REVDescription} from "../src/structs/REVDescription.sol";
+import {REVStageConfig} from "../src/structs/REVStageConfig.sol";
+import {REVSuckerDeploymentConfig} from "../src/structs/REVSuckerDeploymentConfig.sol";
+import {REVLoans, IREVLoans} from "./../src/REVLoans.sol";
+
+struct FeeProjectConfig {
+    REVConfig configuration;
+    JBTerminalConfig[] terminalConfigurations;
+    REVSuckerDeploymentConfig suckerDeploymentConfiguration;
+}
+
+contract DeployScript is Script, Sphinx {
+    /// @notice tracks the deployment of the buyback hook.
+    BuybackDeployment buybackHook;
+    /// @notice tracks the deployment of the core contracts for the chain we are deploying to.
+    CoreDeployment core;
+    /// @notice tracks the deployment of the croptop contracts for the chain we are deploying to.
+    CroptopDeployment croptop;
+    /// @notice tracks the deployment of the 721 hook contracts for the chain we are deploying to.
+    Hook721Deployment hook;
+    /// @notice tracks the deployment of the sucker contracts for the chain we are deploying to.
+    SuckerDeployment suckers;
+    /// @notice tracks the deployment of the swap terminal.
+    SwapTerminalDeployment swapTerminal;
+
+    uint32 PREMINT_CHAIN_ID = 1;
+    string NAME = "Revnet";
+    string SYMBOL = "REV";
+    string PROJECT_URI = "ipfs://QmcCBD5fM927LjkLDSJWtNEU9FohcbiPSfqtGRHXFHzJ4W";
+    uint32 NATIVE_CURRENCY = uint32(uint160(JBConstants.NATIVE_TOKEN));
+    uint32 ETH_CURRENCY = JBCurrencyIds.ETH;
+    uint8 DECIMALS = 18;
+    uint256 DECIMAL_MULTIPLIER = 10 ** DECIMALS;
+    bytes32 ERC20_SALT = "_REV_ERC20_SALT_V6_";
+    bytes32 SUCKER_SALT = "_REV_SUCKER_SALT_V6_";
+    bytes32 DEPLOYER_SALT = "_REV_DEPLOYER_SALT_V6_";
+    bytes32 REVLOANS_SALT = "_REV_LOANS_SALT_V6_";
+    address LOANS_OWNER;
+    address OPERATOR;
+    address TRUSTED_FORWARDER;
+    IPermit2 PERMIT2;
+    uint48 REV_START_TIME = 1_740_089_444;
+    uint104 REV_MAINNET_AUTO_ISSUANCE_ = 1_050_482_341_387_116_262_330_122;
+    uint104 REV_BASE_AUTO_ISSUANCE_ = 38_544_322_230_437_559_731_228;
+    uint104 REV_OP_AUTO_ISSUANCE_ = 32_069_388_242_375_817_844;
+    uint104 REV_ARB_AUTO_ISSUANCE_ = 3_479_431_776_906_850_000_000;
+
+    function configureSphinx() public override {
+        // TODO: Update to contain revnet devs.
+        sphinxConfig.projectName = "revnet-core-v6";
+        sphinxConfig.mainnets = ["ethereum", "optimism", "base", "arbitrum"];
+        sphinxConfig.testnets = ["ethereum_sepolia", "optimism_sepolia", "base_sepolia", "arbitrum_sepolia"];
+    }
+
+    function run() public {
+        // Get the operator address.
+        OPERATOR = safeAddress();
+        // Get the loans owner address.
+        LOANS_OWNER = safeAddress();
+
+        // Get the deployment addresses for the nana CORE for this chain.
+        // We want to do this outside of the `sphinx` modifier.
+        core = CoreDeploymentLib.getDeployment(
+            vm.envOr("NANA_CORE_DEPLOYMENT_PATH", string("node_modules/@bananapus/core-v6/deployments/"))
+        );
+        // Get the deployment addresses for the suckers contracts for this chain.
+        suckers = SuckerDeploymentLib.getDeployment(
+            vm.envOr("NANA_SUCKERS_DEPLOYMENT_PATH", string("node_modules/@bananapus/suckers-v6/deployments/"))
+        );
+        // Get the deployment addresses for the 721 hook contracts for this chain.
+        croptop = CroptopDeploymentLib.getDeployment(
+            vm.envOr("CROPTOP_CORE_DEPLOYMENT_PATH", string("node_modules/@croptop/core-v6/deployments/"))
+        );
+        // Get the deployment addresses for the 721 hook contracts for this chain.
+        hook = Hook721DeploymentLib.getDeployment(
+            vm.envOr("NANA_721_DEPLOYMENT_PATH", string("node_modules/@bananapus/721-hook-v6/deployments/"))
+        );
+        // Get the deployment addresses for the 721 hook contracts for this chain.
+        swapTerminal = SwapTerminalDeploymentLib.getDeployment(
+            vm.envOr(
+                "NANA_SWAP_TERMINAL_DEPLOYMENT_PATH", string("node_modules/@bananapus/swap-terminal-v6/deployments/")
+            )
+        );
+        // Get the deployment addresses for the 721 hook contracts for this chain.
+        buybackHook = BuybackDeploymentLib.getDeployment(
+            vm.envOr(
+                "NANA_BUYBACK_HOOK_DEPLOYMENT_PATH", string("node_modules/@bananapus/buyback-hook-v6/deployments/")
+            )
+        );
+
+        // We use the same trusted forwarder and permit2 as the core deployment.
+        TRUSTED_FORWARDER = core.controller.trustedForwarder();
+        PERMIT2 = core.terminal.PERMIT2();
+
+        // Perform the deployment transactions.
+        deploy();
+    }
+
+    function getFeeProjectConfig() internal view returns (FeeProjectConfig memory) {
+        // The tokens that the project accepts and stores.
+        JBAccountingContext[] memory accountingContextsToAccept = new JBAccountingContext[](1);
+
+        // Accept the chain's native currency through the multi terminal.
+        accountingContextsToAccept[0] =
+            JBAccountingContext({token: JBConstants.NATIVE_TOKEN, decimals: DECIMALS, currency: NATIVE_CURRENCY});
+
+        // The terminals that the project will accept funds through.
+        JBTerminalConfig[] memory terminalConfigurations = new JBTerminalConfig[](2);
+        terminalConfigurations[0] =
+            JBTerminalConfig({terminal: core.terminal, accountingContextsToAccept: accountingContextsToAccept});
+        terminalConfigurations[1] = JBTerminalConfig({
+            terminal: IJBTerminal(address(swapTerminal.native_registry)),
+            accountingContextsToAccept: new JBAccountingContext[](0)
+        });
+
+        // The project's revnet stage configurations.
+        REVStageConfig[] memory stageConfigurations = new REVStageConfig[](3);
+
+        // Create a split group that assigns all of the splits to the operator.
+        JBSplit[] memory splits = new JBSplit[](1);
+        splits[0] = JBSplit({
+            preferAddToBalance: false,
+            percent: JBConstants.SPLITS_TOTAL_PERCENT,
+            projectId: 0,
+            beneficiary: payable(OPERATOR),
+            lockedUntil: 0,
+            hook: IJBSplitHook(address(0))
+        });
+
+        {
+            REVAutoIssuance[] memory issuanceConfs = new REVAutoIssuance[](4);
+            issuanceConfs[0] = REVAutoIssuance({chainId: 1, count: REV_MAINNET_AUTO_ISSUANCE_, beneficiary: OPERATOR});
+            issuanceConfs[1] = REVAutoIssuance({chainId: 8453, count: REV_BASE_AUTO_ISSUANCE_, beneficiary: OPERATOR});
+            issuanceConfs[2] = REVAutoIssuance({chainId: 10, count: REV_OP_AUTO_ISSUANCE_, beneficiary: OPERATOR});
+            issuanceConfs[3] = REVAutoIssuance({chainId: 42_161, count: REV_ARB_AUTO_ISSUANCE_, beneficiary: OPERATOR});
+
+            stageConfigurations[0] = REVStageConfig({
+                startsAtOrAfter: REV_START_TIME,
+                autoIssuances: issuanceConfs,
+                splitPercent: 3800, // 38%
+                splits: splits,
+                initialIssuance: uint112(10_000 * DECIMAL_MULTIPLIER),
+                issuanceCutFrequency: 90 days,
+                issuanceCutPercent: 380_000_000, // 38%
+                cashOutTaxRate: 1000, // 0.1
+                extraMetadata: 4 // Allow adding suckers.
+            });
+        }
+
+        {
+            REVAutoIssuance[] memory issuanceConfs = new REVAutoIssuance[](1);
+            issuanceConfs[0] = REVAutoIssuance({
+                chainId: PREMINT_CHAIN_ID, count: uint104(1_550_000 * DECIMAL_MULTIPLIER), beneficiary: OPERATOR
+            });
+
+            stageConfigurations[1] = REVStageConfig({
+                startsAtOrAfter: uint40(stageConfigurations[0].startsAtOrAfter + 720 days),
+                autoIssuances: issuanceConfs,
+                splitPercent: 3800, // 38%
+                splits: splits,
+                initialIssuance: 1, // inherit from previous cycle.
+                issuanceCutFrequency: 30 days,
+                issuanceCutPercent: 70_000_000, // 7%
+                cashOutTaxRate: 1000, // 0.1
+                extraMetadata: 4 // Allow adding suckers.
+            });
+        }
+
+        stageConfigurations[2] = REVStageConfig({
+            startsAtOrAfter: uint40(stageConfigurations[1].startsAtOrAfter + 3600 days),
+            autoIssuances: new REVAutoIssuance[](0),
+            splitPercent: 3800, // 38%
+            splits: splits,
+            initialIssuance: 0, // no more issaunce.
+            issuanceCutFrequency: 0,
+            issuanceCutPercent: 0,
+            cashOutTaxRate: 1000, // 0.1
+            extraMetadata: 4 // Allow adding suckers.
+        });
+
+        // The project's revnet configuration
+        REVConfig memory revnetConfiguration = REVConfig({
+            description: REVDescription(NAME, SYMBOL, PROJECT_URI, ERC20_SALT),
+            baseCurrency: ETH_CURRENCY,
+            splitOperator: OPERATOR,
+            stageConfigurations: stageConfigurations
+        });
+
+        // Organize the instructions for how this project will connect to other chains.
+        JBTokenMapping[] memory tokenMappings = new JBTokenMapping[](1);
+        tokenMappings[0] = JBTokenMapping({
+            localToken: JBConstants.NATIVE_TOKEN,
+            remoteToken: bytes32(uint256(uint160(JBConstants.NATIVE_TOKEN))),
+            minGas: 200_000,
+            minBridgeAmount: 0.01 ether
+        });
+
+        REVSuckerDeploymentConfig memory suckerDeploymentConfiguration;
+
+        {
+            JBSuckerDeployerConfig[] memory suckerDeployerConfigurations;
+            if (block.chainid == 1 || block.chainid == 11_155_111) {
+                suckerDeployerConfigurations = new JBSuckerDeployerConfig[](3);
+                // OP
+                suckerDeployerConfigurations[0] =
+                    JBSuckerDeployerConfig({deployer: suckers.optimismDeployer, mappings: tokenMappings});
+
+                suckerDeployerConfigurations[1] =
+                    JBSuckerDeployerConfig({deployer: suckers.baseDeployer, mappings: tokenMappings});
+
+                suckerDeployerConfigurations[2] =
+                    JBSuckerDeployerConfig({deployer: suckers.arbitrumDeployer, mappings: tokenMappings});
+            } else {
+                suckerDeployerConfigurations = new JBSuckerDeployerConfig[](1);
+                // L2 -> Mainnet
+                suckerDeployerConfigurations[0] = JBSuckerDeployerConfig({
+                    deployer: address(suckers.optimismDeployer) != address(0)
+                        ? suckers.optimismDeployer
+                        : address(suckers.baseDeployer) != address(0) ? suckers.baseDeployer : suckers.arbitrumDeployer,
+                    mappings: tokenMappings
+                });
+
+                if (address(suckerDeployerConfigurations[0].deployer) == address(0)) {
+                    revert("L2 > L1 Sucker is not configured");
+                }
+            }
+            // Specify all sucker deployments.
+            suckerDeploymentConfiguration =
+                REVSuckerDeploymentConfig({deployerConfigurations: suckerDeployerConfigurations, salt: SUCKER_SALT});
+        }
+
+        return FeeProjectConfig({
+            configuration: revnetConfiguration,
+            terminalConfigurations: terminalConfigurations,
+            suckerDeploymentConfiguration: suckerDeploymentConfiguration
+        });
+    }
+
+    function deploy() public sphinx {
+        // TODO figure out how to reference project ID if the contracts are already deployed.
+        uint256 FEE_PROJECT_ID = core.projects.createFor(safeAddress());
+
+        // Deploy REVLoans first — it only depends on the controller.
+        (address _revloansAddr, bool _revloansIsDeployed) = _isDeployed(
+            REVLOANS_SALT,
+            type(REVLoans).creationCode,
+            abi.encode(core.controller, core.projects, FEE_PROJECT_ID, LOANS_OWNER, PERMIT2, TRUSTED_FORWARDER)
+        );
+        REVLoans revloans = _revloansIsDeployed
+            ? REVLoans(payable(_revloansAddr))
+            : new REVLoans{salt: REVLOANS_SALT}({
+                controller: core.controller,
+                projects: core.projects,
+                revId: FEE_PROJECT_ID,
+                owner: LOANS_OWNER,
+                permit2: PERMIT2,
+                trustedForwarder: TRUSTED_FORWARDER
+            });
+
+        // Deploy REVDeployer with the REVLoans and buyback hook addresses.
+        (address _deployerAddr, bool _deployerIsDeployed) = _isDeployed(
+            DEPLOYER_SALT,
+            type(REVDeployer).creationCode,
+            abi.encode(
+                core.controller,
+                suckers.registry,
+                FEE_PROJECT_ID,
+                hook.hook_deployer,
+                croptop.publisher,
+                IJBRulesetDataHook(address(buybackHook.registry)),
+                address(revloans),
+                TRUSTED_FORWARDER
+            )
+        );
+        REVDeployer _basicDeployer = _deployerIsDeployed
+            ? REVDeployer(payable(_deployerAddr))
+            : new REVDeployer{salt: DEPLOYER_SALT}(
+                core.controller,
+                suckers.registry,
+                FEE_PROJECT_ID,
+                hook.hook_deployer,
+                croptop.publisher,
+                IJBRulesetDataHook(address(buybackHook.registry)),
+                address(revloans),
+                TRUSTED_FORWARDER
+            );
+
+        // Approve the basic deployer to configure the project.
+        core.projects.approve(address(_basicDeployer), FEE_PROJECT_ID);
+
+        // Build the config.
+        FeeProjectConfig memory feeProjectConfig = getFeeProjectConfig();
+
+        // Configure the project.
+        _basicDeployer.deployFor({
+            revnetId: FEE_PROJECT_ID,
+            configuration: feeProjectConfig.configuration,
+            terminalConfigurations: feeProjectConfig.terminalConfigurations,
+            suckerDeploymentConfiguration: feeProjectConfig.suckerDeploymentConfiguration
+        });
+    }
+
+    function _isDeployed(
+        bytes32 salt,
+        bytes memory creationCode,
+        bytes memory arguments
+    )
+        internal
+        view
+        returns (address deployedTo, bool isDeployed)
+    {
+        address _deployedTo = vm.computeCreate2Address({
+            salt: salt,
+            initCodeHash: keccak256(abi.encodePacked(creationCode, arguments)),
+            // Arachnid/deterministic-deployment-proxy address.
+            deployer: address(0x4e59b44847b379578588920cA78FbF26c0B4956C)
+        });
+
+        // Return if code is already present at this address.
+        return (_deployedTo, address(_deployedTo).code.length != 0);
+    }
+}

package/script/helpers/RevnetCoreDeploymentLib.sol

@@ -0,0 +1,72 @@
+// SPDX-License-Identifier: MIT
+pragma solidity 0.8.23;
+
+import {stdJson} from "forge-std/Script.sol";
+import {Vm} from "forge-std/Vm.sol";
+import {SphinxConstants, NetworkInfo} from "@sphinx-labs/contracts/SphinxConstants.sol";
+
+import {IREVDeployer} from "./../../src/interfaces/IREVDeployer.sol";
+import {IREVLoans} from "./../../src/interfaces/IREVLoans.sol";
+
+struct RevnetCoreDeployment {
+    IREVDeployer basic_deployer;
+    IREVLoans loans;
+}
+
+library RevnetCoreDeploymentLib {
+    // Cheat code address, 0x7109709ECfa91a80626fF3989D68f67F5b1DD12D.
+    address internal constant VM_ADDRESS = address(uint160(uint256(keccak256("hevm cheat code"))));
+    Vm internal constant vm = Vm(VM_ADDRESS);
+
+    function getDeployment(string memory path) internal returns (RevnetCoreDeployment memory deployment) {
+        // get chainId for which we need to get the deployment.
+        uint256 chainId = block.chainid;
+
+        // Deploy to get the constants.
+        // TODO: get constants without deploy.
+        SphinxConstants sphinxConstants = new SphinxConstants();
+        NetworkInfo[] memory networks = sphinxConstants.getNetworkInfoArray();
+
+        for (uint256 _i; _i < networks.length; _i++) {
+            if (networks[_i].chainId == chainId) {
+                return getDeployment(path, networks[_i].name);
+            }
+        }
+
+        revert("ChainID is not (currently) supported by Sphinx.");
+    }
+
+    function getDeployment(
+        string memory path,
+        string memory network_name
+    )
+        internal
+        view
+        returns (RevnetCoreDeployment memory deployment)
+    {
+        deployment.basic_deployer =
+            IREVDeployer(_getDeploymentAddress(path, "revnet-core-v6", network_name, "REVDeployer"));
+
+        deployment.loans = IREVLoans(_getDeploymentAddress(path, "revnet-core-v6", network_name, "REVLoans"));
+    }
+
+    /// @notice Get the address of a contract that was deployed by the Deploy script.
+    /// @dev Reverts if the contract was not found.
+    /// @param path The path to the deployment file.
+    /// @param contractName The name of the contract to get the address of.
+    /// @return The address of the contract.
+    function _getDeploymentAddress(
+        string memory path,
+        string memory project_name,
+        string memory network_name,
+        string memory contractName
+    )
+        internal
+        view
+        returns (address)
+    {
+        string memory deploymentJson =
+            vm.readFile(string.concat(path, project_name, "/", network_name, "/", contractName, ".json"));
+        return stdJson.readAddress(deploymentJson, ".address");
+    }
+}

package/slither-ci.config.json

@@ -0,0 +1,10 @@
+{
+  "detectors_to_exclude": "timestamp,uninitialized-local,naming-convention,solc-version,shadowing-local",
+  "exclude_informational": true,
+  "exclude_low": false,
+  "exclude_medium": false,
+  "exclude_high": false,
+  "disable_color": false,
+  "filter_paths": "(mocks/|test/|node_modules/)",
+  "legacy_ast": false
+}