@pendle/core-v2 0.6.9 → 0.7.0

package/contracts/core/PendleERC20.sol

@@ -0,0 +1,358 @@
+// SPDX-License-Identifier: MIT
+// OpenZeppelin Contracts (last updated v4.6.0) (token/ERC20/ERC20.sol)
+
+pragma solidity ^0.8.0;
+
+import "@openzeppelin/contracts/token/ERC20/IERC20.sol";
+import "@openzeppelin/contracts/token/ERC20/extensions/IERC20Metadata.sol";
+import "@openzeppelin/contracts/utils/Context.sol";
+
+/**
+ * @dev Pendle's ERC20 implementation, modified from @openzeppelin implementation
+ * Changes are:
+ * - comes with built-in reentrancy protection, storage-packed with totalSupply variable
+ * - delete increaseAllowance / decreaseAllowance
+ * - add nonReentrancy protection to transfer / transferFrom functions
+ * - allow decimals to by passed in
+ * - block self-transfer by default
+ */
+// solhint-disable
+contract PendleERC20 is Context, IERC20, IERC20Metadata {
+    uint8 private constant _NOT_ENTERED = 1;
+    uint8 private constant _ENTERED = 2;
+
+    mapping(address => uint256) private _balances;
+
+    mapping(address => mapping(address => uint256)) private _allowances;
+
+    uint248 private _totalSupply;
+    uint8 private _status;
+
+    string private _name;
+    string private _symbol;
+    uint8 public immutable decimals;
+
+    /**
+     * @dev Prevents a contract from calling itself, directly or indirectly.
+     * Calling a `nonReentrant` function from another `nonReentrant`
+     * function is not supported. It is possible to prevent this from happening
+     * by making the `nonReentrant` function external, and making it call a
+     * `private` function that does the actual work.
+     */
+    modifier nonReentrant() {
+        // On the first call to nonReentrant, _notEntered will be true
+        require(_status != _ENTERED, "ReentrancyGuard: reentrant call");
+
+        // Any calls to nonReentrant after this point will fail
+        _status = _ENTERED;
+
+        _;
+
+        // By storing the original value once again, a refund is triggered (see
+        // https://eips.ethereum.org/EIPS/eip-2200)
+        _status = _NOT_ENTERED;
+    }
+
+    /**
+     * @dev Sets the values for {name} and {symbol}.
+     *
+     * The default value of {decimals} is 18. To select a different value for
+     * {decimals} you should overload it.
+     *
+     * All two of these values are immutable: they can only be set once during
+     * construction.
+     */
+    constructor(
+        string memory name_,
+        string memory symbol_,
+        uint8 decimals_
+    ) {
+        _name = name_;
+        _symbol = symbol_;
+        decimals = decimals_;
+        _status = _NOT_ENTERED;
+    }
+
+    /**
+     * @dev Returns the name of the token.
+     */
+    function name() public view virtual override returns (string memory) {
+        return _name;
+    }
+
+    /**
+     * @dev Returns the symbol of the token, usually a shorter version of the
+     * name.
+     */
+    function symbol() public view virtual override returns (string memory) {
+        return _symbol;
+    }
+
+    /**
+     * @dev See {IERC20-totalSupply}.
+     */
+    function totalSupply() public view virtual override returns (uint256) {
+        return _totalSupply;
+    }
+
+    /**
+     * @dev See {IERC20-balanceOf}.
+     */
+    function balanceOf(address account) public view virtual override returns (uint256) {
+        return _balances[account];
+    }
+
+    /**
+     * @dev See {IERC20-transfer}.
+     *
+     * Requirements:
+     *
+     * - `to` cannot be the zero address.
+     * - the caller must have a balance of at least `amount`.
+     */
+    function transfer(address to, uint256 amount)
+        external
+        virtual
+        override
+        nonReentrant
+        returns (bool)
+    {
+        address owner = _msgSender();
+        _transfer(owner, to, amount);
+        return true;
+    }
+
+    /**
+     * @dev See {IERC20-allowance}.
+     */
+    function allowance(address owner, address spender)
+        public
+        view
+        virtual
+        override
+        returns (uint256)
+    {
+        return _allowances[owner][spender];
+    }
+
+    /**
+     * @dev See {IERC20-approve}.
+     *
+     * NOTE: If `amount` is the maximum `uint256`, the allowance is not updated on
+     * `transferFrom`. This is semantically equivalent to an infinite approval.
+     *
+     * Requirements:
+     *
+     * - `spender` cannot be the zero address.
+     */
+    function approve(address spender, uint256 amount) external virtual override returns (bool) {
+        address owner = _msgSender();
+        _approve(owner, spender, amount);
+        return true;
+    }
+
+    /**
+     * @dev See {IERC20-transferFrom}.
+     *
+     * Emits an {Approval} event indicating the updated allowance. This is not
+     * required by the EIP. See the note at the beginning of {ERC20}.
+     *
+     * NOTE: Does not update the allowance if the current allowance
+     * is the maximum `uint256`.
+     *
+     * Requirements:
+     *
+     * - `from` and `to` cannot be the zero address.
+     * - `from` must have a balance of at least `amount`.
+     * - the caller must have allowance for ``from``'s tokens of at least
+     * `amount`.
+     */
+    function transferFrom(
+        address from,
+        address to,
+        uint256 amount
+    ) external virtual override nonReentrant returns (bool) {
+        address spender = _msgSender();
+        _spendAllowance(from, spender, amount);
+        _transfer(from, to, amount);
+        return true;
+    }
+
+    /**
+     * @dev Moves `amount` of tokens from `sender` to `recipient`.
+     *
+     * This internal function is equivalent to {transfer}, and can be used to
+     * e.g. implement automatic token fees, slashing mechanisms, etc.
+     *
+     * Emits a {Transfer} event.
+     *
+     * Requirements:
+     *
+     * - `from` cannot be the zero address.
+     * - `to` cannot be the zero address.
+     * - `from` must have a balance of at least `amount`.
+     */
+    function _transfer(
+        address from,
+        address to,
+        uint256 amount
+    ) internal virtual {
+        require(from != address(0), "ERC20: transfer from the zero address");
+        require(to != address(0), "ERC20: transfer to the zero address");
+        require(from != to, "ERC20: transfer to self");
+
+        _beforeTokenTransfer(from, to, amount);
+
+        uint256 fromBalance = _balances[from];
+        require(fromBalance >= amount, "ERC20: transfer amount exceeds balance");
+        unchecked {
+            _balances[from] = fromBalance - amount;
+        }
+        _balances[to] += amount;
+
+        emit Transfer(from, to, amount);
+
+        _afterTokenTransfer(from, to, amount);
+    }
+
+    /** @dev Creates `amount` tokens and assigns them to `account`, increasing
+     * the total supply.
+     *
+     * Emits a {Transfer} event with `from` set to the zero address.
+     *
+     * Requirements:
+     *
+     * - `account` cannot be the zero address.
+     */
+    function _mint(address account, uint256 amount) internal virtual {
+        require(account != address(0), "ERC20: mint to the zero address");
+
+        _beforeTokenTransfer(address(0), account, amount);
+
+        _totalSupply += toUint248(amount);
+        _balances[account] += amount;
+        emit Transfer(address(0), account, amount);
+
+        _afterTokenTransfer(address(0), account, amount);
+    }
+
+    /**
+     * @dev Destroys `amount` tokens from `account`, reducing the
+     * total supply.
+     *
+     * Emits a {Transfer} event with `to` set to the zero address.
+     *
+     * Requirements:
+     *
+     * - `account` cannot be the zero address.
+     * - `account` must have at least `amount` tokens.
+     */
+    function _burn(address account, uint256 amount) internal virtual {
+        require(account != address(0), "ERC20: burn from the zero address");
+
+        _beforeTokenTransfer(account, address(0), amount);
+
+        uint256 accountBalance = _balances[account];
+        require(accountBalance >= amount, "ERC20: burn amount exceeds balance");
+        unchecked {
+            _balances[account] = accountBalance - amount;
+        }
+        _totalSupply -= toUint248(amount);
+
+        emit Transfer(account, address(0), amount);
+
+        _afterTokenTransfer(account, address(0), amount);
+    }
+
+    /**
+     * @dev Sets `amount` as the allowance of `spender` over the `owner` s tokens.
+     *
+     * This internal function is equivalent to `approve`, and can be used to
+     * e.g. set automatic allowances for certain subsystems, etc.
+     *
+     * Emits an {Approval} event.
+     *
+     * Requirements:
+     *
+     * - `owner` cannot be the zero address.
+     * - `spender` cannot be the zero address.
+     */
+    function _approve(
+        address owner,
+        address spender,
+        uint256 amount
+    ) internal virtual {
+        require(owner != address(0), "ERC20: approve from the zero address");
+        require(spender != address(0), "ERC20: approve to the zero address");
+
+        _allowances[owner][spender] = amount;
+        emit Approval(owner, spender, amount);
+    }
+
+    /**
+     * @dev Updates `owner` s allowance for `spender` based on spent `amount`.
+     *
+     * Does not update the allowance amount in case of infinite allowance.
+     * Revert if not enough allowance is available.
+     *
+     * Might emit an {Approval} event.
+     */
+    function _spendAllowance(
+        address owner,
+        address spender,
+        uint256 amount
+    ) internal virtual {
+        uint256 currentAllowance = allowance(owner, spender);
+        if (currentAllowance != type(uint256).max) {
+            require(currentAllowance >= amount, "ERC20: insufficient allowance");
+            unchecked {
+                _approve(owner, spender, currentAllowance - amount);
+            }
+        }
+    }
+
+    /**
+     * @dev Hook that is called before any transfer of tokens. This includes
+     * minting and burning.
+     *
+     * Calling conditions:
+     *
+     * - when `from` and `to` are both non-zero, `amount` of ``from``'s tokens
+     * will be transferred to `to`.
+     * - when `from` is zero, `amount` tokens will be minted for `to`.
+     * - when `to` is zero, `amount` of ``from``'s tokens will be burned.
+     * - `from` and `to` are never both zero.
+     *
+     * To learn more about hooks, head to xref:ROOT:extending-contracts.adoc#using-hooks[Using Hooks].
+     */
+    function _beforeTokenTransfer(
+        address from,
+        address to,
+        uint256 amount
+    ) internal virtual {}
+
+    /**
+     * @dev Hook that is called after any transfer of tokens. This includes
+     * minting and burning.
+     *
+     * Calling conditions:
+     *
+     * - when `from` and `to` are both non-zero, `amount` of ``from``'s tokens
+     * has been transferred to `to`.
+     * - when `from` is zero, `amount` tokens have been minted for `to`.
+     * - when `to` is zero, `amount` of ``from``'s tokens have been burned.
+     * - `from` and `to` are never both zero.
+     *
+     * To learn more about hooks, head to xref:ROOT:extending-contracts.adoc#using-hooks[Using Hooks].
+     */
+    function _afterTokenTransfer(
+        address from,
+        address to,
+        uint256 amount
+    ) internal virtual {}
+
+    function toUint248(uint256 x) internal virtual returns (uint248) {
+        require(x < (1 << 248)); // signed, lim = bit-1
+        return uint248(x);
+    }
+}

