@rarible/external-contracts 3.11.4

package/contracts/infra/TWFactory.sol

@@ -0,0 +1,140 @@
+// SPDX-License-Identifier: Apache-2.0
+pragma solidity ^0.8.11;
+
+/// @author thirdweb
+
+//   $$\     $$\       $$\                 $$\                         $$\
+//   $$ |    $$ |      \__|                $$ |                        $$ |
+// $$$$$$\   $$$$$$$\  $$\  $$$$$$\   $$$$$$$ |$$\  $$\  $$\  $$$$$$\  $$$$$$$\
+// \_$$  _|  $$  __$$\ $$ |$$  __$$\ $$  __$$ |$$ | $$ | $$ |$$  __$$\ $$  __$$\
+//   $$ |    $$ |  $$ |$$ |$$ |  \__|$$ /  $$ |$$ | $$ | $$ |$$$$$$$$ |$$ |  $$ |
+//   $$ |$$\ $$ |  $$ |$$ |$$ |      $$ |  $$ |$$ | $$ | $$ |$$   ____|$$ |  $$ |
+//   \$$$$  |$$ |  $$ |$$ |$$ |      \$$$$$$$ |\$$$$$\$$$$  |\$$$$$$$\ $$$$$$$  |
+//    \____/ \__|  \__|\__|\__|       \_______| \_____\____/  \_______|\_______/
+
+import { TWRegistry } from "./TWRegistry.sol";
+import "./interface/IThirdwebContract.sol";
+import "../extension/interface/IContractFactory.sol";
+
+import { AccessControlEnumerable, Context } from "@openzeppelin/contracts/access/AccessControlEnumerable.sol";
+import { ERC2771Context } from "../external-deps/openzeppelin/metatx/ERC2771Context.sol";
+import { Create2 } from "@openzeppelin/contracts/utils/Create2.sol";
+import { Multicall } from "../extension/Multicall.sol";
+import "@openzeppelin/contracts/utils/Address.sol";
+import { Clones } from "@openzeppelin/contracts/proxy/Clones.sol";
+
+contract TWFactory is Multicall, ERC2771Context, AccessControlEnumerable, IContractFactory {
+    /// @dev Only FACTORY_ROLE holders can approve/unapprove implementations for proxies to point to.
+    bytes32 public constant FACTORY_ROLE = keccak256("FACTORY_ROLE");
+
+    TWRegistry public immutable registry;
+
+    /// @dev Emitted when a proxy is deployed.
+    event ProxyDeployed(address indexed implementation, address proxy, address indexed deployer);
+    event ImplementationAdded(address implementation, bytes32 indexed contractType, uint256 version);
+    event ImplementationApproved(address implementation, bool isApproved);
+
+    /// @dev mapping of implementation address to deployment approval
+    mapping(address => bool) public approval;
+
+    /// @dev mapping of implementation address to implementation added version
+    mapping(bytes32 => uint256) public currentVersion;
+
+    /// @dev mapping of contract type to module version to implementation address
+    mapping(bytes32 => mapping(uint256 => address)) public implementation;
+
+    /// @dev mapping of proxy address to deployer address
+    mapping(address => address) public deployer;
+
+    constructor(address[] memory _trustedForwarders, address _registry) ERC2771Context(_trustedForwarders) {
+        _setupRole(DEFAULT_ADMIN_ROLE, _msgSender());
+        _setupRole(FACTORY_ROLE, _msgSender());
+
+        registry = TWRegistry(_registry);
+    }
+
+    /// @dev Deploys a proxy that points to the latest version of the given contract type.
+    function deployProxy(bytes32 _type, bytes memory _data) external returns (address) {
+        bytes32 salt = bytes32(registry.count(_msgSender()));
+        return deployProxyDeterministic(_type, _data, salt);
+    }
+
+    /**
+     *  @dev Deploys a proxy at a deterministic address by taking in `salt` as a parameter.
+     *       Proxy points to the latest version of the given contract type.
+     */
+    function deployProxyDeterministic(bytes32 _type, bytes memory _data, bytes32 _salt) public returns (address) {
+        address _implementation = implementation[_type][currentVersion[_type]];
+        return deployProxyByImplementation(_implementation, _data, _salt);
+    }
+
+    /// @dev Deploys a proxy that points to the given implementation.
+    function deployProxyByImplementation(
+        address _implementation,
+        bytes memory _data,
+        bytes32 _salt
+    ) public override returns (address deployedProxy) {
+        require(approval[_implementation], "implementation not approved");
+
+        bytes32 salthash = keccak256(abi.encodePacked(_msgSender(), _salt));
+        deployedProxy = Clones.cloneDeterministic(_implementation, salthash);
+
+        deployer[deployedProxy] = _msgSender();
+
+        emit ProxyDeployed(_implementation, deployedProxy, _msgSender());
+
+        registry.add(_msgSender(), deployedProxy);
+
+        if (_data.length > 0) {
+            // slither-disable-next-line unused-return
+            Address.functionCall(deployedProxy, _data);
+        }
+    }
+
+    /// @dev Lets a contract admin set the address of a contract type x version.
+    function addImplementation(address _implementation) external {
+        require(hasRole(FACTORY_ROLE, _msgSender()), "not admin.");
+
+        IThirdwebContract module = IThirdwebContract(_implementation);
+
+        bytes32 ctype = module.contractType();
+        require(ctype.length > 0, "invalid module");
+
+        uint8 version = module.contractVersion();
+        uint8 currentVersionOfType = uint8(currentVersion[ctype]);
+        require(version >= currentVersionOfType, "wrong module version");
+
+        currentVersion[ctype] = version;
+        implementation[ctype][version] = _implementation;
+        approval[_implementation] = true;
+
+        emit ImplementationAdded(_implementation, ctype, version);
+    }
+
+    /// @dev Lets a contract admin approve a specific contract for deployment.
+    function approveImplementation(address _implementation, bool _toApprove) external {
+        require(hasRole(FACTORY_ROLE, _msgSender()), "not admin.");
+
+        approval[_implementation] = _toApprove;
+
+        emit ImplementationApproved(_implementation, _toApprove);
+    }
+
+    /// @dev Returns the implementation given a contract type and version.
+    function getImplementation(bytes32 _type, uint256 _version) external view returns (address) {
+        return implementation[_type][_version];
+    }
+
+    /// @dev Returns the latest implementation given a contract type.
+    function getLatestImplementation(bytes32 _type) external view returns (address) {
+        return implementation[_type][currentVersion[_type]];
+    }
+
+    function _msgSender() internal view virtual override(Context, ERC2771Context, Multicall) returns (address sender) {
+        return ERC2771Context._msgSender();
+    }
+
+    function _msgData() internal view virtual override(Context, ERC2771Context) returns (bytes calldata) {
+        return ERC2771Context._msgData();
+    }
+}

