@moralcode/qrcode-brightscript 0.1.0

package/LICENSE.txt

@@ -0,0 +1,21 @@
+MIT License
+
+Copyright (c) 2022 Paramount
+
+Permission is hereby granted, free of charge, to any person obtaining a copy
+of this software and associated documentation files (the "Software"), to deal
+in the Software without restriction, including without limitation the rights
+to use, copy, modify, merge, publish, distribute, sublicense, and/or sell
+copies of the Software, and to permit persons to whom the Software is
+furnished to do so, subject to the following conditions:
+
+The above copyright notice and this permission notice shall be included in all
+copies or substantial portions of the Software.
+
+THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS OR
+IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF MERCHANTABILITY,
+FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT. IN NO EVENT SHALL THE
+AUTHORS OR COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER
+LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE, ARISING FROM,
+OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE USE OR OTHER DEALINGS IN THE
+SOFTWARE.

package/README.md

@@ -0,0 +1,33 @@
+# QR-Code-generator-brightscript
+
+## Introduction:
+
+With this Library, adding a QR code to your Roku app is a simple as including this in your xml file: 
+
+\<qrCode text="https://www.paramountplus.com/" />
+
+## License
+
+Copyright (c) 2022 Paramount (MIT License)
+
+Permission is hereby granted, free of charge, to any person obtaining a copy
+of this software and associated documentation files (the "Software"), to deal
+in the Software without restriction, including without limitation the rights
+to use, copy, modify, merge, publish, distribute, sublicense, and/or sell
+copies of the Software, and to permit persons to whom the Software is
+furnished to do so, subject to the following conditions:
+
+The above copyright notice and this permission notice shall be included in all
+copies or substantial portions of the Software.
+
+THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS OR
+IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF MERCHANTABILITY,
+FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT. IN NO EVENT SHALL THE
+AUTHORS OR COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER
+LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE, ARISING FROM,
+OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE USE OR OTHER DEALINGS IN THE
+SOFTWARE.
+
+## Attribution
+
+This work, ["QR-Code-generator-brightscript"](https://github.com/paramount-engineering/QR-Code-generator-brightscript), is a derivative of ["QR Code generator"](https://github.com/nayuki/QR-Code-generator) by [Project Nayuki](https://www.nayuki.io/page/qr-code-generator-library), used under [MIT](https://choosealicense.com/licenses/mit/). ["QR-Code-generator-brightscript"](https://github.com/paramount-engineering/QR-Code-generator-brightscript) is licensed under [MIT](https://choosealicense.com/licenses/mit/) BY [Paramount](https://www.paramount.com).

package/package.json

@@ -0,0 +1,17 @@
+{
+  "name": "@moralcode/qrcode-brightscript",
+  "version": "0.1.0",
+  "description": "A Roku component that can generate QR codes",
+  "keywords": [
+    "ropm",
+    "roku",
+    "brightscript",
+    "brighterscript"
+  ],
+  "files": [
+    "src/**/*"
+  ],
+  "ropm": {
+    "rootDir": "src"
+  }
+}

package/src/components/qrCode/qrCode.brs

@@ -0,0 +1,201 @@
+'**************************************************************************************
+' QR Code generator library (Brightscript)
+' Copyright (c) Kevin Hoos.
+'**************************************************************************************
+' Ported from:
+' Copyright (c) Project Nayuki. (MIT License)
+' https://www.nayuki.io/page/qr-code-generator-library
+'
+' Permission is hereby granted, free of charge, to any person obtaining a copy of
+' this software and associated documentation files (the "Software"), to deal in
+' the Software without restriction, including without limitation the rights to
+' use, copy, modify, merge, publish, distribute, sublicense, and/or sell copies of
+' the Software, and to permit persons to whom the Software is furnished to do so,
+' subject to the following conditions:
+' - The above copyright notice and this permission notice shall be included in
+'   all copies or substantial portions of the Software.
+' - The Software is provided "as is", without warranty of any kind, express or
+'   implied, including but not limited to the warranties of merchantability,
+'   fitness for a particular purpose and noninfringement. In no event shall the
+'   authors or copyright holders be liable for any claim, damages or other
+'   liability, whether in an action of contract, tort or otherwise, arising from,
+'   out of or in connection with the Software or the use or other dealings in the
+'   Software.
+'**************************************************************************************
+
+
+'---- QR Code symbol class ----
+
+'**************************************************************************************
+' A QR Code symbol, which is a type of two-dimension barcode.
+' Invented by Denso Wave and described in the ISO/IEC 18004 standard.
+' Instances of this class represent an immutable square grid of dark and light cells.
+' The class provides static factory functions to create a QR Code from text or binary data.
+' The class covers the QR Code Model 2 specification, supporting all versions (sizes)
+' from 1 to 40, all 4 error correction levels, and 4 character encoding modes.
+'
+' Ways to create a QR Code object:
+' - High level: Take the payload data and call QrCode.encodeText() or QrCode.encodeBinary().
+' - Mid level: Custom-make the list of segments and call QrCode.encodeSegments().
+' - Low level: Custom-make the array of data codeword bytes (including
+'   segment headers and final padding, excluding error correction codewords),
+'   supply the appropriate version number, and call the QrCode() constructor.
+' (Note that all ways require supplying the desired error correction level.)
+'**************************************************************************************
+function QrCode()
+    this = {}
+    '-- Static factory functions (high level) --
+    this.encodeText = _qrCode_high_encodeText
+    this.encodeBinary = _qrCode_high_encodeBinary
+
+
+    '-- Static factory functions (mid level) --
+    this.encodeSegments = _qrCode_mid_encodeSegments
+
+
+    '-- Fields --
+
+    ' The width and height of this QR Code, measured in modules, between
+    ' 21 and 177 (inclusive). This is equal to version * 4 + 17.
+    this.size = 0
+
+    ' The index of the mask pattern used in this QR Code, which is between 0 and 7 (inclusive).
+    ' Even if a QR Code is created with automatic masking requested (mask = -1),
+    ' the resulting object still has a mask value between 0 and 7.
+    this.mask = -1
+
+    ' The modules of this QR Code (false = light, true = dark).
+    ' Immutable after constructor finishes. Accessed through getModule().
+    this.modules = []
+
+    ' Indicates function modules that are not subjected to masking. Discarded when constructor finishes.
+    this.isFunction = []
+
+
+    '-- Constructor (low level) and fields --
+    this.constructor = _qrCode_low_constructor
+
+
+    '-- Accessor methods --
+    this.getModule = _qrCode_low_getModule
+
+
+    '-- Private helper methods for constructor: Drawing function modules --
+    this.drawFunctionPatterns = _qrCode_draw_drawFunctionPatterns
+    this.drawFormatBits = _qrCode_draw_drawFormatBits
+    this.drawVersion = _qrCode_draw_drawVersion
+    this.drawFinderPattern = _qrCode_draw_drawFinderPattern
+    this.drawAlignmentPattern = _qrCode_draw_drawAlignmentPattern
+    this.setFunctionModule = _qrCode_draw_setFunctionModule
+
+
+    '-- Private helper methods for constructor: Codewords and masking --
+    this.addEccAndInterleave = _qrCode_mask_addEccAndInterleave
+    this.drawCodewords = _qrCode_mask_drawCodewords
+    this.applyMask = _qrCode_mask_applyMask
+    this.getPenaltyScore = _qrCode_mask_getPenaltyScore
+
+
+    '-- Private helper functions --
+    this.getAlignmentPatternPositions = _qrCode_help_getAlignmentPatternPositions
+    this.getNumRawDataModules = _qrCode_help_getNumRawDataModules
+    this.getNumDataCodewords = _qrCode_help_getNumDataCodewords
+    this.reedSolomonComputeDivisor = _qrCode_help_reedSolomonComputeDivisor
+    this.reedSolomonComputeRemainder = _qrCode_help_reedSolomonComputeRemainder
+    this.reedSolomonMultiply = _qrCode_help_reedSolomonMultiply
+    this.finderPenaltyCountPatterns = _qrCode_help_finderPenaltyCountPatterns
+    this.finderPenaltyTerminateAndCount = _qrCode_help_finderPenaltyTerminateAndCount
+    this.finderPenaltyAddHistory = _qrCode_help_finderPenaltyAddHistory
+
+    this.QrSegment = QrSegment()
+    this.Ecc = []
+    levels = ["LOW", "MEDIUM", "QUARTILE", "HIGH"]
+    for each level in levels
+        ecc = CreateObject("roSGNode", "QREcc")
+        ecc.level = level
+        this.Ecc.push(ecc)
+    next
+
+
+    '-- Constants and tables --
+
+    ' The minimum version number supported in the QR Code Model 2 standard.
+    this.MIN_VERSION = 1
+    ' The maximum version number supported in the QR Code Model 2 standard.
+    this.MAX_VERSION = 40
+
+    ' For use in getPenaltyScore(), when evaluating which mask is best.
+    this.PENALTY_N1 = 3
+    this.PENALTY_N2 = 3
+    this.PENALTY_N3 = 40
+    this.PENALTY_N4 = 10
+
+    this.ECC_CODEWORDS_PER_BLOCK = [
+        ' Version: (note that index 0 is for padding, and is set to an illegal value)
+        '0,  1,  2,  3,  4,  5,  6,  7,  8,  9, 10, 11, 12, 13, 14, 15, 16, 17, 18, 19, 20, 21, 22, 23, 24, 25, 26, 27, 28, 29, 30, 31, 32, 33, 34, 35, 36, 37, 38, 39, 40    Error correction level
+        [-1, 7, 10, 15, 20, 26, 18, 20, 24, 30, 18, 20, 24, 26, 30, 22, 24, 28, 30, 28, 28, 28, 28, 30, 30, 26, 28, 30, 30, 30, 30, 30, 30, 30, 30, 30, 30, 30, 30, 30, 30], ' Low
+        [-1, 10, 16, 26, 18, 24, 16, 18, 22, 22, 26, 30, 22, 22, 24, 24, 28, 28, 26, 26, 26, 26, 28, 28, 28, 28, 28, 28, 28, 28, 28, 28, 28, 28, 28, 28, 28, 28, 28, 28, 28], ' Medium
+        [-1, 13, 22, 18, 26, 18, 24, 18, 22, 20, 24, 28, 26, 24, 20, 30, 24, 28, 28, 26, 30, 28, 30, 30, 30, 30, 28, 30, 30, 30, 30, 30, 30, 30, 30, 30, 30, 30, 30, 30, 30], ' Quartile
+        [-1, 17, 28, 22, 16, 22, 28, 26, 26, 24, 28, 24, 28, 22, 24, 24, 30, 28, 28, 26, 28, 30, 24, 30, 30, 30, 30, 30, 30, 30, 30, 30, 30, 30, 30, 30, 30, 30, 30, 30, 30], ' High
+    ]
+
+    this.NUM_ERROR_CORRECTION_BLOCKS = [
+        ' Version: (note that index 0 is for padding, and is set to an illegal value)
+        '0, 1, 2, 3, 4, 5, 6, 7, 8, 9,10, 11, 12, 13, 14, 15, 16, 17, 18, 19, 20, 21, 22, 23, 24, 25, 26, 27, 28, 29, 30, 31, 32, 33, 34, 35, 36, 37, 38, 39, 40    Error correction level
+        [-1, 1, 1, 1, 1, 1, 2, 2, 2, 2, 4, 4, 4, 4, 4, 6, 6, 6, 6, 7, 8, 8, 9, 9, 10, 12, 12, 12, 13, 14, 15, 16, 17, 18, 19, 19, 20, 21, 22, 24, 25], ' Low
+        [-1, 1, 1, 1, 2, 2, 4, 4, 4, 5, 5, 5, 8, 9, 9, 10, 10, 11, 13, 14, 16, 17, 17, 18, 20, 21, 23, 25, 26, 28, 29, 31, 33, 35, 37, 38, 40, 43, 45, 47, 49], ' Medium
+        [-1, 1, 1, 2, 2, 4, 4, 6, 6, 8, 8, 8, 10, 12, 16, 12, 17, 16, 18, 21, 20, 23, 23, 25, 27, 29, 34, 34, 35, 38, 40, 43, 45, 48, 51, 53, 56, 59, 62, 65, 68], ' Quartile
+        [-1, 1, 1, 2, 4, 4, 4, 5, 6, 8, 8, 11, 11, 16, 16, 18, 16, 19, 21, 25, 25, 25, 34, 30, 32, 35, 37, 40, 42, 45, 48, 51, 54, 57, 60, 63, 66, 70, 74, 77, 81], ' High
+    ]
+
+    return this
+end function
+
+function onTextChanged(nodeEvent)
+    time = createObject("roTimespan")
+    text = nodeEvent.getData()
+    qr = QrCode()
+    ecl = getEcl()
+    qr.encodeText(text, ecl)
+    ba = CreateObject("roByteArray")
+    ba.FromAsciiString(text)
+    digest = CreateObject("roEVPDigest")
+    digest.Setup("sha1")
+    sha1 = digest.Process(ba)
+    renderCode(qr, "tmp:/" + sha1 + ".png")
+    ?"Time:", time.totalMilliseconds(), text
+end function
+
+function getEcl()
+    ecl = CreateObject("roSGNode", "QREcc")
+    ecl.level = "LOW"
+    if not isNullOrEmpty(m.top.ecl) then
+        ecl.level = uCase(m.top.ecl)
+    end if
+    return ecl
+end function
+
+sub renderCode(qr as object, filename as string)
+    border = m.top.border
+    pixel = m.top.pixel
+    lightColor = m.top.lightColor
+    darkColor = m.top.darkColor
+    size = qr.size
+    imageSide = ((border * 2) + size) * pixel
+
+    bm = CreateObject("roBitmap", { width: imageSide, height: imageSide, AlphaEnable: true })
+    if bm <> invalid then
+        bm.DrawRect(0, 0, imageSide, imageSide, lightColor)
+        for y = 0 to size - 1
+            for x = 0 to size - 1
+                if qr.modules[y][x] = 1 then
+                    bm.DrawRect((border + x) * pixel, (border + y) * pixel, pixel, pixel, darkColor)
+                end if
+            next
+        next
+        bm.Finish()
+        ba = bm.GetPng(0, 0, imageSide, imageSide)
+        ba.WriteFile(filename)
+        m.top.uri = filename
+    end if
+end sub

package/src/components/qrCode/qrCode.draw.brs

@@ -0,0 +1,126 @@
+'-- Private helper methods for constructor: Drawing function modules --
+
+' Reads this object's version field, and draws and marks all function modules.
+function _qrCode_draw_drawFunctionPatterns()
+    ' Draw horizontal and vertical timing patterns
+    for i = 0 to m.size - 1
+        m.setFunctionModule(6, i, i MOD 2 = 0)
+        m.setFunctionModule(i, 6, i MOD 2 = 0)
+    next
+
+    ' Draw 3 finder patterns (all corners except bottom right; overwrites some timing modules)
+    m.drawFinderPattern(3, 3)
+    m.drawFinderPattern(m.size - 4, 3)
+    m.drawFinderPattern(3, m.size - 4)
+
+    ' Draw numerous alignment patterns
+    alignPatPos = m.getAlignmentPatternPositions()
+    numAlign = alignPatPos.count()
+    for i = 0 to numAlign - 1
+        for j = 0 to numAlign - 1
+            ' Don't draw on the three finder corners
+            if (not ((i = 0) and (j = 0) or (i = 0) and (j = numAlign - 1) or (i = numAlign - 1) and (j = 0))) then
+                m.drawAlignmentPattern(alignPatPos[i], alignPatPos[j])
+            end if
+        next
+    next
+
+    ' Draw configuration data
+    m.drawFormatBits(0) ' Dummy mask value; overwritten later in the constructor
+    m.drawVersion()
+end function
+
+
+' Draws two copies of the format bits (with its own error correction code)
+' based on the given mask and this object's error correction level field.
+function _qrCode_draw_drawFormatBits(mask as integer)
+    ' Calculate error correction code and pack bits
+    data = m.errorCorrectionLevel.formatBits << 3 or mask ' errCorrLvl is uint2, mask is uint3
+    remain = data
+    for i = 0 to 9
+        remain = xor((remain << 1), (remain >> 9) * &h537)
+    next
+    bits = xor((data << 10 or remain), &h5412) ' uint15
+    assert(bits >> 15 = 0)
+
+    ' Draw first copy
+    for i = 0 to 5
+        m.setFunctionModule(8, i, getBit(bits, i))
+    next
+    m.setFunctionModule(8, 7, getBit(bits, 6))
+    m.setFunctionModule(8, 8, getBit(bits, 7))
+    m.setFunctionModule(7, 8, getBit(bits, 8))
+    for i = 9 to 14
+        m.setFunctionModule(14 - i, 8, getBit(bits, i))
+    next
+
+    ' Draw second copy
+    for i = 0 to 7
+        m.setFunctionModule(m.size - 1 - i, 8, getBit(bits, i))
+    next
+    for i = 8 to 14
+        m.setFunctionModule(8, m.size - 15 + i, getBit(bits, i))
+    next
+    m.setFunctionModule(8, m.size - 8, true) ' Always dark
+end function
+
+
+' Draws two copies of the version bits (with its own error correction code),
+' based on this object's version field, iff 7 <= version <= 40.
+function _qrCode_draw_drawVersion()
+    if (m.version < 7) then
+        return false
+    end if
+
+    ' Calculate error correction code and pack bits
+    remain = m.version ' version is uint6, in the range [7, 40]
+    for i = 0 to 11
+        remain = xor((remain << 1), (remain >> 11) * &h1F25)
+    next
+    bits = m.version << 12 or remain ' uint18
+    assert(bits >> 18 = 0)
+
+    ' Draw two copies
+    for i = 0 to 17
+        color = getBit(bits, i)
+        a = m.size - 11 + i MOD 3
+        b = floor(i / 3)
+        m.setFunctionModule(a, b, color)
+        m.setFunctionModule(b, a, color)
+    next
+end function
+
+
+' Draws a 9*9 finder pattern including the border separator,
+' with the center module at (x, y). Modules can be out of bounds.
+function _qrCode_draw_drawFinderPattern(x as integer, y as integer)
+    for dy = -4 to 4
+        for dx = -4 to 4
+            dist = max(abs(dx), abs(dy)) ' Chebyshev/infinity norm
+            xx = x + dx
+            yy = y + dy
+            if ((0 <= xx) and (xx < m.size) and (0 <= yy) and (yy < m.size)) then
+                m.setFunctionModule(xx, yy, (dist <> 2) and (dist <> 4))
+            end if
+        next
+    next
+end function
+
+
+' Draws a 5*5 alignment pattern, with the center module
+' at (x, y). All modules must be in bounds.
+function _qrCode_draw_drawAlignmentPattern(x as integer, y as integer)
+    for dy = -2 to 2
+        for dx = -2 to 2
+            m.setFunctionModule(x + dx, y + dy, max(abs(dx), abs(dy)) <> 1)
+        next
+    next
+end function
+
+
+' Sets the color of a module and marks it as a function module.
+' Only used by the constructor. Coordinates must be in bounds.
+function _qrCode_draw_setFunctionModule(x as integer, y as integer, isDark as boolean)
+    m.modules[y][x] = iif(isDark, 1, 0)
+    m.isFunction[y][x] = true
+end function

package/src/components/qrCode/qrCode.help.brs

@@ -0,0 +1,148 @@
+'-- Private helper functions --
+
+' Returns an ascending list of positions of alignment patterns for this version number.
+' Each position is in the range [0,177), and are used on both the x and y axes.
+' This could be implemented as lookup table of 40 variable-length lists of integers.
+function _qrCode_help_getAlignmentPatternPositions() as object
+    if (m.version = 1) then
+        return []
+    else
+        numAlign = floor(m.version / 7) + 2
+        stepSize = iif(m.version = 32, 26, ceil((m.version * 4 + 4) / (numAlign * 2 - 2)) * 2)
+        result = []
+        position = m.size - 7
+        while(result.count() < numAlign)
+            result.unshift(position)
+            position -= stepSize
+        end while
+        return result
+    end if
+end function
+
+
+' Returns the number of data bits that can be stored in a QR Code of the given version number, after
+' all function modules are excluded. This includes remainder bits, so it might not be a multiple of 8.
+' The result is in the range [208, 29648]. This could be implemented as a 40-entry lookup table.
+function _qrCode_help_getNumRawDataModules(ver as integer) as integer
+    if ((ver < m.MIN_VERSION) or (ver > m.MAX_VERSION)) then
+        throw("Version number out of range")
+    end if
+    result = (16 * ver + 128) * ver + 64
+    if (ver >= 2) then
+        numAlign = floor(ver / 7) + 2
+        result -= (25 * numAlign - 10) * numAlign - 55
+        if (ver >= 7) then
+            result -= 36
+        end if
+    end if
+    assert((208 <= result) and (result <= 29648))
+    return result
+end function
+
+
+' Returns the number of 8-bit data (i.e. not error correction) codewords contained in any
+' QR Code of the given version number and error correction level, with remainder bits discarded.
+' This stateless pure function could be implemented as a (40*4)-cell lookup table.
+function _qrCode_help_getNumDataCodewords(ver as integer, ecl as object) as integer
+    return floor(m.getNumRawDataModules(ver) / 8) - m.ECC_CODEWORDS_PER_BLOCK[ecl.ordinal][ver] * m.NUM_ERROR_CORRECTION_BLOCKS[ecl.ordinal][ver]
+end function
+
+
+' Returns a Reed-Solomon ECC generator polynomial for the given degree. This could be
+' implemented as a lookup table over all possible parameter values, instead of as an algorithm.
+function _qrCode_help_reedSolomonComputeDivisor(degree as integer) as object
+    if ((degree < 1) or (degree > 255)) then
+        throw("Degree out of range")
+    end if
+    ' Polynomial coefficients are stored from highest to lowest power, excluding the leading term which is always 1.
+    ' For example the polynomial x^3 + 255x^2 + 8x + 93 is stored as the uint8 array [255, 8, 93].
+    result = []
+    for i = 0 to degree - 2
+        result.push(0)
+    next
+    result.push(1) ' Start off with the monomial x^0
+
+    ' Compute the product polynomial (x - r^0) * (x - r^1) * (x - r^2) * ... * (x - r^{degree-1}),
+    ' and drop the highest monomial term which is always 1x^degree.
+    ' Note that r = 0x02, which is a generator element of this field GF(2^8/0x11D).
+    root = 1
+    for i = 0 to degree - 1
+        ' Multiply the current product by (x - r^i)
+        for j = 0 to result.count() - 1
+            result[j] = m.reedSolomonMultiply(result[j], root)
+            if (j + 1 < result.count()) then
+                result[j] = xor(result[j], result[j + 1])
+            end if
+        next
+        root = m.reedSolomonMultiply(root, &h02)
+    next
+    return result
+end function
+
+
+' Returns the Reed-Solomon error correction codeword for the given data and divisor polynomials.
+function _qrCode_help_reedSolomonComputeRemainder(data as object, divisor as object) as object
+    result = []
+    for each _d in divisor ' Prefix d with underscore to avoid unused variable warning
+        result.push(0)
+    next
+    for each b in data ' Polynomial division
+        factor = xor(b, result.shift())
+        result.push(0)
+        for i = 0 to divisor.count() - 1
+            coef = divisor[i]
+            res = result[i]
+            result[i] = xor(res, m.reedSolomonMultiply(coef, factor))
+        next
+    next
+    return result
+end function
+
+
+' Returns the product of the two given field elements modulo GF(2^8/0x11D). The arguments and result
+' are unsigned 8-bit integers. This could be implemented as a lookup table of 256*256 entries of uint8.
+function _qrCode_help_reedSolomonMultiply(x as integer, y as integer) as integer
+    if ((x >> 8 <> 0) or (y >> 8 <> 0)) then
+        throw("Byte out of range")
+    end if
+    ' Russian peasant multiplication
+    z = 0
+    for i = 7 to 0 step -1
+        z = xor((z << 1), ((z >> 7) * &h11D))
+        z = xor(z, ((y >> i) and 1) * x)
+    next
+    assert(z >> 8 = 0)
+    return z
+end function
+
+
+' Can only be called immediately after a light run is added, and
+' returns either 0, 1, or 2. A helper function for getPenaltyScore().
+function _qrCode_help_finderPenaltyCountPatterns(runHistory as object) as integer
+    n = runHistory[1]
+    assert(n <= m.size * 3)
+    core = iif((n > 0) and (runHistory[2] = n) and (runHistory[3] = n * 3) and (runHistory[4] = n) and (runHistory[5] = n), 1, 0)
+    return (core and iif(runHistory[0] >= n * 4, 1, 0) and iif(runHistory[6] >= n, 1, 0)) + (core and iif(runHistory[6] >= n * 4, 1, 0) and iif(runHistory[0] >= n, 1, 0))
+end function
+
+
+' Must be called at the end of a line (row or column) of modules. A helper function for getPenaltyScore().
+function _qrCode_help_finderPenaltyTerminateAndCount(currentRunColor as boolean, currentRunLength as integer, runHistory as object) as integer
+    if (currentRunColor) then ' Terminate dark run
+        m.finderPenaltyAddHistory(currentRunLength, runHistory)
+        currentRunLength = 0
+    end if
+    currentRunLength += m.size ' Add light border to final run
+    m.finderPenaltyAddHistory(currentRunLength, runHistory)
+    return m.finderPenaltyCountPatterns(runHistory)
+end function
+
+
+' Pushes the given value to the front and drops the last value. A helper function for getPenaltyScore().
+function _qrCode_help_finderPenaltyAddHistory(currentRunLength as integer, runHistory as object)
+    if (runHistory[0] = 0)
+        currentRunLength += m.size ' Add light border to initial run
+    end if
+    runHistory.pop()
+    runHistory.unshift(currentRunLength)
+end function

package/src/components/qrCode/qrCode.high.brs

@@ -0,0 +1,20 @@
+'-- Static factory functions (high level) --
+
+' Returns a QR Code representing the given Unicode text string at the given error correction level.
+' As a conservative upper bound, this function is guaranteed to succeed for strings that have 738 or fewer
+' Unicode code points (not UTF-16 code units) if the low error correction level is used. The smallest possible
+' QR Code version is automatically chosen for the output. The ECC level of the result may be higher than the
+' ecl argument if it can be done without increasing the version.
+function _qrCode_high_encodeText(text as string, ecl as object) as object
+    segs = m.QrSegment.makeSegments(text)
+    return m.encodeSegments(segs, ecl)
+end function
+
+' Returns a QR Code representing the given binary data at the given error correction level.
+' This function always encodes using the binary segment mode, not any text mode. The maximum number of
+' bytes allowed is 2953. The smallest possible QR Code version is automatically chosen for the output.
+' The ECC level of the result may be higher than the ecl argument if it can be done without increasing the version.
+function _qrCode_high_encodeBinary(data as object, ecl as object) as object
+    seg = m.QrSegment.makeBytes(data)
+    return m.encodeSegments([seg], ecl)
+end function

package/src/components/qrCode/qrCode.low.brs

@@ -0,0 +1,68 @@
+'-- Constructor (low level) and fields --
+
+' Creates a new QR Code with the given version number,
+' error correction level, data codeword bytes, and mask number.
+' This is a low - level API that most users should not use directly.
+' A mid - level API is the encodeSegments() function.
+function _qrCode_low_constructor(version as integer, errorCorrectionLevel as object, dataCodewords as object, msk as integer)
+    ' The version number of this QR Code, which is between 1 and 40 (inclusive).
+    ' This determines the size of this barcode.
+    m.version = version
+
+    ' The error correction level used in this QR Code.
+    m.errorCorrectionLevel = errorCorrectionLevel
+
+    ' Check scalar arguments
+    if ((version < m.MIN_VERSION) or (version > m.MAX_VERSION)) then
+        throw("Version value out of range")
+    end if
+    if ((msk < -1) or (msk > 7)) then
+        throw("Mask value out of range")
+    end if
+    m.size = version * 4 + 17
+
+    ' Initialize both grids to be size * size arrays of boolean false
+    for y = 0 to m.size - 1
+        m.modules[y] = []
+        m.isFunction[y] = []
+        for x = 0 to m.size - 1
+            m.modules[y][x] = 0 ' Initially all light
+            m.isFunction[y][x] = false
+        next
+    next
+
+    ' Compute ECC, draw modules
+    m.drawFunctionPatterns()
+    allCodewords = m.addEccAndInterleave(dataCodewords)
+    m.drawCodewords(allCodewords)
+
+    ' Do masking
+    if (msk = -1) then ' Automatically choose best mask
+        minPenalty = 1000000000
+        for i = 0 to 7
+            m.applyMask(i)
+            m.drawFormatBits(i)
+            penalty = m.getPenaltyScore()
+            if (penalty < minPenalty) then
+                msk = i
+                minPenalty = penalty
+            end if
+            m.applyMask(i) ' Undoes the mask due to XOR
+        next
+    end if
+    assert((0 <= msk) and (msk <= 7))
+    m.mask = msk
+    m.applyMask(msk) ' Apply the final choice of mask
+    m.drawFormatBits(msk) ' Overwrite old format bits
+
+    m.isFunction = []
+end function
+
+'-- Accessor methods --
+
+' Returns the color of the module (pixel) at the given coordinates, which is false
+' for light or true for dark. The top left corner has the coordinates (x = 0, y = 0).
+' if the given coordinates are out of bounds, then false (light) is returned.
+function _qrCode_low_getModule(x as integer, y as integer) as boolean
+    return (0 <= x) and (x < m.size) and (0 <= y) and (y < m.size) and m.modules[y][x]
+end function