package/contracts/core/PendleERC20Permit.sol

@@ -0,0 +1,84 @@
+// SPDX-License-Identifier: MIT
+// OpenZeppelin Contracts (last updated v4.6.0) (token/ERC20/ERC20.sol)
+
+pragma solidity ^0.8.0;
+
+import "./PendleERC20.sol";
+import "@openzeppelin/contracts/token/ERC20/IERC20.sol";
+import "@openzeppelin/contracts/token/ERC20/extensions/IERC20Metadata.sol";
+import "@openzeppelin/contracts/utils/Context.sol";
+import "@openzeppelin/contracts/token/ERC20/extensions/draft-ERC20Permit.sol";
+import "@openzeppelin/contracts/utils/cryptography/draft-EIP712.sol";
+import "@openzeppelin/contracts/utils/cryptography/ECDSA.sol";
+import "@openzeppelin/contracts/utils/Counters.sol";
+
+/// @dev forked from OZ's ERC20Permit
+contract PendleERC20Permit is PendleERC20, IERC20Permit, EIP712 {
+    using Counters for Counters.Counter;
+
+    mapping(address => Counters.Counter) private _nonces;
+
+    // solhint-disable-next-line var-name-mixedcase
+    bytes32 private immutable _PERMIT_TYPEHASH =
+        keccak256(
+            "Permit(address owner,address spender,uint256 value,uint256 nonce,uint256 deadline)"
+        );
+
+    constructor(
+        string memory name_,
+        string memory symbol_,
+        uint8 decimals_
+    ) PendleERC20(name_, symbol_, decimals) EIP712(name_, "1") {}
+
+    /**
+     * @dev See {IERC20Permit-permit}.
+     */
+    function permit(
+        address owner,
+        address spender,
+        uint256 value,
+        uint256 deadline,
+        uint8 v,
+        bytes32 r,
+        bytes32 s
+    ) public virtual override {
+        require(block.timestamp <= deadline, "ERC20Permit: expired deadline");
+
+        bytes32 structHash = keccak256(
+            abi.encode(_PERMIT_TYPEHASH, owner, spender, value, _useNonce(owner), deadline)
+        );
+
+        bytes32 hash = _hashTypedDataV4(structHash);
+
+        address signer = ECDSA.recover(hash, v, r, s);
+        require(signer == owner, "ERC20Permit: invalid signature");
+
+        _approve(owner, spender, value);
+    }
+
+    /**
+     * @dev See {IERC20Permit-nonces}.
+     */
+    function nonces(address owner) public view virtual override returns (uint256) {
+        return _nonces[owner].current();
+    }
+
+    /**
+     * @dev See {IERC20Permit-DOMAIN_SEPARATOR}.
+     */
+    // solhint-disable-next-line func-name-mixedcase
+    function DOMAIN_SEPARATOR() external view override returns (bytes32) {
+        return _domainSeparatorV4();
+    }
+
+    /**
+     * @dev "Consume a nonce": return the current value and increment.
+     *
+     * _Available since v4.1._
+     */
+    function _useNonce(address owner) internal virtual returns (uint256 current) {
+        Counters.Counter storage nonce = _nonces[owner];
+        current = nonce.current();
+        nonce.increment();
+    }
+}

