@mathers101/react-native-render-rich-text 0.0.0-stage → 0.1.10

package/ios/utils/HeightUpdateUtils.h

@@ -0,0 +1,25 @@
+#pragma once
+#import "ENRMUIKit.h"
+#import <React/RCTUtils.h>
+#include <memory>
+#import <react/utils/ManagedObjectWrapper.h>
+
+/// Returns YES if the measured content height differs from the frame height
+/// Yoga assigned, comparing at physical-pixel granularity to avoid
+/// false positives from sub-pixel floating-point differences.
+static inline BOOL needsHeightUpdate(CGSize measuredSize, CGRect bounds)
+{
+  CGFloat scale = RCTScreenScale();
+  CGFloat assignedHeight = ceil(bounds.size.height * scale) / scale;
+  CGFloat measuredHeight = ceil(measuredSize.height * scale) / scale;
+  return assignedHeight != measuredHeight;
+}
+
+template <typename StateDataT, typename ConcreteStateT>
+inline void ENRMRequestHeightUpdate(std::shared_ptr<const ConcreteStateT> const &state, int &counter, id self)
+{
+  if (!state)
+    return;
+  counter++;
+  state->updateState(StateDataT(counter, facebook::react::wrapManagedObjectWeakly(self)));
+}

package/ios/utils/ImageRequestHeaderUtils.h

@@ -0,0 +1,35 @@
+#pragma once
+
+#import <Foundation/Foundation.h>
+
+#ifdef __cplusplus
+#include <vector>
+
+template <typename T>
+static bool ENRMImageRequestHeadersChanged(const std::vector<T> &oldHeaders, const std::vector<T> &newHeaders)
+{
+  if (newHeaders.size() != oldHeaders.size()) {
+    return true;
+  }
+  for (size_t i = 0; i < newHeaders.size(); i++) {
+    if (newHeaders[i].name != oldHeaders[i].name || newHeaders[i].value != oldHeaders[i].value) {
+      return true;
+    }
+  }
+  return false;
+}
+
+template <typename T>
+static NSDictionary<NSString *, NSString *> *_Nullable ENRMImageRequestHeadersFromProps(const std::vector<T> &headers)
+{
+  if (headers.empty()) {
+    return nil;
+  }
+  NSMutableDictionary<NSString *, NSString *> *result = [NSMutableDictionary dictionaryWithCapacity:headers.size()];
+  for (const auto &header : headers) {
+    result[@(header.name.c_str())] = @(header.value.c_str());
+  }
+  return [result copy];
+}
+
+#endif

package/ios/utils/LastElementUtils.h