package/contracts/infra/TWFee.sol

@@ -0,0 +1,162 @@
+// SPDX-License-Identifier: Apache-2.0
+pragma solidity ^0.8.11;
+
+/// @author thirdweb
+
+import "./TWFactory.sol";
+import "./interface/ITWFee.sol";
+
+import "@openzeppelin/contracts/access/AccessControlEnumerable.sol";
+import { Multicall } from "../extension/Multicall.sol";
+import "../external-deps/openzeppelin/metatx/ERC2771Context.sol";
+
+interface IFeeTierPlacementExtension {
+    /// @dev Returns the fee tier for a given proxy contract address and proxy deployer address.
+    function getFeeTier(
+        address deployer,
+        address proxy
+    ) external view returns (uint128 tierId, uint128 validUntilTimestamp);
+}
+
+contract TWFee is ITWFee, Multicall, ERC2771Context, AccessControlEnumerable, IFeeTierPlacementExtension {
+    /// @dev The factory for deploying contracts.
+    TWFactory public immutable factory;
+
+    /// @dev The maximum threshold for fees. 1%
+    uint256 public constant MAX_FEE_BPS = 100;
+
+    /// @dev TIER_FEE_ROLE holders can create tiers.
+    bytes32 private constant TIER_FEE_ROLE = keccak256("TIER_FEE_ROLE");
+
+    /// @dev TIER_CONTROLLER_ROLE holders can assign tiers to deployer or proxy.
+    bytes32 private constant TIER_CONTROLLER_ROLE = keccak256("TIER_CONTROLLER_ROLE");
+
+    /// @dev Mapping from proxy contract or proxy deployer address => pricing tier.
+    mapping(address => Tier) private tier;
+
+    /// @dev Mapping from pricing tier id => Fee Type (lib/FeeType.sol) => FeeInfo
+    mapping(uint256 => mapping(uint256 => FeeInfo)) public feeInfo;
+
+    /// @dev If we want to extend the logic for fee tier placement, we
+    /// could easily points it to a different extension implementation.
+    IFeeTierPlacementExtension public tierPlacementExtension;
+
+    struct Tier {
+        uint128 id;
+        uint128 validUntilTimestamp;
+    }
+
+    struct FeeInfo {
+        uint256 bps;
+        address recipient;
+    }
+
+    /// @dev Events
+    event TierUpdated(address indexed proxyOrDeployer, uint256 tierId, uint256 validUntilTimestamp);
+    event FeeTierUpdated(uint256 indexed tierId, uint256 indexed feeType, address recipient, uint256 bps);
+
+    constructor(address[] memory _trustedForwarders, address _factory) ERC2771Context(_trustedForwarders) {
+        factory = TWFactory(_factory);
+
+        _setupRole(DEFAULT_ADMIN_ROLE, _msgSender());
+        _setupRole(TIER_FEE_ROLE, _msgSender());
+        _setupRole(TIER_CONTROLLER_ROLE, _msgSender());
+    }
+
+    function setFeeTierPlacementExtension(address _extension) public onlyRole(DEFAULT_ADMIN_ROLE) {
+        tierPlacementExtension = IFeeTierPlacementExtension(_extension);
+    }
+
+    /// @dev Returns the fee tier for a proxy deployer wallet or contract address.
+    function getFeeTier(
+        address _deployer,
+        address _proxy
+    ) public view override returns (uint128 tierId, uint128 validUntilTimestamp) {
+        Tier memory targetTier = tier[_proxy];
+        if (block.timestamp <= targetTier.validUntilTimestamp) {
+            tierId = targetTier.id;
+            validUntilTimestamp = targetTier.validUntilTimestamp;
+        } else {
+            tierId = 0;
+            validUntilTimestamp = 0;
+        }
+
+        // if the proxy doesn't have a tier, then look up the deployer's tier
+        if (tierId == 0 && validUntilTimestamp == 0) {
+            targetTier = tier[_deployer];
+            if (block.timestamp <= targetTier.validUntilTimestamp) {
+                tierId = targetTier.id;
+                validUntilTimestamp = targetTier.validUntilTimestamp;
+            } else {
+                tierId = 0;
+                validUntilTimestamp = 0;
+            }
+        }
+    }
+
+    /// @dev Returns the fee info for a given module and fee type.
+    function getFeeInfo(address _proxy, uint256 _feeType) external view returns (address recipient, uint256 bps) {
+        address deployer = factory.deployer(_proxy);
+        uint128 tierId = 0;
+        uint128 validUntilTimestamp = 0;
+
+        if (address(tierPlacementExtension) != address(0)) {
+            // https://github.com/crytic/slither/issues/982
+            // slither-disable-next-line unused-return
+            try tierPlacementExtension.getFeeTier(deployer, _proxy) returns (
+                // slither-disable-next-line uninitialized-local,variable-scope
+                uint128 retTierId,
+                // slither-disable-next-line uninitialized-local,variable-scope
+                uint128 retValidUntilTimestamp
+            ) {
+                tierId = retTierId;
+                validUntilTimestamp = retValidUntilTimestamp;
+                // solhint-disable-next-line no-empty-blocks
+            } catch {}
+        }
+
+        // if extension doesn't return a tier, then we fetch the local states
+        if (tierId == 0 && validUntilTimestamp == 0) {
+            (tierId, ) = getFeeTier(deployer, _proxy);
+        }
+
+        FeeInfo memory targetFeeInfo = feeInfo[tierId][_feeType];
+        (recipient, bps) = (targetFeeInfo.recipient, targetFeeInfo.bps);
+    }
+
+    /// @dev Lets a TIER_CONTROLLER_ROLE holder assign a tier to a proxy deployer.
+    function setTier(
+        address _proxyOrDeployer,
+        uint128 _tierId,
+        uint128 _validUntilTimestamp
+    ) external onlyRole(TIER_CONTROLLER_ROLE) {
+        tier[_proxyOrDeployer] = Tier({ id: _tierId, validUntilTimestamp: _validUntilTimestamp });
+
+        emit TierUpdated(_proxyOrDeployer, _tierId, _validUntilTimestamp);
+    }
+
+    /// @dev Lets the admin set fee bps and recipient for the given pricing tier and fee type.
+    function setFeeInfoForTier(
+        uint256 _tierId,
+        uint256 _feeBps,
+        address _feeRecipient,
+        uint256 _feeType
+    ) external onlyRole(TIER_FEE_ROLE) {
+        require(_feeBps <= MAX_FEE_BPS, "fee too high.");
+
+        FeeInfo memory feeInfoToSet = FeeInfo({ bps: _feeBps, recipient: _feeRecipient });
+        feeInfo[_tierId][_feeType] = feeInfoToSet;
+
+        emit FeeTierUpdated(_tierId, _feeType, _feeRecipient, _feeBps);
+    }
+
+    //  =====   Getters   =====
+
+    function _msgSender() internal view virtual override(Context, ERC2771Context, Multicall) returns (address sender) {
+        return ERC2771Context._msgSender();
+    }
+
+    function _msgData() internal view virtual override(Context, ERC2771Context) returns (bytes calldata) {
+        return ERC2771Context._msgData();
+    }
+}

