@pendle/core-v2 1.3.0-mainnet → 1.3.0-testnet

package/contracts/offchain-helpers/router-static/base/ActionMintRedeemStatic.sol

@@ -0,0 +1,158 @@
+// SPDX-License-Identifier: GPL-3.0-or-later
+pragma solidity 0.8.17;
+
+import "../../../interfaces/IPRouterStatic.sol";
+import "../../../interfaces/IPBulkSeller.sol";
+import "../../../interfaces/IPBulkSellerFactory.sol";
+import "./StorageLayout.sol";
+
+contract ActionMintRedeemStatic is StorageLayout, IPActionMintRedeemStatic {
+    using Math for uint256;
+    using BulkSellerMathCore for BulkSellerState;
+
+    function mintPyFromSyStatic(
+        address YT,
+        uint256 netSyToMint
+    ) public returns (uint256 netPYOut) {
+        if (IPYieldToken(YT).isExpired()) revert Errors.YCExpired();
+        return netSyToMint.mulDown(IPYieldToken(YT).pyIndexCurrent());
+    }
+
+    function redeemPyToSyStatic(
+        address YT,
+        uint256 netPYToRedeem
+    ) public returns (uint256 netSyOut) {
+        return netPYToRedeem.divDown(IPYieldToken(YT).pyIndexCurrent());
+    }
+
+    function mintPyFromTokenStatic(
+        address YT,
+        address tokenIn,
+        uint256 netTokenIn,
+        address bulk
+    ) external returns (uint256 netPyOut) {
+        address SY = IPYieldToken(YT).SY();
+        uint256 netSyReceived = mintSyFromTokenStatic(SY, tokenIn, netTokenIn, bulk);
+        netPyOut = mintPyFromSyStatic(YT, netSyReceived);
+    }
+
+    function redeemPyToTokenStatic(
+        address YT,
+        uint256 netPYToRedeem,
+        address tokenOut,
+        address bulk
+    ) external returns (uint256 netTokenOut) {
+        address SY = IPYieldToken(YT).SY();
+        uint256 netSyReceived = redeemPyToSyStatic(YT, netPYToRedeem);
+        netTokenOut = redeemSyToTokenStatic(SY, tokenOut, netSyReceived, bulk);
+    }
+
+    function mintSyFromTokenStatic(
+        address SY,
+        address tokenIn,
+        uint256 netTokenIn,
+        address bulk
+    ) public view returns (uint256 netSyOut) {
+        if (bulk != address(0)) {
+            BulkSellerState memory state = _readBulkSellerState(bulk);
+            return state.calcSwapExactTokenForSy(netTokenIn);
+        } else {
+            return IStandardizedYield(SY).previewDeposit(tokenIn, netTokenIn);
+        }
+    }
+
+    function redeemSyToTokenStatic(
+        address SY,
+        address tokenOut,
+        uint256 netSyIn,
+        address bulk
+    ) public view returns (uint256 netTokenOut) {
+        if (bulk != address(0)) {
+            BulkSellerState memory state = _readBulkSellerState(bulk);
+            return state.calcSwapExactSyForToken(netSyIn);
+        } else {
+            return IStandardizedYield(SY).previewRedeem(tokenOut, netSyIn);
+        }
+    }
+
+    function getAmountTokenToMintSy(
+        address SY,
+        address tokenIn,
+        address bulk,
+        uint256 netSyOut
+    ) external view returns (uint256 netTokenIn) {
+        uint256 pivotAmount;
+
+        if (tokenIn == address(0)) pivotAmount = 1e18;
+        else pivotAmount = 10 ** IStandardizedYield(SY).decimals();
+
+        uint256 low = pivotAmount;
+        {
+            while (true) {
+                uint256 lowSyOut = mintSyFromTokenStatic(SY, tokenIn, low, bulk);
+                if (lowSyOut >= netSyOut) low /= 10;
+                else break;
+            }
+        }
+
+        uint256 high = pivotAmount;
+        {
+            while (true) {
+                uint256 highSyOut = mintSyFromTokenStatic(SY, tokenIn, high, bulk);
+                if (highSyOut < netSyOut) high *= 10;
+                else break;
+            }
+        }
+
+        while (low <= high) {
+            uint256 mid = (low + high) / 2;
+            uint256 syOut = mintSyFromTokenStatic(SY, tokenIn, mid, bulk);
+
+            if (syOut >= netSyOut) {
+                netTokenIn = mid;
+                high = mid - 1;
+            } else {
+                low = mid + 1;
+            }
+        }
+
+        assert(netTokenIn > 0);
+    }
+
+    function getBulkSellerInfo(
+        address token,
+        address SY,
+        uint256 netTokenIn,
+        uint256 netSyIn
+    ) external view returns (address bulk, uint256 totalToken, uint256 totalSy) {
+        if (address(bulkSellerFactory) == address(0)) return (address(0), 0, 0);
+
+        bulk = bulkSellerFactory.get(token, SY);
+        if (bulk == address(0)) return (address(0), 0, 0);
+
+        BulkSellerState memory state = _readBulkSellerState(bulk);
+
+        // Paused check
+        if (state.rateTokenToSy == 0 || state.rateSyToToken == 0) {
+            return (address(0), 0, 0);
+        }
+
+        // Liquidity check
+        uint256 postFeeRateTokenToSy = state.rateTokenToSy.mulDown(Math.ONE - state.feeRate);
+        uint256 postFeeRateSyToToken = state.rateSyToToken.mulDown(Math.ONE - state.feeRate);
+        if (
+            netTokenIn.mulDown(postFeeRateTokenToSy) > state.totalSy ||
+            netSyIn.mulDown(postFeeRateSyToToken) > state.totalToken
+        ) {
+            return (address(0), 0, 0);
+        }
+
+        // return...
+        totalToken = state.totalToken;
+        totalSy = state.totalSy;
+    }
+
+    function _readBulkSellerState(address bulk) internal view returns (BulkSellerState memory) {
+        return IPBulkSeller(bulk).readState();
+    }
+}

