@pendle/core-v2 2.26.4 → 2.27.0

package/contracts/core/StandardizedYield/implementations/PendleERC4626SY.sol

@@ -0,0 +1,97 @@
+// SPDX-License-Identifier: GPL-3.0-or-later
+pragma solidity 0.8.17;
+
+import "../SYBase.sol";
+import "../../../interfaces/IERC4626.sol";
+
+contract PendleERC4626SY is SYBase {
+    using Math for uint256;
+    address public immutable asset;
+
+    constructor(
+        string memory _name,
+        string memory _symbol,
+        address _erc4626
+    ) SYBase(_name, _symbol, _erc4626) {
+        asset = IERC4626(_erc4626).asset();
+        _safeApproveInf(asset, _erc4626);
+    }
+
+    function _deposit(
+        address tokenIn,
+        uint256 amountDeposited
+    ) internal virtual override returns (uint256 /*amountSharesOut*/) {
+        if (tokenIn == yieldToken) {
+            return amountDeposited;
+        } else {
+            return IERC4626(yieldToken).deposit(amountDeposited, address(this));
+        }
+    }
+
+    function _redeem(
+        address receiver,
+        address tokenOut,
+        uint256 amountSharesToRedeem
+    ) internal override returns (uint256 amountTokenOut) {
+        if (tokenOut == yieldToken) {
+            amountTokenOut = amountSharesToRedeem;
+            _transferOut(yieldToken, receiver, amountTokenOut);
+        } else {
+            amountTokenOut = IERC4626(yieldToken).redeem(
+                amountSharesToRedeem,
+                receiver,
+                address(this)
+            );
+        }
+    }
+
+    function exchangeRate() public view virtual override returns (uint256) {
+        uint256 totalAssets = IERC4626(yieldToken).totalAssets();
+        uint256 totalSupply = IERC4626(yieldToken).totalSupply();
+        return totalAssets.divDown(totalSupply);
+    }
+
+    function _previewDeposit(
+        address tokenIn,
+        uint256 amountTokenToDeposit
+    ) internal view override returns (uint256 /*amountSharesOut*/) {
+        if (tokenIn == yieldToken) return amountTokenToDeposit;
+        else return IERC4626(yieldToken).previewDeposit(amountTokenToDeposit);
+    }
+
+    function _previewRedeem(
+        address tokenOut,
+        uint256 amountSharesToRedeem
+    ) internal view override returns (uint256 /*amountTokenOut*/) {
+        if (tokenOut == yieldToken) return amountSharesToRedeem;
+        else return IERC4626(yieldToken).previewRedeem(amountSharesToRedeem);
+    }
+
+    function getTokensIn() public view override returns (address[] memory res) {
+        res = new address[](2);
+        res[0] = asset;
+        res[1] = yieldToken;
+    }
+
+    function getTokensOut() public view override returns (address[] memory res) {
+        res = new address[](2);
+        res[0] = asset;
+        res[1] = yieldToken;
+    }
+
+    function isValidTokenIn(address token) public view override returns (bool) {
+        return token == yieldToken || token == asset;
+    }
+
+    function isValidTokenOut(address token) public view override returns (bool) {
+        return token == yieldToken || token == asset;
+    }
+
+    function assetInfo()
+        external
+        view
+        returns (AssetType assetType, address assetAddress, uint8 assetDecimals)
+    {
+        return (AssetType.TOKEN, asset, IERC20Metadata(asset).decimals());
+    }
+}

package/contracts/core/StandardizedYield/implementations/PendleEUSDSY.sol