package/contracts/infra/TWMinimalFactory.sol

@@ -0,0 +1,47 @@
+// SPDX-License-Identifier: Apache-2.0
+pragma solidity ^0.8.11;
+
+/// @author thirdweb
+
+//   $$\     $$\       $$\                 $$\                         $$\
+//   $$ |    $$ |      \__|                $$ |                        $$ |
+// $$$$$$\   $$$$$$$\  $$\  $$$$$$\   $$$$$$$ |$$\  $$\  $$\  $$$$$$\  $$$$$$$\
+// \_$$  _|  $$  __$$\ $$ |$$  __$$\ $$  __$$ |$$ | $$ | $$ |$$  __$$\ $$  __$$\
+//   $$ |    $$ |  $$ |$$ |$$ |  \__|$$ /  $$ |$$ | $$ | $$ |$$$$$$$$ |$$ |  $$ |
+//   $$ |$$\ $$ |  $$ |$$ |$$ |      $$ |  $$ |$$ | $$ | $$ |$$   ____|$$ |  $$ |
+//   \$$$$  |$$ |  $$ |$$ |$$ |      \$$$$$$$ |\$$$$$\$$$$  |\$$$$$$$\ $$$$$$$  |
+//    \____/ \__|  \__|\__|\__|       \_______| \_____\____/  \_______|\_______/
+
+import "@openzeppelin/contracts/utils/Address.sol";
+import "@openzeppelin/contracts/proxy/Clones.sol";
+
+contract TWMinimalFactory {
+    /// @dev Deploys a proxy that points to the given implementation.
+    constructor(address _implementation, bytes memory _data, bytes32 _salt) payable {
+        address instance;
+        bytes32 salthash = keccak256(abi.encodePacked(msg.sender, _salt));
+        assembly {
+            let ptr := mload(0x40)
+            mstore(ptr, 0x3d602d80600a3d3981f3363d3d373d3d3d363d73000000000000000000000000)
+            mstore(add(ptr, 0x14), shl(0x60, _implementation))
+            mstore(add(ptr, 0x28), 0x5af43d82803e903d91602b57fd5bf30000000000000000000000000000000000)
+            instance := create2(0, ptr, 0x37, salthash)
+        }
+
+        if (_data.length > 0) {
+            // instance.call{ value: msg.value }(_data);
+
+            // solhint-disable-next-line avoid-low-level-calls
+            (bool success, bytes memory result) = instance.call{ value: msg.value }(_data);
+
+            if (!success) {
+                // Next 5 lines from https://ethereum.stackexchange.com/a/83577
+                if (result.length < 68) revert("Transaction reverted silently");
+                assembly {
+                    result := add(result, 0x04)
+                }
+                revert(abi.decode(result, (string)));
+            }
+        }
+    }
+}