@@ -0,0 +1,97 @@
+#pragma once
+#import "ENRMLinkPillAttachment.h"
+#import "ENRMUIKit.h"
+
+NS_ASSUME_NONNULL_BEGIN
+
+static NSString *const CodeBlockAttributeName = @"CodeBlock";
+static NSString *const CodeBlockIndentAttributeName = @"CodeBlockIndent";
+
+/**
+ * Returns YES when the last semantic block in the storage is a code block, ignoring any
+ * trailing newline spacers (e.g. codeBlockMarginBottom) that may follow it.
+ *
+ * Detection is based on the last non-newline character: if it sits inside a CodeBlock
+ * attribute run, the answer is YES regardless of what newlines come after.
+ *
+ * Use this in render-time cleanup paths (e.g. removeTrailingSpacing) that need to know
+ * "is the document ending with a code block?" before any trailing newlines have been trimmed.
+ * The stricter `isLastElementCodeBlock` would answer NO in that pre-trim state because
+ * the CodeBlock range hasn't yet been pushed to text.length.
+ */
+static inline BOOL isLastBlockACodeBlock(NSAttributedString *text)
+{
+  if (text.length == 0)
+    return NO;
+
+  NSRange lastContent = [text.string rangeOfCharacterFromSet:[[NSCharacterSet newlineCharacterSet] invertedSet]
+                                                     options:NSBackwardsSearch];
+  if (lastContent.location == NSNotFound)
+    return NO;
+
+  NSNumber *isCodeBlock = [text attribute:CodeBlockAttributeName atIndex:lastContent.location effectiveRange:nil];
+  return isCodeBlock.boolValue;
+}
+
+/**
+ * Stricter sibling of `isLastBlockACodeBlock`: requires both that the last non-newline
+ * character is inside a CodeBlock run AND that the CodeBlock range extends literally to
+ * text.length (i.e. no characters at all live after the code block).
+ *
+ * Used in the iOS measurement path (and the analogous drawing-compensation check) to
+ * decide whether to add `codeBlockPadding` to make up for iOS not measuring/drawing
+ * trailing newlines that carry custom minimum/maximum line heights.
+ *
+ * After `removeTrailingSpacing` runs, the bottom padding spacer is preserved together
+ * with a single trailing newline outside the code block range, so this returns NO and
+ * the compensation is skipped — the bottom padding spacer is no longer the trailing
+ * paragraph terminator, so iOS lays its line fragment out as part of usedRect normally.
+ * The check still exists as a safety net for unexpected storage shapes.
+ */
+static inline BOOL isLastElementCodeBlock(NSAttributedString *text)
+{
+  if (text.length == 0)
+    return NO;
+
+  NSRange lastContent = [text.string rangeOfCharacterFromSet:[[NSCharacterSet newlineCharacterSet] invertedSet]
+                                                     options:NSBackwardsSearch];
+  if (lastContent.location == NSNotFound)
+    return NO;
+
+  NSNumber *isCodeBlock = [text attribute:CodeBlockAttributeName atIndex:lastContent.location effectiveRange:nil];
+  if (!isCodeBlock.boolValue)
+    return NO;
+
+  NSRange codeBlockRange;
+  [text attribute:CodeBlockAttributeName atIndex:lastContent.location effectiveRange:&codeBlockRange];
+  return NSMaxRange(codeBlockRange) == text.length;
+}
+
+/**
+ * Checks if the last element in the attributed string is an image attachment.
+ * Used to compensate for iOS text attachment baseline spacing issues.
+ */
+static inline BOOL isLastElementImage(NSAttributedString *text)
+{
+  if (text.length == 0)
+    return NO;
+
+  NSRange lastContent = [text.string rangeOfCharacterFromSet:[[NSCharacterSet newlineCharacterSet] invertedSet]
+                                                     options:NSBackwardsSearch];
+  if (lastContent.location == NSNotFound)
+    return NO;
+
+  unichar lastChar = [text.string characterAtIndex:lastContent.location];
+  if (lastChar != 0xFFFC)
+    return NO;
+
+  id attachment = [text attribute:NSAttachmentAttributeName atIndex:lastContent.location effectiveRange:nil];
+#if !TARGET_OS_OSX
+  // A link pill sits on the text baseline like a word; it needs no image compensation.
+  if ([attachment isKindOfClass:[ENRMLinkPillAttachment class]])
+    return NO;
+#endif
+  return attachment != nil;
+}
+
+NS_ASSUME_NONNULL_END

package/ios/utils/LinkContextMenuUtils.h

@@ -0,0 +1,55 @@
+#pragma once
+
+#import "ENRMLinkContextMenus.h"
+#import <Foundation/Foundation.h>
+
+#ifdef __cplusplus
+#include <vector>
+
+// The `linkContextMenuItems` prop: link long-press menu items by URL pattern.
+
+template <typename T>
+static bool ENRMLinkContextMenuItemsChanged(const std::vector<T> &oldMenus, const std::vector<T> &newMenus)
+{
+  if (newMenus.size() != oldMenus.size()) {
+    return true;
+  }
+  for (size_t i = 0; i < newMenus.size(); i++) {
+    const auto &oldItems = oldMenus[i].items;
+    const auto &newItems = newMenus[i].items;
+    if (newMenus[i].pattern != oldMenus[i].pattern || newItems.size() != oldItems.size()) {
+      return true;
+    }
+    for (size_t j = 0; j < newItems.size(); j++) {
+      if (newItems[j].text != oldItems[j].text || newItems[j].icon != oldItems[j].icon ||
+          newItems[j].disabled != oldItems[j].disabled || newItems[j].destructive != oldItems[j].destructive) {
+        return true;
+      }
+    }
+  }
+  return false;
+}
+
+template <typename T>
+static NSArray<ENRMLinkContextMenuEntry *> *_Nonnull ENRMLinkContextMenuEntriesFromProps(const std::vector<T> &menus)
+{
+  NSMutableArray<ENRMLinkContextMenuEntry *> *entries = [NSMutableArray arrayWithCapacity:menus.size()];
+  for (const auto &menu : menus) {
+    NSMutableArray<ENRMLinkContextMenuItem *> *items = [NSMutableArray arrayWithCapacity:menu.items.size()];
+    for (const auto &source : menu.items) {
+      ENRMLinkContextMenuItem *item = [[ENRMLinkContextMenuItem alloc] init];
+      item.text = @(source.text.c_str());
+      item.icon = @(source.icon.c_str());
+      item.disabled = source.disabled;
+      item.destructive = source.destructive;
+      [items addObject:item];
+    }
+    ENRMLinkContextMenuEntry *entry = [[ENRMLinkContextMenuEntry alloc] init];
+    entry.pattern = @(menu.pattern.c_str());
+    entry.items = items;
+    [entries addObject:entry];
+  }
+  return entries;
+}
+
+#endif

