@pendle/core-v2 1.2.0-mainnet → 1.2.0-testnet

package/contracts/interfaces/IPMiniDiamond.sol

@@ -0,0 +1,12 @@
+pragma solidity ^0.8.17;
+
+interface IPMiniDiamond {
+    struct SelectorsToFacet {
+        address facet;
+        bytes4[] selectors;
+    }
+
+    function setFacetForSelectors(SelectorsToFacet[] calldata arr) external;
+
+    function facetAddress(bytes4 selector) external view returns (address);
+}

package/contracts/interfaces/IPMsgReceiverApp.sol

@@ -3,5 +3,5 @@
 pragma solidity >=0.8.0;
 
 interface IPMsgReceiverApp {
-    function executeMessage(bytes calldata message) external payable;
+    function executeMessage(bytes calldata message) external;
 }

package/contracts/interfaces/IPRouterStatic.sol

@@ -0,0 +1,19 @@
+pragma solidity ^0.8.17;
+
+import "./IPActionMarketAuxStatic.sol";
+import "./IPActionMintRedeemStatic.sol";
+import "./IPActionInfoStatic.sol";
+import "./IPActionMarketCoreStatic.sol";
+import "./IPActionVePendleStatic.sol";
+import "./IPMiniDiamond.sol";
+import "./IPActionStorageStatic.sol";
+
+interface IPRouterStatic is
+    IPActionMintRedeemStatic,
+    IPActionInfoStatic,
+    IPActionMarketAuxStatic,
+    IPActionMarketCoreStatic,
+    IPActionVePendleStatic,
+    IPMiniDiamond,
+    IPActionStorageStatic
+{}

package/contracts/interfaces/IPVotingController.sol

@@ -40,4 +40,10 @@ interface IPVotingController {
         );
 
     function getPoolTotalVoteAt(address pool, uint128 wTime) external view returns (uint128);
+
+    function finalizeEpoch() external;
+
+    function getBroadcastResultFee(uint64 chainId) external view returns (uint256);
+
+    function broadcastResults(uint64 chainId) external payable;
 }

package/contracts/interfaces/IPYieldTokenV2.sol

@@ -0,0 +1,66 @@
+// SPDX-License-Identifier: GPL-3.0-or-later
+pragma solidity 0.8.17;
+import "@openzeppelin/contracts/token/ERC20/extensions/IERC20Metadata.sol";
+import "./IRewardManager.sol";
+import "./IPInterestManagerYTV2.sol";
+
+interface IPYieldTokenV2 is IERC20Metadata, IRewardManager, IPInterestManagerYTV2 {
+    event Mint(
+        address indexed caller,
+        address indexed receiverPT,
+        address indexed receiverYT,
+        uint256 amountSyToMint,
+        uint256 amountPYOut
+    );
+
+    event Burn(
+        address indexed caller,
+        address indexed receiver,
+        uint256 amountPYToRedeem,
+        uint256 amountSyOut
+    );
+
+    event RedeemRewards(address indexed user, uint256[] amountRewardsOut);
+
+    event RedeemInterest(address indexed user, uint256 interestOut);
+
+    event WithdrawFeeToTreasury(uint256[] amountRewardsOut, uint256 syOut);
+
+    event CollectInterestFee(uint256 amountInterestFee);
+
+    event CollectRewardFee(address indexed rewardToken, uint256 amountRewardFee);
+
+    function mintPY(address receiverPT, address receiverYT) external returns (uint256 amountPYOut);
+
+    function redeemPY(address receiver) external returns (uint256 amountSyOut);
+
+    function redeemPYMulti(address[] calldata receivers, uint256[] calldata amountPYToRedeems)
+        external
+        returns (uint256[] memory amountSyOuts);
+
+    function redeemDueInterestAndRewards(
+        address user,
+        bool redeemInterest,
+        bool redeemRewards
+    ) external returns (uint256 interestOut, uint256[] memory rewardsOut);
+
+    function rewardIndexesCurrent() external returns (uint256[] memory);
+
+    function pyIndexCurrent() external returns (uint256);
+
+    function pyIndexStored() external view returns (uint256);
+
+    function getRewardTokens() external view returns (address[] memory);
+
+    function SY() external view returns (address);
+
+    function PT() external view returns (address);
+
+    function factory() external view returns (address);
+
+    function expiry() external view returns (uint256);
+
+    function isExpired() external view returns (bool);
+
+    function doCacheIndexSameBlock() external view returns (bool);
+}

