@pendle/core-v2 3.0.0-beta-11 → 3.0.0-beta-12

package/contracts/core/Market/v3/PendleMarketV3.sol

@@ -0,0 +1,360 @@
+// SPDX-License-Identifier: GPL-3.0-or-later
+pragma solidity ^0.8.17;
+
+import "../../../interfaces/IPMarketV3.sol";
+import "../../../interfaces/IPMarketFactoryV3.sol";
+import "../../../interfaces/IPMarketSwapCallback.sol";
+
+import "../../erc20/PendleERC20Permit.sol";
+import "../PendleGauge.sol";
+import "../OracleLib.sol";
+
+/**
+Invariance to maintain:
+- Internal balances totalPt & totalSy not interfered by people transferring tokens in directly
+- address(0) & address(this) should never have any rewards & activeBalance accounting done. This is
+    guaranteed by address(0) & address(this) check in each updateForTwo function
+*/
+contract PendleMarketV3 is PendleERC20Permit, PendleGauge, IPMarketV3 {
+    using PMath for uint256;
+    using PMath for int256;
+    using MarketMathCore for MarketState;
+    using SafeERC20 for IERC20;
+    using PYIndexLib for IPYieldToken;
+    using OracleLib for OracleLib.Observation[65535];
+
+    struct MarketStorage {
+        int128 totalPt;
+        int128 totalSy;
+        // 1 SLOT = 256 bits
+        uint96 lastLnImpliedRate;
+        uint16 observationIndex;
+        uint16 observationCardinality;
+        uint16 observationCardinalityNext;
+        // 1 SLOT = 144 bits
+    }
+
+    string private constant NAME = "Pendle Market";
+    string private constant SYMBOL = "PENDLE-LPT";
+
+    IPPrincipalToken internal immutable PT;
+    IStandardizedYield internal immutable SY;
+    IPYieldToken internal immutable YT;
+
+    address public immutable factory;
+    uint256 public immutable expiry;
+
+    int256 internal immutable scalarRoot;
+    int256 internal immutable initialAnchor;
+    uint80 internal immutable lnFeeRateRoot;
+
+    MarketStorage public _storage;
+
+    OracleLib.Observation[65535] public observations;
+
+    modifier notExpired() {
+        if (isExpired()) revert Errors.MarketExpired();
+        _;
+    }
+
+    constructor(
+        address _PT,
+        int256 _scalarRoot,
+        int256 _initialAnchor,
+        uint80 _lnFeeRateRoot,
+        address _vePendle,
+        address _gaugeController
+    ) PendleERC20Permit(NAME, SYMBOL, 18) PendleGauge(IPPrincipalToken(_PT).SY(), _vePendle, _gaugeController) {
+        PT = IPPrincipalToken(_PT);
+        SY = IStandardizedYield(PT.SY());
+        YT = IPYieldToken(PT.YT());
+
+        (_storage.observationCardinality, _storage.observationCardinalityNext) = observations.initialize(
+            uint32(block.timestamp)
+        );
+
+        if (_scalarRoot <= 0) revert Errors.MarketScalarRootBelowZero(_scalarRoot);
+
+        scalarRoot = _scalarRoot;
+        initialAnchor = _initialAnchor;
+        lnFeeRateRoot = _lnFeeRateRoot;
+        expiry = IPPrincipalToken(_PT).expiry();
+        factory = msg.sender;
+    }
+
+    /**
+     * @notice PendleMarket allows users to provide in PT & SY in exchange for LPs, which
+     * will grant LP holders more exchange fee over time
+     * @dev will mint as much LP as possible such that the corresponding SY and PT used do
+     * not exceed `netSyDesired` and `netPtDesired`, respectively
+     * @dev PT and SY should be transferred to this contract prior to calling
+     * @dev will revert if PT is expired
+     */
+    function mint(
+        address receiver,
+        uint256 netSyDesired,
+        uint256 netPtDesired
+    ) external nonReentrant notExpired returns (uint256 netLpOut, uint256 netSyUsed, uint256 netPtUsed) {
+        MarketState memory market = readState(msg.sender);
+        PYIndex index = YT.newIndex();
+
+        uint256 lpToReserve;
+
+        (lpToReserve, netLpOut, netSyUsed, netPtUsed) = market.addLiquidity(
+            netSyDesired,
+            netPtDesired,
+            block.timestamp
+        );
+
+        // initializing the market
+        if (lpToReserve != 0) {
+            market.setInitialLnImpliedRate(index, initialAnchor, block.timestamp);
+            _mint(address(1), lpToReserve);
+        }
+
+        _mint(receiver, netLpOut);
+
+        _writeState(market);
+
+        if (_selfBalance(SY) < market.totalSy.Uint())
+            revert Errors.MarketInsufficientSyReceived(_selfBalance(SY), market.totalSy.Uint());
+        if (_selfBalance(PT) < market.totalPt.Uint())
+            revert Errors.MarketInsufficientPtReceived(_selfBalance(PT), market.totalPt.Uint());
+
+        emit Mint(receiver, netLpOut, netSyUsed, netPtUsed);
+    }
+
+    /**
+     * @notice LP Holders can burn their LP to receive back SY & PT proportionally
+     * to their share of the market
+     */
+    function burn(
+        address receiverSy,
+        address receiverPt,
+        uint256 netLpToBurn
+    ) external nonReentrant returns (uint256 netSyOut, uint256 netPtOut) {
+        MarketState memory market = readState(msg.sender);
+
+        _burn(address(this), netLpToBurn);
+
+        (netSyOut, netPtOut) = market.removeLiquidity(netLpToBurn);
+
+        if (receiverSy != address(this)) IERC20(SY).safeTransfer(receiverSy, netSyOut);
+        if (receiverPt != address(this)) IERC20(PT).safeTransfer(receiverPt, netPtOut);
+
+        _writeState(market);
+
+        emit Burn(receiverSy, receiverPt, netLpToBurn, netSyOut, netPtOut);
+    }
+
+    /**
+     * @notice Pendle Market allows swaps between PT & SY it is holding. This function
+     * aims to swap an exact amount of PT to SY.
+     * @dev steps working of this contract
+       - The outcome amount of SY will be precomputed by MarketMathLib
+       - Release the calculated amount of SY to receiver
+       - Callback to msg.sender if data.length > 0
+       - Ensure exactPtIn amount of PT has been transferred to this address
+     * @dev will revert if PT is expired
+     * @param data bytes data to be sent in the callback (if any)
+     */
+    function swapExactPtForSy(
+        address receiver,
+        uint256 exactPtIn,
+        bytes calldata data
+    ) external nonReentrant notExpired returns (uint256 netSyOut, uint256 netSyFee) {
+        MarketState memory market = readState(msg.sender);
+
+        uint256 netSyToReserve;
+        (netSyOut, netSyFee, netSyToReserve) = market.swapExactPtForSy(YT.newIndex(), exactPtIn, block.timestamp);
+
+        if (receiver != address(this)) IERC20(SY).safeTransfer(receiver, netSyOut);
+        IERC20(SY).safeTransfer(market.treasury, netSyToReserve);
+
+        _writeState(market);
+
+        if (data.length > 0) {
+            IPMarketSwapCallback(msg.sender).swapCallback(exactPtIn.neg(), netSyOut.Int(), data);
+        }
+
+        if (_selfBalance(PT) < market.totalPt.Uint())
+            revert Errors.MarketInsufficientPtReceived(_selfBalance(PT), market.totalPt.Uint());
+
+        emit Swap(msg.sender, receiver, exactPtIn.neg(), netSyOut.Int(), netSyFee, netSyToReserve);
+    }
+
+    /**
+     * @notice Pendle Market allows swaps between PT & SY it is holding. This function
+     * aims to swap SY for an exact amount of PT.
+     * @dev steps working of this function
+       - The exact outcome amount of PT will be transferred to receiver
+       - Callback to msg.sender if data.length > 0
+       - Ensure the calculated required amount of SY is transferred to this address
+     * @dev will revert if PT is expired
+     * @param data bytes data to be sent in the callback (if any)
+     */
+    function swapSyForExactPt(
+        address receiver,
+        uint256 exactPtOut,
+        bytes calldata data
+    ) external nonReentrant notExpired returns (uint256 netSyIn, uint256 netSyFee) {
+        MarketState memory market = readState(msg.sender);
+
+        uint256 netSyToReserve;
+        (netSyIn, netSyFee, netSyToReserve) = market.swapSyForExactPt(YT.newIndex(), exactPtOut, block.timestamp);
+
+        if (receiver != address(this)) IERC20(PT).safeTransfer(receiver, exactPtOut);
+        IERC20(SY).safeTransfer(market.treasury, netSyToReserve);
+
+        _writeState(market);
+
+        if (data.length > 0) {
+            IPMarketSwapCallback(msg.sender).swapCallback(exactPtOut.Int(), netSyIn.neg(), data);
+        }
+
+        // have received enough SY
+        if (_selfBalance(SY) < market.totalSy.Uint())
+            revert Errors.MarketInsufficientSyReceived(_selfBalance(SY), market.totalSy.Uint());
+
+        emit Swap(msg.sender, receiver, exactPtOut.Int(), netSyIn.neg(), netSyFee, netSyToReserve);
+    }
+
+    /// @notice forces balances to match reserves
+    function skim() external nonReentrant {
+        MarketState memory market = readState(msg.sender);
+        uint256 excessPt = _selfBalance(PT) - market.totalPt.Uint();
+        uint256 excessSy = _selfBalance(SY) - market.totalSy.Uint();
+        if (excessPt != 0) IERC20(PT).safeTransfer(market.treasury, excessPt);
+        if (excessSy != 0) IERC20(SY).safeTransfer(market.treasury, excessSy);
+    }
+
+    /**
+     * @notice redeems the user's reward
+     * @return amount of reward token redeemed, in the same order as `getRewardTokens()`
+     */
+    function redeemRewards(address user) external nonReentrant returns (uint256[] memory) {
+        return _redeemRewards(user);
+    }
+
+    /// @notice returns the list of reward tokens
+    function getRewardTokens() external view returns (address[] memory) {
+        return _getRewardTokens();
+    }
+
+    /*///////////////////////////////////////////////////////////////
+                                ORACLE
+    //////////////////////////////////////////////////////////////*/
+
+    function observe(uint32[] memory secondsAgos) external view returns (uint216[] memory lnImpliedRateCumulative) {
+        return
+            observations.observe(
+                uint32(block.timestamp),
+                secondsAgos,
+                _storage.lastLnImpliedRate,
+                _storage.observationIndex,
+                _storage.observationCardinality
+            );
+    }
+
+    function increaseObservationsCardinalityNext(uint16 cardinalityNext) external nonReentrant {
+        uint16 cardinalityNextOld = _storage.observationCardinalityNext;
+        uint16 cardinalityNextNew = observations.grow(cardinalityNextOld, cardinalityNext);
+        if (cardinalityNextOld != cardinalityNextNew) {
+            _storage.observationCardinalityNext = cardinalityNextNew;
+            emit IncreaseObservationCardinalityNext(cardinalityNextOld, cardinalityNextNew);
+        }
+    }
+
+    /*///////////////////////////////////////////////////////////////
+                                READ/WRITE STATES
+    //////////////////////////////////////////////////////////////*/
+
+    /**
+     * @notice read the state of the market from storage into memory for gas-efficient manipulation
+     */
+    function readState(address router) public view returns (MarketState memory market) {
+        market.totalPt = _storage.totalPt;
+        market.totalSy = _storage.totalSy;
+        market.totalLp = totalSupply().Int();
+
+        uint80 overriddenFee;
+
+        (market.treasury, overriddenFee, market.reserveFeePercent) = IPMarketFactoryV3(factory).getMarketConfig(
+            address(this),
+            router
+        );
+
+        market.lnFeeRateRoot = overriddenFee == 0 ? lnFeeRateRoot : overriddenFee;
+        market.scalarRoot = scalarRoot;
+        market.expiry = expiry;
+
+        market.lastLnImpliedRate = _storage.lastLnImpliedRate;
+    }
+
+    /// @notice write back the state of the market from memory to storage
+    function _writeState(MarketState memory market) internal {
+        uint96 lastLnImpliedRate96 = market.lastLnImpliedRate.Uint96();
+        int128 totalPt128 = market.totalPt.Int128();
+        int128 totalSy128 = market.totalSy.Int128();
+
+        (uint16 observationIndex, uint16 observationCardinality) = observations.write(
+            _storage.observationIndex,
+            uint32(block.timestamp),
+            _storage.lastLnImpliedRate,
+            _storage.observationCardinality,
+            _storage.observationCardinalityNext
+        );
+
+        _storage.totalPt = totalPt128;
+        _storage.totalSy = totalSy128;
+        _storage.lastLnImpliedRate = lastLnImpliedRate96;
+        _storage.observationIndex = observationIndex;
+        _storage.observationCardinality = observationCardinality;
+
+        emit UpdateImpliedRate(block.timestamp, market.lastLnImpliedRate);
+    }
+
+    function getNonOverrideLnFeeRateRoot() external view returns (uint80) {
+        return lnFeeRateRoot;
+    }
+
+    /*///////////////////////////////////////////////////////////////
+                            TRIVIAL FUNCTIONS
+    //////////////////////////////////////////////////////////////*/
+
+    function readTokens() external view returns (IStandardizedYield _SY, IPPrincipalToken _PT, IPYieldToken _YT) {
+        _SY = SY;
+        _PT = PT;
+        _YT = YT;
+    }
+
+    function isExpired() public view returns (bool) {
+        return MiniHelpers.isCurrentlyExpired(expiry);
+    }
+
+    /*///////////////////////////////////////////////////////////////
+                    PENDLE GAUGE - RELATED
+    //////////////////////////////////////////////////////////////*/
+
+    function _stakedBalance(address user) internal view override returns (uint256) {
+        return balanceOf(user);
+    }
+
+    function _totalStaked() internal view override returns (uint256) {
+        return totalSupply();
+    }
+
+    // solhint-disable-next-line ordering
+    function _beforeTokenTransfer(
+        address from,
+        address to,
+        uint256 amount
+    ) internal override(PendleERC20, PendleGauge) {
+        PendleGauge._beforeTokenTransfer(from, to, amount);
+    }
+
+    // solhint-disable-next-line ordering
+    function _afterTokenTransfer(address from, address to, uint256 amount) internal override(PendleERC20, PendleGauge) {
+        PendleGauge._afterTokenTransfer(from, to, amount);
+    }
+}

