@pdftron/pdfnet-node 10.4.0-beta → 10.4.0

package/node_modules/xhr2/test/src/helpers/xhr_server.coffee

@@ -0,0 +1,156 @@
+express = require 'express'
+fs = require 'fs'
+http = require 'http'
+https = require 'https'
+open = require 'open'
+
+# express.js server for testing the Web application.
+class XhrServer
+  # Starts up a HTTP server.
+  constructor: (@port, @useHttps) ->
+    @createApp()
+
+  # Opens the test URL in a browser.
+  openBrowser: (appName) ->
+    open @testUrl(), appName
+
+  # The URL that should be used to start the tests.
+  testUrl: ->
+    "https://localhost:#{@port}/test/html/browser_test.html"
+
+  # The self-signed certificate used by this server.
+  sslCertificate: ->
+    return null unless @useHttps
+    keyMaterial = fs.readFileSync 'test/ssl/cert.pem', 'utf8'
+    certIndex = keyMaterial.indexOf '-----BEGIN CERTIFICATE-----'
+    keyMaterial.substring certIndex
+
+  # The key for the self-signed certificate used by this server.
+  sslKey: ->
+    return null unless @useHttps
+    keyMaterial = fs.readFileSync 'test/ssl/cert.pem', 'utf8'
+    certIndex = keyMaterial.indexOf '-----BEGIN CERTIFICATE-----'
+    keyMaterial.substring 0, certIndex
+
+  # The server code.
+  createApp: ->
+    @app = express()
+
+    ## Middleware.
+
+    # CORS headers on everything, in case that ever gets implemented.
+    @app.use (request, response, next) ->
+      response.header 'Access-Control-Allow-Origin', '*'
+      response.header 'Access-Control-Allow-Methods', 'DELETE,GET,POST,PUT'
+      response.header 'Access-Control-Allow-Headers',
+                      'Content-Type, Authorization'
+      next()
+
+    @app.use express.static(fs.realpathSync(__dirname + '/../../../'),
+                            { dotfiles: 'allow' })
+
+    ## Routes
+
+    @app.all '/_/method', (request, response) ->
+      body = request.method
+      response.header 'Content-Type', 'text/plain; charset=utf-8'
+      response.header 'Content-Length', body.length.toString()
+      response.end body
+
+    # Echoes the request body. Used to test send(data).
+    @app.post '/_/echo', (request, response) ->
+      if request.headers['content-type']
+        response.header 'Content-Type', request.headers['content-type']
+      if request.headers['content-length']
+        response.header 'Content-Length', request.headers['content-length']
+
+      request.on 'data', (chunk) -> response.write chunk
+      request.on 'end', -> response.end()
+
+    # Lists the request headers. Used to test setRequestHeader().
+    @app.all '/_/headers', (request, response) ->
+      body = JSON.stringify request.headers
+      response.header 'Content-Type', 'application/json'
+      response.header 'Content-Length', body.length.toString()
+      response.end body
+
+    # Sets the response headers in the request. Used to test getResponse*().
+    @app.post '/_/get_headers', (request, response) ->
+      jsonString = ''
+      request.on 'data', (chunk) -> jsonString += chunk
+      request.on 'end', ->
+        headers = JSON.parse jsonString
+        for name, value of headers
+          response.header name, value
+        response.header 'Content-Length', '0'
+        response.end ''
+
+    # Sets every response detail. Used for error testing.
+    @app.post '/_/response', (request, response) ->
+      jsonString = ''
+      request.on 'data', (chunk) -> jsonString += chunk
+      request.on 'end', ->
+        json = JSON.parse jsonString
+        response.writeHead json.code, json.status, json.headers
+        response.write json.body if json.body
+        response.end()
+
+    # Sends data in small chunks. Used for event testing.
+    @app.post '/_/drip', (request, response) ->
+      request.connection.setNoDelay()
+      jsonString = ''
+      request.on 'data', (chunk) -> jsonString += chunk
+      request.on 'end', ->
+        json = JSON.parse jsonString
+        sentDrips = 0
+        drip = new Array(json.size + 1).join '.'
+        response.header 'Content-Type', 'text/plain'
+        if json.length
+          response.header 'Content-Length', (json.drips * json.size).toString()
+        sendDrip = =>
+          response.write drip
+          sentDrips += 1
+          if sentDrips >= json.drips
+            response.end()
+          else
+            setTimeout sendDrip, json.ms
+        sendDrip()
+
+    # Returns a HTTP redirect. Used to test the redirection handling code.
+    @app.all '/_/redirect/:status/:next_page', (request, response) =>
+      response.statusCode = parseInt(request.params.status)
+      response.header 'Location',
+          "http://#{request.get('host')}/_/#{request.params.next_page}"
+      body = "<p>This is supposed to have a redirect link</p>"
+      response.header 'Content-Type', 'text/html'
+      response.header 'Content-Length', body.length.toString()
+      response.header 'X-Redirect-Header', 'should not show up'
+      response.end body
+
+    # Requested when the browser test suite completes.
+    @app.get '/diediedie', (request, response) =>
+      if 'failed' of request.query
+        failed = parseInt request.query['failed']
+      else
+        failed = 1
+      total = parseInt request.query['total'] || 0
+      passed = total - failed
+      exitCode = if failed == 0 then 0 else 1
+      console.log "#{passed} passed, #{failed} failed"
+
+      response.header 'Content-Type', 'image/png'
+      response.header 'Content-Length', '0'
+      response.end ''
+      unless 'NO_EXIT' of process.env
+        @server.close()
+        process.exit exitCode
+
+    if @useHttps
+      options = key: @sslKey(), cert: @sslCertificate()
+      @server = https.createServer options, @app
+    else
+      @server = http.createServer @app
+    @server.listen @port
+
+module.exports.https = new XhrServer 8911, true
+module.exports.http = new XhrServer 8912, false