package/contracts/core/PendleRouter.sol

@@ -1,5 +1,5 @@
 // SPDX-License-Identifier: GPL-3.0-or-later
-pragma solidity 0.8.9;
+pragma solidity 0.8.13;
 
 import "@openzeppelin/contracts-upgradeable/proxy/utils/Initializable.sol";
 import "@openzeppelin/contracts-upgradeable/proxy/utils/UUPSUpgradeable.sol";
@@ -8,7 +8,6 @@ import "../interfaces/IPActionCore.sol";
 import "../interfaces/IPActionYT.sol";
 import "../interfaces/IPRouterStatic.sol";
 import "../interfaces/IPMarketSwapCallback.sol";
-import "../interfaces/IPActionRedeem.sol";
 import "../periphery/PermissionsV2Upg.sol";
 
 /// @dev this contract will be deployed behind an ERC1967 proxy
@@ -20,26 +19,22 @@ contract PendleRouter is Proxy, Initializable, UUPSUpgradeable, PermissionsV2Upg
     address public immutable ACTION_CORE;
     address public immutable ACTION_YT;
     address public immutable ACTION_CALLBACK;
-    address public immutable ACTION_REDEEM;
 
     constructor(
         address _ACTION_CORE,
         address _ACTION_YT,
         address _ACTION_CALLBACK,
-        address _ACTION_REDEEM,
         address _governanceManager
     ) PermissionsV2Upg(_governanceManager) initializer {
         require(
             _ACTION_CORE != address(0) &&
                 _ACTION_YT != address(0) &&
-                _ACTION_CALLBACK != address(0) &&
-                _ACTION_REDEEM != address(0),
+                _ACTION_CALLBACK != address(0),
             "zero address"
         );
         ACTION_CORE = _ACTION_CORE;
         ACTION_YT = _ACTION_YT;
         ACTION_CALLBACK = _ACTION_CALLBACK;
-        ACTION_REDEEM = _ACTION_REDEEM;
     }
 
     function initialize() external initializer {
@@ -60,7 +55,8 @@ contract PendleRouter is Proxy, Initializable, UUPSUpgradeable, PermissionsV2Upg
             sig == IPActionCore.swapScyForExactPt.selector ||
             sig == IPActionCore.swapExactScyForPt.selector ||
             sig == IPActionCore.swapExactRawTokenForPt.selector ||
-            sig == IPActionCore.swapExactPtForRawToken.selector
+            sig == IPActionCore.swapExactPtForRawToken.selector ||
+            sig == IPActionCore.redeemDueIncome.selector
         ) {
             return ACTION_CORE;
         } else if (
@@ -72,17 +68,15 @@ contract PendleRouter is Proxy, Initializable, UUPSUpgradeable, PermissionsV2Upg
             sig == IPActionYT.swapYtForExactScy.selector
         ) {
             return ACTION_YT;
-        } else if (sig == IPActionRedeem.redeemDueIncome.selector) {
-            return ACTION_REDEEM;
         } else if (sig == IPMarketSwapCallback.swapCallback.selector) {
             return ACTION_CALLBACK;
         }
         require(false, "invalid market sig");
     }
 