package/contracts/core/RewardManager/PendleLinearDistributor.sol

@@ -0,0 +1,143 @@
+// SPDX-License-Identifier: GPL-3.0-or-later
+pragma solidity ^0.8.17;
+
+import "@openzeppelin/contracts/proxy/utils/UUPSUpgradeable.sol";
+import "@openzeppelin/contracts-upgradeable/access/AccessControlUpgradeable.sol";
+import "../libraries/BoringOwnableUpgradeable.sol";
+import "../libraries/TokenHelper.sol";
+import "../libraries/math/PMath.sol";
+import "../../interfaces/IPLinearDistributor.sol";
+
+contract PendleLinearDistributor is UUPSUpgradeable, AccessControlUpgradeable, TokenHelper, IPLinearDistributor {
+    using PMath for uint128;
+    using PMath for uint192;
+    using PMath for uint256;
+
+    bytes32 public constant MAINTAINER = keccak256("MAINTAINER");
+
+    mapping(address => bool) internal isWhitelisted;
+
+    // [token, addr] => distribution
+    mapping(address => mapping(address => DistributionData)) public distributionDatas;
+
+    constructor() {
+        _disableInitializers();
+    }
+
+    modifier onlyWhitelisted() {
+        require(isWhitelisted[msg.sender], "not whitelisted");
+        _;
+    }
+
+    function isMaintainer(address addr) public view returns (bool) {
+        return (hasRole(DEFAULT_ADMIN_ROLE, addr) || hasRole(MAINTAINER, addr));
+    }
+
+    modifier onlyMaintainer() {
+        require(isMaintainer(msg.sender), "not maintainer");
+        _;
+    }
+
+    modifier onlyAdmin() {
+        require(hasRole(DEFAULT_ADMIN_ROLE, msg.sender), "not admin");
+        _;
+    }
+
+    // ----------------- core-logic ----------------------
+
+    function queueVestAndClaim(address token, uint256 amountVestToQueue) external onlyWhitelisted returns (uint256) {
+        require(amountVestToQueue > 0, "invalid amountVestToQueue");
+
+        uint256 amountOut = _getClaimableRewardAndUpdate(token, msg.sender, amountVestToQueue);
+
+        // dodging extreme case of amountOut = amountVestToQueue
+        if (amountOut > amountVestToQueue) {
+            _transferOut(token, msg.sender, amountOut - amountVestToQueue);
+        } else if (amountVestToQueue > amountOut) {
+            _transferIn(token, msg.sender, amountVestToQueue - amountOut);
+        }
+
+        emit VestQueued(token, msg.sender, amountVestToQueue);
+        emit Claim(token, msg.sender, amountOut);
+
+        return amountOut;
+    }
+
+    function claim(address token) external returns (uint256) {
+        uint256 amountOut = _getClaimableRewardAndUpdate(token, msg.sender, 0);
+        if (amountOut > 0) {
+            _transferOut(token, msg.sender, amountOut);
+        }
+        emit Claim(token, msg.sender, amountOut);
+        return amountOut;
+    }
+
+    function applyVestRewards(
+        address[] memory tokens,
+        address[] memory addrs,
+        uint256[] memory durations
+    ) external onlyMaintainer {
+        require(tokens.length == addrs.length, "invalid array length");
+        require(tokens.length == durations.length, "invalid array length");
+
+        for (uint256 i = 0; i < tokens.length; ++i) {
+            _applyVestReward(tokens[i], addrs[i], durations[i]);
+        }
+    }
+
+    function _applyVestReward(address token, address addr, uint256 duration) internal {
+        DistributionData memory data = _updateRewardView(token, addr);
+
+        uint256 amountVesting = data.unvestedReward;
+        if (amountVesting == 0) {
+            return;
+        }
+
+        uint256 leftOver = data.rewardPerSec.mulDown((data.endTime - PMath.min(block.timestamp, data.endTime)));
+        uint256 undistrbutedReward = amountVesting + leftOver;
+
+        data.unvestedReward = 0;
+        data.endTime = (block.timestamp + duration).Uint32();
+        data.rewardPerSec = undistrbutedReward.divDown(duration).Uint192();
+        distributionDatas[token][addr] = data;
+
+        emit Vested(token, addr, amountVesting, duration);
+    }
+
+    // data.lastDistributedTime is guaranteed to be block.timestamp after calling this
+    function _getClaimableRewardAndUpdate(
+        address token,
+        address addr,
+        uint256 amountVestToQueue
+    ) internal returns (uint256 amountOut) {
+        DistributionData memory data = _updateRewardView(token, addr);
+        amountOut = data.accruedReward;
+
+        data.accruedReward = 0;
+        data.unvestedReward += amountVestToQueue.Uint128();
+
+        distributionDatas[token][addr] = data;
+    }
+
+    function _updateRewardView(address token, address addr) internal view returns (DistributionData memory data) {
+        data = distributionDatas[token][addr];
+        uint256 distributeFrom = PMath.min(data.lastDistributedTime, data.endTime);
+        uint256 distributeTo = PMath.min(block.timestamp, data.endTime);
+        data.accruedReward += data.rewardPerSec.mulDown(distributeTo - distributeFrom).Uint128();
+        data.lastDistributedTime = block.timestamp.Uint32();
+    }
+
+    // ----------------- governance-related --------------
+
+    function setWhitelisted(address addr, bool status) external onlyAdmin {
+        isWhitelisted[addr] = status;
+    }
+
+    function initialize() external initializer {
+        _grantRole(DEFAULT_ADMIN_ROLE, msg.sender);
+    }
+
+    // ----------------- upgrade-related -----------------
+
+    function _authorizeUpgrade(address) internal override onlyAdmin {}
+}