package/node_modules/xhr2/test/src/nodejs_set_test.coffee

@@ -0,0 +1,162 @@
+describe 'XMLHttpRequest', ->
+  describe '.nodejsSet', ->
+    beforeEach ->
+      @xhr = new XMLHttpRequest
+      @customXhr = new XMLHttpRequest
+
+    describe 'with a httpAgent option', ->
+      beforeEach ->
+        return unless XMLHttpRequest.nodejsSet  # Skip in browsers.
+
+        @customAgent = { custom: 'httpAgent' }
+        @customXhr.nodejsHttpAgent = @customAgent
+
+        @default = XMLHttpRequest::nodejsHttpAgent
+        @agent = { mocking: 'httpAgent' }
+        XMLHttpRequest.nodejsSet httpAgent: @agent
+
+      it 'sets the default nodejsHttpAgent', ->
+        return unless XMLHttpRequest.nodejsSet  # Skip in browsers.
+        expect(@xhr.nodejsHttpAgent).to.equal @agent
+
+      it 'does not interfere with custom nodejsHttpAgent settings', ->
+        return unless XMLHttpRequest.nodejsSet  # Skip in browsers.
+        expect(@customXhr.nodejsHttpAgent).to.equal @customAgent
+
+      afterEach ->
+        XMLHttpRequest.nodejsSet httpAgent: @default
+
+    describe 'with a httpsAgent option', ->
+      beforeEach ->
+        return unless XMLHttpRequest.nodejsSet  # Skip in browsers.
+
+        @customAgent = { custom: 'httpsAgent' }
+        @customXhr.nodejsHttpsAgent = @customAgent
+
+        @default = XMLHttpRequest::nodejsHttpsAgent
+        @agent = { mocking: 'httpsAgent' }
+        XMLHttpRequest.nodejsSet httpsAgent: @agent
+
+      it 'sets the default nodejsHttpsAgent', ->
+        return unless XMLHttpRequest.nodejsSet  # Skip in browsers.
+        expect(@xhr.nodejsHttpsAgent).to.equal @agent
+
+      it 'does not interfere with custom nodejsHttpsAgent settings', ->
+        return unless XMLHttpRequest.nodejsSet  # Skip in browsers.
+        expect(@customXhr.nodejsHttpsAgent).to.equal @customAgent
+
+      afterEach ->
+        XMLHttpRequest.nodejsSet httpsAgent: @default
+
+    describe 'with a baseUrl option', ->
+      beforeEach ->
+        return unless XMLHttpRequest.nodejsSet  # Skip in browsers.
+
+        @customBaseUrl = 'http://custom.url/base'
+        @customXhr.nodejsBaseUrl = @customBaseUrl
+
+        @default = XMLHttpRequest::nodejsBaseUrl
+        @baseUrl = 'http://localhost/base'
+        XMLHttpRequest.nodejsSet baseUrl: @baseUrl
+
+      it 'sets the default nodejsBaseUrl', ->
+        return unless XMLHttpRequest.nodejsSet  # Skip in browsers.
+        expect(@xhr.nodejsBaseUrl).to.equal @baseUrl
+
+      it 'does not interfere with custom nodejsBaseUrl settings', ->
+        return unless XMLHttpRequest.nodejsSet  # Skip in browsers.
+        expect(@customXhr.nodejsBaseUrl).to.equal @customBaseUrl
+
+      afterEach ->
+        XMLHttpRequest.nodejsSet baseUrl: @default
+
+  describe '#nodejsSet', ->
+    beforeEach ->
+      @xhr = new XMLHttpRequest
+      @customXhr = new XMLHttpRequest
+
+    describe 'with a httpAgent option', ->
+      beforeEach ->
+        return unless XMLHttpRequest.nodejsSet  # Skip in browsers.
+
+        @customAgent = { custom: 'httpAgent' }
+        @customXhr.nodejsSet httpAgent: @customAgent
+
+      it 'sets nodejsHttpAgent on the XHR instance', ->
+        return unless XMLHttpRequest.nodejsSet  # Skip in browsers.
+        expect(@customXhr.nodejsHttpAgent).to.equal @customAgent
+
+      it 'does not interfere with default nodejsHttpAgent settings', ->
+        return unless XMLHttpRequest.nodejsSet  # Skip in browsers.
+        expect(@xhr.nodejsHttpAgent).not.to.equal @customAgent
+
+    describe 'with a httpsAgent option', ->
+      beforeEach ->
+        return unless XMLHttpRequest.nodejsSet  # Skip in browsers.
+
+        @customAgent = { custom: 'httpsAgent' }
+        @customXhr.nodejsSet httpsAgent: @customAgent
+
+      it 'sets nodejsHttpsAgent on the XHR instance', ->
+        return unless XMLHttpRequest.nodejsSet  # Skip in browsers.
+        expect(@customXhr.nodejsHttpsAgent).to.equal @customAgent
+
+      it 'does not interfere with default nodejsHttpsAgent settings', ->
+        return unless XMLHttpRequest.nodejsSet  # Skip in browsers.
+        expect(@xhr.nodejsHttpsAgent).not.to.equal @customAgent
+
+  describe 'base URL parsing', ->
+    beforeEach ->
+      @xhr = new XMLHttpRequest
+
+    describe 'with null baseUrl', ->
+      beforeEach ->
+        return unless XMLHttpRequest.nodejsSet  # Skip in browsers.
+        @xhr.nodejsSet baseUrl: null
+
+      it 'parses an absolute URL', ->
+        return unless XMLHttpRequest.nodejsSet  # Skip in browsers.
+        parsedUrl = @xhr._parseUrl('http://www.domain.com/path')
+        expect(parsedUrl).to.be.ok
+        expect(parsedUrl).to.have.property 'href'
+        expect(parsedUrl.href).to.equal 'http://www.domain.com/path'
+
+    describe 'with a (protocol, domain, filePath) baseUrl', ->
+      beforeEach ->
+        return unless XMLHttpRequest.nodejsSet  # Skip in browsers.
+        @xhr.nodejsSet baseUrl: 'https://base.url/dir/file.html'
+
+      it 'parses an absolute URL', ->
+        return unless XMLHttpRequest.nodejsSet  # Skip in browsers.
+        parsedUrl = @xhr._parseUrl('http://www.domain.com/path')
+        expect(parsedUrl).to.be.ok
+        expect(parsedUrl).to.have.property 'href'
+        expect(parsedUrl.href).to.equal 'http://www.domain.com/path'
+
+      it 'parses a path-relative URL', ->
+        return unless XMLHttpRequest.nodejsSet  # Skip in browsers.
+        parsedUrl = @xhr._parseUrl('path/to.js')
+        expect(parsedUrl).to.be.ok
+        expect(parsedUrl).to.have.property 'href'
+        expect(parsedUrl.href).to.equal 'https://base.url/dir/path/to.js'
+
+      it 'parses a path-relative URL with ..', ->
+        return unless XMLHttpRequest.nodejsSet  # Skip in browsers.
+        parsedUrl = @xhr._parseUrl('../path/to.js')
+        expect(parsedUrl).to.be.ok
+        expect(parsedUrl).to.have.property 'href'
+        expect(parsedUrl.href).to.equal 'https://base.url/path/to.js'
+
+      it 'parses a host-relative URL', ->
+        return unless XMLHttpRequest.nodejsSet  # Skip in browsers.
+        parsedUrl = @xhr._parseUrl('/path/to.js')
+        expect(parsedUrl).to.be.ok
+        expect(parsedUrl).to.have.property 'href'
+        expect(parsedUrl.href).to.equal 'https://base.url/path/to.js'
+
+      it 'parses a protocol-relative URL', ->
+        return unless XMLHttpRequest.nodejsSet  # Skip in browsers.
+        parsedUrl = @xhr._parseUrl('//domain.com/path/to.js')
+        expect(parsedUrl).to.be.ok
+        expect(parsedUrl).to.have.property 'href'
+        expect(parsedUrl.href).to.equal 'https://domain.com/path/to.js'

