@pkmn/engine 0.1.0-dev.4d039f83 → 0.1.0-dev.526bb2e1

package/src/lib/common/rational.zig

@@ -0,0 +1,353 @@
+const builtin = @import("builtin");
+const std = @import("std");
+
+const assert = std.debug.assert;
+const expect = std.testing.expect;
+const expectEqual = std.testing.expectEqual;
+const expectError = std.testing.expectError;
+
+/// Specialization of a rational number used by the engine to compute probabilties.
+/// For performance reasons the rational is only reduced lazily and thus `reduce` must be
+/// invoked explicitly before reading.
+pub fn Rational(comptime T: type) type {
+    return extern struct {
+        const Self = @This();
+
+        /// Numerator. Must always be >= 1. Not guaranteed to be reduced in all cases.
+        p: T = 1,
+        /// Denominator. Must always be >= 1. Not guaranteed to be reduced in all cases.
+        q: T = 1,
+
+        // With floats we can't rely on an overflow bit to let us know when to reduce, so we instead
+        // start reducing when we get sufficiently close to the limit of the mantissa (in our domain
+        // we expect updates to involve numbers < 2**10, so we should be safe not reducing before we
+        // are 2**10 away from "overflowing" the mantissa)
+        const REDUCE = if (@typeInfo(T) == .Float)
+            std.math.pow(T, 2, std.math.floatMantissaBits(T) - 10)
+        else
+            0;
+
+        /// Possible error returned by operations on the Rational.
+        pub const Error = switch (@typeInfo(T)) {
+            .Int => error{Overflow},
+            .Float => error{},
+            else => unreachable,
+        };
+
+        /// Resets the rational back to 1.
+        pub fn reset(r: *Self) void {
+            r.p = 1;
+            r.q = 1;
+        }
+
+        /// Update the rational by multiplying its numerator by p and its denominator by q.
+        /// Both p and q must be >= 1, and if computable at comptime must have no common factors.
+        pub fn update(r: *Self, p: anytype, q: anytype) Error!void {
+            // FIXME
+            // std.debug.print("({d}/{d}) * ", .{p, q});
+            assert(p >= 1);
+            assert(q >= 1);
+
+            // If our parameters are not fully reduced they may prematurely
+            // cause overflow/loss of precision after the multiplication below
+            assert(switch (@typeInfo(@TypeOf(p, q))) {
+                .ComptimeInt, .ComptimeFloat => comptime gcd(p, q),
+                else => 1,
+            } == 1);
+
+            switch (@typeInfo(T)) {
+                .Int => {
+                    // Greedily attempt to multiply and if it fails, reduce and try again
+                    r.multiplication(p, q) catch |err| switch (err) {
+                        error.Overflow => {
+                            r.reduce();
+                            try r.multiplication(p, q);
+                        },
+                        else => unreachable,
+                    };
+                },
+                .Float => {
+                    // Reduce in situations where we're likely to start losing precision
+                    if (r.q > REDUCE or r.p > REDUCE) r.reduce();
+
+                    r.p *= switch (@typeInfo(@TypeOf(p))) {
+                        .Float, .ComptimeFloat => p,
+                        else => @floatFromInt(p),
+                    };
+                    r.q *= switch (@typeInfo(@TypeOf(q))) {
+                        .Float, .ComptimeFloat => q,
+                        else => @floatFromInt(q),
+                    };
+
+                    // We should always be dealing with whole numbers
+                    assert(std.math.modf(r.p).fpart == 0);
+                    assert(std.math.modf(r.q).fpart == 0);
+                },
+                else => unreachable,
+            }
+        }
+
+        /// Add two rationals using the identity (a/b) + (c/d) = (ad+bc)/(bd).
+        pub fn add(r: *Self, s: *Self) Error!void {
+            switch (@typeInfo(T)) {
+                .Int => {
+                    if (r.q == s.q) {
+                        r.p = std.math.add(T, r.p, s.p) catch |err| switch (err) {
+                            error.Overflow => val: {
+                                r.reduce();
+                                s.reduce();
+                                break :val try std.math.add(T, r.p, s.p);
+                            },
+                            else => unreachable,
+                        };
+                    } else {
+                        r.addition(s.p, s.q) catch |err| switch (err) {
+                            error.Overflow => {
+                                r.reduce();
+                                s.reduce();
+                                try r.addition(s.p, s.q);
+                            },
+                            else => unreachable,
+                        };
+                    }
+                },
+                .Float => {
+                    if (r.q == s.q) {
+                        if (r.p > REDUCE) r.reduce();
+                        if (s.p > REDUCE) s.reduce();
+
+                        r.p += s.p;
+                    } else {
+                        // Always reduce to minimize loss of precision from the multiplications
+                        r.reduce();
+                        s.reduce();
+
+                        r.p = (r.p * s.q) + (r.q * s.p);
+                        r.q *= s.q;
+                    }
+
+                    assert(std.math.modf(r.p).fpart == 0);
+                    assert(std.math.modf(r.q).fpart == 0);
+                },
+                else => unreachable,
+            }
+        }
+
+        /// Multiplies two rationals.
+        pub fn mul(r: *Self, s: *Self) Error!void {
+            switch (@typeInfo(T)) {
+                .Int => {
+                    r.multiplication(s.p, s.q) catch |err| switch (err) {
+                        error.Overflow => {
+                            r.reduce();
+                            s.reduce();
+                            try r.multiplication(s.p, s.q);
+                        },
+                        else => unreachable,
+                    };
+                },
+                .Float => {
+                    if (r.q > REDUCE or r.p > REDUCE) r.reduce();
+                    if (s.q > REDUCE or s.p > REDUCE) s.reduce();
+
+                    r.p *= s.p;
+                    r.q *= s.q;
+
+                    assert(std.math.modf(r.p).fpart == 0);
+                    assert(std.math.modf(r.q).fpart == 0);
+                },
+                else => unreachable,
+            }
+        }
+
+        /// Normalize the rational by reducing by the greatest common divisor.
+        pub fn reduce(r: *Self) void {
+            const d = gcd(r.p, r.q);
+            if (d == 1) return;
+
+            assert(@mod(r.p, d) == 0);
+            assert(@mod(r.q, d) == 0);
+
+            r.p /= d;
+            r.q /= d;
+
+            assert(r.p >= 1);
+            assert(r.q >= 1);
+        }
+
+        pub fn format(
+            self: Self,
+            comptime fmt: []const u8,
+            opts: std.fmt.FormatOptions,
+            writer: anytype,
+        ) !void {
+            _ = .{ fmt, opts };
+            try writer.print("{d}/{d}", .{ self.p, self.q });
+        }
+
+        inline fn multiplication(r: *Self, p: anytype, q: anytype) !void {
+            r.p = try std.math.mul(T, r.p, p);
+            r.q = try std.math.mul(T, r.q, q);
+        }
+
+        inline fn addition(r: *Self, p: anytype, q: anytype) !void {
+            // (a/b) + (c/d) = (ad+bc)/(bd)
+            var d = try std.math.mul(T, r.q, q);
+            var n1 = try std.math.mul(T, r.p, q);
+            var n2 = try std.math.mul(T, r.q, p);
+
+            r.p = try std.math.add(T, n1, n2);
+            r.q = d;
+        }
+    };
+}
+
+// https://en.wikipedia.org/wiki/Euclidean_algorithm
+inline fn gcd(p: anytype, q: anytype) @TypeOf(p, q) {
+    assert(p >= 1);
+    assert(q >= 1);
+
+    var a = p;
+    var b = q;
+    var c: @TypeOf(p, q) = undefined;
+
+    while (b != 0) {
+        c = b;
+        b = @mod(a, b);
+        a = c;
+    }
+
+    assert(a > 0);
+    return a;
+}
+
+fn doTurn(r: anytype) !void {
+    try r.update(1, 163); // Metronome
+    try r.update(33, 256); // Critical Hit (67 Speed)
+    try r.update(1, 39); // Damage roll
+    try r.update(89, 128); // Thunder accuracy (178/256)
+    try r.update(77, 256); // Thunder secondary proc
+}
+
+test Rational {
+    inline for (.{ u64, u128, f64 }) |t| {
+        var r: Rational(t) = .{};
+
+        var c: t = 128;
+        try r.update(c, 256);
+        try doTurn(&r);
+
+        r.reduce();
+        try expectEqual(Rational(t){ .p = 75383, .q = 35550920704 }, r);
+
+        try r.update(1, 4);
+        if (t == u64) {
+            try expectError(error.Overflow, doTurn(&r));
+        } else {
+            try doTurn(&r);
+            r.reduce();
+            try expectEqual(Rational(t){ .p = 5682596689, .q = 2527735925804191711232 }, r);
+        }
+
+        r.reset();
+
+        var s = Rational(t){ .p = 10, .q = 13 };
+        try r.mul(&s);
+        s = Rational(t){ .p = 3, .q = 4 };
+        try r.mul(&s);
+        try expectEqual(Rational(t){ .p = 30, .q = 52 }, r);
+
+        s = Rational(t){ .p = 1, .q = 3 };
+        try r.add(&s);
+        r.reduce();
+        try expectEqual(Rational(t){ .p = 71, .q = 78 }, r);
+    }
+}
+
+/// Adapter of std.math.big.Rational to the engines Rational interface.
+pub const BigRational = struct {
+    /// The underlying rational number.
+    val: std.math.big.Rational,
+
+    /// Possible error returned by operations on the rational.
+    pub const Error = error{OutOfMemory};
+
+    /// Create a new BigRational wrapper.  A small amount of memory will be allocated on
+    /// initialization. Not default initialized to 1 - you must explicitly `reset` first.
+    pub fn init(alloc: std.mem.Allocator) !BigRational {
+        return BigRational{ .val = try std.math.big.Rational.init(alloc) };
+    }
+
+    /// Frees all memory associated with a rational.
+    pub fn deinit(r: *BigRational) void {
+        r.val.deinit();
+    }
+
+    /// Resets the rational back to 1.
+    pub fn reset(r: *BigRational) !void {
+        try r.val.setInt(1);
+    }
+
+    /// Update the rational by multiplying its numerator by p and its denominator by q.
+    /// Both p and q must be >= 1.
+    pub fn update(r: *BigRational, p: anytype, q: anytype) !void {
+        assert(p >= 1);
+        assert(q >= 1);
+
+        var s = try std.math.big.Rational.init(r.val.p.allocator);
+        defer s.deinit();
+        try s.setRatio(p, q);
+        try r.val.mul(r.val, s);
+    }
+
+    /// Adds two rationals.
+    pub fn add(r: *BigRational, s: *const BigRational) !void {
+        try r.val.add(r.val, s.val);
+    }
+
+    /// Multiplies two rationals.
+    pub fn mul(r: *BigRational, s: *const BigRational) !void {
+        try r.val.mul(r.val, s.val);
+    }
+};
+
+test BigRational {
+    var r = try BigRational.init(std.testing.allocator);
+    defer r.deinit();
+    var s = try std.math.big.Rational.init(std.testing.allocator);
+    defer s.deinit();
+
+    try r.reset();
+
+    var c: u8 = 128;
+    try r.update(c, 256);
+    try doTurn(&r);
+
+    try s.setRatio(75383, 35550920704);
+    try expect((try s.order(r.val)) == .eq);
+
+    try r.update(1, 4);
+    try doTurn(&r);
+
+    try s.setRatio(5682596689, 2527735925804191711232);
+    try expect((try s.order(r.val)) == .eq);
+
+    try r.reset();
+
+    var t = try BigRational.init(std.testing.allocator);
+    defer t.deinit();
+
+    try t.val.setRatio(10, 13);
+    try r.mul(&t);
+    try t.val.setRatio(3, 4);
+    try r.mul(&t);
+
+    try s.setRatio(15, 26);
+    try expect((try s.order(r.val)) == .eq);
+
+    try t.val.setRatio(1, 3);
+    try r.add(&t);
+
+    try s.setRatio(71, 78);
+    try expect((try s.order(r.val)) == .eq);
+}