package/contracts/core/RewardManager/RewardManager.sol

@@ -13,7 +13,6 @@ abstract contract RewardManager is RewardManagerAbstract {
 
     mapping(address => RewardState) public rewardState;
 
-
     function _updateRewardIndex()
         internal
         virtual
@@ -37,18 +36,26 @@ abstract contract RewardManager is RewardManagerAbstract {
                 address token = tokens[i];
 
                 // the entire token balance of the contract must be the rewards of the contract
-                uint256 accrued = _selfBalance(tokens[i]) - rewardState[token].lastBalance;
-                uint256 index = rewardState[token].index;
+
+                RewardState memory _state = rewardState[token];
+                (uint256 lastBalance, uint256 index) = (_state.lastBalance, _state.index);
+
+                uint256 accrued = _selfBalance(tokens[i]) - lastBalance;
 
                 if (index == 0) index = INITIAL_REWARD_INDEX;
                 if (totalShares != 0) index += accrued.divDown(totalShares);
 
-                rewardState[token].index = index.Uint128();
-                rewardState[token].lastBalance += accrued.Uint128();
+                rewardState[token] = RewardState({
+                    index: index.Uint128(),
+                    lastBalance: (lastBalance + accrued).Uint128()
+                });
+                indexes[i] = index;
+            }
+        } else {
+            for (uint256 i = 0; i < tokens.length; i++) {
+                indexes[i] = rewardState[tokens[i]].index;
             }
         }