package/contracts/offchain-helpers/router-static/base/ActionStorageStatic.sol

@@ -0,0 +1,76 @@
+// SPDX-License-Identifier: GPL-3.0-or-later
+pragma solidity 0.8.17;
+
+import "./StorageLayout.sol";
+import "../../../interfaces/IPActionStorageStatic.sol";
+import "../../../interfaces/IPMiniDiamond.sol";
+
+contract ActionStorageStatic is StorageLayout, IPActionStorageStatic, IPMiniDiamond {
+    function setDefaultApproxParams(ApproxParams memory params) external onlyOwner {
+        defaultApproxParams = params;
+    }
+
+    function setBulkSellerFactory(address _bulkSellerFactory) external onlyOwner {
+        bulkSellerFactory = IPBulkSellerFactory(_bulkSellerFactory);
+    }
+
+    function getDefaultApproxParams() external view returns (ApproxParams memory) {
+        return defaultApproxParams;
+    }
+
+    function getBulkSellerFactory() external view returns (address) {
+        return address(bulkSellerFactory);
+    }
+
+    function getOwnerAndPendingOwner()
+        external
+        view
+        returns (address _owner, address _pendingOwner)
+    {
+        _owner = owner;
+        _pendingOwner = pendingOwner;
+    }
+
+    function setFacetForSelectors(SelectorsToFacet[] calldata arr) external onlyOwner {
+        for (uint256 i = 0; i < arr.length; ) {
+            SelectorsToFacet memory s = arr[i];
+            for (uint256 j = 0; j < s.selectors.length; ) {
+                selectorToFacet[s.selectors[j]] = s.facet;
+                unchecked {
+                    j++;
+                }
+            }
+            unchecked {
+                i++;
+            }
+        }
+    }
+
+    function facetAddress(bytes4 selector) external view returns (address res) {
+        res = selectorToFacet[selector];
+        require(res != address(0), "selector not found");
+    }
+
+    // Ownable
+    function transferOwnership(address newOwner, bool direct, bool renounce) external onlyOwner {
+        if (direct) {
+            require(newOwner != address(0) || renounce, "Ownable: zero address");
+
+            emit OwnershipTransferred(owner, newOwner);
+            owner = newOwner;
+            pendingOwner = address(0);
+        } else {
+            pendingOwner = newOwner;
+        }
+    }
+
+    function claimOwnership() external {
+        address _pendingOwner = pendingOwner;
+
+        require(msg.sender == _pendingOwner, "Ownable: caller != pending owner");
+
+        emit OwnershipTransferred(owner, _pendingOwner);
+        owner = _pendingOwner;
+        pendingOwner = address(0);
+    }
+}