package/contracts/interfaces/IStandardizedYield.sol

@@ -62,7 +62,7 @@ interface IStandardizedYield is IERC20Metadata {
      * @dev Emits a {Deposit} event
      *
      * Requirements:
-     * - (`baseTokenIn`) must be a valid base token.
+     * - (`tokenIn`) must be a valid base token.
      */
     function deposit(
         address receiver,

package/contracts/offchain-helpers/AddressProvider.sol

@@ -0,0 +1,16 @@
+pragma solidity 0.8.17;
+
+import "../interfaces/IAddressProvider.sol";
+import "../core/libraries/BoringOwnableUpgradeable.sol";
+
+contract AddressProvider is IAddressProvider, BoringOwnableUpgradeable {
+    mapping(uint256 => address) public get;
+
+    function initialize() external initializer {
+        __BoringOwnable_init();
+    }
+
+    function set(uint256 id, address addr) external onlyOwner {
+        get[id] = addr;
+    }
+}

package/contracts/offchain-helpers/Broadcaster.sol

@@ -0,0 +1,48 @@
+// SPDX-License-Identifier: GPL-3.0-or-later
+pragma solidity 0.8.17;
+
+import "../interfaces/IPVotingController.sol";
+import "../LiquidityMining/libraries/WeekMath.sol";
+import "../core/libraries/BoringOwnableUpgradeable.sol";
+import "../core/libraries/TokenHelper.sol";
+
+import "@openzeppelin/contracts-upgradeable/proxy/utils/Initializable.sol";
+import "@openzeppelin/contracts/proxy/utils/UUPSUpgradeable.sol";
+import "@openzeppelin/contracts/proxy/Proxy.sol";
+
+contract Broadcaster is Initializable, BoringOwnableUpgradeable, UUPSUpgradeable, TokenHelper {
+    IPVotingController public immutable votingController;
+    uint256 public lastBroadcastedWeek;
+
+    constructor(address _votingController) initializer {
+        votingController = IPVotingController(_votingController);
+    }
+
+    function initialize() external initializer {
+        __BoringOwnable_init();
+    }
+
+    function finalizeAndBroadcast(uint64[] calldata chainIds) external {
+        uint256 currentWeek = WeekMath.getCurrentWeekStart();
+        require(lastBroadcastedWeek < currentWeek, "current week already broadcasted");
+        lastBroadcastedWeek = currentWeek;
+
+        votingController.finalizeEpoch();
+        for (uint256 i = 0; i < chainIds.length; ) {
+            uint64 chainId = chainIds[i];
+            uint256 fee = votingController.getBroadcastResultFee(chainId);
+            votingController.broadcastResults{ value: fee }(chainId);
+            unchecked {
+                i++;
+            }
+        }
+    }
+
+    function withdrawETH() external onlyOwner {
+        _transferOut(NATIVE, owner, address(this).balance);
+    }
+
+    function _authorizeUpgrade(address newImplementation) internal override onlyOwner {}
+
+    receive() external payable {}
+}

package/contracts/offchain-helpers/PendleMulticall.sol

@@ -0,0 +1,26 @@
+// SPDX-License-Identifier: MIT
+pragma solidity 0.8.17;
+
+/// @title PendleMulticall - A more gas-efficient version of Multicall3 (~700 gas saved for each call)
+/// @author UncleGrandpa925 <longvh@pendle.finance>
+contract PendleMulticall {
+    error MulticallFailed(uint256 index);
+
+    struct Call {
+        address target;
+        bytes callData;
+    }
+
+    function aggregate(Call[] calldata calls) external payable {
+        uint256 length = calls.length;
+        Call calldata call;
+        for (uint256 i = 0; i < length; ) {
+            call = calls[i];
+            (bool success, ) = call.target.call(call.callData);
+            if (!success) revert MulticallFailed(i);
+            unchecked {
+                ++i;
+            }
+        }
+    }
+}

package/contracts/offchain-helpers/{MarketMathStatic.sol → legacy/MarketMathStatic.sol}

@@ -1,8 +1,8 @@
 // SPDX-License-Identifier: GPL-3.0-or-later
 pragma solidity 0.8.17;
 
-import "../router/base/MarketApproxLib.sol";
-import "../interfaces/IPMarket.sol";
+import "../../router/base/MarketApproxLib.sol";
+import "../../interfaces/IPMarket.sol";
 
 library MarketMathStatic {
     using MarketMathCore for MarketState;

package/contracts/offchain-helpers/{RouterStatic.sol → legacy/RouterStatic.sol}

@@ -1,16 +1,16 @@
 // SPDX-License-Identifier: GPL-3.0-or-later
 pragma solidity 0.8.17;
 
-import "../interfaces/IPYieldContractFactory.sol";
-import "../interfaces/IPMarketFactory.sol";
-import "../interfaces/IPVotingEscrowMainchain.sol";
-import "../interfaces/IPBulkSellerFactory.sol";
-import "../interfaces/IPBulkSeller.sol";
+import "../../interfaces/IPYieldContractFactory.sol";
+import "../../interfaces/IPMarketFactory.sol";
+import "../../interfaces/IPVotingEscrowMainchain.sol";
+import "../../interfaces/IPBulkSellerFactory.sol";
+import "../../interfaces/IPBulkSeller.sol";
 
 import "./MarketMathStatic.sol";
 
-import "../core/libraries/BoringOwnableUpgradeable.sol";
-import "../LiquidityMining/libraries/VeBalanceLib.sol";
+import "../../core/libraries/BoringOwnableUpgradeable.sol";
+import "../../LiquidityMining/libraries/VeBalanceLib.sol";
 
 import "@openzeppelin/contracts-upgradeable/proxy/utils/Initializable.sol";
 import "@openzeppelin/contracts/proxy/utils/UUPSUpgradeable.sol";

package/contracts/offchain-helpers/router-static/PendleRouterStatic.sol

@@ -0,0 +1,19 @@
+// SPDX-License-Identifier: GPL-3.0-or-later
+pragma solidity 0.8.17;
+
+import "@openzeppelin/contracts/proxy/Proxy.sol";
+import "../../interfaces/IPRouterStatic.sol";
+import "./StorageLayout.sol";
+
+// solhint-disable no-empty-blocks
+contract PendleRouterStatic is Proxy, StorageLayout {
+    constructor(address actionStorage) {
+        owner = msg.sender;
+        selectorToFacet[IPMiniDiamond.setFacetForSelectors.selector] = actionStorage;
+    }
+
+    function _implementation() internal view override returns (address res) {
+        res = selectorToFacet[msg.sig];
+        require(res != address(0), "selector not found");
+    }
+}

package/contracts/offchain-helpers/router-static/StorageLayout.sol

@@ -0,0 +1,21 @@
+// SPDX-License-Identifier: GPL-3.0-or-later
+pragma solidity 0.8.17;
+
+import "../../router/base/MarketApproxLib.sol";
+import "../../interfaces/IPBulkSellerFactory.sol";
+
+contract StorageLayout {
+    address internal owner;
+    address internal pendingOwner;
+
+    mapping(bytes4 => address) internal selectorToFacet;
+
+    ApproxParams internal defaultApproxParams;
+
+    IPBulkSellerFactory internal bulkSellerFactory;
+
+    modifier onlyOwner() {
+        require(msg.sender == owner, "Ownable: caller is not the owner");
+        _;
+    }
+}

package/contracts/offchain-helpers/router-static/base/ActionInfoStatic.sol

@@ -0,0 +1,125 @@
+// SPDX-License-Identifier: GPL-3.0-or-later
+pragma solidity 0.8.17;
+
+import "../../../interfaces/IPMarket.sol";
+import "../../../interfaces/IPRouterStatic.sol";
+import "../../../interfaces/IPYieldContractFactory.sol";
+import "../../../interfaces/IPMarketFactory.sol";
+import "../../../interfaces/IPBulkSellerFactory.sol";
+import "../../../interfaces/IPBulkSeller.sol";
+
+// solhint-disable no-empty-blocks
+contract ActionInfoStatic is IPActionInfoStatic {
+    function getPY(address py) public view returns (address pt, address yt) {
+        try IPYieldToken(py).PT() returns (address _pt) {
+            pt = _pt;
+            yt = py;
+        } catch {
+            pt = py;
+            yt = IPPrincipalToken(py).YT();
+        }
+    }
+
+    /// can be SY, PY or Market
+    function getTokensInOut(address token)
+        external
+        view
+        returns (address[] memory tokensIn, address[] memory tokensOut)
+    {
+        try IStandardizedYield(token).getTokensIn() returns (address[] memory res) {
+            return (res, IStandardizedYield(token).getTokensOut());
+        } catch {}
+
+        try IPYieldToken(token).SY() returns (address SY) {
+            return (IStandardizedYield(SY).getTokensIn(), IStandardizedYield(SY).getTokensOut());
+        } catch {}
+
+        try IPMarket(token).readTokens() returns (
+            IStandardizedYield SY,
+            IPPrincipalToken,
+            IPYieldToken
+        ) {
+            return (SY.getTokensIn(), SY.getTokensOut());
+        } catch {}
+
+        revert("invalid token");
+    }
+
+    function getUserSYInfo(address sy, address user) external returns (UserSYInfo memory res) {
+        IStandardizedYield SY = IStandardizedYield(sy);
+
+        // SY
+        res.syBalance = TokenAmount(sy, _balanceOf(sy, user));
+
+        // Rewards
+        uint256[] memory rewardsOut = SY.claimRewards(user);
+        address[] memory rewardTokens = SY.getRewardTokens();
+
+        res.unclaimedRewards = _zipTokenAmounts(rewardTokens, rewardsOut);
+    }
+
+    function getUserPYInfo(address py, address user) external returns (UserPYInfo memory res) {
+        (address _PT, address _YT) = getPY(py);
+        IPYieldToken YT = IPYieldToken(_YT);
+
+        // PT / YT
+        res.ytBalance = TokenAmount(_YT, _balanceOf(_YT, user));
+        res.ptBalance = TokenAmount(_PT, _balanceOf(_PT, user));
+
+        // interest
+        (uint256 interestOut, uint256[] memory rewardsOut) = YT.redeemDueInterestAndRewards(
+            user,
+            true,
+            true
+        );
+
+        res.unclaimedInterest = TokenAmount(YT.SY(), interestOut);
+
+        // Rewards
+        address[] memory rewardTokens = YT.getRewardTokens();
+        res.unclaimedRewards = _zipTokenAmounts(rewardTokens, rewardsOut);
+    }
+
+    function getUserMarketInfo(address market, address user)
+        external
+        returns (UserMarketInfo memory res)
+    {
+        IPMarket _market = IPMarket(market);
+        MarketState memory state = _market.readState(address(this));
+
+        if (uint256(state.totalLp) == 0) return res; // market not initialized
+
+        // LP PT SY
+        (IStandardizedYield SY, IPPrincipalToken PT, ) = _market.readTokens();
+
+        uint256 userLp = _balanceOf(market, user);
+        uint256 userPt = (userLp * uint256(state.totalPt)) / uint256(state.totalLp);
+        uint256 userSy = (userLp * uint256(state.totalSy)) / uint256(state.totalLp);
+
+        res.lpBalance = TokenAmount(market, userLp);
+        res.ptBalance = TokenAmount(address(PT), userPt);
+        res.syBalance = TokenAmount(address(SY), userSy);
+
+        // Rewards
+        uint256[] memory rewardsOut = _market.redeemRewards(user);
+        address[] memory rewardTokens = _market.getRewardTokens();
+
+        res.unclaimedRewards = _zipTokenAmounts(rewardTokens, rewardsOut);
+    }
+
+    function _zipTokenAmounts(address[] memory tokens, uint256[] memory amounts)
+        internal
+        pure
+        returns (TokenAmount[] memory res)
+    {
+        res = new TokenAmount[](tokens.length);
+
+        for (uint256 i = 0; i < tokens.length; i++) {
+            res[i] = TokenAmount(tokens[i], amounts[i]);
+        }
+    }
+
+    function _balanceOf(address token, address user) internal view returns (uint256) {
+        return IERC20(token).balanceOf(user);
+    }
+}

package/contracts/offchain-helpers/router-static/base/ActionMarketAuxStatic.sol

@@ -0,0 +1,166 @@
+// SPDX-License-Identifier: GPL-3.0-or-later
+pragma solidity 0.8.17;
+
+import "../../../interfaces/IPMarket.sol";
+import "../../../interfaces/IPRouterStatic.sol";
+import "../StorageLayout.sol";
+
+contract ActionMarketAuxStatic is IPActionMarketAuxStatic {
+    using MarketMathCore for MarketState;
+    using Math for int256;
+    using Math for uint256;
+    using LogExpMath for int256;
+    using PYIndexLib for PYIndex;
+    using PYIndexLib for IPYieldToken;
+
+    function getMarketState(address market)
+        public
+        returns (
+            address pt,
+            address yt,
+            address sy,
+            int256 impliedYield,
+            uint256 marketExchangeRateExcludeFee,
+            MarketState memory state
+        )
+    {
+        (IStandardizedYield SY, IPPrincipalToken PT, IPYieldToken YT) = IPMarket(market)
+            .readTokens();
+
+        pt = address(PT);
+        yt = address(YT);
+        sy = address(SY);
+        state = _readState(market);
+        impliedYield = _getPtImpliedYield(market);
+        marketExchangeRateExcludeFee = getTradeExchangeRateExcludeFee(market, state);
+    }
+
+    function getTradeExchangeRateExcludeFee(address market, MarketState memory state)
+        public
+        returns (uint256)
+    {
+        if (IPMarket(market).isExpired()) return Math.ONE;
+
+        MarketPreCompute memory comp = state.getMarketPreCompute(
+            _pyIndex(market),
+            block.timestamp
+        );
+        int256 preFeeExchangeRate = MarketMathCore._getExchangeRate(
+            state.totalPt,
+            comp.totalAsset,
+            comp.rateScalar,
+            comp.rateAnchor,
+            0
+        );
+        return preFeeExchangeRate.Uint();
+    }
+
+    function getTradeExchangeRateIncludeFee(address market, int256 netPtOut)
+        public
+        returns (uint256)
+    {
+        if (IPMarket(market).isExpired()) return Math.ONE;
+
+        int256 netPtToAccount = netPtOut;
+        MarketState memory state = _readState(market);
+        MarketPreCompute memory comp = state.getMarketPreCompute(
+            _pyIndex(market),
+            block.timestamp
+        );
+
+        int256 preFeeExchangeRate = MarketMathCore._getExchangeRate(
+            state.totalPt,
+            comp.totalAsset,
+            comp.rateScalar,
+            comp.rateAnchor,
+            netPtToAccount
+        );
+
+        if (netPtToAccount > 0) {
+            int256 postFeeExchangeRate = preFeeExchangeRate.divDown(comp.feeRate);
+            if (postFeeExchangeRate < Math.IONE)
+                revert Errors.MarketExchangeRateBelowOne(postFeeExchangeRate);
+            return postFeeExchangeRate.Uint();
+        } else {
+            return preFeeExchangeRate.mulDown(comp.feeRate).Uint();
+        }
+    }
+
+    function calcPriceImpactPt(address market, int256 netPtOut)
+        public
+        returns (uint256 priceImpact)
+    {
+        uint256 preTradeRate = getTradeExchangeRateIncludeFee(market, _getSign(netPtOut));
+        uint256 tradedRate = getTradeExchangeRateIncludeFee(market, netPtOut);
+        priceImpact = _calculateImpact(preTradeRate, tradedRate);
+    }
+
+    function calcPriceImpactYt(address market, int256 netPtOut)
+        public
+        returns (uint256 priceImpact)
+    {
+        uint256 ytPreTradeRate = _calcVirtualYTPrice(
+            getTradeExchangeRateIncludeFee(market, _getSign(netPtOut))
+        );
+        uint256 ytTradedRate = _calcVirtualYTPrice(
+            getTradeExchangeRateIncludeFee(market, netPtOut)
+        );
+        priceImpact = _calculateImpact(ytPreTradeRate, ytTradedRate);
+    }
+
+    function calcPriceImpactPY(address market, int256 netPtOut)
+        public
+        returns (uint256 priceImpact)
+    {
+        uint256 ptPreTradeRate = getTradeExchangeRateIncludeFee(market, _getSign(netPtOut));
+        uint256 ytPreTradeRate = _calcVirtualYTPrice(ptPreTradeRate);
+        uint256 ptTradeRate = getTradeExchangeRateIncludeFee(market, netPtOut);
+        uint256 ytTradeRate = _calcVirtualYTPrice(ptTradeRate);
+
+        uint256 pyPreTradeRate = ytPreTradeRate.divDown(ptPreTradeRate);
+        uint256 pyTradeRate = ytTradeRate.divDown(ptTradeRate);
+        priceImpact = _calculateImpact(pyPreTradeRate, pyTradeRate);
+    }
+
+    function _getPtImpliedYield(address market) internal view returns (int256) {
+        MarketState memory state = _readState(market);
+
+        int256 lnImpliedRate = (state.lastLnImpliedRate).Int();
+        return lnImpliedRate.exp();
+    }
+
+    function _calcVirtualYTPrice(uint256 ptAssetExchangeRate)
+        private
+        pure
+        returns (uint256 ytAssetExchangeRate)
+    {
+        // 1 asset = EX pt
+        // 1 pt = 1/EX Asset
+        // 1 yt + 1/EX Asset = 1 Asset
+        // 1 yt = 1 Asset - 1/EX Asset
+        // 1 yt = (EX - 1) / EX Asset
+        return (ptAssetExchangeRate - Math.ONE).divDown(ptAssetExchangeRate);
+    }
+
+    function _readState(address market) internal view returns (MarketState memory) {
+        return IPMarket(market).readState(address(this));
+    }
+
+    function _getSign(int256 netPtOut) private pure returns (int256) {
+        return netPtOut > 0 ? int256(1) : int256(-1);
+    }
+
+    function _calculateImpact(uint256 rateBefore, uint256 rateTraded)
+        private
+        pure
+        returns (uint256 impact)
+    {
+        impact = (rateBefore.Int() - rateTraded.Int()).abs().divDown(rateBefore);
+    }
+
+    function _pyIndex(address market) internal returns (PYIndex index) {
+        (, , IPYieldToken YT) = IPMarket(market).readTokens();
+
+        return YT.newIndex();
+    }
+}