package/node_modules/xhr2/test/src/redirect_test.coffee

@@ -0,0 +1,57 @@
+describe 'XMLHttpRequest', ->
+  describe 'when redirected', ->
+    beforeEach ->
+      @xhr = new XMLHttpRequest
+
+    it 'issues a GET for the next location', (done) ->
+      @xhr.open 'POST', 'http://localhost:8912/_/redirect/302/method'
+      @xhr.onload = =>
+        expect(@xhr.responseText).to.match(/GET/i)
+        done()
+      @xhr.send 'This should be dropped during the redirect'
+
+    it 'does not return the redirect headers', (done) ->
+      @xhr.open 'GET', 'http://localhost:8912/_/redirect/302/method'
+      @xhr.onload = =>
+        expect(@xhr.getResponseHeader('Content-Type')).to.equal(
+            'text/plain; charset=utf-8')
+        expect(@xhr.getResponseHeader('X-Redirect-Header')).not.to.be.ok
+        done()
+      @xhr.send()
+
+    it 'persists custom request headers across redirects', (done) ->
+      @xhr.open 'GET', 'http://localhost:8912/_/redirect/302/headers'
+      @xhr.setRequestHeader 'X-Redirect-Test', 'should be preserved'
+      @xhr.onload = =>
+        expect(@xhr.responseText).to.match(/^\{.*\}$/)
+        headers = JSON.parse @xhr.responseText
+        expect(headers['connection']).to.equal 'keep-alive'
+        expect(headers).to.have.property 'host'
+        expect(headers['host']).to.equal 'localhost:8912'
+        expect(headers).to.have.property 'x-redirect-test'
+        expect(headers['x-redirect-test']).to.equal 'should be preserved'
+        done()
+      @xhr.send()
+
+    it 'drops content-related headers across redirects', (done) ->
+      @xhr.open 'POST', 'http://localhost:8912/_/redirect/302/headers'
+      @xhr.setRequestHeader 'X-Redirect-Test', 'should be preserved'
+      @xhr.onload = =>
+        expect(@xhr.responseText).to.match(/^\{.*\}$/)
+        headers = JSON.parse @xhr.responseText
+        expect(headers['connection']).to.equal 'keep-alive'
+        expect(headers).to.have.property 'host'
+        expect(headers['host']).to.equal 'localhost:8912'
+        expect(headers).to.have.property 'x-redirect-test'
+        expect(headers['x-redirect-test']).to.equal 'should be preserved'
+        expect(headers).not.to.have.property 'content-type'
+        expect(headers).not.to.have.property 'content-length'
+        done()
+      @xhr.send 'This should be dropped during the redirect'
+
+    it 'provides the final responseURL', (done) ->
+      @xhr.open 'GET', 'http://localhost:8912/_/redirect/302/method'
+      @xhr.onload = =>
+        expect(@xhr.responseURL).to.equal("http://localhost:8912/_/method")
+        done()
+      @xhr.send()

