@pendle/core-v2 2.29.0 → 2.29.2

package/contracts/core/erc20/PendleERC20Upg.sol

@@ -0,0 +1,340 @@
+// SPDX-License-Identifier: GPL-3.0-or-later
+// OpenZeppelin Contracts (last updated v4.6.0) (token/ERC20/ERC20.sol)
+
+pragma solidity ^0.8.0;
+
+import "@openzeppelin/contracts/token/ERC20/IERC20.sol";
+import "@openzeppelin/contracts/token/ERC20/extensions/IERC20Metadata.sol";
+import "@openzeppelin/contracts/utils/Context.sol";
+import "@openzeppelin/contracts-upgradeable/proxy/utils/Initializable.sol";
+
+/**
+ * @dev Pendle's ERC20 implementation, modified from @openzeppelin implementation
+ * Changes are:
+ * - comes with built-in reentrancy protection, storage-packed with totalSupply variable
+ * - delete increaseAllowance / decreaseAllowance
+ * - add nonReentrancy protection to transfer / transferFrom functions
+ * - allow decimals to be passed in
+ * - block self-transfer by default
+ */
+// solhint-disable
+abstract contract PendleERC20Upg is Context, Initializable, IERC20, IERC20Metadata {
+    uint8 private constant _NOT_ENTERED = 1;
+    uint8 private constant _ENTERED = 2;
+
+    mapping(address => uint256) private _balances;
+
+    mapping(address => mapping(address => uint256)) private _allowances;
+
+    uint248 private _totalSupply;
+    uint8 private _status;
+
+    string private _name;
+    string private _symbol;
+    uint8 public immutable decimals;
+
+    uint256[100] private __gap;
+
+    /**
+     * @dev Prevents a contract from calling itself, directly or indirectly.
+     * Calling a `nonReentrant` function from another `nonReentrant`
+     * function is not supported. It is possible to prevent this from happening
+     * by making the `nonReentrant` function external, and making it call a
+     * `private` function that does the actual work.
+     */
+    modifier nonReentrant() {
+        // On the first call to nonReentrant, _notEntered will be true
+        require(_status != _ENTERED, "ReentrancyGuard: reentrant call");
+
+        // Any calls to nonReentrant after this point will fail
+        _status = _ENTERED;
+
+        _;
+
+        // By storing the original value once again, a refund is triggered (see
+        // https://eips.ethereum.org/EIPS/eip-2200)
+        _status = _NOT_ENTERED;
+    }
+
+    /**
+     * @dev Sets the values for {name}, {symbol} and {decimals}.
+     *
+     * All three of these values are immutable: they can only be set once during
+     * construction.
+     */
+    constructor(uint8 decimals_)  {
+        decimals = decimals_;
+    }
+
+    /**
+     * @dev Sets the values for {name} and {symbol}.
+     *
+     * The default value of {decimals} is 18. To select a different value for
+     * {decimals} you should overload it.
+     *
+     * All two of these values are immutable: they can only be set once during
+     * construction.
+     */
+    function __ERC20Upg_init(string memory name_, string memory symbol_) internal onlyInitializing {
+        _name = name_;
+        _symbol = symbol_;
+        _status = _NOT_ENTERED;
+    }
+
+    /**
+     * @dev Returns the name of the token.
+     */
+    function name() public view virtual override returns (string memory) {
+        return _name;
+    }
+
+    /**
+     * @dev Returns the symbol of the token, usually a shorter version of the
+     * name.
+     */
+    function symbol() public view virtual override returns (string memory) {
+        return _symbol;
+    }
+
+    /**
+     * @dev See {IERC20-totalSupply}.
+     */
+    function totalSupply() public view virtual override returns (uint256) {
+        return _totalSupply;
+    }
+
+    /**
+     * @dev See {IERC20-balanceOf}.
+     */
+    function balanceOf(address account) public view virtual override returns (uint256) {
+        return _balances[account];
+    }
+
+    /**
+     * @dev See {IERC20-transfer}.
+     *
+     * Requirements:
+     *
+     * - `to` cannot be the zero address.
+     * - the caller must have a balance of at least `amount`.
+     */
+    function transfer(
+        address to,
+        uint256 amount
+    ) external virtual override nonReentrant returns (bool) {
+        address owner = _msgSender();
+        _transfer(owner, to, amount);
+        return true;
+    }
+
+    /**
+     * @dev See {IERC20-allowance}.
+     */
+    function allowance(
+        address owner,
+        address spender
+    ) public view virtual override returns (uint256) {
+        return _allowances[owner][spender];
+    }
+
+    /**
+     * @dev See {IERC20-approve}.
+     *
+     * NOTE: If `amount` is the maximum `uint256`, the allowance is not updated on
+     * `transferFrom`. This is semantically equivalent to an infinite approval.
+     *
+     * Requirements:
+     *
+     * - `spender` cannot be the zero address.
+     */
+    function approve(address spender, uint256 amount) external virtual override returns (bool) {
+        address owner = _msgSender();
+        _approve(owner, spender, amount);
+        return true;
+    }
+
+    /**
+     * @dev See {IERC20-transferFrom}.
+     *
+     * Emits an {Approval} event indicating the updated allowance. This is not
+     * required by the EIP. See the note at the beginning of {ERC20}.
+     *
+     * NOTE: Does not update the allowance if the current allowance
+     * is the maximum `uint256`.
+     *
+     * Requirements:
+     *
+     * - `from` and `to` cannot be the zero address.
+     * - `from` must have a balance of at least `amount`.
+     * - the caller must have allowance for ``from``'s tokens of at least
+     * `amount`.
+     */
+    function transferFrom(
+        address from,
+        address to,
+        uint256 amount
+    ) external virtual override nonReentrant returns (bool) {
+        address spender = _msgSender();
+        _spendAllowance(from, spender, amount);
+        _transfer(from, to, amount);
+        return true;
+    }
+
+    /**
+     * @dev Moves `amount` of tokens from `sender` to `recipient`.
+     *
+     * This internal function is equivalent to {transfer}, and can be used to
+     * e.g. implement automatic token fees, slashing mechanisms, etc.
+     *
+     * Emits a {Transfer} event.
+     *
+     * Requirements:
+     *
+     * - `from` cannot be the zero address.
+     * - `to` cannot be the zero address.
+     * - `from` must have a balance of at least `amount`.
+     */
+    function _transfer(address from, address to, uint256 amount) internal virtual {
+        require(from != address(0), "ERC20: transfer from the zero address");
+        require(to != address(0), "ERC20: transfer to the zero address");
+        require(from != to, "ERC20: transfer to self");
+
+        _beforeTokenTransfer(from, to, amount);
+
+        uint256 fromBalance = _balances[from];
+        require(fromBalance >= amount, "ERC20: transfer amount exceeds balance");
+        unchecked {
+            _balances[from] = fromBalance - amount;
+        }
+        _balances[to] += amount;
+
+        emit Transfer(from, to, amount);
+
+        _afterTokenTransfer(from, to, amount);
+    }
+
+    /** @dev Creates `amount` tokens and assigns them to `account`, increasing
+     * the total supply.
+     *
+     * Emits a {Transfer} event with `from` set to the zero address.
+     *
+     * Requirements:
+     *
+     * - `account` cannot be the zero address.
+     */
+    function _mint(address account, uint256 amount) internal virtual {
+        require(account != address(0), "ERC20: mint to the zero address");
+
+        _beforeTokenTransfer(address(0), account, amount);
+
+        _totalSupply += toUint248(amount);
+        _balances[account] += amount;
+        emit Transfer(address(0), account, amount);
+
+        _afterTokenTransfer(address(0), account, amount);
+    }
+
+    /**
+     * @dev Destroys `amount` tokens from `account`, reducing the
+     * total supply.
+     *
+     * Emits a {Transfer} event with `to` set to the zero address.
+     *
+     * Requirements:
+     *
+     * - `account` cannot be the zero address.
+     * - `account` must have at least `amount` tokens.
+     */
+    function _burn(address account, uint256 amount) internal virtual {
+        require(account != address(0), "ERC20: burn from the zero address");
+
+        _beforeTokenTransfer(account, address(0), amount);
+
+        uint256 accountBalance = _balances[account];
+        require(accountBalance >= amount, "ERC20: burn amount exceeds balance");
+        unchecked {
+            _balances[account] = accountBalance - amount;
+        }
+        _totalSupply -= toUint248(amount);
+
+        emit Transfer(account, address(0), amount);
+
+        _afterTokenTransfer(account, address(0), amount);
+    }
+
+    /**
+     * @dev Sets `amount` as the allowance of `spender` over the `owner` s tokens.
+     *
+     * This internal function is equivalent to `approve`, and can be used to
+     * e.g. set automatic allowances for certain subsystems, etc.
+     *
+     * Emits an {Approval} event.
+     *
+     * Requirements:
+     *
+     * - `owner` cannot be the zero address.
+     * - `spender` cannot be the zero address.
+     */
+    function _approve(address owner, address spender, uint256 amount) internal virtual {
+        require(owner != address(0), "ERC20: approve from the zero address");
+        require(spender != address(0), "ERC20: approve to the zero address");
+
+        _allowances[owner][spender] = amount;
+        emit Approval(owner, spender, amount);
+    }
+
+    /**
+     * @dev Updates `owner` s allowance for `spender` based on spent `amount`.
+     *
+     * Does not update the allowance amount in case of infinite allowance.
+     * Revert if not enough allowance is available.
+     *
+     * Might emit an {Approval} event.
+     */
+    function _spendAllowance(address owner, address spender, uint256 amount) internal virtual {
+        uint256 currentAllowance = allowance(owner, spender);
+        if (currentAllowance != type(uint256).max) {
+            require(currentAllowance >= amount, "ERC20: insufficient allowance");
+            unchecked {
+                _approve(owner, spender, currentAllowance - amount);
+            }
+        }
+    }
+
+    /**
+     * @dev Hook that is called before any transfer of tokens. This includes
+     * minting and burning.
+     *
+     * Calling conditions:
+     *
+     * - when `from` and `to` are both non-zero, `amount` of ``from``'s tokens
+     * will be transferred to `to`.
+     * - when `from` is zero, `amount` tokens will be minted for `to`.
+     * - when `to` is zero, `amount` of ``from``'s tokens will be burned.
+     * - `from` and `to` are never both zero.
+     *
+     * To learn more about hooks, head to xref:ROOT:extending-contracts.adoc#using-hooks[Using Hooks].
+     */
+    function _beforeTokenTransfer(address from, address to, uint256 amount) internal virtual {}
+
+    /**
+     * @dev Hook that is called after any transfer of tokens. This includes
+     * minting and burning.
+     *
+     * Calling conditions:
+     *
+     * - when `from` and `to` are both non-zero, `amount` of ``from``'s tokens
+     * has been transferred to `to`.
+     * - when `from` is zero, `amount` tokens have been minted for `to`.
+     * - when `to` is zero, `amount` of ``from``'s tokens have been burned.
+     * - `from` and `to` are never both zero.
+     *
+     * To learn more about hooks, head to xref:ROOT:extending-contracts.adoc#using-hooks[Using Hooks].
+     */
+    function _afterTokenTransfer(address from, address to, uint256 amount) internal virtual {}
+
+    function toUint248(uint256 x) internal virtual returns (uint248) {
+        require(x <= type(uint248).max); // signed, lim = bit-1
+        return uint248(x);
+    }
+}

