@pendle/core-v2 2.29.1 → 3.0.0-beta-2

package/contracts/offchain-helpers/BulkSellerOffchain.sol

@@ -1,69 +0,0 @@
-// SPDX-License-Identifier: GPL-3.0-or-later
-pragma solidity 0.8.17;
-
-import "../core/BulkSeller/BulkSellerMathCore.sol";
-import "../core/BulkSeller/BulkSeller.sol";
-
-contract BulkSellerOffchain {
-    using BulkSellerMathCore for BulkSellerState;
-    using PMath for uint256;
-
-    function calcCurrentRates(IPBulkSeller bulk)
-        external
-        view
-        returns (uint256 rateTokenToSy, uint256 rateSyToToken)
-    {
-        BulkSellerState memory state = bulk.readState();
-        address SY = bulk.SY();
-        address token = bulk.token();
-
-        {
-            uint256 hypoTotalToken = state.totalToken + state.totalSy.mulDown(state.rateSyToToken);
-            uint256 netSyFromToken = IStandardizedYield(SY).previewDeposit(token, hypoTotalToken);
-
-            rateTokenToSy = netSyFromToken.divDown(hypoTotalToken);
-        }
-
-        {
-            uint256 hypoTotalSy = state.totalSy + state.totalToken.mulDown(state.rateTokenToSy);
-            uint256 netTokenFromSy = IStandardizedYield(SY).previewRedeem(token, hypoTotalSy);
-            rateSyToToken = netTokenFromSy.divDown(hypoTotalSy);
-        }
-    }
-
-    function getCurrentState(IPBulkSeller bulk)
-        external
-        view
-        returns (
-            BulkSellerState memory state,
-            uint256 tokenProp,
-            uint256 hypoTokenBal
-        )
-    {
-        state = bulk.readState();
-
-        tokenProp = state.getTokenProp();
-        hypoTokenBal =
-            state.totalToken +
-            IStandardizedYield(bulk.SY()).previewRedeem(bulk.token(), state.totalSy);
-    }
-
-    function calcCurrentRatesWithAmount(
-        IPBulkSeller bulk,
-        uint256 hypoTotalToken,
-        uint256 hypoTotalSy
-    ) external view returns (uint256 rateTokenToSy, uint256 rateSyToToken) {
-        address SY = bulk.SY();
-        address token = bulk.token();
-
-        {
-            uint256 netSyFromToken = IStandardizedYield(SY).previewDeposit(token, hypoTotalToken);
-            rateTokenToSy = netSyFromToken.divDown(hypoTotalToken);
-        }
-
-        {
-            uint256 netTokenFromSy = IStandardizedYield(SY).previewRedeem(token, hypoTotalSy);
-            rateSyToToken = netTokenFromSy.divDown(hypoTotalSy);
-        }
-    }
-}

package/contracts/router/ActionMintRedeem.sol

