@pendle/core-v2 5.2.0-beta-5 → 5.2.1-beta-1

package/contracts/oracles/PtYtLpOracle/chainlink/PendleChainlinkOracleBase.sol

@@ -1,129 +0,0 @@
-// SPDX-License-Identifier: GPL-3.0-or-later
-pragma solidity ^0.8.17;
-
-import "../../../interfaces/IPChainlinkOracle.sol";
-import "../PendleLpOracleLib.sol";
-
-/**
- * @dev The round data returned from this contract will follow:
- * - There will be only one round (roundId=0)
- * - startedAt=0, updatedAt=block.timestamp
- */
-abstract contract PendleChainlinkOracleBase is IPChainlinkOracle {
-    using PendlePYOracleLib for IPMarket;
-    using PendleLpOracleLib for IPMarket;
-
-    error InvalidRoundId();
-
-    uint8 internal constant LP_DECIMALS = 18;
-
-    // solhint-disable immutable-vars-naming
-    address public immutable factory;
-    address public immutable market;
-    uint32 public immutable twapDuration;
-
-    uint8 public immutable fromTokenDecimals;
-    uint8 public immutable toTokenDecimals;
-
-    PendleOracleType public immutable baseOracleType;
-
-    function(IPMarket, uint32) internal view returns (uint256) internal immutable getPendlePrice;
-
-    modifier validateRoundId(uint80 roundId) {
-        if (roundId != 0) {
-            revert InvalidRoundId();
-        }
-        _;
-    }
-
-    constructor(address _market, uint32 _twapDuration, PendleOracleType _baseOracleType) {
-        factory = msg.sender;
-        market = _market;
-        twapDuration = _twapDuration;
-        baseOracleType = _baseOracleType;
-        (fromTokenDecimals, toTokenDecimals) = _readDecimals(_market, _baseOracleType);
-        getPendlePrice = _getPendlePriceFunc();
-    }
-
-    // =================================================================
-    //                          CHAINLINK INTERFACE
-    // =================================================================
-
-    function latestRoundData()
-        public
-        view
-        virtual
-        returns (uint80 roundId, int256 answer, uint256 startedAt, uint256 updatedAt, uint80 answeredInRound);
-
-    function getRoundData(
-        uint80 roundId
-    ) external view validateRoundId(roundId) returns (uint80, int256, uint256, uint256, uint80) {
-        return latestRoundData();
-    }
-
-    function decimals() external pure returns (uint8) {
-        return 18;
-    }
-
-    function description() external pure returns (string memory) {
-        return "Pendle Chainlink-compatible Oracle";
-    }
-
-    function version() external pure returns (uint256) {
-        return 1;
-    }
-
-    // =================================================================
-    //                          PRICING FUNCTIONS
-    // =================================================================
-
-    function _getPendleTokenPrice() internal view returns (int256) {
-        return _descalePrice(getPendlePrice(IPMarket(market), twapDuration));
-    }
-
-    function _descalePrice(uint256 price) internal view returns (int256 unwrappedPrice) {
-        return PMath.Int((price * (10 ** fromTokenDecimals)) / (10 ** toTokenDecimals));
-    }
-
-    // =================================================================
-    //                          USE ONLY AT INITIALIZATION
-    // =================================================================
-
-    function _getPendlePriceFunc() internal view returns (function(IPMarket, uint32) internal view returns (uint256)) {
-        if (baseOracleType == PendleOracleType.PT_TO_SY) {
-            return PendlePYOracleLib.getPtToSyRate;
-        } else if (baseOracleType == PendleOracleType.PT_TO_ASSET) {
-            return PendlePYOracleLib.getPtToAssetRate;
-        } else if (baseOracleType == PendleOracleType.YT_TO_SY) {
-            return PendlePYOracleLib.getYtToSyRate;
-        } else if (baseOracleType == PendleOracleType.YT_TO_ASSET) {
-            return PendlePYOracleLib.getYtToAssetRate;
-        } else if (baseOracleType == PendleOracleType.LP_TO_SY) {
-            return PendleLpOracleLib.getLpToSyRate;
-        } else if (baseOracleType == PendleOracleType.LP_TO_ASSET) {
-            return PendleLpOracleLib.getLpToAssetRate;
-        } else {
-            revert("not supported");
-        }
-    }
-
-    function _readDecimals(
-        address _market,
-        PendleOracleType _oracleType
-    ) internal view returns (uint8 _fromDecimals, uint8 _toDecimals) {
-        (IStandardizedYield SY, , ) = IPMarket(_market).readTokens();
-
-        uint8 syDecimals = SY.decimals();
-        (, , uint8 assetDecimals) = SY.assetInfo();
-
-        if (_oracleType == PendleOracleType.LP_TO_ASSET) {
-            return (LP_DECIMALS, assetDecimals);
-        } else if (_oracleType == PendleOracleType.LP_TO_SY) {
-            return (LP_DECIMALS, syDecimals);
-        } else if (_oracleType == PendleOracleType.PT_TO_ASSET || _oracleType == PendleOracleType.YT_TO_ASSET) {
-            return (assetDecimals, assetDecimals);
-        } else if (_oracleType == PendleOracleType.PT_TO_SY || _oracleType == PendleOracleType.YT_TO_SY) {
-            return (assetDecimals, syDecimals);
-        }
-    }
-}