package/node_modules/xhr2/test/src/response_type_test.coffee

@@ -0,0 +1,88 @@
+describe 'XMLHttpRequest', ->
+  describe '#responseType', ->
+    beforeEach ->
+      @xhr = new XMLHttpRequest
+      @jsonUrl = 'http://localhost:8912/test/fixtures/hello.json'
+      @jsonString = '{"hello": "world", "answer": 42}\n'
+      @imageUrl = 'http://localhost:8912/test/fixtures/xhr2.png'
+
+    describe 'text', ->
+      it 'reads a JSON file into a String', (done) ->
+        @xhr.addEventListener 'load', =>
+          expect(@xhr.response).to.equal @jsonString
+          expect(@xhr.responseText).to.equal @jsonString
+          done()
+        @xhr.open 'GET', @jsonUrl
+        @xhr.responseType = 'text'
+        @xhr.send()
+
+    describe 'json', ->
+      it 'reads a JSON file into a parsed JSON object', (done) ->
+        _done = false
+        @xhr.addEventListener 'readystatechange', =>
+          return if _done or @xhr.readyState isnt XMLHttpRequest.DONE
+          _done = true
+          expect(@xhr.response).to.deep.equal hello: 'world', answer: 42
+          done()
+        @xhr.open 'GET', @jsonUrl
+        @xhr.responseType = 'json'
+        @xhr.send()
+
+      it 'produces null when reading a non-JSON file ', (done) ->
+        @xhr.addEventListener 'loadend', =>
+          expect(@xhr.response).to.equal null
+          done()
+        @xhr.open 'GET', 'http://localhost:8912/test/fixtures/hello.txt'
+        @xhr.responseType = 'json'
+        @xhr.send()
+
+    describe 'arraybuffer', ->
+      it 'reads a JSON file into an ArrayBuffer', (done) ->
+        @xhr.addEventListener 'loadend', =>
+          expect(@xhr.response).to.be.instanceOf ArrayBuffer
+          view = new Uint8Array @xhr.response
+          string = (String.fromCharCode(view[i]) for i in [0...view.length]).
+              join ''
+          expect(string).to.equal @jsonString
+          done()
+        @xhr.open 'GET', @jsonUrl
+        @xhr.responseType = 'arraybuffer'
+        @xhr.send()
+
+      it 'reads a binary file into an ArrayBuffer', (done) ->
+        @xhr.addEventListener 'loadend', =>
+          expect(@xhr.response).to.be.instanceOf ArrayBuffer
+          view = new Uint8Array @xhr.response
+          bytes = (view[i] for i in [0...view.length])
+          expect(bytes).to.deep.equal xhr2PngBytes
+          done()
+        @xhr.open 'GET', @imageUrl
+        @xhr.responseType = 'arraybuffer'
+        @xhr.send()
+
+
+    describe 'buffer', ->
+      it 'reads a JSON file into a node.js Buffer', (done) ->
+        return done() if typeof Buffer is 'undefined'
+        @xhr.addEventListener 'loadend', =>
+          buffer = @xhr.response
+          expect(buffer).to.be.instanceOf Buffer
+          stringChars = for i in [0...buffer.length]
+            String.fromCharCode buffer.readUInt8(i)
+          expect(stringChars.join('')).to.equal @jsonString
+          done()
+        @xhr.open 'GET', @jsonUrl
+        @xhr.responseType = 'buffer'
+        @xhr.send()
+
+      it 'reads a binary file into a node.js Buffer', (done) ->
+        return done() if typeof Buffer is 'undefined'
+        @xhr.addEventListener 'loadend', =>
+          buffer = @xhr.response
+          expect(buffer).to.be.instanceOf Buffer
+          bytes = (buffer.readUInt8(i) for i in [0...buffer.length])
+          expect(bytes).to.deep.equal xhr2PngBytes
+          done()
+        @xhr.open 'GET', @imageUrl
+        @xhr.responseType = 'buffer'
+        @xhr.send()