@@ -1,134 +0,0 @@
-// SPDX-License-Identifier: GPL-3.0-or-later
-pragma solidity 0.8.17;
-
-import "./base/ActionBaseMintRedeem.sol";
-import "../interfaces/IPMarket.sol";
-import "../interfaces/IPActionMintRedeem.sol";
-import "../core/libraries/Errors.sol";
-
-contract ActionMintRedeem is IPActionMintRedeem, ActionBaseMintRedeem {
-    using MarketMathCore for MarketState;
-    using PMath for uint256;
-    using PMath for int256;
-
-    /**
-     * @notice swaps input token for SY-mintable tokens (if needed), then mints SY from such
-     * @param input data for input token, see {`./kyberswap/KyberSwapHelper.sol`}
-     */
-    function mintSyFromToken(
-        address receiver,
-        address SY,
-        uint256 minSyOut,
-        TokenInput calldata input
-    ) external payable returns (uint256 netSyOut) {
-        netSyOut = _mintSyFromToken(receiver, SY, minSyOut, input);
-        emit MintSyFromToken(msg.sender, input.tokenIn, SY, receiver, input.netTokenIn, netSyOut);
-    }
-
-    /**
-     * @notice redeems SY for SY-mintable tokens, then (if needed) swaps resulting tokens for
-     * desired output token through Kyberswap
-     * @param output data for desired output token, see {`./kyberswap/KyberSwapHelper.sol`}
-     */
-    function redeemSyToToken(
-        address receiver,
-        address SY,
-        uint256 netSyIn,
-        TokenOutput calldata output
-    ) external returns (uint256 netTokenOut) {
-        netTokenOut = _redeemSyToToken(receiver, SY, netSyIn, output, true);
-        emit RedeemSyToToken(msg.sender, output.tokenOut, SY, receiver, netSyIn, netTokenOut);
-    }
-
-    /**
-     * @notice mints PY from any input token
-     * @dev swaps input token through Kyberswap to SY-mintable tokens first, then mints SY, finally
-     * mints PY from SY
-     * @param input data for input token, see {`./kyberswap/KyberSwapHelper.sol`}
-     * @dev reverts if PY is expired
-     */
-    function mintPyFromToken(
-        address receiver,
-        address YT,
-        uint256 minPyOut,
-        TokenInput calldata input
-    ) external payable returns (uint256 netPyOut) {
-        address SY = IPYieldToken(YT).SY();
-
-        uint256 netSyToMint = _mintSyFromToken(YT, SY, 0, input);
-        netPyOut = _mintPyFromSy(receiver, SY, YT, netSyToMint, minPyOut, false);
-
-        emit MintPyFromToken(msg.sender, input.tokenIn, YT, receiver, input.netTokenIn, netPyOut);
-    }
-
-    /**
-     * @notice redeems PY for token
-     * @dev redeems PT(+YT) for SY first, then redeems SY, finally swaps resulting tokens to output
-     * token through Kyberswap (if needed)
-     * @param output data for desired output token, see {`./kyberswap/KyberSwapHelper.sol`}
-     */
-    function redeemPyToToken(
-        address receiver,
-        address YT,
-        uint256 netPyIn,
-        TokenOutput calldata output
-    ) external returns (uint256 netTokenOut) {
-        address SY = IPYieldToken(YT).SY();
-
-        uint256 netSyToRedeem = _redeemPyToSy(_syOrBulk(SY, output), YT, netPyIn, 1);
-        netTokenOut = _redeemSyToToken(receiver, SY, netSyToRedeem, output, false);
-
-        emit RedeemPyToToken(msg.sender, output.tokenOut, YT, receiver, netPyIn, netTokenOut);
-    }
-
-    /**
-     * @notice mints PT+YT from input SY
-     * @dev reverts if the PY pair is expired
-     */
-    function mintPyFromSy(
-        address receiver,
-        address YT,
-        uint256 netSyIn,
-        uint256 minPyOut
-    ) external returns (uint256 netPyOut) {
-        netPyOut = _mintPyFromSy(receiver, IPYieldToken(YT).SY(), YT, netSyIn, minPyOut, true);
-        emit MintPyFromSy(msg.sender, receiver, YT, netSyIn, netPyOut);
-    }
-
-    /// @notice redeems PT(+YT) for its corresponding SY
-    function redeemPyToSy(
-        address receiver,
-        address YT,
-        uint256 netPyIn,
-        uint256 minSyOut
-    ) external returns (uint256 netSyOut) {
-        netSyOut = _redeemPyToSy(receiver, YT, netPyIn, minSyOut);
-        emit RedeemPyToSy(msg.sender, receiver, YT, netPyIn, netSyOut);
-    }
-
-    /**
-     * @notice A unified interface for redeeming rewards and interests for any SYs,
-     * YTs, and markets alike for `user`.
-     * @dev returns arrays of amounts claimed for each asset.
-     */
-    function redeemDueInterestAndRewards(
-        address user,
-        address[] calldata sys,
-        address[] calldata yts,
-        address[] calldata markets
-    ) external {
-        unchecked {
-            for (uint256 i = 0; i < sys.length; ++i) {
-                IStandardizedYield(sys[i]).claimRewards(user);
-            }
-
-            for (uint256 i = 0; i < yts.length; ++i) {
-                IPYieldToken(yts[i]).redeemDueInterestAndRewards(user, true, true);
-            }
-
-            for (uint256 i = 0; i < markets.length; ++i) {
-                IPMarket(markets[i]).redeemRewards(user);
-            }
-        }
-    }
-}