package/contracts/infra/TWMultichainRegistry.sol

@@ -0,0 +1,116 @@
+// SPDX-License-Identifier: Apache-2.0
+pragma solidity ^0.8.11;
+
+/// @author thirdweb
+
+//   $$\     $$\       $$\                 $$\                         $$\
+//   $$ |    $$ |      \__|                $$ |                        $$ |
+// $$$$$$\   $$$$$$$\  $$\  $$$$$$\   $$$$$$$ |$$\  $$\  $$\  $$$$$$\  $$$$$$$\
+// \_$$  _|  $$  __$$\ $$ |$$  __$$\ $$  __$$ |$$ | $$ | $$ |$$  __$$\ $$  __$$\
+//   $$ |    $$ |  $$ |$$ |$$ |  \__|$$ /  $$ |$$ | $$ | $$ |$$$$$$$$ |$$ |  $$ |
+//   $$ |$$\ $$ |  $$ |$$ |$$ |      $$ |  $$ |$$ | $$ | $$ |$$   ____|$$ |  $$ |
+//   \$$$$  |$$ |  $$ |$$ |$$ |      \$$$$$$$ |\$$$$$\$$$$  |\$$$$$$$\ $$$$$$$  |
+//    \____/ \__|  \__|\__|\__|       \_______| \_____\____/  \_______|\_______/
+
+import "@openzeppelin/contracts/utils/structs/EnumerableSet.sol";
+import "@openzeppelin/contracts/access/AccessControlEnumerable.sol";
+import "../extension/Multicall.sol";
+import "../external-deps/openzeppelin/metatx/ERC2771Context.sol";
+
+import "./interface/ITWMultichainRegistry.sol";
+
+contract TWMultichainRegistry is ITWMultichainRegistry, Multicall, ERC2771Context, AccessControlEnumerable {
+    bytes32 public constant OPERATOR_ROLE = keccak256("OPERATOR_ROLE");
+
+    using EnumerableSet for EnumerableSet.AddressSet;
+    using EnumerableSet for EnumerableSet.UintSet;
+
+    /// @dev wallet address => [contract addresses]
+    mapping(address => mapping(uint256 => EnumerableSet.AddressSet)) private deployments;
+    /// @dev contract address deployed => imported metadata uri
+    mapping(uint256 => mapping(address => string)) private addressToMetadataUri;
+
+    EnumerableSet.UintSet private chainIds;
+
+    constructor(address[] memory _trustedForwarders) ERC2771Context(_trustedForwarders) {
+        _setupRole(DEFAULT_ADMIN_ROLE, _msgSender());
+    }
+
+    // slither-disable-next-line similar-names
+    function add(address _deployer, address _deployment, uint256 _chainId, string memory metadataUri) external {
+        require(hasRole(OPERATOR_ROLE, _msgSender()) || _deployer == _msgSender(), "not operator or deployer.");
+
+        bool added = deployments[_deployer][_chainId].add(_deployment);
+        require(added, "failed to add");
+
+        chainIds.add(_chainId);
+
+        if (bytes(metadataUri).length > 0) {
+            addressToMetadataUri[_chainId][_deployment] = metadataUri;
+        }
+
+        emit Added(_deployer, _deployment, _chainId, metadataUri);
+    }
+
+    // slither-disable-next-line similar-names
+    function remove(address _deployer, address _deployment, uint256 _chainId) external {
+        require(hasRole(OPERATOR_ROLE, _msgSender()) || _deployer == _msgSender(), "not operator or deployer.");
+
+        bool removed = deployments[_deployer][_chainId].remove(_deployment);
+        require(removed, "failed to remove");
+
+        emit Deleted(_deployer, _deployment, _chainId);
+    }
+
+    function getAll(address _deployer) external view returns (Deployment[] memory allDeployments) {
+        uint256 totalDeployments;
+        uint256 chainIdsLen = chainIds.length();
+
+        for (uint256 i = 0; i < chainIdsLen; i += 1) {
+            uint256 chainId = chainIds.at(i);
+
+            totalDeployments += deployments[_deployer][chainId].length();
+        }
+
+        allDeployments = new Deployment[](totalDeployments);
+        uint256 idx;
+
+        for (uint256 j = 0; j < chainIdsLen; j += 1) {
+            uint256 chainId = chainIds.at(j);
+
+            uint256 len = deployments[_deployer][chainId].length();
+            address[] memory deploymentAddrs = deployments[_deployer][chainId].values();
+
+            for (uint256 k = 0; k < len; k += 1) {
+                allDeployments[idx] = Deployment({
+                    deploymentAddress: deploymentAddrs[k],
+                    chainId: chainId,
+                    metadataURI: addressToMetadataUri[chainId][deploymentAddrs[k]]
+                });
+                idx += 1;
+            }
+        }
+    }
+
+    function count(address _deployer) external view returns (uint256 deploymentCount) {
+        uint256 chainIdsLen = chainIds.length();
+
+        for (uint256 i = 0; i < chainIdsLen; i += 1) {
+            uint256 chainId = chainIds.at(i);
+
+            deploymentCount += deployments[_deployer][chainId].length();
+        }
+    }
+
+    function getMetadataUri(uint256 _chainId, address _deployment) external view returns (string memory metadataUri) {
+        metadataUri = addressToMetadataUri[_chainId][_deployment];
+    }
+
+    function _msgSender() internal view virtual override(Context, ERC2771Context, Multicall) returns (address sender) {
+        return ERC2771Context._msgSender();
+    }
+
+    function _msgData() internal view virtual override(Context, ERC2771Context) returns (bytes calldata) {
+        return ERC2771Context._msgData();
+    }
+}

