@openzeppelin/confidential-contracts 0.2.0-rc.2 → 0.3.0-rc.0

package/utils/FHESafeMath.sol

@@ -0,0 +1,72 @@
+// SPDX-License-Identifier: MIT
+// OpenZeppelin Confidential Contracts (last updated v0.3.0-rc.0) (utils/FHESafeMath.sol)
+pragma solidity ^0.8.24;
+
+import {FHE, ebool, euint64} from "@fhevm/solidity/lib/FHE.sol";
+
+/**
+ * @dev Library providing safe arithmetic operations for encrypted values
+ * to handle potential overflows in FHE operations.
+ */
+library FHESafeMath {
+    /**
+     * @dev Try to increase the encrypted value `oldValue` by `delta`. If the operation is successful,
+     * `success` will be true and `updated` will be the new value. Otherwise, `success` will be false
+     * and `updated` will be the original value.
+     */
+    function tryIncrease(euint64 oldValue, euint64 delta) internal returns (ebool success, euint64 updated) {
+        if (!FHE.isInitialized(oldValue)) {
+            return (FHE.asEbool(true), delta);
+        }
+        euint64 newValue = FHE.add(oldValue, delta);
+        success = FHE.ge(newValue, oldValue);
+        updated = FHE.select(success, newValue, oldValue);
+    }
+
+    /**
+     * @dev Try to decrease the encrypted value `oldValue` by `delta`. If the operation is successful,
+     * `success` will be true and `updated` will be the new value. Otherwise, `success` will be false
+     * and `updated` will be the original value.
+     */
+    function tryDecrease(euint64 oldValue, euint64 delta) internal returns (ebool success, euint64 updated) {
+        if (!FHE.isInitialized(oldValue)) {
+            if (!FHE.isInitialized(delta)) {
+                return (FHE.asEbool(true), oldValue);
+            }
+            return (FHE.eq(oldValue, delta), oldValue);
+        }
+        success = FHE.ge(oldValue, delta);
+        updated = FHE.select(success, FHE.sub(oldValue, delta), oldValue);
+    }
+
+    /**
+     * @dev Try to add `a` and `b`. If the operation is successful, `success` will be true and `res`
+     * will be the sum of `a` and `b`. Otherwise, `success` will be false, and `res` will be 0.
+     */
+    function tryAdd(euint64 a, euint64 b) internal returns (ebool success, euint64 res) {
+        if (!FHE.isInitialized(a)) {
+            return (FHE.asEbool(true), b);
+        }
+        if (!FHE.isInitialized(b)) {
+            return (FHE.asEbool(true), a);
+        }
+
+        euint64 sum = FHE.add(a, b);
+        success = FHE.ge(sum, a);
+        res = FHE.select(success, sum, FHE.asEuint64(0));
+    }
+
+    /**
+     * @dev Try to subtract `b` from `a`. If the operation is successful, `success` will be true and `res`
+     * will be `a - b`. Otherwise, `success` will be false, and `res` will be 0.
+     */
+    function trySub(euint64 a, euint64 b) internal returns (ebool success, euint64 res) {
+        if (!FHE.isInitialized(b)) {
+            return (FHE.asEbool(true), a);
+        }
+
+        euint64 difference = FHE.sub(a, b);
+        success = FHE.le(difference, a);
+        res = FHE.select(success, difference, FHE.asEuint64(0));
+    }
+}

package/utils/HandleAccessManager.sol

@@ -0,0 +1,29 @@
+// SPDX-License-Identifier: MIT
+// OpenZeppelin Confidential Contracts (last updated v0.2.0) (utils/HandleAccessManager.sol)
+pragma solidity ^0.8.24;
+
+import {Impl} from "@fhevm/solidity/lib/Impl.sol";
+
+abstract contract HandleAccessManager {
+    /**
+     * @dev Get handle access for the given handle `handle`. Access will be given to the
+     * account `account` with the given persistence flag.
+     *
+     * NOTE: This function call is gated by `msg.sender` and validated by the
+     * {_validateHandleAllowance} function.
+     */
+    function getHandleAllowance(bytes32 handle, address account, bool persistent) public virtual {
+        _validateHandleAllowance(handle);
+        if (persistent) {
+            Impl.allow(handle, account);
+        } else {
+            Impl.allowTransient(handle, account);
+        }
+    }
+
+    /**
+     * @dev Unimplemented function that must revert if the message sender is not allowed to call
+     * {getHandleAllowance} for the given handle.
+     */
+    function _validateHandleAllowance(bytes32 handle) internal view virtual;
+}

package/utils/structs/CheckpointsConfidential.sol

@@ -1,5 +1,5 @@
 // SPDX-License-Identifier: MIT