package/contracts/oracles/PtYtLpOracle/chainlink/PendleChainlinkOracleFactory.sol

@@ -1,109 +0,0 @@
-// SPDX-License-Identifier: GPL-3.0-or-later
-pragma solidity ^0.8.17;
-
-import "./PendleChainlinkOracle.sol";
-import "./PendleChainlinkOracleWithQuote.sol";
-import "../../../interfaces/IPChainlinkOracleFactory.sol";
-import "../../../interfaces/IPPYLpOracle.sol";
-
-contract PendleChainlinkOracleFactory is IPChainlinkOracleFactory {
-    error OracleAlreadyExists();
-
-    error OracleIncreaseCardinalityRequired(uint32 cardinalityRequired);
-    error OracleOldestObservationNotSatisfied();
-
-    // [keccak256(market, duration, baseOracleType)]
-    mapping(bytes32 oracleId => address oracleAddr) public oracles;
-
-    // [keccak256(market, duration, baseOracleType, quoteOracle)]
-    mapping(bytes32 oracleId => address oracleAddr) public oraclesWithQuote;
-
-    address public immutable pyLpOracle;
-
-    constructor(address _pyLpOracle) {
-        pyLpOracle = _pyLpOracle;
-    }
-
-    function createOracle(
-        address market,
-        uint32 twapDuration,
-        PendleOracleType baseOracleType
-    ) external returns (address oracle) {
-        bytes32 oracleId = _getOracleId(market, twapDuration, baseOracleType);
-        if (oracles[oracleId] != address(0)) revert OracleAlreadyExists();
-
-        _checkOracleState(market, twapDuration);
-
-        oracle = address(new PendleChainlinkOracle(market, twapDuration, baseOracleType));
-        oracles[oracleId] = oracle;
-        emit OracleCreated(market, twapDuration, baseOracleType, oracle, oracleId);
-    }
-
-    /**
-     * @dev quoteOracle must has Chainlink-compatible interface
-     */
-    function createOracleWithQuote(
-        address market,
-        uint32 twapDuration,
-        PendleOracleType baseOracleType,
-        address quoteOracle
-    ) external returns (address oracle) {
-        bytes32 oracleId = _getOracleWithQuoteId(market, twapDuration, baseOracleType, quoteOracle);
-        if (oraclesWithQuote[oracleId] != address(0)) revert OracleAlreadyExists();
-
-        _checkOracleState(market, twapDuration);
-
-        oracle = address(new PendleChainlinkOracleWithQuote(market, twapDuration, baseOracleType, quoteOracle));
-        oraclesWithQuote[oracleId] = oracle;
-        emit OracleWithQuoteCreated(market, twapDuration, baseOracleType, quoteOracle, oracle, oracleId);
-    }
-
-    function getOracle(
-        address market,
-        uint32 twapDuration,
-        PendleOracleType baseOracleType
-    ) public view returns (address) {
-        return oracles[_getOracleId(market, twapDuration, baseOracleType)];
-    }
-
-    function getOracleWithQuote(
-        address market,
-        uint32 twapDuration,
-        PendleOracleType baseOracleType,
-        address quoteOracle
-    ) public view returns (address) {
-        return oraclesWithQuote[_getOracleWithQuoteId(market, twapDuration, baseOracleType, quoteOracle)];
-    }
-
-    function _getOracleId(
-        address market,
-        uint32 twapDuration,
-        PendleOracleType baseOracleType
-    ) internal pure returns (bytes32) {
-        return keccak256(abi.encode(market, twapDuration, baseOracleType));
-    }
-
-    function _getOracleWithQuoteId(
-        address market,
-        uint32 twapDuration,
-        PendleOracleType baseOracleType,
-        address quoteOracle
-    ) internal pure returns (bytes32) {
-        return keccak256(abi.encode(market, twapDuration, baseOracleType, quoteOracle));
-    }
-
-    function _checkOracleState(address market, uint32 twapDuration) internal view {
-        (bool increaseCardinalityRequired, uint32 cardinalityRequired, bool oldestObservationSatisfied) = IPPYLpOracle(
-            pyLpOracle
-        ).getOracleState(market, twapDuration);
-
-        if (increaseCardinalityRequired) {
-            // call IPMarket(market).increaseObservationsCardinalityNext(cardinalityRequired) then wait for twapDuration seconds
-            revert OracleIncreaseCardinalityRequired(cardinalityRequired);
-        }
-        if (!oldestObservationSatisfied) {
-            // wait for twapDuration seconds
-            revert OracleOldestObservationNotSatisfied();
-        }
-    }
-}