package/contracts/core/libraries/ArrayLib.sol

@@ -39,6 +39,7 @@ library ArrayLib {
         }
         out[length] = element;
     }
+
     /**
      * @dev This function assumes a and b each contains unidentical elements
      * @param a array of addresses a
@@ -52,7 +53,7 @@ library ArrayLib {
         unchecked {
             uint256 countUnidenticalB = 0;
             bool[] memory isUnidentical = new bool[](b.length);
-            for(uint256 i = 0; i < b.length; ++i) {
+            for (uint256 i = 0; i < b.length; ++i) {
                 if (!contains(a, b[i])) {
                     countUnidenticalB++;
                     isUnidentical[i] = true;
@@ -60,11 +61,11 @@ library ArrayLib {
             }
 
             out = new address[](a.length + countUnidenticalB);
-            for(uint256 i = 0; i < a.length; ++i) {
+            for (uint256 i = 0; i < a.length; ++i) {
                 out[i] = a[i];
             }
             uint256 id = a.length;
-            for(uint256 i = 0; i < b.length; ++i) {
+            for (uint256 i = 0; i < b.length; ++i) {
                 if (isUnidentical[i]) {
                     out[id++] = b[i];
                 }
@@ -105,4 +106,9 @@ library ArrayLib {
         res[0] = a;
         res[1] = b;
     }
+
+    function create(uint256 a) internal pure returns (uint256[] memory res) {
+        res = new uint256[](1);
+        res[0] = a;
+    }
 }

package/contracts/interfaces/IPMerkleDistributor.sol

@@ -0,0 +1,24 @@
+// SPDX-License-Identifier: GPL-3.0-or-later
+pragma solidity ^0.8.0;
+
+interface IPMerkleDistributor {
+    event Claimed(address indexed user, address indexed receiver, uint256 amount);
+    event Verified(address indexed user, uint256 amountClaimable);
+    event SetMerkleRoot(bytes32 indexed merkleRoot);
+
+    error InvalidMerkleProof();
+
+    function claim(
+        address receiver,
+        uint256 totalAccrued,
+        bytes32[] calldata proof
+    ) external returns (uint256 amountOut);
+
+    function claimVerified(address receiver) external returns (uint256 amountOut);
+
+    function verify(
+        address user,
+        uint256 totalAccrued,
+        bytes32[] calldata proof
+    ) external returns (uint256 amountVerified);
+}

package/contracts/interfaces/Kyber/IKyberElasticFactory.sol

@@ -0,0 +1,165 @@
+// SPDX-License-Identifier: MIT
+pragma solidity >=0.8.0;
+
+/// @title KyberSwap v2 factory
+/// @notice Deploys KyberSwap v2 pools and manages control over government fees
+interface IKyberElasticFactory {
+  /// @notice Emitted when a pool is created
+  /// @param token0 First pool token by address sort order
+  /// @param token1 Second pool token by address sort order
+  /// @param swapFeeUnits Fee to be collected upon every swap in the pool, in fee units
+  /// @param tickDistance Minimum number of ticks between initialized ticks
+  /// @param pool The address of the created pool
+  event PoolCreated(
+    address indexed token0,
+    address indexed token1,
+    uint24 indexed swapFeeUnits,
+    int24 tickDistance,
+    address pool
+  );
+
+  /// @notice Emitted when a new fee is enabled for pool creation via the factory
+  /// @param swapFeeUnits Fee to be collected upon every swap in the pool, in fee units
+  /// @param tickDistance Minimum number of ticks between initialized ticks for pools created with the given fee
+  event SwapFeeEnabled(uint24 indexed swapFeeUnits, int24 indexed tickDistance);
+
+  /// @notice Emitted when vesting period changes
+  /// @param vestingPeriod The maximum time duration for which LP fees
+  /// are proportionally burnt upon LP removals
+  event VestingPeriodUpdated(uint32 vestingPeriod);
+
+  /// @notice Emitted when configMaster changes
+  /// @param oldConfigMaster configMaster before the update
+  /// @param newConfigMaster configMaster after the update
+  event ConfigMasterUpdated(address oldConfigMaster, address newConfigMaster);
+
+  /// @notice Emitted when fee configuration changes
+  /// @param feeTo Recipient of government fees
+  /// @param governmentFeeUnits Fee amount, in fee units,
+  /// to be collected out of the fee charged for a pool swap
+  event FeeConfigurationUpdated(address feeTo, uint24 governmentFeeUnits);
+
+  /// @notice Emitted when whitelist feature is enabled
+  event WhitelistEnabled();
+
+  /// @notice Emitted when whitelist feature is disabled
+  event WhitelistDisabled();
+
+  /// @notice Returns the maximum time duration for which LP fees
+  /// are proportionally burnt upon LP removals
+  function vestingPeriod() external view returns (uint32);
+
+  /// @notice Returns the tick distance for a specified fee.
+  /// @dev Once added, cannot be updated or removed.
+  /// @param swapFeeUnits Swap fee, in fee units.
+  /// @return The tick distance. Returns 0 if fee has not been added.
+  function feeAmountTickDistance(uint24 swapFeeUnits) external view returns (int24);
+
+  /// @notice Returns the address which can update the fee configuration
+  function configMaster() external view returns (address);
+
+  /// @notice Returns the keccak256 hash of the Pool creation code
+  /// This is used for pre-computation of pool addresses
+  function poolInitHash() external view returns (bytes32);
+
+  /// @notice Returns the pool oracle contract for twap
+  function poolOracle() external view returns (address);
+
+  /// @notice Fetches the recipient of government fees
+  /// and current government fee charged in fee units
+  function feeConfiguration() external view returns (address _feeTo, uint24 _governmentFeeUnits);
+
+  /// @notice Returns the status of whitelisting feature of NFT managers
+  /// If true, anyone can mint liquidity tokens
+  /// Otherwise, only whitelisted NFT manager(s) are allowed to mint liquidity tokens
+  function whitelistDisabled() external view returns (bool);
+
+  //// @notice Returns all whitelisted NFT managers
+  /// If the whitelisting feature is turned on,
+  /// only whitelisted NFT manager(s) are allowed to mint liquidity tokens
+  function getWhitelistedNFTManagers() external view returns (address[] memory);
+
+  /// @notice Checks if sender is a whitelisted NFT manager
+  /// If the whitelisting feature is turned on,
+  /// only whitelisted NFT manager(s) are allowed to mint liquidity tokens
+  /// @param sender address to be checked
+  /// @return true if sender is a whistelisted NFT manager, false otherwise
+  function isWhitelistedNFTManager(address sender) external view returns (bool);
+
+  /// @notice Returns the pool address for a given pair of tokens and a swap fee
+  /// @dev Token order does not matter
+  /// @param tokenA Contract address of either token0 or token1
+  /// @param tokenB Contract address of the other token
+  /// @param swapFeeUnits Fee to be collected upon every swap in the pool, in fee units
+  /// @return pool The pool address. Returns null address if it does not exist
+  function getPool(
+    address tokenA,
+    address tokenB,
+    uint24 swapFeeUnits
+  ) external view returns (address pool);
+
+  /// @notice Fetch parameters to be used for pool creation
+  /// @dev Called by the pool constructor to fetch the parameters of the pool
+  /// @return factory The factory address
+  /// @return poolOracle The pool oracle for twap
+  /// @return token0 First pool token by address sort order
+  /// @return token1 Second pool token by address sort order
+  /// @return swapFeeUnits Fee to be collected upon every swap in the pool, in fee units
+  /// @return tickDistance Minimum number of ticks between initialized ticks
+  function parameters()
+    external
+    view
+    returns (
+      address factory,
+      address poolOracle,
+      address token0,
+      address token1,
+      uint24 swapFeeUnits,
+      int24 tickDistance
+    );
+
+  /// @notice Creates a pool for the given two tokens and fee
+  /// @param tokenA One of the two tokens in the desired pool
+  /// @param tokenB The other of the two tokens in the desired pool
+  /// @param swapFeeUnits Desired swap fee for the pool, in fee units
+  /// @dev Token order does not matter. tickDistance is determined from the fee.
+  /// Call will revert under any of these conditions:
+  ///     1) pool already exists
+  ///     2) invalid swap fee
+  ///     3) invalid token arguments
+  /// @return pool The address of the newly created pool
+  function createPool(
+    address tokenA,
+    address tokenB,
+    uint24 swapFeeUnits
+  ) external returns (address pool);
+
+  /// @notice Enables a fee amount with the given tickDistance
+  /// @dev Fee amounts may never be removed once enabled
+  /// @param swapFeeUnits The fee amount to enable, in fee units
+  /// @param tickDistance The distance between ticks to be enforced for all pools created with the given fee amount
+  function enableSwapFee(uint24 swapFeeUnits, int24 tickDistance) external;
+
+  /// @notice Updates the address which can update the fee configuration
+  /// @dev Must be called by the current configMaster
+  function updateConfigMaster(address) external;
+
+  /// @notice Updates the vesting period
+  /// @dev Must be called by the current configMaster
+  function updateVestingPeriod(uint32) external;
+
+  /// @notice Updates the address receiving government fees and fee quantity
+  /// @dev Only configMaster is able to perform the update
+  /// @param feeTo Address to receive government fees collected from pools
+  /// @param governmentFeeUnits Fee amount, in fee units,
+  /// to be collected out of the fee charged for a pool swap
+  function updateFeeConfiguration(address feeTo, uint24 governmentFeeUnits) external;
+
+  /// @notice Enables the whitelisting feature
+  /// @dev Only configMaster is able to perform the update
+  function enableWhitelist() external;
+
+  /// @notice Disables the whitelisting feature
+  /// @dev Only configMaster is able to perform the update
+  function disableWhitelist() external;
+}

package/contracts/interfaces/Kyber/IKyberElasticPool.sol

@@ -0,0 +1,112 @@
+// SPDX-License-Identifier: MIT
+pragma solidity >=0.8.0;
+
+interface IKyberElasticPool {
+
+  function factory() external view returns (address);
+
+  /// @notice The first of the two tokens of the pool, sorted by address
+  /// @return The token contract address
+  function token0() external view returns (address);
+
+  /// @notice The second of the two tokens of the pool, sorted by address
+  /// @return The token contract address
+  function token1() external view returns (address);
+
+  /// @notice The fee to be charged for a swap in basis points
+  /// @return The swap fee in basis points
+  function swapFeeUnits() external view returns (uint24);
+
+  function totalSupply() external view returns (uint256);
+
+  /// @notice The pool tick distance
+  /// @dev Ticks can only be initialized and used at multiples of this value
+  /// It remains an int24 to avoid casting even though it is >= 1.
+  /// e.g: a tickDistance of 5 means ticks can be initialized every 5th tick, i.e., ..., -10, -5, 0, 5, 10, ...
+  /// @return The tick distance
+  function tickDistance() external view returns (int24);
+
+  /// @notice Maximum gross liquidity that an initialized tick can have
+  /// @dev This is to prevent overflow the pool's active base liquidity (uint128)
+  /// also prevents out-of-range liquidity from being used to prevent adding in-range liquidity to a pool
+  /// @return The max amount of liquidity per tick
+  function maxTickLiquidity() external view returns (uint128);
+
+  /// @notice Look up information about a specific tick in the pool
+  /// @param tick The tick to look up
+  /// @return liquidityGross total liquidity amount from positions that uses this tick as a lower or upper tick
+  /// liquidityNet how much liquidity changes when the pool tick crosses above the tick
+  /// feeGrowthOutside the fee growth on the other side of the tick relative to the current tick
+  /// secondsPerLiquidityOutside the seconds per unit of liquidity  spent on the other side of the tick relative to the current tick
+  function ticks(int24 tick)
+    external
+    view
+    returns (
+      uint128 liquidityGross,
+      int128 liquidityNet,
+      uint256 feeGrowthOutside,
+      uint128 secondsPerLiquidityOutside
+    );
+
+  /// @notice Returns the previous and next initialized ticks of a specific tick
+  /// @dev If specified tick is uninitialized, the returned values are zero.
+  /// @param tick The tick to look up
+  function initializedTicks(int24 tick) external view returns (int24 previous, int24 next);
+
+  /// @notice Returns the information about a position by the position's key
+  /// @return liquidity the liquidity quantity of the position
+  /// @return feeGrowthInsideLast fee growth inside the tick range as of the last mint / burn action performed
+  function getPositions(
+    address owner,
+    int24 tickLower,
+    int24 tickUpper
+  ) external view returns (uint128 liquidity, uint256 feeGrowthInsideLast);
+
+  /// @notice Fetches the pool's prices, ticks and lock status
+  /// @return sqrtP sqrt of current price: sqrt(token1/token0)
+  /// @return currentTick pool's current tick
+  /// @return nearestCurrentTick pool's nearest initialized tick that is <= currentTick
+  /// @return locked true if pool is locked, false otherwise
+  function getPoolState()
+    external
+    view
+    returns (
+      uint160 sqrtP,
+      int24 currentTick,
+      int24 nearestCurrentTick,
+      bool locked
+    );
+
+  /// @notice Fetches the pool's liquidity values
+  /// @return baseL pool's base liquidity without reinvest liqudity
+  /// @return reinvestL the liquidity is reinvested into the pool
+  /// @return reinvestLLast last cached value of reinvestL, used for calculating reinvestment token qty
+  function getLiquidityState()
+    external
+    view
+    returns (
+      uint128 baseL,
+      uint128 reinvestL,
+      uint128 reinvestLLast
+    );
+
+  /// @return feeGrowthGlobal All-time fee growth per unit of liquidity of the pool
+  function getFeeGrowthGlobal() external view returns (uint256);
+
+  /// @return secondsPerLiquidityGlobal All-time seconds per unit of liquidity of the pool
+  /// @return lastUpdateTime The timestamp in which secondsPerLiquidityGlobal was last updated
+  function getSecondsPerLiquidityData()
+    external
+    view
+    returns (uint128 secondsPerLiquidityGlobal, uint32 lastUpdateTime);
+
+  /// @notice Calculates and returns the active time per unit of liquidity until current block.timestamp
+  /// @param tickLower The lower tick (of a position)
+  /// @param tickUpper The upper tick (of a position)
+  /// @return secondsPerLiquidityInside active time (multiplied by 2^96)
+  /// between the 2 ticks, per unit of liquidity.
+  function getSecondsPerLiquidityInside(int24 tickLower, int24 tickUpper)
+    external
+    view
+    returns (uint128 secondsPerLiquidityInside);
+}