package/node_modules/xhr2/test/src/send_test.coffee

@@ -0,0 +1,89 @@
+describe 'XMLHttpRequest', ->
+  describe '#send', ->
+    beforeEach ->
+      @xhr = new XMLHttpRequest
+      @xhr.open 'POST', 'http://localhost:8912/_/echo'
+
+      @arrayBuffer = new ArrayBuffer xhr2PngBytes.length
+      @arrayBufferView = new Uint8Array @arrayBuffer
+      if typeof Buffer is 'undefined'
+        @buffer = null
+      else
+        @buffer = Buffer.alloc xhr2PngBytes.length
+
+      for i in [0...xhr2PngBytes.length]
+        @arrayBufferView[i] = xhr2PngBytes[i]
+        @buffer.writeUInt8 xhr2PngBytes[i], i if @buffer
+
+    it 'works with ASCII DOMStrings', (done) ->
+      @xhr.onload = =>
+        expect(@xhr.getResponseHeader('content-type')).to.
+            match(/^text\/plain(;\s?charset=UTF-8)?$/)
+        expect(@xhr.responseText).to.equal 'Hello world!'
+        done()
+      @xhr.send "Hello world!"
+
+    it 'works with UTF-8 DOMStrings', (done) ->
+      @xhr.onloadend = =>
+        expect(@xhr.getResponseHeader('content-type')).to.
+            match(/^text\/plain(;\s?charset=UTF-8)?$/)
+        expect(@xhr.responseText).to.equal '世界你好!'
+        done()
+      @xhr.send '世界你好!'
+
+    it 'works with ArrayBufferViews', (done) ->
+      @xhr.responseType = 'arraybuffer'
+      @xhr.onload = =>
+        expect(@xhr.getResponseHeader('content-type')).to.equal null
+        responseView = new Uint8Array @xhr.response
+        responseBytes = (responseView[i] for i in [0...responseView.length])
+        expect(responseBytes).to.deep.equal xhr2PngBytes
+        done()
+      @xhr.send @arrayBufferView
+
+    it 'works with ArrayBufferViews with set index and length', (done) ->
+      @xhr.responseType = 'arraybuffer'
+      @xhr.onload = =>
+        expect(@xhr.getResponseHeader('content-type')).to.equal null
+        responseView = new Uint8Array @xhr.response
+        responseBytes = (responseView[i] for i in [0...responseView.length])
+        expect(responseBytes).to.deep.equal xhr2PngBytes[10...52]
+        done()
+      arrayBufferView10 = new Uint8Array @arrayBuffer, 10, 42
+      @xhr.send arrayBufferView10
+
+    it 'works with ArrayBuffers', (done) ->
+      @xhr.responseType = 'arraybuffer'
+      @xhr.onload = =>
+        expect(@xhr.getResponseHeader('content-type')).to.equal null
+        responseView = new Uint8Array @xhr.response
+        responseBytes = (responseView[i] for i in [0...responseView.length])
+        expect(responseBytes).to.deep.equal xhr2PngBytes
+        done()
+      @xhr.send @arrayBuffer
+
+    it 'works with node.js Buffers', (done) ->
+      return done() unless @buffer
+      # NOTE: using the same exact code as above, which is tested in a browser
+      @xhr.responseType = 'arraybuffer'
+      @xhr.onload = =>
+        expect(@xhr.getResponseHeader('content-type')).to.equal null
+        responseView = new Uint8Array @xhr.response
+        responseBytes = (responseView[i] for i in [0...responseView.length])
+        expect(responseBytes).to.deep.equal xhr2PngBytes
+        done()
+      @xhr.send @buffer
+
+    it 'sets POST headers correctly when given null data', (done) ->
+      @xhr.open 'POST', 'http://localhost:8912/_/headers'
+      @xhr.responseType = 'text'
+      @xhr.onload = =>
+        expect(@xhr.responseText).to.match(/^\{.*\}$/)
+        headers = JSON.parse @xhr.responseText
+        expect(headers).to.have.property 'content-length'
+        expect(headers['content-length']).to.equal '0'
+        expect(headers).not.to.have.property 'content-type'
+        done()
+      @xhr.send()
+
+