package/src/lib/common/rng.zig

@@ -47,7 +47,7 @@ pub const PSRNG = extern struct {
     }
 
     pub fn range(self: *PSRNG, comptime T: type, from: T, to: Bound(T)) T {
-        return @intCast(T, @as(u64, self.src.next()) * (to - from) / divisor + from);
+        return @intCast(@as(u64, self.src.next()) * (to - from) / divisor + from);
     }
 
     pub fn chance(self: *PSRNG, comptime T: type, numerator: T, denominator: Bound(T)) bool {
@@ -72,28 +72,28 @@ test PSRNG {
 // https://pkmn.cc/pokered/engine/battle/core.asm#L6644-L6693
 // https://pkmn.cc/pokecrystal/engine/battle/core.asm#L6922-L6938
 pub const Gen12 = extern struct {
-    seed: [10]u8,
+    seed: [9]u8,
     index: u8 = 0,
 
     comptime {
-        assert(@sizeOf(Gen12) == 11);
+        assert(@sizeOf(Gen12) == 10);
     }
 
     pub fn percent(p: u8) u8 {
-        return @intCast(u8, (@as(u16, p) * 0xFF) / 100);
+        return @intCast((@as(u16, p) * 0xFF) / 100);
     }
 
     pub fn next(self: *Gen12) u8 {
         const val = 5 *% self.seed[self.index] +% 1;
         self.seed[self.index] = val;
-        self.index = (self.index + 1) % 10;
+        self.index = (self.index + 1) % 9;
         return val;
     }
 };
 
 test Gen12 {
-    const expected = [_]u8{ 6, 11, 16, 21, 26, 31, 36, 41, 46, 51, 31, 56, 81 };
-    var rng = Gen12{ .seed = .{ 1, 2, 3, 4, 5, 6, 7, 8, 9, 10 } };
+    const expected = [_]u8{ 6, 11, 16, 21, 26, 31, 36, 41, 46, 31, 56, 81 };
+    var rng = Gen12{ .seed = .{ 1, 2, 3, 4, 5, 6, 7, 8, 9 } };
     for (expected) |e| {
         try expectEqual(e, rng.next());
     }
@@ -114,7 +114,7 @@ pub const Gen34 = extern struct {
 
     pub fn next(self: *Gen34) u16 {
         self.advance();
-        return @intCast(u16, self.seed >> 16);
+        return @intCast(self.seed >> 16);
     }
 
     pub fn advance(self: *Gen34) void {
@@ -144,7 +144,7 @@ pub const Gen56 = extern struct {
 
     pub fn next(self: *Gen56) u32 {
         self.advance();
-        return @intCast(u32, self.seed >> 32);
+        return @intCast(self.seed >> 32);
     }
 
     pub fn advance(self: *Gen56) void {
@@ -190,7 +190,7 @@ pub fn FixedRNG(comptime gen: comptime_int, comptime len: usize) type {
 
         pub fn range(self: *Self, comptime T: type, from: T, to: Bound(T)) T {
             assert(showdown);
-            return @intCast(T, @as(u64, self.next()) * (to - from) / divisor + from);
+            return @intCast(@as(u64, self.next()) * (to - from) / divisor + from);
         }
 
         pub fn chance(

package/src/lib/common/util.zig

@@ -0,0 +1,12 @@
+const std = @import("std");
+
+const expectEqual = std.testing.expectEqual;
+
+pub fn PointerType(comptime P: type, comptime C: type) type {
+    return if (@typeInfo(P).Pointer.is_const) *const C else *C;
+}
+
+test PointerType {
+    try expectEqual(*bool, PointerType(*u8, bool));
+    try expectEqual(*const f64, PointerType(*const i32, f64));
+}

package/src/lib/gen1/README.md

@@ -286,9 +286,9 @@ padding](https://en.wikipedia.org/wiki/Data_structure_alignment) and
   - the active Pokémon's level and current and max HP can always be referred to the `Pokemon`
     struct
 - **`Side`**: `ActivePokemon` + 6× `Pokemon` + active (`3`) + last used (`8`) + last selected
-  (`8`)
+  (`8`) + counterable (`1`) + last move index (`3`)
   - `order` does not need to be stored as the party can always be rearranged as switches occur
-- **`Battle`**: 6× `Side` + seed (10× `8` + `4`) + turn (`10`) + last damage (`10`)
+- **`Battle`**: 6× `Side` + seed (9× `8` + `4`) + turn (`10`) + last damage (`10`)
 - **`Type.CHART`**: attacking types (`15`) × defending types (`15`) × effectiveness (`2`)[^2]
 - **`Type.PRECEDENCE`**: 29× attacking type (`4`) + defending type (`4`) pairs
 - **`Moves.DATA`**: 165× base power (`6`) + effect (`7`) + accuracy (`4`) + type (`4`) + target
@@ -299,8 +299,8 @@ padding](https://en.wikipedia.org/wiki/Data_structure_alignment) and
 | ----------------- | ----------- | ------------ | -------- |
 | `Pokemon`         | 192         | 147          | 30.6%    |
 | `ActivePokemon`   | 256         | 202          | 26.7%    |
-| `Side`            | 1472        | 1056         | 33.5%    |
-| `Battle`          | 3088        | 2216         | 33.7%    |
+| `Side`            | 1472        | 1107         | 33.0%    |
+| `Battle`          | 3088        | 2310         | 33.7%    |
 | `Type.CHART`      | 1800        | 450          | 300.0%   |
 | `Type.PRECEDENCE` | 232         | 232          | 0.0%     |
 | `Moves.DATA`      | 5280        | 3960         | 33.3%    |
@@ -348,8 +348,8 @@ data in the browser for ease of debugging.
 | 184     | 368     | [`sides[1]`](#side) | Player 2's side                                         |
 | 368     | 370     | `turn`              | The current turn number                                 |
 | 370     | 372     | `last_damage`       | The last damage dealt by either side                    |
-| 372     | 373-376 | `last_moves`        | The slot index of the last selected moves for each side |
-| 373-376 | 384     | `rng`               | The RNG state                                           |
+| 372     | 374-376 | `last_moves`        | The slot index of the last selected moves for each side |
+| 374-376 | 384     | `rng`               | The RNG state                                           |
 
 - the current `turn` is 2 bytes, written in native-endianness
 - `last_moves` layout depends on whether or not Pokémon Showdown compatibility mode is enabled
@@ -359,13 +359,13 @@ data in the browser for ease of debugging.
   - if `showdown` is enabled byte 372 is used to store the last selected move index of `side[0]` and
     byte 373 is used to store whether or not the side's last executed move would have been considered
     "counterable"; and bytes 374 and 375 store the same information for `side[1]`
-  - otherwise the first 3 bits of byte 372 stores the last selected move index of `side[0]` and the
-    next bit stores whether that side's last executed move would have been considered "counterable",
-    with the same information for `side[1]`'s being stored in the second 4 bits
+  - otherwise the first 4 bits of byte 372 stores the last selected move index of `side[0]` and the
+    next 4 bits store whether that side's last executed move would have been considered
+    "counterable", with the same information for `side[1]`'s being stored in the second byte
 - the `rng` depends on whether or not Pokémon Showdown compatibility mode is enabled (`-Dshowdown`):
   - if `showdown` is enabled, the RNG state begins on byte 376 and consists of a 64-bit seed,
     written in native-endianness
-  - otherwise the RNG state begins on byte 373 and consists of the 10 bytes of the seed followed by
+  - otherwise the RNG state begins on byte 374 and consists of the 9 bytes of the seed followed by
     the index pointing to which byte of the seed is currently being used
 
 ### `Side`
@@ -497,7 +497,9 @@ the pkmn engine, but the following moves have their broken behavior preserved in
   damage grow unbounded. Additionally, if the opponent faints after Bide inflicts damage on Pokémon
   Showdown residual damage incorrectly still gets applied to Bide's user.
 - **Counter**: On Pokémon Showdown choices made while sleeping (which should not have been
-  registered) can erroneously cause Counter to trigger Desync Clause Mod behavior.
+  registered) can erroneously cause Counter to trigger Desync Clause Mod behavior. Additionally,
+  because Pokémon Showdown neglects to zero the last battle damage if a move misses due to immunity
+  or invulnerability Counter will occasionally work on Pokémon Showdown when it should fail.
 - **Leech Seed**: Leech Seed fails to heal its source side if a seeded target faints due to
   recoil/crash damage on Pokémon Showdown.
 - **Pay Day**: Pay Day should still scatter coins if it hits (but doesn't break) and opponent's
@@ -665,7 +667,7 @@ the pkmn engine aims to be as compatible with Pokémon Showdown as possible when
 compatibility mode, the implications of these differences are outlined below:
 
 - **RNG**: Pokémon Showdown uses the RNG from Generation V & VI in every generation, despite
-  the seeds and algorithm being different. Pokémon Red uses a simple 8-bit RNG with 10 distinct
+  the seeds and algorithm being different. Pokémon Red uses a simple 8-bit RNG with 9 distinct
   seeds generated when the link connection is established, whereas Pokémon Showdown uses a 64-bit
   RNG with a 32-bit output.
 - **Algorithm**: As detailed in the table below, the algorithm used by Pokémon Showdown in the
@@ -700,9 +702,9 @@ compatibility mode, the implications of these differences are outlined below:
   when they are not relevant:
   - Roar / Whirlwind roll to hit and can "miss" as opposed to simply failing
 
-Finally, the **initial 10-byte seed for link battles on Pokémon Red cannot include bytes larger than
+Finally, the **initial 9-byte seed for link battles on Pokémon Red cannot include bytes larger than
 the `SERIAL_PREAMBLE_BYTE`**, so must be in the range $\left[0, 252\right]$. This has implications
-on the first 10 random numbers generated during the battle and has [**non-trivial competitive
+on the first 9 random numbers generated during the battle and has [**non-trivial competitive
 implications**](https://www.smogon.com/forums/posts/9068411/show) (at the start of the battle move
 effects become more likely, the ["1/256-miss" glitch](https://glitchcity.wiki/1/256_miss_glitch)
 cannot happen, Player 1 is more likely to win speed ties, etc) that Pokémon Showdown cannot
@@ -726,7 +728,7 @@ All of places in the link battle code where randomness is required are outlined
 | **Paralysis** (full)     | `beforeMove`             | Trigger if $X < 63$                                                                                                                                                                                       |
 | **Poison** (chance)      | `Effects.poison`         | Trigger if $X < 52$ ($103$ for Smog / Sludge)                                                                                                                                                             |
 | **Sleep** (duration)     | `Effects.sleep`          | <dl><dt>Pokémon Red</dt><dd>Continue generating until $X \land 7 \neq 0$</dd><dt>Pokémon Showdown</dt><dd>Generate $X \in \left[1, 8\right)$</dd></dl>                                                    |
-| **Bide** (duration)      | `Effects.bide`           | <dl><dt>Pokémon Red</dt><dd>Last for $\left(X \land 1\right) + 2$ turns</dd><dt>Pokémon Showdown</dt><dd>Last for $X \in \left[2, 4\right)$ turns</dd></dl>                                           |
+| **Bide** (duration)      | `Effects.bide`           | <dl><dt>Pokémon Red</dt><dd>Last for $\left(X \land 1\right) + 2$ turns</dd><dt>Pokémon Showdown</dt><dd>Last for $X \in \left[2, 4\right)$ turns</dd></dl>                                               |
 | **Disable** (move)       | `Effects.disable`        | <dl><dt>Pokémon Red</dt><dd>Continue generating until $X \land 3$ is the index of a non-empty move slot</dd><dt>Pokémon Showdown</dt><dd>Generate $X \in \left[0, \|movesSlots\|\right)$</dd></dl>        |
 | **Disable** (duration)   | `Effects.disable`        | <dl><dt>Pokémon Red</dt><dd>Last for $\left(X \land 7\right) + 1$ turns</dd><dt>Pokémon Showdown</dt><dd>Last for $X \in \left[1, 9\right)$ turns</dd></dl>                                               |
 | **Metronome** (move)     | `metronome`              | <dl><dt>Pokémon Red</dt><dd>Continue generating until $X$ matches the index of a move which is not Struggle or Metronome</dd><dt>Pokémon Showdown</dt><dd>Generate $X \in \left[0, \|validMoves\|\right)$, where $validMoves$ is ordered set of moves with  Struggle and Metronome removed <i>(indexes of moves > Metronome will be shifted down)</i></dd></dl> |
@@ -734,7 +736,7 @@ All of places in the link battle code where randomness is required are outlined
 | **Psywave** (power)      | `specialDamage`          | <dl><dt>Pokémon Red</dt><dd>Continue generating until $X < {3\over2} \cdot level$</dd><dt>Pokémon Showdown</dt><dd>Generate $X \in \left[0, {3\over2} \cdot level\right)$</dd></dl>                       |
 | **Thrash** (rampage)     | `Effects.thrash`         | <dl><dt>Pokémon Red</dt><dd>Last for $\left(X \land 1\right) + 2$ turns</dd><dt>Pokémon Showdown</dt><dd>Last for $X \in \left[2, 4\right)$ turns</dd></dl>                                               |
 | **Thrash** (confusion)   | `beforeMove`             | <dl><dt>Pokémon Red</dt><dd>Last for $\left(X \land 3\right) + 2$ turns</dd><dt>Pokémon Showdown</dt><dd>Last for $X \in \left[2, 6\right)$ turns</dd></dl>                                               |
-| **Binding** (duration)   | `Effects.binding`        | <dl><dt>Pokémon Red</dt><dd>Last for $\left(X \land 3\right) + 1$ further turns if $\left(X \land 3\right) < 2$<br /> otherwise last for $\left(Y \land 3\right) + 1$ further turns (reroll)</dd><dt>Pokémon Showdown</dt><dd>Last for $X \in \{2, 2, 3, 3, 4, 5\} - 1$ further turns</dd></dl> |
+| **Binding** (duration)   | `Effects.binding`        | <dl><dt>Pokémon Red</dt><dd>Last for $\left(X \land 3\right) + 1$ further turns if $\left(X \land 3\right) < 2$<br /> otherwise last for $\left(Y \land 3\right) + 1$ further turns (reroll)</dd><dt>Pokémon Showdown</dt><dd>Last for $X \in \{2, 2, 2, 3, 3, 3, 4, 5 \} - 1$ further turns</dd></dl> |
 | **Multi-Hit** (hits)     | `Effects.multiHit`       | *Ibid.*                                                                                                                                                                                                   |
 | **Unboost** (chance)     | `Effects.unboost`        | Trigger if $X < 85$                                                                                                                                                                                       |