package/contracts/router/base/ActionBaseMintRedeem.sol

@@ -1,203 +0,0 @@
-// SPDX-License-Identifier: GPL-3.0-or-later
-pragma solidity 0.8.17;
-
-import "../../core/libraries/TokenHelper.sol";
-import "../../interfaces/IStandardizedYield.sol";
-import "../../interfaces/IPYieldToken.sol";
-import "../../interfaces/IPBulkSeller.sol";
-
-import "../../core/libraries/Errors.sol";
-import "../swap-aggregator/IPSwapAggregator.sol";
-
-struct TokenInput {
-    // Token/Sy data
-    address tokenIn;
-    uint256 netTokenIn;
-    address tokenMintSy;
-    address bulk;
-    // aggregator data
-    address pendleSwap;
-    SwapData swapData;
-}
-
-struct TokenOutput {
-    // Token/Sy data
-    address tokenOut;
-    uint256 minTokenOut;
-    address tokenRedeemSy;
-    address bulk;
-    // aggregator data
-    address pendleSwap;
-    SwapData swapData;
-}
-
-// solhint-disable no-empty-blocks
-abstract contract ActionBaseMintRedeem is TokenHelper {
-    bytes internal constant EMPTY_BYTES = abi.encode();
-
-    function _mintSyFromToken(
-        address receiver,
-        address SY,
-        uint256 minSyOut,
-        TokenInput calldata inp
-    ) internal returns (uint256 netSyOut) {
-        SwapType swapType = inp.swapData.swapType;
-
-        uint256 netTokenMintSy;
-
-        if (swapType == SwapType.NONE) {
-            _transferIn(inp.tokenIn, msg.sender, inp.netTokenIn);
-            netTokenMintSy = inp.netTokenIn;
-        } else if (swapType == SwapType.ETH_WETH) {
-            _transferIn(inp.tokenIn, msg.sender, inp.netTokenIn);
-            _wrap_unwrap_ETH(inp.tokenIn, inp.tokenMintSy, inp.netTokenIn);
-            netTokenMintSy = inp.netTokenIn;
-        } else {
-            if (inp.tokenIn == NATIVE) _transferIn(NATIVE, msg.sender, inp.netTokenIn);
-            else _transferFrom(IERC20(inp.tokenIn), msg.sender, inp.pendleSwap, inp.netTokenIn);
-
-            IPSwapAggregator(inp.pendleSwap).swap{
-                value: inp.tokenIn == NATIVE ? inp.netTokenIn : 0
-            }(inp.tokenIn, inp.netTokenIn, inp.swapData);
-            netTokenMintSy = _selfBalance(inp.tokenMintSy);
-        }
-
-        // outcome of all branches: satisfy pre-condition of __mintSy
-
-        netSyOut = __mintSy(receiver, SY, netTokenMintSy, minSyOut, inp);
-    }
-
-    /// @dev pre-condition: having netTokenMintSy of tokens in this contract
-    function __mintSy(
-        address receiver,
-        address SY,
-        uint256 netTokenMintSy,
-        uint256 minSyOut,
-        TokenInput calldata inp
-    ) private returns (uint256 netSyOut) {
-        uint256 netNative = inp.tokenMintSy == NATIVE ? netTokenMintSy : 0;
-
-        if (inp.bulk != address(0)) {
-            netSyOut = IPBulkSeller(inp.bulk).swapExactTokenForSy{ value: netNative }(
-                receiver,
-                netTokenMintSy,
-                minSyOut
-            );
-        } else {
-            netSyOut = IStandardizedYield(SY).deposit{ value: netNative }(
-                receiver,
-                inp.tokenMintSy,
-                netTokenMintSy,
-                minSyOut
-            );
-        }
-    }
-
-    function _redeemSyToToken(
-        address receiver,
-        address SY,
-        uint256 netSyIn,
-        TokenOutput calldata out,
-        bool doPull
-    ) internal returns (uint256 netTokenOut) {
-        SwapType swapType = out.swapData.swapType;
-
-        if (swapType == SwapType.NONE) {
-            netTokenOut = __redeemSy(receiver, SY, netSyIn, out, doPull);
-        } else if (swapType == SwapType.ETH_WETH) {
-            netTokenOut = __redeemSy(address(this), SY, netSyIn, out, doPull); // ETH:WETH is 1:1
-
-            _wrap_unwrap_ETH(out.tokenRedeemSy, out.tokenOut, netTokenOut);
-
-            _transferOut(out.tokenOut, receiver, netTokenOut);
-        } else {
-            uint256 netTokenRedeemed = __redeemSy(out.pendleSwap, SY, netSyIn, out, doPull);
-
-            IPSwapAggregator(out.pendleSwap).swap(
-                out.tokenRedeemSy,
-                netTokenRedeemed,
-                out.swapData
-            );
-
-            netTokenOut = _selfBalance(out.tokenOut);
-
-            _transferOut(out.tokenOut, receiver, netTokenOut);
-        }
-
-        // outcome of all branches: netTokenOut of tokens goes back to receiver
-
-        if (netTokenOut < out.minTokenOut) {
-            revert Errors.RouterInsufficientTokenOut(netTokenOut, out.minTokenOut);
-        }
-    }
-
-    function __redeemSy(
-        address receiver,
-        address SY,
-        uint256 netSyIn,
-        TokenOutput calldata out,
-        bool doPull
-    ) private returns (uint256 netTokenRedeemed) {
-        if (doPull) {
-            _transferFrom(IERC20(SY), msg.sender, _syOrBulk(SY, out), netSyIn);
-        }
-
-        if (out.bulk != address(0)) {
-            netTokenRedeemed = IPBulkSeller(out.bulk).swapExactSyForToken(
-                receiver,
-                netSyIn,
-                0,
-                true
-            );
-        } else {
-            netTokenRedeemed = IStandardizedYield(SY).redeem(
-                receiver,
-                netSyIn,
-                out.tokenRedeemSy,
-                0,
-                true
-            );
-        }
-    }
-
-    function _mintPyFromSy(
-        address receiver,
-        address SY,
-        address YT,
-        uint256 netSyIn,
-        uint256 minPyOut,
-        bool doPull
-    ) internal returns (uint256 netPyOut) {
-        if (doPull) {
-            _transferFrom(IERC20(SY), msg.sender, YT, netSyIn);
-        }
-
-        netPyOut = IPYieldToken(YT).mintPY(receiver, receiver);
-        if (netPyOut < minPyOut) revert Errors.RouterInsufficientPYOut(netPyOut, minPyOut);
-    }
-
-    function _redeemPyToSy(
-        address receiver,
-        address YT,
-        uint256 netPyIn,
-        uint256 minSyOut
-    ) internal returns (uint256 netSyOut) {
-        address PT = IPYieldToken(YT).PT();
-
-        _transferFrom(IERC20(PT), msg.sender, YT, netPyIn);
-
-        bool needToBurnYt = (!IPYieldToken(YT).isExpired());
-        if (needToBurnYt) _transferFrom(IERC20(YT), msg.sender, YT, netPyIn);
-
-        netSyOut = IPYieldToken(YT).redeemPY(receiver);
-        if (netSyOut < minSyOut) revert Errors.RouterInsufficientSyOut(netSyOut, minSyOut);
-    }
-
-    function _syOrBulk(address SY, TokenOutput calldata output)
-        internal
-        pure
-        returns (address addr)
-    {
-        return output.bulk != address(0) ? output.bulk : SY;
-    }
-}