+    function _authorizeUpgrade(address newImplementation) internal override onlyGovernance {}
+
     function _implementation() internal view override returns (address) {
         return getRouterImplementation(msg.sig);
     }
-
-    function _authorizeUpgrade(address newImplementation) internal override onlyGovernance {}
 }

package/contracts/core/YieldContracts/InterestManagerYT.sol

@@ -0,0 +1,87 @@
+// SPDX-License-Identifier: GPL-3.0-or-later
+pragma solidity 0.8.13;
+
+import "../../interfaces/IPYieldToken.sol";
+import "../../interfaces/IPPrincipalToken.sol";
+import "../../interfaces/IPInterestManagerYT.sol";
+
+import "@openzeppelin/contracts/token/ERC20/utils/SafeERC20.sol";
+
+import "../../libraries/math/Math.sol";
+import "../../interfaces/IPYieldContractFactory.sol";
+import "../../libraries/SCY/SCYUtils.sol";
+import "../../libraries/helpers/TokenHelper.sol";
+
+import "../PendleERC20Permit.sol";
+
+/*
+With YT yielding more SCYs overtime, which is allowed to be redeemed by users, the reward distribution should
+be based on the amount of SCYs that their YT currently represent, plus with their dueInterest.
+
+It has been proven and tested that totalScyRedeemable will not change over time, unless users redeem their interest or redeemPY.
+
+Due to this, it is required to update users' accruedReward STRICTLY BEFORE redeeming their interest.
+*/
+abstract contract InterestManagerYT is TokenHelper, IPInterestManagerYT {
+    using Math for uint256;
+
+    struct UserInterest {
+        uint128 index;
+        uint128 accrued;
+    }
+
+    mapping(address => UserInterest) public userInterest;
+
+    function _distributeInterest(address user) internal {
+        _distributeInterestForTwo(user, address(0));
+    }
+
+    function _distributeInterestForTwo(address user1, address user2) internal {
+        // no updateRewardIndex since we rely on SCY's rewardIndexes
+        uint256 index = _getInterestIndex();
+        if (user1 != address(0) && user1 != address(this)) _distributeInterest(user1, index);
+        if (user2 != address(0) && user2 != address(this)) _distributeInterest(user2, index);
+    }
+
+    function _doTransferOutInterest(
+        address user,
+        address SCY,
+        address factory
+    ) internal returns (uint256 interestAmount) {
+        uint256 interestPreFee = userInterest[user].accrued;
+        userInterest[user].accrued = 0;
+
+        address treasury = IPYieldContractFactory(factory).treasury();
+
+        uint256 feeRate = IPYieldContractFactory(factory).interestFeeRate();
+
+        uint256 feeAmount = interestPreFee.mulDown(feeRate);
+        interestAmount = interestPreFee - feeAmount;
+
+        _transferOut(SCY, treasury, feeAmount);
+        _transferOut(SCY, user, interestAmount);
+    }
+
+    function _distributeInterest(address user, uint256 currentIndex) private {
+        uint256 prevIndex = userInterest[user].index;
+
+        if (prevIndex == currentIndex) return;
+        if (prevIndex == 0) {
+            userInterest[user].index = currentIndex.Uint128();
+            return;
+        }
+
+        uint256 principal = _YTbalance(user);
+
+        uint256 interestFromYT = (principal * (currentIndex - prevIndex)).divDown(
+            prevIndex * currentIndex
+        );
+
+        userInterest[user].accrued += interestFromYT.Uint128();
+        userInterest[user].index = currentIndex.Uint128();
+    }
+
+    function _getInterestIndex() internal virtual returns (uint256 index);
+
+    function _YTbalance(address user) internal view virtual returns (uint256);
+}