package/contracts/oracles/PtYtLpOracle/chainlink/PendleChainlinkOracleWithQuote.sol

@@ -1,54 +0,0 @@
-// SPDX-License-Identifier: GPL-3.0-or-later
-pragma solidity ^0.8.17;
-
-import "./PendleChainlinkOracleBase.sol";
-
-/**
- * @dev The round data returned from this contract will follow:
- * - There will be only one round (roundId=0)
- * - startedAt=0, updatedAt=quoteOracle.updatedAt()
- */
-contract PendleChainlinkOracleWithQuote is PendleChainlinkOracleBase {
-    error QuoteOracleCannotBeZero();
-
-    // solhint-disable immutable-vars-naming
-    address public immutable quoteOracle;
-    int256 public immutable quoteScale;
-
-    constructor(
-        address _market,
-        uint32 _twapDuration,
-        PendleOracleType _baseOracleType,
-        address _quoteOracle
-    ) PendleChainlinkOracleBase(_market, _twapDuration, _baseOracleType) {
-        if (_quoteOracle == address(0)) revert QuoteOracleCannotBeZero();
-
-        quoteOracle = _quoteOracle;
-        quoteScale = PMath.Int(10 ** AggregatorV3Interface(_quoteOracle).decimals());
-    }
-
-    /**
-     * @notice The round data returned from this contract will follow:
-     * - answer will satisfy 1 natural unit of PendleToken = (answer/1e18) natural unit of quoteToken
-     * - In other words, 10**(PendleToken.decimals) = (answer/1e18) * 10**(quoteToken.decimals)
-     * @return roundId always 0 for this contract
-     * @return answer The answer (in 18 decimals)
-     * @return startedAt always 0 for this contract
-     * @return updatedAt will be the same as quoteOracle.updatedAt()
-     * @return answeredInRound always 0 for this contract
-     */
-    function latestRoundData()
-        public
-        view
-        virtual
-        override
-        returns (uint80 roundId, int256 answer, uint256 startedAt, uint256 updatedAt, uint80 answeredInRound)
-    {
-        (, int256 quoteAnswer, , uint256 quoteUpdatedAt, ) = AggregatorV3Interface(quoteOracle).latestRoundData();
-        answer = (_getPendleTokenPrice() * quoteAnswer) / quoteScale;
-        updatedAt = quoteUpdatedAt;
-        roundId = 0;
-        startedAt = 0;
-        answeredInRound = 0;
-    }
-}