package/contracts/infra/TWProxy.sol

@@ -0,0 +1,42 @@
+// SPDX-License-Identifier: Apache-2.0
+pragma solidity ^0.8.11;
+
+/// @author thirdweb
+
+//   $$\     $$\       $$\                 $$\                         $$\
+//   $$ |    $$ |      \__|                $$ |                        $$ |
+// $$$$$$\   $$$$$$$\  $$\  $$$$$$\   $$$$$$$ |$$\  $$\  $$\  $$$$$$\  $$$$$$$\
+// \_$$  _|  $$  __$$\ $$ |$$  __$$\ $$  __$$ |$$ | $$ | $$ |$$  __$$\ $$  __$$\
+//   $$ |    $$ |  $$ |$$ |$$ |  \__|$$ /  $$ |$$ | $$ | $$ |$$$$$$$$ |$$ |  $$ |
+//   $$ |$$\ $$ |  $$ |$$ |$$ |      $$ |  $$ |$$ | $$ | $$ |$$   ____|$$ |  $$ |
+//   \$$$$  |$$ |  $$ |$$ |$$ |      \$$$$$$$ |\$$$$$\$$$$  |\$$$$$$$\ $$$$$$$  |
+//    \____/ \__|  \__|\__|\__|       \_______| \_____\____/  \_______|\_______/
+
+import "@openzeppelin/contracts/proxy/Proxy.sol";
+import "@openzeppelin/contracts/utils/Address.sol";
+import "@openzeppelin/contracts/utils/StorageSlot.sol";
+
+contract TWProxy is Proxy {
+    /**
+     * @dev Storage slot with the address of the current implementation.
+     * This is the keccak-256 hash of "eip1967.proxy.implementation" subtracted by 1, and is
+     * validated in the constructor.
+     */
+    bytes32 internal constant _IMPLEMENTATION_SLOT = 0x360894a13ba1a3210667c828492db98dca3e2076cc3735a920a3ca505d382bbc;
+
+    constructor(address _logic, bytes memory _data) payable {
+        assert(_IMPLEMENTATION_SLOT == bytes32(uint256(keccak256("eip1967.proxy.implementation")) - 1));
+        StorageSlot.getAddressSlot(_IMPLEMENTATION_SLOT).value = _logic;
+        if (_data.length > 0) {
+            // slither-disable-next-line unused-return
+            Address.functionDelegateCall(_logic, _data);
+        }
+    }
+
+    /**
+     * @dev Returns the current implementation address.
+     */
+    function _implementation() internal view override returns (address impl) {
+        return StorageSlot.getAddressSlot(_IMPLEMENTATION_SLOT).value;
+    }
+}