package/contracts/core/YieldContracts/PendlePrincipalToken.sol

@@ -0,0 +1,52 @@
+// SPDX-License-Identifier: GPL-3.0-or-later
+pragma solidity 0.8.13;
+
+import "../../interfaces/IPPrincipalToken.sol";
+import "../../interfaces/IPYieldToken.sol";
+
+import "../PendleERC20Permit.sol";
+import "../../libraries/helpers/MiniHelpers.sol";
+
+contract PendlePrincipalToken is PendleERC20Permit, IPPrincipalToken {
+    address public immutable SCY;
+    address public immutable YT;
+    address public immutable factory;
+    uint256 public immutable expiry;
+
+    modifier onlyYT() {
+        require(msg.sender == address(YT), "ONLY_YT");
+        _;
+    }
+
+    constructor(
+        address _SCY,
+        address _YT,
+        string memory _name,
+        string memory _symbol,
+        uint8 __decimals,
+        uint256 _expiry
+    ) PendleERC20Permit(_name, _symbol, __decimals) {
+        SCY = _SCY;
+        YT = _YT;
+        expiry = _expiry;
+        factory = msg.sender;
+    }
+
+    /**
+     * @dev only callable by the YT correspond to this PT
+     */
+    function burnByYT(address user, uint256 amount) external onlyYT {
+        _burn(user, amount);
+    }
+
+    /**
+     * @dev only callable by the YT correspond to this PT
+     */
+    function mintByYT(address user, uint256 amount) external onlyYT {
+        _mint(user, amount);
+    }
+
+    function isExpired() public view returns (bool) {
+        return MiniHelpers.isCurrentlyExpired(expiry);
+    }
+}