-
-        for (uint256 i = 0; i < tokens.length; i++) indexes[i] = rewardState[tokens[i]].index;
     }
 
     /// @dev this function doesn't need redeemExternal since redeemExternal is bundled in updateRewardIndex

package/contracts/core/RewardManager/RewardManagerAbstract.sol

@@ -36,18 +36,12 @@ abstract contract RewardManagerAbstract is IRewardManager, TokenHelper {
         (address[] memory tokens, uint256[] memory indexes) = _updateRewardIndex();
         if (tokens.length == 0) return;
 
-        if (user1 != address(0) && user1 != address(this))
-            _distributeRewardsPrivate(user1, tokens, indexes);
-        if (user2 != address(0) && user2 != address(this))
-            _distributeRewardsPrivate(user2, tokens, indexes);
+        if (user1 != address(0) && user1 != address(this)) _distributeRewardsPrivate(user1, tokens, indexes);
+        if (user2 != address(0) && user2 != address(this)) _distributeRewardsPrivate(user2, tokens, indexes);
     }
 
     // should only be callable from `_updateAndDistributeRewardsForTwo` to guarantee user != address(0) && user != address(this)
-    function _distributeRewardsPrivate(
-        address user,
-        address[] memory tokens,
-        uint256[] memory indexes
-    ) private {
+    function _distributeRewardsPrivate(address user, address[] memory tokens, uint256[] memory indexes) private {
         assert(user != address(0) && user != address(this));
 
         uint256 userShares = _rewardSharesUser(user);
@@ -67,17 +61,11 @@ abstract contract RewardManagerAbstract is IRewardManager, TokenHelper {
             uint256 rewardDelta = userShares.mulDown(deltaIndex);
             uint256 rewardAccrued = userReward[token][user].accrued + rewardDelta;
 
-            userReward[token][user] = UserReward({
-                index: index.Uint128(),
-                accrued: rewardAccrued.Uint128()
-            });
+            userReward[token][user] = UserReward({index: index.Uint128(), accrued: rewardAccrued.Uint128()});
         }
     }
 
-    function _updateRewardIndex()
-        internal
-        virtual
-        returns (address[] memory tokens, uint256[] memory indexes);
+    function _updateRewardIndex() internal virtual returns (address[] memory tokens, uint256[] memory indexes);
 
     function _redeemExternalReward() internal virtual;