package/contracts/infra/TWRegistry.sol

@@ -0,0 +1,70 @@
+// SPDX-License-Identifier: Apache-2.0
+pragma solidity ^0.8.11;
+
+/// @author thirdweb
+
+//   $$\     $$\       $$\                 $$\                         $$\
+//   $$ |    $$ |      \__|                $$ |                        $$ |
+// $$$$$$\   $$$$$$$\  $$\  $$$$$$\   $$$$$$$ |$$\  $$\  $$\  $$$$$$\  $$$$$$$\
+// \_$$  _|  $$  __$$\ $$ |$$  __$$\ $$  __$$ |$$ | $$ | $$ |$$  __$$\ $$  __$$\
+//   $$ |    $$ |  $$ |$$ |$$ |  \__|$$ /  $$ |$$ | $$ | $$ |$$$$$$$$ |$$ |  $$ |
+//   $$ |$$\ $$ |  $$ |$$ |$$ |      $$ |  $$ |$$ | $$ | $$ |$$   ____|$$ |  $$ |
+//   \$$$$  |$$ |  $$ |$$ |$$ |      \$$$$$$$ |\$$$$$\$$$$  |\$$$$$$$\ $$$$$$$  |
+//    \____/ \__|  \__|\__|\__|       \_______| \_____\____/  \_______|\_______/
+
+import "@openzeppelin/contracts/utils/structs/EnumerableSet.sol";
+import "@openzeppelin/contracts/access/AccessControlEnumerable.sol";
+import "../extension/Multicall.sol";
+import "../external-deps/openzeppelin/metatx/ERC2771Context.sol";
+
+contract TWRegistry is Multicall, ERC2771Context, AccessControlEnumerable {
+    bytes32 public constant OPERATOR_ROLE = keccak256("OPERATOR_ROLE");
+
+    using EnumerableSet for EnumerableSet.AddressSet;
+
+    /// @dev wallet address => [contract addresses]
+    mapping(address => EnumerableSet.AddressSet) private deployments;
+
+    event Added(address indexed deployer, address indexed deployment);
+    event Deleted(address indexed deployer, address indexed deployment);
+
+    constructor(address[] memory _trustedForwarders) ERC2771Context(_trustedForwarders) {
+        _setupRole(DEFAULT_ADMIN_ROLE, _msgSender());
+    }
+
+    // slither-disable-next-line similar-names
+    function add(address _deployer, address _deployment) external {
+        require(hasRole(OPERATOR_ROLE, _msgSender()) || _deployer == _msgSender(), "not operator or deployer.");
+
+        bool added = deployments[_deployer].add(_deployment);
+        require(added, "failed to add");
+
+        emit Added(_deployer, _deployment);
+    }
+
+    // slither-disable-next-line similar-names
+    function remove(address _deployer, address _deployment) external {
+        require(hasRole(OPERATOR_ROLE, _msgSender()) || _deployer == _msgSender(), "not operator or deployer.");
+
+        bool removed = deployments[_deployer].remove(_deployment);
+        require(removed, "failed to remove");
+
+        emit Deleted(_deployer, _deployment);
+    }
+
+    function getAll(address _deployer) external view returns (address[] memory) {
+        return deployments[_deployer].values();
+    }
+
+    function count(address _deployer) external view returns (uint256) {
+        return deployments[_deployer].length();
+    }
+
+    function _msgSender() internal view virtual override(Context, ERC2771Context, Multicall) returns (address sender) {
+        return ERC2771Context._msgSender();
+    }
+
+    function _msgData() internal view virtual override(Context, ERC2771Context) returns (bytes calldata) {
+        return ERC2771Context._msgData();
+    }
+}

