@pendle/core-v2 6.7.1 → 6.8.1

package/contracts/pt-looping/money-market/implementations/aave/dependencies/IPool.sol

@@ -0,0 +1,664 @@
+// SPDX-License-Identifier: AGPL-3.0
+pragma solidity ^0.8.4;
+
+import {IERC20Metadata as IERC20} from "@openzeppelin/contracts/token/ERC20/extensions/IERC20Metadata.sol";
+import {IPoolAddressesProvider} from "./IPoolAddressesProvider.sol";
+import {AaveDataTypes, IERC20} from "./AaveDataTypes.sol";
+
+/**
+ * @title IPool
+ * @author Aave
+ * @notice Defines the basic interface for an Aave Pool.
+ */
+interface IPool {
+    /**
+     * @dev Emitted on mintUnbacked()
+     * @param reserve The address of the underlying asset of the reserve
+     * @param user The address initiating the supply
+     * @param onBehalfOf The beneficiary of the supplied assets, receiving the aTokens
+     * @param amount The amount of supplied assets
+     * @param referralCode The referral code used
+     */
+    event MintUnbacked(
+        address indexed reserve, address user, address indexed onBehalfOf, uint256 amount, uint16 indexed referralCode
+    );
+
+    /**
+     * @dev Emitted on backUnbacked()
+     * @param reserve The address of the underlying asset of the reserve
+     * @param backer The address paying for the backing
+     * @param amount The amount added as backing
+     * @param fee The amount paid in fees
+     */
+    event BackUnbacked(address indexed reserve, address indexed backer, uint256 amount, uint256 fee);
+
+    /**
+     * @dev Emitted on supply()
+     * @param reserve The address of the underlying asset of the reserve
+     * @param user The address initiating the supply
+     * @param onBehalfOf The beneficiary of the supply, receiving the aTokens
+     * @param amount The amount supplied
+     * @param referralCode The referral code used
+     */
+    event Supply(
+        address indexed reserve, address user, address indexed onBehalfOf, uint256 amount, uint16 indexed referralCode
+    );
+
+    /**
+     * @dev Emitted on withdraw()
+     * @param reserve The address of the underlying asset being withdrawn
+     * @param user The address initiating the withdrawal, owner of aTokens
+     * @param to The address that will receive the underlying
+     * @param amount The amount to be withdrawn
+     */
+    event Withdraw(address indexed reserve, address indexed user, address indexed to, uint256 amount);
+
+    /**
+     * @dev Emitted on borrow() and flashLoan() when debt needs to be opened
+     * @param reserve The address of the underlying asset being borrowed
+     * @param user The address of the user initiating the borrow(), receiving the funds on borrow() or just
+     * initiator of the transaction on flashLoan()
+     * @param onBehalfOf The address that will be getting the debt
+     * @param amount The amount borrowed out
+     * @param interestRateMode The rate mode: 1 for Stable, 2 for Variable
+     * @param borrowRate The numeric rate at which the user has borrowed, expressed in ray
+     * @param referralCode The referral code used
+     */
+    event Borrow(
+        address indexed reserve,
+        address user,
+        address indexed onBehalfOf,
+        uint256 amount,
+        AaveDataTypes.InterestRateMode interestRateMode,
+        uint256 borrowRate,
+        uint16 indexed referralCode
+    );
+
+    /**
+     * @dev Emitted on repay()
+     * @param reserve The address of the underlying asset of the reserve
+     * @param user The beneficiary of the repayment, getting his debt reduced
+     * @param repayer The address of the user initiating the repay(), providing the funds
+     * @param amount The amount repaid
+     * @param useATokens True if the repayment is done using aTokens, `false` if done with underlying asset directly
+     */
+    event Repay(
+        address indexed reserve, address indexed user, address indexed repayer, uint256 amount, bool useATokens
+    );
+
+    /**
+     * @dev Emitted on swapBorrowRateMode()
+     * @param reserve The address of the underlying asset of the reserve
+     * @param user The address of the user swapping his rate mode
+     * @param interestRateMode The current interest rate mode of the position being swapped: 1 for Stable, 2 for Variable
+     */
+    event SwapBorrowRateMode(
+        address indexed reserve, address indexed user, AaveDataTypes.InterestRateMode interestRateMode
+    );
+
+    /**
+     * @dev Emitted on borrow(), repay() and liquidationCall() when using isolated assets
+     * @param asset The address of the underlying asset of the reserve
+     * @param totalDebt The total isolation mode debt for the reserve
+     */
+    event IsolationModeTotalDebtUpdated(address indexed asset, uint256 totalDebt);
+
+    /**
+     * @dev Emitted when the user selects a certain asset category for eMode
+     * @param user The address of the user
+     * @param categoryId The category id
+     */
+    event UserEModeSet(address indexed user, uint8 categoryId);
+
+    /**
+     * @dev Emitted on setUserUseReserveAsCollateral()
+     * @param reserve The address of the underlying asset of the reserve
+     * @param user The address of the user enabling the usage as collateral
+     */
+    event ReserveUsedAsCollateralEnabled(address indexed reserve, address indexed user);
+
+    /**
+     * @dev Emitted on setUserUseReserveAsCollateral()
+     * @param reserve The address of the underlying asset of the reserve
+     * @param user The address of the user enabling the usage as collateral
+     */
+    event ReserveUsedAsCollateralDisabled(address indexed reserve, address indexed user);
+
+    /**
+     * @dev Emitted on rebalanceStableBorrowRate()
+     * @param reserve The address of the underlying asset of the reserve
+     * @param user The address of the user for which the rebalance has been executed
+     */
+    event RebalanceStableBorrowRate(address indexed reserve, address indexed user);
+
+    /**
+     * @dev Emitted on flashLoan()
+     * @param target The address of the flash loan receiver contract
+     * @param initiator The address initiating the flash loan
+     * @param asset The address of the asset being flash borrowed
+     * @param amount The amount flash borrowed
+     * @param interestRateMode The flashloan mode: 0 for regular flashloan, 1 for Stable debt, 2 for Variable debt
+     * @param premium The fee flash borrowed
+     * @param referralCode The referral code used
+     */
+    event FlashLoan(
+        address indexed target,
+        address initiator,
+        address indexed asset,
+        uint256 amount,
+        AaveDataTypes.InterestRateMode interestRateMode,
+        uint256 premium,
+        uint16 indexed referralCode
+    );
+
+    /**
+     * @dev Emitted when a borrower is liquidated.
+     * @param collateral The address of the underlying asset used as collateral, to receive as result of the liquidation
+     * @param debtAsset The address of the underlying borrowed asset to be repaid with the liquidation
+     * @param user The address of the borrower getting liquidated
+     * @param debtToCover The debt amount of borrowed `asset` the liquidator wants to cover
+     * @param liquidatedCollateralAmount The amount of collateral received by the liquidator
+     * @param liquidator The address of the liquidator
+     * @param receiveAToken True if the liquidators wants to receive the collateral aTokens, `false` if he wants
+     * to receive the underlying collateral asset directly
+     */
+    event LiquidationCall(
+        address indexed collateral,
+        address indexed debtAsset,
+        address indexed user,
+        uint256 debtToCover,
+        uint256 liquidatedCollateralAmount,
+        address liquidator,
+        bool receiveAToken
+    );
+
+    /**
+     * @dev Emitted when the state of a reserve is updated.
+     * @param reserve The address of the underlying asset of the reserve
+     * @param liquidityRate The next liquidity rate
+     * @param stableBorrowRate The next stable borrow rate
+     * @param variableBorrowRate The next variable borrow rate
+     * @param liquidityIndex The next liquidity index
+     * @param variableBorrowIndex The next variable borrow index
+     */
+    event ReserveDataUpdated(
+        address indexed reserve,
+        uint256 liquidityRate,
+        uint256 stableBorrowRate,
+        uint256 variableBorrowRate,
+        uint256 liquidityIndex,
+        uint256 variableBorrowIndex
+    );
+
+    /**
+     * @dev Emitted when the protocol treasury receives minted aTokens from the accrued interest.
+     * @param reserve The address of the reserve
+     * @param amountMinted The amount minted to the treasury
+     */
+    event MintedToTreasury(address indexed reserve, uint256 amountMinted);
+
+    /**
+     * @notice Mints an `amount` of aTokens to the `onBehalfOf`
+     * @param asset The address of the underlying asset to mint
+     * @param amount The amount to mint
+     * @param onBehalfOf The address that will receive the aTokens
+     * @param referralCode Code used to register the integrator originating the operation, for potential rewards.
+     *   0 if the action is executed directly by the user, without any middle-man
+     */
+    function mintUnbacked(address asset, uint256 amount, address onBehalfOf, uint16 referralCode) external;
+
+    /**
+     * @notice Back the current unbacked underlying with `amount` and pay `fee`.
+     * @param asset The address of the underlying asset to back
+     * @param amount The amount to back
+     * @param fee The amount paid in fees
+     * @return The backed amount
+     */
+    function backUnbacked(address asset, uint256 amount, uint256 fee) external returns (uint256);
+
+    /**
+     * @notice Supplies an `amount` of underlying asset into the reserve, receiving in return overlying aTokens.
+     * - E.g. User supplies 100 USDC and gets in return 100 aUSDC
+     * @param asset The address of the underlying asset to supply
+     * @param amount The amount to be supplied
+     * @param onBehalfOf The address that will receive the aTokens, same as msg.sender if the user
+     *   wants to receive them on his own wallet, or a different address if the beneficiary of aTokens
+     *   is a different wallet
+     * @param referralCode Code used to register the integrator originating the operation, for potential rewards.
+     *   0 if the action is executed directly by the user, without any middle-man
+     */
+    function supply(address asset, uint256 amount, address onBehalfOf, uint16 referralCode) external;
+
+    /**
+     * @notice Supply with transfer approval of asset to be supplied done via permit function
+     * see: https://eips.ethereum.org/EIPS/eip-2612 and https://eips.ethereum.org/EIPS/eip-713
+     * @param asset The address of the underlying asset to supply
+     * @param amount The amount to be supplied
+     * @param onBehalfOf The address that will receive the aTokens, same as msg.sender if the user
+     *   wants to receive them on his own wallet, or a different address if the beneficiary of aTokens
+     *   is a different wallet
+     * @param deadline The deadline timestamp that the permit is valid
+     * @param referralCode Code used to register the integrator originating the operation, for potential rewards.
+     *   0 if the action is executed directly by the user, without any middle-man
+     * @param permitV The V parameter of ERC712 permit sig
+     * @param permitR The R parameter of ERC712 permit sig
+     * @param permitS The S parameter of ERC712 permit sig
+     */
+    function supplyWithPermit(
+        address asset,
+        uint256 amount,
+        address onBehalfOf,
+        uint16 referralCode,
+        uint256 deadline,
+        uint8 permitV,
+        bytes32 permitR,
+        bytes32 permitS
+    ) external;
+
+    /**
+     * @notice Withdraws an `amount` of underlying asset from the reserve, burning the equivalent aTokens owned
+     * E.g. User has 100 aUSDC, calls withdraw() and receives 100 USDC, burning the 100 aUSDC
+     * @param asset The address of the underlying asset to withdraw
+     * @param amount The underlying amount to be withdrawn
+     *   - Send the value type(uint256).max in order to withdraw the whole aToken balance
+     * @param to The address that will receive the underlying, same as msg.sender if the user
+     *   wants to receive it on his own wallet, or a different address if the beneficiary is a
+     *   different wallet
+     * @return The final amount withdrawn
+     */
+    function withdraw(address asset, uint256 amount, address to) external returns (uint256);
+
+    /**
+     * @notice Allows users to borrow a specific `amount` of the reserve underlying asset, provided that the borrower
+     * already supplied enough collateral, or he was given enough allowance by a credit delegator on the
+     * corresponding debt token (StableDebtToken or VariableDebtToken)
+     * - E.g. User borrows 100 USDC passing as `onBehalfOf` his own address, receiving the 100 USDC in his wallet
+     *   and 100 stable/variable debt tokens, depending on the `interestRateMode`
+     * @param asset The address of the underlying asset to borrow
+     * @param amount The amount to be borrowed
+     * @param interestRateMode The interest rate mode at which the user wants to borrow: 1 for Stable, 2 for Variable
+     * @param referralCode The code used to register the integrator originating the operation, for potential rewards.
+     *   0 if the action is executed directly by the user, without any middle-man
+     * @param onBehalfOf The address of the user who will receive the debt. Should be the address of the borrower itself
+     * calling the function if he wants to borrow against his own collateral, or the address of the credit delegator
+     * if he has been given credit delegation allowance
+     */
+    function borrow(address asset, uint256 amount, uint256 interestRateMode, uint16 referralCode, address onBehalfOf)
+        external;
+
+    /**
+     * @notice Repays a borrowed `amount` on a specific reserve, burning the equivalent debt tokens owned
+     * - E.g. User repays 100 USDC, burning 100 variable/stable debt tokens of the `onBehalfOf` address
+     * @param asset The address of the borrowed underlying asset previously borrowed
+     * @param amount The amount to repay
+     * - Send the value type(uint256).max in order to repay the whole debt for `asset` on the specific `debtMode`
+     * @param interestRateMode The interest rate mode at of the debt the user wants to repay: 1 for Stable, 2 for Variable
+     * @param onBehalfOf The address of the user who will get his debt reduced/removed. Should be the address of the
+     * user calling the function if he wants to reduce/remove his own debt, or the address of any other
+     * other borrower whose debt should be removed
+     * @return The final amount repaid
+     */
+    function repay(address asset, uint256 amount, uint256 interestRateMode, address onBehalfOf)
+        external
+        returns (uint256);
+
+    /**
+     * @notice Repay with transfer approval of asset to be repaid done via permit function
+     * see: https://eips.ethereum.org/EIPS/eip-2612 and https://eips.ethereum.org/EIPS/eip-713
+     * @param asset The address of the borrowed underlying asset previously borrowed
+     * @param amount The amount to repay
+     * - Send the value type(uint256).max in order to repay the whole debt for `asset` on the specific `debtMode`
+     * @param interestRateMode The interest rate mode at of the debt the user wants to repay: 1 for Stable, 2 for Variable
+     * @param onBehalfOf Address of the user who will get his debt reduced/removed. Should be the address of the
+     * user calling the function if he wants to reduce/remove his own debt, or the address of any other
+     * other borrower whose debt should be removed
+     * @param deadline The deadline timestamp that the permit is valid
+     * @param permitV The V parameter of ERC712 permit sig
+     * @param permitR The R parameter of ERC712 permit sig
+     * @param permitS The S parameter of ERC712 permit sig
+     * @return The final amount repaid
+     */
+    function repayWithPermit(
+        address asset,
+        uint256 amount,
+        uint256 interestRateMode,
+        address onBehalfOf,
+        uint256 deadline,
+        uint8 permitV,
+        bytes32 permitR,
+        bytes32 permitS
+    ) external returns (uint256);
+
+    /**
+     * @notice Repays a borrowed `amount` on a specific reserve using the reserve aTokens, burning the
+     * equivalent debt tokens
+     * - E.g. User repays 100 USDC using 100 aUSDC, burning 100 variable/stable debt tokens
+     * @dev  Passing uint256.max as amount will clean up any residual aToken dust balance, if the user aToken
+     * balance is not enough to cover the whole debt
+     * @param asset The address of the borrowed underlying asset previously borrowed
+     * @param amount The amount to repay
+     * - Send the value type(uint256).max in order to repay the whole debt for `asset` on the specific `debtMode`
+     * @param interestRateMode The interest rate mode at of the debt the user wants to repay: 1 for Stable, 2 for Variable
+     * @return The final amount repaid
+     */
+    function repayWithATokens(address asset, uint256 amount, uint256 interestRateMode) external returns (uint256);
+
+    /**
+     * @notice Allows a borrower to swap his debt between stable and variable mode, or vice versa
+     * @param asset The address of the underlying asset borrowed
+     * @param interestRateMode The current interest rate mode of the position being swapped: 1 for Stable, 2 for Variable
+     */
+    function swapBorrowRateMode(address asset, uint256 interestRateMode) external;
+
+    /**
+     * @notice Rebalances the stable interest rate of a user to the current stable rate defined on the reserve.
+     * - Users can be rebalanced if the following conditions are satisfied:
+     *     1. Usage ratio is above 95%
+     *     2. the current supply APY is below REBALANCE_UP_THRESHOLD * maxVariableBorrowRate, which means that too
+     *        much has been borrowed at a stable rate and suppliers are not earning enough
+     * @param asset The address of the underlying asset borrowed
+     * @param user The address of the user to be rebalanced
+     */
+    function rebalanceStableBorrowRate(address asset, address user) external;
+
+    /**
+     * @notice Allows suppliers to enable/disable a specific supplied asset as collateral
+     * @param asset The address of the underlying asset supplied
+     * @param useAsCollateral True if the user wants to use the supply as collateral, false otherwise
+     */
+    function setUserUseReserveAsCollateral(address asset, bool useAsCollateral) external;
+
+    /**
+     * @notice Function to liquidate a non-healthy position collateral-wise, with Health Factor below 1
+     * - The caller (liquidator) covers `debtToCover` amount of debt of the user getting liquidated, and receives
+     *   a proportionally amount of the `collateral` plus a bonus to cover market risk
+     * @param collateral The address of the underlying asset used as collateral, to receive as result of the liquidation
+     * @param debtAsset The address of the underlying borrowed asset to be repaid with the liquidation
+     * @param user The address of the borrower getting liquidated
+     * @param debtToCover The debt amount of borrowed `asset` the liquidator wants to cover
+     * @param receiveAToken True if the liquidators wants to receive the collateral aTokens, `false` if he wants
+     * to receive the underlying collateral asset directly
+     */
+    function liquidationCall(
+        IERC20 collateral,
+        IERC20 debtAsset,
+        address user,
+        uint256 debtToCover,
+        bool receiveAToken
+    ) external;
+
+    /**
+     * @notice Allows smartcontracts to access the liquidity of the pool within one transaction,
+     * as long as the amount taken plus a fee is returned.
+     * @dev IMPORTANT There are security concerns for developers of flashloan receiver contracts that must be kept
+     * into consideration. For further details please visit https://docs.aave.com/developers/
+     * @param receiverAddress The address of the contract receiving the funds, implementing IFlashLoanReceiver interface
+     * @param assets The addresses of the assets being flash-borrowed
+     * @param amounts The amounts of the assets being flash-borrowed
+     * @param interestRateModes Types of the debt to open if the flash loan is not returned:
+     *   0 -> Don't open any debt, just revert if funds can't be transferred from the receiver
+     *   1 -> Open debt at stable rate for the value of the amount flash-borrowed to the `onBehalfOf` address
+     *   2 -> Open debt at variable rate for the value of the amount flash-borrowed to the `onBehalfOf` address
+     * @param onBehalfOf The address  that will receive the debt in the case of using on `modes` 1 or 2
+     * @param params Variadic packed params to pass to the receiver as extra information
+     * @param referralCode The code used to register the integrator originating the operation, for potential rewards.
+     *   0 if the action is executed directly by the user, without any middle-man
+     */
+    function flashLoan(
+        address receiverAddress,
+        address[] calldata assets,
+        uint256[] calldata amounts,
+        uint256[] calldata interestRateModes,
+        address onBehalfOf,
+        bytes calldata params,
+        uint16 referralCode
+    ) external;
+
+    /**
+     * @notice Allows smartcontracts to access the liquidity of the pool within one transaction,
+     * as long as the amount taken plus a fee is returned.
+     * @dev IMPORTANT There are security concerns for developers of flashloan receiver contracts that must be kept
+     * into consideration. For further details please visit https://docs.aave.com/developers/
+     * @param receiverAddress The address of the contract receiving the funds, implementing IFlashLoanSimpleReceiver interface
+     * @param asset The address of the asset being flash-borrowed
+     * @param amount The amount of the asset being flash-borrowed
+     * @param params Variadic packed params to pass to the receiver as extra information
+     * @param referralCode The code used to register the integrator originating the operation, for potential rewards.
+     *   0 if the action is executed directly by the user, without any middle-man
+     */
+    function flashLoanSimple(
+        address receiverAddress,
+        address asset,
+        uint256 amount,
+        bytes calldata params,
+        uint16 referralCode
+    ) external;
+
+    /**
+     * @notice Returns the user account data across all the reserves
+     * @param user The address of the user
+     * @return totalCollateralBase The total collateral of the user in the base currency used by the price feed
+     * @return totalDebtBase The total debt of the user in the base currency used by the price feed
+     * @return availableBorrowsBase The borrowing power left of the user in the base currency used by the price feed
+     * @return currentLiquidationThreshold The liquidation threshold of the user
+     * @return ltv The loan to value of The user
+     * @return healthFactor The current health factor of the user
+     */
+    function getUserAccountData(address user)
+        external
+        view
+        returns (
+            uint256 totalCollateralBase,
+            uint256 totalDebtBase,
+            uint256 availableBorrowsBase,
+            uint256 currentLiquidationThreshold,
+            uint256 ltv,
+            uint256 healthFactor
+        );
+
+    /**
+     * @notice Initializes a reserve, activating it, assigning an aToken and debt tokens and an
+     * interest rate strategy
+     * @dev Only callable by the PoolConfigurator contract
+     * @param asset The address of the underlying asset of the reserve
+     * @param aTokenAddress The address of the aToken that will be assigned to the reserve
+     * @param stableDebtAddress The address of the StableDebtToken that will be assigned to the reserve
+     * @param variableDebtAddress The address of the VariableDebtToken that will be assigned to the reserve
+     * @param interestRateStrategyAddress The address of the interest rate strategy contract
+     */
+    function initReserve(
+        address asset,
+        address aTokenAddress,
+        address stableDebtAddress,
+        address variableDebtAddress,
+        address interestRateStrategyAddress
+    ) external;
+
+    /**
+     * @notice Drop a reserve
+     * @dev Only callable by the PoolConfigurator contract
+     * @param asset The address of the underlying asset of the reserve
+     */
+    function dropReserve(address asset) external;
+
+    /**
+     * @notice Updates the address of the interest rate strategy contract
+     * @dev Only callable by the PoolConfigurator contract
+     * @param asset The address of the underlying asset of the reserve
+     * @param rateStrategyAddress The address of the interest rate strategy contract
+     */
+    function setReserveInterestRateStrategyAddress(address asset, address rateStrategyAddress) external;
+
+    /**
+     * @notice Sets the configuration bitmap of the reserve as a whole
+     * @dev Only callable by the PoolConfigurator contract
+     * @param asset The address of the underlying asset of the reserve
+     * @param configuration The new configuration bitmap
+     */
+    function setConfiguration(address asset, AaveDataTypes.ReserveConfigurationMap calldata configuration) external;
+
+    /**
+     * @notice Returns the configuration of the reserve
+     * @param asset The address of the underlying asset of the reserve
+     * @return The configuration of the reserve
+     */
+    function getConfiguration(address asset) external view returns (AaveDataTypes.ReserveConfigurationMap memory);
+
+    /**
+     * @notice Returns the configuration of the user across all the reserves
+     * @param user The user address
+     * @return The configuration of the user
+     */
+    function getUserConfiguration(address user) external view returns (AaveDataTypes.UserConfigurationMap memory);
+
+    /**
+     * @notice Returns the normalized income of the reserve
+     * @param asset The address of the underlying asset of the reserve
+     * @return The reserve's normalized income
+     */
+    function getReserveNormalizedIncome(IERC20 asset) external view returns (uint256);
+
+    /**
+     * @notice Returns the normalized variable debt per unit of asset
+     * @dev WARNING: This function is intended to be used primarily by the protocol itself to get a
+     * "dynamic" variable index based on time, current stored index and virtual rate at the current
+     * moment (approx. a borrower would get if opening a position). This means that is always used in
+     * combination with variable debt supply/balances.
+     * If using this function externally, consider that is possible to have an increasing normalized
+     * variable debt that is not equivalent to how the variable debt index would be updated in storage
+     * (e.g. only updates with non-zero variable debt supply)
+     * @param asset The address of the underlying asset of the reserve
+     * @return The reserve normalized variable debt
+     */
+    function getReserveNormalizedVariableDebt(address asset) external view returns (uint256);
+
+    /**
+     * @notice Returns the state and configuration of the reserve
+     * @param asset The address of the underlying asset of the reserve
+     * @return The state and configuration data of the reserve
+     */
+    function getReserveData(IERC20 asset) external view returns (AaveDataTypes.ReserveData memory);
+
+    /**
+     * @notice Validates and finalizes an aToken transfer
+     * @dev Only callable by the overlying aToken of the `asset`
+     * @param asset The address of the underlying asset of the aToken
+     * @param from The user from which the aTokens are transferred
+     * @param to The user receiving the aTokens
+     * @param amount The amount being transferred/withdrawn
+     * @param balanceFromBefore The aToken balance of the `from` user before the transfer
+     * @param balanceToBefore The aToken balance of the `to` user before the transfer
+     */
+    function finalizeTransfer(
+        address asset,
+        address from,
+        address to,
+        uint256 amount,
+        uint256 balanceFromBefore,
+        uint256 balanceToBefore
+    ) external;
+
+    /**
+     * @notice Returns the list of the underlying assets of all the initialized reserves
+     * @dev It does not include dropped reserves
+     * @return The addresses of the underlying assets of the initialized reserves
+     */
+    function getReservesList() external view returns (address[] memory);
+
+    /**
+     * @notice Returns the address of the underlying asset of a reserve by the reserve id as stored in the AaveDataTypes.ReserveData struct
+     * @param id The id of the reserve as stored in the AaveDataTypes.ReserveData struct
+     * @return The address of the reserve associated with id
+     */
+    function getReserveAddressById(uint16 id) external view returns (address);
+
+    /**
+     * @notice Returns the PoolAddressesProvider connected to this contract
+     * @return The address of the PoolAddressesProvider
+     */
+    function ADDRESSES_PROVIDER() external view returns (IPoolAddressesProvider);
+
+    /**
+     * @notice Returns the data of an eMode category
+     * @param id The id of the category
+     */
+    function getEModeCategoryData(uint8 id) external view returns (bytes32, uint16 ltv, uint16 liquidationThreshold);
+
+    /**
+     * @notice Allows a user to use the protocol in eMode
+     * @param categoryId The id of the category
+     */
+    function setUserEMode(uint8 categoryId) external;
+
+    /**
+     * @notice Returns the eMode the user is using
+     * @param user The address of the user
+     * @return The eMode id
+     */
+    function getUserEMode(address user) external view returns (uint256);
+
+    /**
+     * @notice Resets the isolation mode total debt of the given asset to zero
+     * @dev It requires the given asset has zero debt ceiling
+     * @param asset The address of the underlying asset to reset the isolationModeTotalDebt
+     */
+    function resetIsolationModeTotalDebt(address asset) external;
+
+    /**
+     * @notice Returns the percentage of available liquidity that can be borrowed at once at stable rate
+     * @return The percentage of available liquidity to borrow, expressed in bps
+     */
+    function MAX_STABLE_RATE_BORROW_SIZE_PERCENT() external view returns (uint256);
+
+    /**
+     * @notice Returns the total fee on flash loans
+     * @return The total fee on flashloans
+     */
+    function FLASHLOAN_PREMIUM_TOTAL() external view returns (uint128);
+
+    /**
+     * @notice Returns the part of the bridge fees sent to protocol
+     * @return The bridge fee sent to the protocol treasury
+     */
+    function BRIDGE_PROTOCOL_FEE() external view returns (uint256);
+
+    /**
+     * @notice Returns the part of the flashloan fees sent to protocol
+     * @return The flashloan fee sent to the protocol treasury
+     */
+    function FLASHLOAN_PREMIUM_TO_PROTOCOL() external view returns (uint128);
+
+    /**
+     * @notice Returns the maximum number of reserves supported to be listed in this Pool
+     * @return The maximum number of reserves supported
+     */
+    function MAX_NUMBER_RESERVES() external view returns (uint16);
+
+    /**
+     * @notice Mints the assets accrued through the reserve factor to the treasury in the form of aTokens
+     * @param assets The list of reserves for which the minting needs to be executed
+     */
+    function mintToTreasury(address[] calldata assets) external;
+
+    /**
+     * @notice Rescue and transfer tokens locked in this contract
+     * @param token The address of the token
+     * @param to The address of the recipient
+     * @param amount The amount of token to transfer
+     */
+    function rescueTokens(address token, address to, uint256 amount) external;
+
+    /**
+     * @notice Supplies an `amount` of underlying asset into the reserve, receiving in return overlying aTokens.
+     * - E.g. User supplies 100 USDC and gets in return 100 aUSDC
+     * @dev Deprecated: Use the `supply` function instead
+     * @param asset The address of the underlying asset to supply
+     * @param amount The amount to be supplied
+     * @param onBehalfOf The address that will receive the aTokens, same as msg.sender if the user
+     *   wants to receive them on his own wallet, or a different address if the beneficiary of aTokens
+     *   is a different wallet
+     * @param referralCode Code used to register the integrator originating the operation, for potential rewards.
+     *   0 if the action is executed directly by the user, without any middle-man
+     */
+    function deposit(address asset, uint256 amount, address onBehalfOf, uint16 referralCode) external;
+}