@@ -0,0 +1,90 @@
+// SPDX-License-Identifier: GPL-3.0-or-later
+pragma solidity 0.8.17;
+
+import "../SYBase.sol";
+import "../../../interfaces/Lybra/IEUSD.sol";
+
+contract PendleEUSDSY is SYBase {
+    address public immutable eUSD;
+
+    constructor(
+        string memory _name,
+        string memory _symbol,
+        address _eUSD
+    ) SYBase(_name, _symbol, _eUSD) {
+        eUSD = _eUSD;
+    }
+
+    /*///////////////////////////////////////////////////////////////
+                    DEPOSIT/REDEEM USING BASE TOKENS
+    //////////////////////////////////////////////////////////////*/
+
+    function _deposit(
+        address /*tokenIn*/,
+        uint256 amountDeposited
+    ) internal virtual override returns (uint256 /*amountSharesOut*/) {
+        return IEUSD(eUSD).getSharesByMintedEUSD(amountDeposited);
+    }
+
+    function _redeem(
+        address receiver,
+        address /*tokenOut*/,
+        uint256 amountSharesToRedeem
+    ) internal virtual override returns (uint256 /*amountTokenOut*/) {
+        return IEUSD(eUSD).transferShares(receiver, amountSharesToRedeem);
+    }
+
+    /*///////////////////////////////////////////////////////////////
+                               EXCHANGE-RATE
+    //////////////////////////////////////////////////////////////*/
+
+    function exchangeRate() public view virtual override returns (uint256) {
+        return IEUSD(eUSD).getMintedEUSDByShares(1e18);
+    }
+
+    /*///////////////////////////////////////////////////////////////
+                MISC FUNCTIONS FOR METADATA
+    //////////////////////////////////////////////////////////////*/
+
+    function _previewDeposit(
+        address /*tokenIn*/,
+        uint256 amountTokenToDeposit
+    ) internal view override returns (uint256 /*amountSharesOut*/) {
+        return IEUSD(eUSD).getSharesByMintedEUSD(amountTokenToDeposit);
+    }
+
+    function _previewRedeem(
+        address /*tokenOut*/,
+        uint256 amountSharesToRedeem
+    ) internal view override returns (uint256 /*amountTokenOut*/) {
+        return IEUSD(eUSD).getMintedEUSDByShares(amountSharesToRedeem);
+    }
+
+    function getTokensIn() public view virtual override returns (address[] memory res) {
+        res = new address[](1);
+        res[0] = eUSD;
+    }
+
+    function getTokensOut() public view virtual override returns (address[] memory res) {
+        res = new address[](1);
+        res[0] = eUSD;
+    }
+
+    function isValidTokenIn(address token) public view virtual override returns (bool) {
+        return token == eUSD;
+    }
+
+    function isValidTokenOut(address token) public view virtual override returns (bool) {
+        return token == eUSD;
+    }
+
+    function assetInfo()
+        external
+        view
+        returns (AssetType assetType, address assetAddress, uint8 assetDecimals)
+    {
+        assetType = AssetType.TOKEN;
+        assetAddress = eUSD;
+        assetDecimals = 18;
+    }
+}

package/contracts/interfaces/Flux/IFluxErc20.sol

@@ -0,0 +1,26 @@
+// SPDX-License-Identifier: GPL-3.0-or-later
+pragma solidity ^0.8.0;
+
+interface IFluxErc20 {
+    function underlying() external view returns (address);
+
+    function mint(uint256 mintAmount) external returns (uint256);
+
+    function redeem(uint256 redeemTokens) external returns (uint256);
+
+    function accrualBlockNumber() external view returns (uint256);
+
+    function exchangeRateStored() external view returns (uint256);
+
+    function getCash() external view returns (uint256);
+
+    function totalBorrows() external view returns (uint256);
+
+    function totalReserves() external view returns (uint256);
+
+    function reserveFactorMantissa() external view returns (uint256);
+
+    function totalSupply() external view returns (uint256);
+
+    function interestRateModel() external view returns (address);
+}

package/contracts/interfaces/Flux/IFluxInterestRateModel.sol

@@ -0,0 +1,10 @@
+// SPDX-License-Identifier: GPL-3.0-or-later
+pragma solidity ^0.8.0;
+
+interface IFluxInterestRateModel {
+    function getBorrowRate(
+        uint256 cash,
+        uint256 borrows,
+        uint256 reserves
+    ) external view returns (uint256);
+}

package/contracts/interfaces/IERC4626.sol

@@ -34,4 +34,8 @@ interface IERC4626 is IERC20Metadata {
     function convertToAssets(uint256 shares) external view returns (uint256);
 
     function previewDeposit(uint256 assets) external view returns (uint256);
+    
+    function previewRedeem(uint256 shares) external view returns (uint256);
+
+    function totalAssets() external view returns (uint256);
 }