package/contracts/offchain-helpers/router-static/base/ActionVePendleStatic.sol

@@ -0,0 +1,55 @@
+// SPDX-License-Identifier: GPL-3.0-or-later
+pragma solidity 0.8.17;
+
+import "../../../core/libraries/MiniHelpers.sol";
+import "../../../interfaces/IPRouterStatic.sol";
+import "../../../interfaces/IPVotingEscrowMainchain.sol";
+import "../../../LiquidityMining/libraries/VeBalanceLib.sol";
+
+contract ActionVePendleStatic is IPActionVePendleStatic {
+    using VeBalanceLib for VeBalance;
+    using VeBalanceLib for LockedPosition;
+
+    uint128 private constant MAX_LOCK_TIME = 104 weeks;
+    uint128 private constant MIN_LOCK_TIME = 1 weeks;
+
+    IPVotingEscrowMainchain private immutable vePENDLE;
+
+    constructor(IPVotingEscrowMainchain _vePENDLE) {
+        vePENDLE = _vePENDLE;
+    }
+
+    function increaseLockPositionStatic(
+        address user,
+        uint128 additionalAmountToLock,
+        uint128 newExpiry
+    ) external view returns (uint128 newVeBalance) {
+        if (!WeekMath.isValidWTime(newExpiry)) revert Errors.InvalidWTime(newExpiry);
+        if (MiniHelpers.isTimeInThePast(newExpiry)) revert Errors.ExpiryInThePast(newExpiry);
+
+        if (newExpiry > block.timestamp + MAX_LOCK_TIME) revert Errors.VEExceededMaxLockTime();
+        if (newExpiry < block.timestamp + MIN_LOCK_TIME) revert Errors.VEInsufficientLockTime();
+
+        LockedPosition memory oldPosition;
+
+        {
+            (uint128 amount, uint128 expiry) = vePENDLE.positionData(user);
+            oldPosition = LockedPosition(amount, expiry);
+        }
+
+        if (newExpiry < oldPosition.expiry) revert Errors.VENotAllowedReduceExpiry();
+
+        uint128 newTotalAmountLocked = additionalAmountToLock + oldPosition.amount;
+        if (newTotalAmountLocked == 0) revert Errors.VEZeroAmountLocked();
+
+        uint128 additionalDurationToLock = newExpiry - oldPosition.expiry;
+
+        LockedPosition memory newPosition = LockedPosition(
+            oldPosition.amount + additionalAmountToLock,
+            oldPosition.expiry + additionalDurationToLock
+        );
+
+        VeBalance memory newBalance = newPosition.convertToVeBalance();
+        return newBalance.getCurrentValue();
+    }
+}

package/contracts/offchain-helpers/router-static/base/StorageLayout.sol

@@ -0,0 +1,21 @@
+// SPDX-License-Identifier: GPL-3.0-or-later
+pragma solidity 0.8.17;
+
+import "../../../router/base/MarketApproxLib.sol";
+import "../../../interfaces/IPBulkSellerFactory.sol";
+
+abstract contract StorageLayout {
+    address internal owner;
+    address internal pendingOwner;
+
+    mapping(bytes4 => address) internal selectorToFacet;
+
+    ApproxParams internal defaultApproxParams;
+
+    IPBulkSellerFactory internal bulkSellerFactory;
+
+    modifier onlyOwner() {
+        require(msg.sender == owner, "Ownable: caller is not the owner");
+        _;
+    }
+}

package/contracts/router/ActionAddRemoveLiq.sol