package/ios/utils/LinkPillContentUtils.h

@@ -0,0 +1,46 @@
+#pragma once
+
+#import "StyleConfig.h"
+#import <Foundation/Foundation.h>
+
+#ifdef __cplusplus
+#import <React/RCTConversions.h>
+#include <vector>
+
+// The `linkPillContent` prop: per-link pill label and icon, keyed by exact URL.
+
+template <typename T>
+static bool ENRMLinkPillContentChanged(const std::vector<T> &oldContent, const std::vector<T> &newContent)
+{
+  if (newContent.size() != oldContent.size()) {
+    return true;
+  }
+  for (size_t i = 0; i < newContent.size(); i++) {
+    if (newContent[i].url != oldContent[i].url || newContent[i].label != oldContent[i].label ||
+        newContent[i].iconUri != oldContent[i].iconUri || newContent[i].iconTintColor != oldContent[i].iconTintColor) {
+      return true;
+    }
+  }
+  return false;
+}
+
+template <typename T>
+static NSDictionary<NSString *, LinkPillContent *> *_Nullable ENRMLinkPillContentFromProps(
+    const std::vector<T> &content)
+{
+  if (content.empty()) {
+    return nil;
+  }
+  NSMutableDictionary<NSString *, LinkPillContent *> *result =
+      [NSMutableDictionary dictionaryWithCapacity:content.size()];
+  for (const auto &entry : content) {
+    LinkPillContent *value = [[LinkPillContent alloc] init];
+    value.label = @(entry.label.c_str());
+    value.iconUri = @(entry.iconUri.c_str());
+    value.iconTintColor = entry.iconTintColor ? RCTUIColorFromSharedColor(entry.iconTintColor) : nil;
+    result[@(entry.url.c_str())] = value;
+  }
+  return [result copy];
+}
+
+#endif

package/ios/utils/LinkTapUtils.h

@@ -0,0 +1,56 @@
+#pragma once
+
+#import "ENRMUIKit.h"
+
+NS_ASSUME_NONNULL_BEGIN
+
+#ifdef __cplusplus
+extern "C" {
+#endif
+
+/// Returns the link URL at the tap location, or nil if no link was tapped.
+NSString *_Nullable linkURLAtTapLocation(ENRMPlatformTextView *textView, ENRMTapRecognizer *recognizer);
+
+/// Returns the original link URL at a point in text-view coordinates.
+NSString *_Nullable linkURLAtPoint(ENRMPlatformTextView *textView, CGPoint point);
+
+/// Returns the link URL at the given character range, or nil if none found.
+NSString *_Nullable linkURLAtRange(ENRMPlatformTextView *textView, NSRange characterRange);
+
+/// What the user sees the link at `index` as: its pill label, or its text. Nil when there is no link.
+NSString *_Nullable linkTitleAtIndex(NSAttributedString *text, NSUInteger index);
+
+/// Returns the tapped image as @{@"url": ..., @"altText": ...}, or nil if the
+/// tap did not land on an image. A linked image resolves to its link (the
+/// linkURL attribute wins), so this returns nil for it.
+NSDictionary<NSString *, NSString *> *_Nullable imageAtTapLocation(ENRMPlatformTextView *textView,
+                                                                   ENRMTapRecognizer *recognizer);
+
+/// Returns the tapped factoid's id, an empty string when the factoid has no id, or nil
+/// when the tap did not land on a factoid.
+NSString *_Nullable factoidIdAtTapLocation(ENRMPlatformTextView *textView, ENRMTapRecognizer *recognizer);
+
+/// Returns @{@"id": ..., @"label": ...} for the mention under the tap, or nil.
+NSDictionary<NSString *, NSString *> *_Nullable mentionAtTapLocation(ENRMPlatformTextView *textView,
+                                                                     ENRMTapRecognizer *recognizer);
+
+/// Returns @{@"id": ..., @"label": ...} for the mention under a point in text-view coordinates, or nil.
+NSDictionary<NSString *, NSString *> *_Nullable mentionAtPoint(ENRMPlatformTextView *textView, CGPoint point);
+
+/// Returns the tapped code block as @{@"code": ..., @"language": ...}, or nil if
+/// the tap did not land on a commonmark code block.
+NSDictionary<NSString *, NSString *> *_Nullable codeBlockAtTapLocation(ENRMPlatformTextView *textView,
+                                                                       ENRMTapRecognizer *recognizer);
+
+/// Returns YES if the point (in textView coordinates) is on a link or task list
+/// checkbox. When `includeImages` is YES, images also count as interactive
+/// (used to stop a parent press handler once `onImagePress` is enabled), and
+/// likewise `includeCodeBlock` for `onCodeBlockPress`.
+BOOL isPointOnInteractiveElement(ENRMPlatformTextView *textView, CGPoint point, BOOL includeImages,
+                                 BOOL includeCodeBlock);
+
+#ifdef __cplusplus
+}
+#endif
+
+NS_ASSUME_NONNULL_END