package/contracts/interfaces/Lybra/IEUSD.sol

@@ -0,0 +1,13 @@
+// SPDX-License-Identifier: MIT
+
+pragma solidity 0.8.17;
+
+interface IEUSD {
+    function transferShares(address _recipient, uint256 _sharesAmount) external returns (uint256);
+
+    function getSharesByMintedEUSD(uint256 _EUSDAmount) external view returns (uint256);
+
+    function getMintedEUSDByShares(uint256 _sharesAmount) external view returns (uint256);
+
+    function sharesOf(address _account) external view returns (uint256);
+}

package/contracts/offchain-helpers/PendleMulticallV2.sol

@@ -0,0 +1,87 @@
+// SPDX-License-Identifier: MIT
+pragma solidity 0.8.17;
+
+contract PendleMulticallV2 {
+    error CallThenRevertError(bool success, bytes res);
+
+    struct Call {
+        address target;
+        bytes callData;
+    }
+
+    struct Result {
+        bool success;
+        bytes returnData;
+    }
+
+    function aggregate(Call[] calldata calls) public payable virtual {
+        uint256 length = calls.length;
+        Call calldata call;
+        for (uint256 i = 0; i < length;) {
+            call = calls[i];
+
+            (bool success, bytes memory resp) = call.target.call(call.callData);
+            if (!success) {
+                assembly {
+                    revert(add(32, resp), mload(resp))
+                }
+            }
+
+            unchecked {
+                ++i;
+            }
+        }
+    }
+
+    function tryAggregate(bool requireSuccess, uint256 gasLimit, Call[] calldata calls)
+        public
+        payable
+        returns (Result[] memory returnData)
+    {
+        uint256 length = calls.length;
+        returnData = new Result[](length);
+        Call calldata call;
+        for (uint256 i = 0; i < length;) {
+            call = calls[i];
+
+            (bool success, bytes memory resp) = call.target.call{gas: gasLimit}(calls[i].callData);
+            if (!success && requireSuccess) {
+                assembly {
+                    revert(add(32, resp), mload(resp))
+                }
+            }
+
+            returnData[i] = Result(success, resp);
+
+            unchecked {
+                ++i;
+            }
+        }
+    }
+
+    function tryAggregateRevert(uint256 gasLimit, Call[] calldata calls)
+        public
+        payable
+        returns (bytes[] memory returnData)
+    {
+        uint256 length = calls.length;
+        returnData = new bytes[](length);
+        Call calldata call;
+        for (uint256 i = 0; i < length;) {
+            call = calls[i];
+
+            (, returnData[i]) = address(this).delegatecall{gas: gasLimit}(
+                abi.encodeWithSignature("callThenRevert(address,bytes)", call.target, call.callData)
+            );
+
+            unchecked {
+                ++i;
+            }
+        }
+    }
+
+    function callThenRevert(address target, bytes memory callData) public {
+        (bool success, bytes memory resp) = target.call(callData);
+        revert CallThenRevertError(success, resp);
+    }
+}

package/deployments/1-markets/BALANCER-LP-AURA-VETH-WETH-SEP2024.json

@@ -0,0 +1,8 @@
+{
+    "SY": "0xFb087F3Da58e59f4707f2E38e98B44F194468ccD",
+    "YT": "0xbf3aDc8976917574dd8FC3363884167F58F9AD79",
+    "PT": "0x046ffBC0458a409Fe5b7e3053bDbEd8a98681bC8",
+    "market": "0xb089C87F41BF37afdD71280660ffED15E3162fF8",
+    "scalarRoot": 43700151949000000000,
+    "initialAnchor": 1056065157000000000
+}

package/deployments/1-markets/FLUX-USDC-26DEC2024.json