-// OpenZeppelin Confidential Contracts (last updated v0.2.0-rc.2) (utils/structs/CheckpointsConfidential.sol)
+// OpenZeppelin Confidential Contracts (last updated v0.2.0) (utils/structs/CheckpointsConfidential.sol)
 // This file was procedurally generated from scripts/generate/templates/CheckpointsConfidential.js.
 
 pragma solidity ^0.8.24;
@@ -18,11 +18,6 @@ import {Checkpoints} from "./temporary-Checkpoints.sol";
 library CheckpointsConfidential {
     using Checkpoints for Checkpoints.Trace256;
 
-    /**
-     * @dev A value was attempted to be inserted on a past checkpoint.
-     */
-    error CheckpointUnorderedInsertion();
-
     struct TraceEuint32 {
         Checkpoints.Trace256 _inner;
     }

package/utils/structs/temporary-Checkpoints.sol

@@ -1,6 +1,6 @@
 // SPDX-License-Identifier: MIT
-// OpenZeppelin Confidential Contracts (last updated v0.2.0-rc.2) (utils/structs/temporary-Checkpoints.sol)
-// OpenZeppelin Contracts (last updated v5.3.0) (utils/structs/Checkpoints.sol)
+// OpenZeppelin Confidential Contracts (last updated v0.3.0-rc.0) (utils/structs/temporary-Checkpoints.sol)
+// OpenZeppelin Contracts (last updated v5.4.0) (utils/structs/Checkpoints.sol)
 // This file was procedurally generated from scripts/generate/templates/Checkpoints.js.
 // WARNING: This file is temporary and will be deleted once the latest version of the file is released in v5.5.0 of @openzeppelin/contracts.
 

package/token/extensions/ConfidentialFungibleTokenVotes.sol

@@ -1,29 +0,0 @@
-// SPDX-License-Identifier: MIT
-// OpenZeppelin Confidential Contracts (last updated v0.2.0-rc.2) (token/extensions/ConfidentialFungibleTokenVotes.sol)
-pragma solidity ^0.8.27;
-
-import {euint64} from "@fhevm/solidity/lib/FHE.sol";
-import {VotesConfidential} from "./../../governance/utils/VotesConfidential.sol";
-import {ConfidentialFungibleToken} from "./../ConfidentialFungibleToken.sol";
-
-abstract contract ConfidentialFungibleTokenVotes is ConfidentialFungibleToken, VotesConfidential {
-    function confidentialTotalSupply()
-        public
-        view
-        virtual
-        override(VotesConfidential, ConfidentialFungibleToken)
-        returns (euint64)
-    {
-        return super.confidentialTotalSupply();
-    }
-
-    function _update(address from, address to, euint64 amount) internal virtual override returns (euint64 transferred) {
-        transferred = super._update(from, to, amount);
-
-        _transferVotingUnits(from, to, transferred);
-    }
-
-    function _getVotingUnits(address account) internal view virtual override returns (euint64) {
-        return confidentialBalanceOf(account);
-    }
-}

package/utils/TFHESafeMath.sol

@@ -1,37 +0,0 @@
-// SPDX-License-Identifier: MIT
-// OpenZeppelin Confidential Contracts (last updated v0.2.0-rc.2) (utils/TFHESafeMath.sol)
-pragma solidity ^0.8.24;
-
-import {FHE, ebool, euint64} from "@fhevm/solidity/lib/FHE.sol";
-
-/**
- * @dev Library providing safe arithmetic operations for encrypted values
- * to handle potential overflows in FHE operations.
- */
-library TFHESafeMath {
-    /**
-     * @dev Try to increase the encrypted value `oldValue` by `delta`. If the operation is successful,
-     * `success` will be true and `updated` will be the new value. Otherwise, `success` will be false
-     * and `updated` will be the original value.
-     */
-    function tryIncrease(euint64 oldValue, euint64 delta) internal returns (ebool success, euint64 updated) {
-        if (!FHE.isInitialized(oldValue)) {
-            success = FHE.asEbool(true);
-            updated = delta;
-        } else {
-            euint64 newValue = FHE.add(oldValue, delta);
-            success = FHE.ge(newValue, oldValue);
-            updated = FHE.select(success, newValue, oldValue);
-        }
-    }
-
-    /**
-     * @dev Try to decrease the encrypted value `oldValue` by `delta`. If the operation is successful,
-     * `success` will be true and `updated` will be the new value. Otherwise, `success` will be false
-     * and `updated` will be the original value.
-     */
-    function tryDecrease(euint64 oldValue, euint64 delta) internal returns (ebool success, euint64 updated) {
-        success = FHE.ge(oldValue, delta);
-        updated = FHE.select(success, FHE.sub(oldValue, delta), oldValue);
-    }
-}