@@ -21,12 +21,7 @@ contract ActionAddRemoveLiq is IPActionAddRemoveLiq, ActionBaseMintRedeem {
     using MarketApproxPtInLib for MarketState;
     using MarketApproxPtOutLib for MarketState;
     using PYIndexLib for IPYieldToken;
-    using BulkSellerMathCore for BulkSellerState;
-
-    /// @dev since this contract will be proxied, it must not contains non-immutable variables
-    constructor(address _kyberScalingLib)
-        ActionBaseMintRedeem(_kyberScalingLib) //solhint-disable-next-line no-empty-blocks
-    {}
+    using PYIndexLib for PYIndex;
 
     /**
      * @notice Adds liquidity to the SY/PT market, granting LP tokens in return
@@ -41,14 +36,7 @@ contract ActionAddRemoveLiq is IPActionAddRemoveLiq, ActionBaseMintRedeem {
         uint256 netSyDesired,
         uint256 netPtDesired,
         uint256 minLpOut
-    )
-        external
-        returns (
-            uint256 netLpOut,
-            uint256 netSyUsed,
-            uint256 netPtUsed
-        )
-    {
+    ) external returns (uint256 netLpOut, uint256 netSyUsed, uint256 netPtUsed) {
         (IStandardizedYield SY, IPPrincipalToken PT, ) = IPMarket(market).readTokens();
 
         // calculate the amount of SY and PT to be used
@@ -91,15 +79,7 @@ contract ActionAddRemoveLiq is IPActionAddRemoveLiq, ActionBaseMintRedeem {
         TokenInput calldata input,
         uint256 netPtDesired,
         uint256 minLpOut
-    )
-        external
-        payable
-        returns (
-            uint256 netLpOut,
-            uint256 netTokenUsed,
-            uint256 netPtUsed
-        )
-    {
+    ) external payable returns (uint256 netLpOut, uint256 netTokenUsed, uint256 netPtUsed) {
         (IStandardizedYield SY, IPPrincipalToken PT, ) = IPMarket(market).readTokens();
 
         uint256 netSyDesired = _mintSyFromToken(market, address(SY), 1, input);
@@ -258,6 +238,78 @@ contract ActionAddRemoveLiq is IPActionAddRemoveLiq, ActionBaseMintRedeem {
         );
     }
 
+    /**
+     * @notice Mints partial SY to PT+YT, returns YT to user, then uses PT+SY to add liquidity
+     * @param netSyIn amount of SY to be transferred in from caller
+     * @return netLpOut actual LP output, will not be lower than `minLpOut`
+     * @return netYtOut actual YT output, will not be lower than `minYtOut`
+     * @dev Reverts if market is expired
+     */
+    function addLiquiditySingleSyKeepYt(
+        address receiver,
+        address market,
+        uint256 netSyIn,
+        uint256 minLpOut,
+        uint256 minYtOut
+    ) external returns (uint256 netLpOut, uint256 netYtOut) {
+        (IStandardizedYield SY, , IPYieldToken YT) = IPMarket(market).readTokens();
+
+        _transferIn(address(SY), msg.sender, netSyIn);
+
+        (netLpOut, netYtOut) = _addLiquiditySingleSyKeepYt(
+            receiver,
+            market,
+            SY,
+            YT,
+            netSyIn,
+            minLpOut,
+            minYtOut
+        );
+
+        emit AddLiquiditySingleSyKeepYt(msg.sender, market, receiver, netSyIn, netLpOut, netYtOut);
+    }
+
+    /**
+     * @notice Adds liquidity and returns leftover YT using a single token input. The input token
+     * is first swapped through Kyberswap to a SY-mintable token, the rest is the same as
+     * `addLiquiditySingleSyKeepYt()`
+     * @param input data for input token, see {`./kyberswap/KyberSwapHelper.sol`}
+     * @return netLpOut actual LP output, will not be lower than `minLpOut`
+     * @return netYtOut actual YT output, will not be lower than `minYtOut`
+     * @dev Reverts if market is expired
+     */
+    function addLiquiditySingleTokenKeepYt(
+        address receiver,
+        address market,
+        uint256 minLpOut,
+        uint256 minYtOut,
+        TokenInput calldata input
+    ) external returns (uint256 netLpOut, uint256 netYtOut) {
+        (IStandardizedYield SY, , IPYieldToken YT) = IPMarket(market).readTokens();
+
+        uint256 netSyUsed = _mintSyFromToken(address(this), address(SY), 1, input);
+
+        (netLpOut, netYtOut) = _addLiquiditySingleSyKeepYt(
+            receiver,
+            market,
+            SY,
+            YT,
+            netSyUsed,
+            minLpOut,
+            minYtOut
+        );
+
+        emit AddLiquiditySingleTokenKeepYt(
+            msg.sender,
+            market,
+            input.tokenIn,
+            receiver,
+            input.netTokenIn,
+            netLpOut,
+            netYtOut
+        );
+    }
+
     /**
      * @notice Burns LP token to remove SY/PT liquidity
      * @param netLpToRemove amount of LP to be burned from caller
@@ -473,6 +525,48 @@ contract ActionAddRemoveLiq is IPActionAddRemoveLiq, ActionBaseMintRedeem {
         if (netLpOut < minLpOut) revert Errors.RouterInsufficientLpOut(netLpOut, minLpOut);
     }
 
+    /**
+     * @dev algorithm:
+        - Split SY into a SY and b SY (with a + b = netSyIn)
+        - Mint PY with a SY ---> gives (a * pyIndex / ONE) PT + YT
+        - Mint LP with (a * pyIndex / ONE) PT and b SY
+
+        -> We want (a * pyIndex / ONE) / totalPt = b / totalSy
+        -> a * (1 + pyIndex * totalSy / ONE / totalPt) = netSyIn
+        -> a = (netSyIn * totalPt) / (totalPt + (pyIndex * totalSy / ONE))
+        -> a = (netSyIn * totalPt) / (totalPt + totalAsset)
+     */
+    function _addLiquiditySingleSyKeepYt(
+        address receiver,
+        address market,
+        IStandardizedYield SY,
+        IPYieldToken YT,
+        uint256 netSyIn,
+        uint256 minLpOut,
+        uint256 minYtOut
+    ) internal returns (uint256 netLpOut, uint256 netYtOut) {
+        MarketState memory state = IPMarket(market).readState(address(this));
+
+        PYIndex pyIndex = YT.newIndex();
+
+        uint256 netSyToPt = (netSyIn * state.totalPt.Uint()) /
+            (state.totalPt.Uint() + pyIndex.syToAsset(state.totalSy.Uint()));
+
+        // transfer SY to mint PY
+        _transferOut(address(SY), address(YT), netSyToPt);
+
+        // the rest of SY goes to market
+        _transferOut(address(SY), market, netSyIn - netSyToPt);
+
+        // PT goes to market, YT goes to receiver
+        netYtOut = YT.mintPY(market, receiver);
+
+        (netLpOut, , ) = IPMarket(market).mint(receiver, netSyIn - netSyToPt, netYtOut);
+
+        if (netLpOut < minLpOut) revert Errors.RouterInsufficientLpOut(netLpOut, minLpOut);
+        if (netYtOut < minYtOut) revert Errors.RouterInsufficientYtOut(netYtOut, minYtOut);
+    }
+
     /// @dev removes SY/PT liquidity, then converts PT to SY
     function _removeLiquiditySingleSy(
         address receiver,
@@ -497,7 +591,7 @@ contract ActionAddRemoveLiq is IPActionAddRemoveLiq, ActionBaseMintRedeem {
     ) internal returns (uint256 netSyOut) {
         (, , IPYieldToken YT) = IPMarket(market).readTokens();
         (uint256 syFromBurn, ) = IPMarket(market).burn(receiver, address(YT), netLpToRemove);
-        netSyOut = syFromBurn + IPYieldToken(YT).redeemPY(receiver);
+        netSyOut = syFromBurn + YT.redeemPY(receiver);
     }
 
     /// @dev swaps PT to SY pre-expiry