@@ -0,0 +1,10 @@
+{
+    "name": "SY fUSDC",
+    "SY": "0xf94A3798B18140b9Bc322314bbD36BC8e245E29B",
+    "YT": "0x5935cEdD7D33a32cD60e0F97cFf54A6Bbdbe7Eee",
+    "PT": "0xd187BEA2C423D908d102ebe5Ee8C65d37f4085c3",
+    "market": "0xcB71c2A73fd7588E1599DF90b88de2316585A860",
+    "expiry": 1735171200,
+    "scalarRoot": "144503282145000000000",
+    "initAnchor": "1054297883000000000"
+}

package/deployments/1-markets/SDAI-26SEP2024.json

@@ -0,0 +1,10 @@
+{
+    "name": "SY sDAI",
+    "SY": "0x90f1935f733Dd8826DcA2Bd01ccFc600F20E978E",
+    "YT": "0xa2D5eb975E20205AcCC3C1a1EFAb43e99070de1A",
+    "PT": "0x988B6914866e2ad9Dc9b034387636D2641f79AA3",
+    "market": "0xCf89d9E82A021167945D3af67B2343111D1d3eB9",
+    "expiry": 1727308800,
+    "scalarRoot": "175060725058000000000",
+    "initAnchor": "1046781571000000000"
+}

package/deployments/1-markets/SDAI-MARCH2024.json

@@ -0,0 +1,6 @@
+{
+    "SY": "0x90f1935f733dd8826dca2bd01ccfc600f20e978e",
+    "market": "0xd16cb4138a0f09885defdbc1fe4a65a8f2fb3950",
+    "YT": "0x013889973cced40030175d138c685266b055e3f4",
+    "PT": "0xAc0650178E8bE0c26B25673618C7BE465A40AaF9"
+}

package/deployments/1-markets/WOETH-DEC2024.json

@@ -0,0 +1,6 @@
+{
+    "SY": "0x0a26e7ab5c554232314a8d459eff0ede72333f08",
+    "market": "0x62187066fd9c24559ffb54b0495a304ade26d50b",
+    "PT": "0x158b791a17956925a2bc55c37b0daf8c3ace4549",
+    "YT": "0xa42374d76d4b7cf95c2c1e3661537d8c89f68ffa"
+}

package/deployments/1-offchain-helper.json

@@ -1,4 +1,5 @@
 {
     "multicall": "0xfd6Df9EFACfEfdF4E610d687A9c9b941D1b1Bf75",
+    "pendleMulticallV2": "0x539fd510fE352CC81822a222F821c340133Ed41C",
     "implicitSwapfeeContract": "0x43D03031FAb845065e9CEfE89Dd122d63F72011F"
 }

package/deployments/10-offchain-helper.json

@@ -1,3 +1,4 @@
 {
-    "multicall": "0xfd6Df9EFACfEfdF4E610d687A9c9b941D1b1Bf75"
+    "multicall": "0xfd6Df9EFACfEfdF4E610d687A9c9b941D1b1Bf75",
+    "pendleMulticallV2": "0x539fd510fE352CC81822a222F821c340133Ed41C"
 }

package/deployments/42161-offchain-helper.json

@@ -1,4 +1,5 @@
 {
     "multicall": "0xfd6Df9EFACfEfdF4E610d687A9c9b941D1b1Bf75",
+    "pendleMulticallV2": "0x539fd510fE352CC81822a222F821c340133Ed41C",
     "implicitSwapfeeContract": "0x704478Dd72FD7F9B83d1F1e0fc18C14B54F034d0"
 }

package/deployments/5000-offchain-helper.json

@@ -1,3 +1,4 @@
 {
-    "multicall": "0xfd6Df9EFACfEfdF4E610d687A9c9b941D1b1Bf75"
+    "multicall": "0xfd6Df9EFACfEfdF4E610d687A9c9b941D1b1Bf75",
+    "pendleMulticallV2": "0x539fd510fE352CC81822a222F821c340133Ed41C"
 }

package/deployments/56-offchain-helper.json

@@ -1,4 +1,5 @@
 {
     "multicall": "0xfd6Df9EFACfEfdF4E610d687A9c9b941D1b1Bf75",
+    "pendleMulticallV2": "0x539fd510fE352CC81822a222F821c340133Ed41C",
     "implicitSwapfeeContract": "0xed18de5442297a4ec1ce59c7c7d9427adc2a012b"
 }