package/contracts/infra/TWStatelessFactory.sol

@@ -0,0 +1,47 @@
+// SPDX-License-Identifier: Apache-2.0
+pragma solidity ^0.8.11;
+
+/// @author thirdweb
+
+//   $$\     $$\       $$\                 $$\                         $$\
+//   $$ |    $$ |      \__|                $$ |                        $$ |
+// $$$$$$\   $$$$$$$\  $$\  $$$$$$\   $$$$$$$ |$$\  $$\  $$\  $$$$$$\  $$$$$$$\
+// \_$$  _|  $$  __$$\ $$ |$$  __$$\ $$  __$$ |$$ | $$ | $$ |$$  __$$\ $$  __$$\
+//   $$ |    $$ |  $$ |$$ |$$ |  \__|$$ /  $$ |$$ | $$ | $$ |$$$$$$$$ |$$ |  $$ |
+//   $$ |$$\ $$ |  $$ |$$ |$$ |      $$ |  $$ |$$ | $$ | $$ |$$   ____|$$ |  $$ |
+//   \$$$$  |$$ |  $$ |$$ |$$ |      \$$$$$$$ |\$$$$$\$$$$  |\$$$$$$$\ $$$$$$$  |
+//    \____/ \__|  \__|\__|\__|       \_______| \_____\____/  \_______|\_______/
+
+import "../extension/interface/IContractFactory.sol";
+
+import "../external-deps/openzeppelin/metatx/ERC2771Context.sol";
+import "../extension/Multicall.sol";
+import "@openzeppelin/contracts/proxy/Clones.sol";
+
+contract TWStatelessFactory is Multicall, ERC2771Context, IContractFactory {
+    /// @dev Emitted when a proxy is deployed.
+    event ProxyDeployed(address indexed implementation, address proxy, address indexed deployer);
+
+    constructor(address[] memory _trustedForwarders) ERC2771Context(_trustedForwarders) {}
+
+    /// @dev Deploys a proxy that points to the given implementation.
+    function deployProxyByImplementation(
+        address _implementation,
+        bytes memory _data,
+        bytes32 _salt
+    ) public override returns (address deployedProxy) {
+        bytes32 salthash = keccak256(abi.encodePacked(_msgSender(), _salt));
+        deployedProxy = Clones.cloneDeterministic(_implementation, salthash);
+
+        emit ProxyDeployed(_implementation, deployedProxy, _msgSender());
+
+        if (_data.length > 0) {
+            // slither-disable-next-line unused-return
+            Address.functionCall(deployedProxy, _data);
+        }
+    }
+
+    function _msgSender() internal view virtual override(Multicall, ERC2771Context) returns (address sender) {
+        return ERC2771Context._msgSender();
+    }
+}