package/node_modules/xhr2/test/src/status_test.coffee

@@ -0,0 +1,47 @@
+describe 'XMLHttpRequest', ->
+  beforeEach ->
+    @xhr = new XMLHttpRequest
+    @okUrl = 'http://localhost:8912/test/fixtures/hello.txt'
+
+    @errorUrl = 'http://localhost:8912/_/response'
+    @errorJson = JSON.stringify
+        code: 401, status: 'Unauthorized',
+        body: JSON.stringify(error: 'Credential error'),
+        headers:
+          'Content-Type': 'application/json', 'Content-Length': '28'
+
+  describe '#status', ->
+    it 'is 200 for a normal request', (done) ->
+      @xhr.open 'GET', @okUrl
+      _done = false
+      @xhr.addEventListener 'readystatechange', =>
+        return if _done
+        if @xhr.readyState < XMLHttpRequest.HEADERS_RECEIVED
+          expect(@xhr.status).to.equal 0
+          expect(@xhr.statusText).to.equal ''
+        else
+          expect(@xhr.status).to.equal 200
+          expect(@xhr.statusText).to.be.ok
+          expect(@xhr.statusText).to.not.equal ''
+          if @xhr.readyState is XMLHttpRequest.DONE
+            _done = true
+            done()
+      @xhr.send()
+
+    it 'returns the server-reported status', (done) ->
+      @xhr.open 'POST', @errorUrl
+      _done = false
+      @xhr.addEventListener 'readystatechange', =>
+        return if _done
+        if @xhr.readyState < XMLHttpRequest.HEADERS_RECEIVED
+          expect(@xhr.status).to.equal 0
+          expect(@xhr.statusText).to.equal ''
+        else
+          expect(@xhr.status).to.equal 401
+          expect(@xhr.statusText).to.be.ok
+          expect(@xhr.statusText).to.not.equal ''
+          if @xhr.readyState is XMLHttpRequest.DONE
+            _done = true
+            done()
+      @xhr.send @errorJson
+