package/ios/utils/LinkTapUtils.m

@@ -0,0 +1,139 @@
+#import "LinkTapUtils.h"
+#import "ENRMLinkPillAttachment.h"
+#import "ENRMSpoilerTapUtils.h"
+#import "ENRMTextHitTest.h"
+#import "FactoidBackground.h"
+#import "MentionBackground.h"
+
+NSString *_Nullable linkURLAtTapLocation(ENRMPlatformTextView *textView, ENRMTapRecognizer *recognizer)
+{
+  NSUInteger characterIndex = ENRMCharacterIndexForTap(textView, recognizer);
+  if (characterIndex == NSNotFound)
+    return nil;
+
+  NSAttributedString *attrText = ENRMGetAttributedText(textView);
+  return [attrText attribute:@"linkURL" atIndex:characterIndex effectiveRange:NULL];
+}
+
+NSString *_Nullable linkURLAtPoint(ENRMPlatformTextView *textView, CGPoint point)
+{
+  NSUInteger index = ENRMCharacterIndexAtPoint(textView, point);
+  if (index == NSNotFound)
+    return nil;
+  return [ENRMGetAttributedText(textView) attribute:@"linkURL" atIndex:index effectiveRange:NULL];
+}
+
+NSString *_Nullable linkURLAtRange(ENRMPlatformTextView *textView, NSRange characterRange)
+{
+  NSAttributedString *attrText = ENRMGetAttributedText(textView);
+  if (characterRange.location >= attrText.length) {
+    return nil;
+  }
+  return [attrText attribute:@"linkURL" atIndex:characterRange.location effectiveRange:NULL];
+}
+
+NSString *_Nullable linkTitleAtIndex(NSAttributedString *text, NSUInteger index)
+{
+  if (index >= text.length)
+    return nil;
+#if !TARGET_OS_OSX
+  id attachment = [text attribute:NSAttachmentAttributeName atIndex:index effectiveRange:NULL];
+  if ([attachment isKindOfClass:ENRMLinkPillAttachment.class])
+    return ((ENRMLinkPillAttachment *)attachment).label;
+#endif
+  NSRange range;
+  id url = [text attribute:@"linkURL" atIndex:index longestEffectiveRange:&range inRange:NSMakeRange(0, text.length)];
+  return url ? [text.string substringWithRange:range] : nil;
+}
+
+NSDictionary<NSString *, NSString *> *_Nullable imageAtTapLocation(ENRMPlatformTextView *textView,
+                                                                   ENRMTapRecognizer *recognizer)
+{
+  NSUInteger characterIndex = ENRMCharacterIndexForTap(textView, recognizer);
+  if (characterIndex == NSNotFound)
+    return nil;
+
+  NSAttributedString *attrText = ENRMGetAttributedText(textView);
+  if ([attrText attribute:@"linkURL" atIndex:characterIndex effectiveRange:NULL] != nil)
+    return nil;
+
+  NSString *url = [attrText attribute:@"imageURL" atIndex:characterIndex effectiveRange:NULL];
+  if (!url)
+    return nil;
+
+  NSString *altText = [attrText attribute:@"imageAltText" atIndex:characterIndex effectiveRange:NULL];
+  return @{@"url" : url, @"altText" : altText ?: @""};
+}
+
+static NSDictionary<NSString *, NSString *> *_Nullable mentionAtIndex(NSAttributedString *attrText, NSUInteger characterIndex)
+{
+  if (characterIndex == NSNotFound || characterIndex >= attrText.length)
+    return nil;
+  if ([attrText attribute:MentionAttributeName atIndex:characterIndex effectiveRange:NULL] == nil)
+    return nil;
+
+  NSString *mentionId = [attrText attribute:MentionIdAttributeName atIndex:characterIndex effectiveRange:NULL] ?: @"";
+  NSString *label = [attrText attribute:MentionLabelAttributeName atIndex:characterIndex effectiveRange:NULL] ?: @"";
+  return @{@"id" : mentionId, @"label" : label};
+}
+
+NSDictionary<NSString *, NSString *> *_Nullable mentionAtTapLocation(ENRMPlatformTextView *textView,
+                                                                     ENRMTapRecognizer *recognizer)
+{
+  return mentionAtIndex(ENRMGetAttributedText(textView), ENRMCharacterIndexForTap(textView, recognizer));
+}
+
+NSDictionary<NSString *, NSString *> *_Nullable mentionAtPoint(ENRMPlatformTextView *textView, CGPoint point)
+{
+  return mentionAtIndex(ENRMGetAttributedText(textView), ENRMCharacterIndexAtPoint(textView, point));
+}
+
+NSString *_Nullable factoidIdAtTapLocation(ENRMPlatformTextView *textView, ENRMTapRecognizer *recognizer)
+{
+  NSUInteger characterIndex = ENRMCharacterIndexForTap(textView, recognizer);
+  if (characterIndex == NSNotFound)
+    return nil;
+
+  NSAttributedString *attrText = ENRMGetAttributedText(textView);
+  if (characterIndex >= attrText.length)
+    return nil;
+  if ([attrText attribute:FactoidAttributeName atIndex:characterIndex effectiveRange:NULL] == nil)
+    return nil;
+
+  NSString *factoidId = [attrText attribute:FactoidIdAttributeName atIndex:characterIndex effectiveRange:NULL];
+  return factoidId ?: @"";
+}
+
+NSDictionary<NSString *, NSString *> *_Nullable codeBlockAtTapLocation(ENRMPlatformTextView *textView,
+                                                                       ENRMTapRecognizer *recognizer)
+{
+  NSUInteger characterIndex = ENRMCharacterIndexForTap(textView, recognizer);
+  if (characterIndex == NSNotFound)
+    return nil;
+
+  NSAttributedString *attrText = ENRMGetAttributedText(textView);
+  NSString *code = [attrText attribute:@"codeBlockText" atIndex:characterIndex effectiveRange:NULL];
+  if (!code)
+    return nil;
+
+  NSString *language = [attrText attribute:@"codeBlockLanguage" atIndex:characterIndex effectiveRange:NULL];
+  return @{@"code" : code, @"language" : language ?: @""};
+}
+
+BOOL isPointOnInteractiveElement(ENRMPlatformTextView *textView, CGPoint point, BOOL includeImages,
+                                 BOOL includeCodeBlock)
+{
+  NSUInteger charIndex = ENRMCharacterIndexAtPoint(textView, point);
+  if (charIndex == NSNotFound)
+    return NO;
+
+  NSDictionary *attrs = [ENRMGetAttributedText(textView) attributesAtIndex:charIndex effectiveRange:NULL];
+  if (attrs[@"linkURL"] != nil || [attrs[@"TaskItem"] boolValue] || attrs[SpoilerAttributeName] != nil ||
+      attrs[FactoidAttributeName] != nil || attrs[MentionAttributeName] != nil)
+    return YES;
+
+  if (includeImages && attrs[@"imageURL"] != nil)
+    return YES;
+
+  return includeCodeBlock && attrs[@"codeBlockText"] != nil;
+}

package/ios/utils/ListMarkerDrawer.h

@@ -0,0 +1,15 @@
+#import "ENRMUIKit.h"
+#import <Foundation/Foundation.h>
+
+@class StyleConfig;
+
+@interface ListMarkerDrawer : NSObject
+
+- (instancetype)initWithConfig:(StyleConfig *)config;
+
+- (void)drawMarkersForGlyphRange:(NSRange)glyphsToShow
+                   layoutManager:(NSLayoutManager *)layoutManager
+                   textContainer:(NSTextContainer *)textContainer
+                         atPoint:(CGPoint)origin;
+
+@end