@quantumcoin/base64 1.0.0

package/README.md

@@ -0,0 +1,33 @@
+# @quantumcoin/base64
+
+Base64 encoding library for Solidity 0.7.6 on the QuantumCoin blockchain.
+
+# Local Development
+
+Requires `node@>=18`. The library is compiled with the
+[`@quantumcoin/solc`](https://www.npmjs.com/package/@quantumcoin/solc) npm package
+(QuantumCoin's Solidity 0.7.6 with 32-byte address support).
+
+## Install Dependencies
+
+`npm install`
+
+## Compile
+
+`npm run compile`
+
+## Run Tests
+
+`npm test`
+
+Tests run against a local QuantumCoin devnet using the `quantumcoin` SDK. The devnet is
+downloaded, installed, and started automatically by `scripts/devnet.js` (Windows, macOS, and
+Ubuntu). Overrides: `QC_RPC_URL`, `QC_DEVNET_DIR`, `QC_KEYSTORE`, `QC_KEY_PASSWORD`.
+
+## Usage
+
+Install via `npm install @quantumcoin/base64`, then:
+
+```solidity
+import '@quantumcoin/base64/base64.sol';
+```

package/base64.sol

@@ -0,0 +1,64 @@
+// SPDX-License-Identifier: MIT
+
+pragma solidity >=0.6.0;
+
+/// @title Base64
+/// @author Brecht Devos - <brecht@loopring.org>
+/// @notice Provides a function for encoding some bytes in base64
+library Base64 {
+    string internal constant TABLE = 'ABCDEFGHIJKLMNOPQRSTUVWXYZabcdefghijklmnopqrstuvwxyz0123456789+/';
+
+    function encode(bytes memory data) internal pure returns (string memory) {
+        if (data.length == 0) return '';
+        
+        // load the table into memory
+        string memory table = TABLE;
+
+        // multiply by 4/3 rounded up
+        uint256 encodedLen = 4 * ((data.length + 2) / 3);
+
+        // add some extra buffer at the end required for the writing
+        string memory result = new string(encodedLen + 32);
+
+        assembly {
+            // set the actual output length
+            mstore(result, encodedLen)
+            
+            // prepare the lookup table
+            let tablePtr := add(table, 1)
+            
+            // input ptr
+            let dataPtr := data
+            let endPtr := add(dataPtr, mload(data))
+            
+            // result ptr, jump over length
+            let resultPtr := add(result, 32)
+            
+            // run over the input, 3 bytes at a time
+            for {} lt(dataPtr, endPtr) {}
+            {
+               dataPtr := add(dataPtr, 3)
+               
+               // read 3 bytes
+               let input := mload(dataPtr)
+               
+               // write 4 characters
+               mstore(resultPtr, shl(248, mload(add(tablePtr, and(shr(18, input), 0x3F)))))
+               resultPtr := add(resultPtr, 1)
+               mstore(resultPtr, shl(248, mload(add(tablePtr, and(shr(12, input), 0x3F)))))
+               resultPtr := add(resultPtr, 1)
+               mstore(resultPtr, shl(248, mload(add(tablePtr, and(shr( 6, input), 0x3F)))))
+               resultPtr := add(resultPtr, 1)
+               mstore(resultPtr, shl(248, mload(add(tablePtr, and(        input,  0x3F)))))
+               resultPtr := add(resultPtr, 1)
+            }
+            
+            // padding with '='
+            switch mod(mload(data), 3)
+            case 1 { mstore(sub(resultPtr, 2), shl(240, 0x3d3d)) }
+            case 2 { mstore(sub(resultPtr, 1), shl(248, 0x3d)) }
+        }
+        
+        return result;
+    }
+}

package/package.json

@@ -0,0 +1,37 @@
+{
+  "name": "@quantumcoin/base64",
+  "version": "1.0.0",
+  "description": "Base64 encoding library for Solidity contracts on the QuantumCoin blockchain",
+  "license": "MIT",
+  "files": [
+    "base64.sol"
+  ],
+  "repository": {
+    "type": "git",
+    "url": "git+https://github.com/quantumcoinproject/base64.git"
+  },
+  "homepage": "https://github.com/quantumcoinproject/base64#readme",
+  "bugs": {
+    "url": "https://github.com/quantumcoinproject/base64/issues"
+  },
+  "keywords": [
+    "quantumcoin",
+    "solidity",
+    "base64"
+  ],
+  "engines": {
+    "node": ">=18"
+  },
+  "publishConfig": {
+    "access": "public"
+  },
+  "scripts": {
+    "compile": "node scripts/compile.js",
+    "test": "npm run compile && node scripts/devnet.js ensure && node --test --test-concurrency=1",
+    "prepublishOnly": "npm run compile"
+  },
+  "devDependencies": {
+    "@quantumcoin/solc": "^0.7.6",
+    "quantumcoin": "^8.0.2"
+  }
+}