@makechart/viewer 0.0.0-stage → 0.0.2
This diff represents the content of publicly available package versions that have been released to one of the supported registries. The information contained in this diff is provided for informational purposes only and reflects changes between package versions as they appear in their respective public registries.
- package/CHANGELOG.md +29 -0
- package/LICENSE +21 -0
- package/README.md +104 -2
- package/bin/cli.js +114 -0
- package/lib/runner.js +64 -0
- package/lib/server.js +206 -0
- package/package.json +49 -4
- package/src/playground.ls +256 -0
- package/src/suite.ls +324 -0
- package/src/ui.ls +148 -0
- package/web/index.html +59 -0
- package/web/playground.html +85 -0
|
@@ -0,0 +1,256 @@
|
|
|
1
|
+
# mctest playground: 拿一張圖來玩. `mctest serve` 之後開 /playground
|
|
2
|
+
#
|
|
3
|
+
# - 資料與設定的起點直接取自 chart 的 test case ( test/index.ls ) 與 mod.sample, 不必另外準備
|
|
4
|
+
# - 選一個 case 就套用它的資料、config 與大小; 有 steps 的可以按「跑 steps」看動畫
|
|
5
|
+
# - 設定面板依 mod.config 自動產生 ( number / boolean / choice / color / format / text ),
|
|
6
|
+
# font / palette / quantity 沒有元件, palette 給幾組現成的
|
|
7
|
+
# - 資料用 CSV 編輯 ( raw ), binding 用 JSON. 動畫是真實時間, 不切 manual
|
|
8
|
+
|
|
9
|
+
$ = (s) -> document.querySelector s
|
|
10
|
+
el = (tag, attr = {}, txt) ->
|
|
11
|
+
n = document.createElement tag
|
|
12
|
+
for k, v of attr => n.setAttribute k, v
|
|
13
|
+
if txt? => n.textContent = txt
|
|
14
|
+
n
|
|
15
|
+
clone = (o) -> if o? => JSON.parse(JSON.stringify o) else o
|
|
16
|
+
wait = (ms) -> new Promise (res) -> setTimeout res, ms
|
|
17
|
+
|
|
18
|
+
pg = mctest.playground = {}
|
|
19
|
+
|
|
20
|
+
# ---------------------------------------------------------------- csv
|
|
21
|
+
# 只處理常見情形: 逗號分隔, 雙引號包住的欄位可以含逗號 / 換行 / "" 跳脫
|
|
22
|
+
csv =
|
|
23
|
+
parse: (s) ->
|
|
24
|
+
[rows, row, cur, q, i] = [[], [], '', false, 0]
|
|
25
|
+
while i < s.length
|
|
26
|
+
c = s[i]
|
|
27
|
+
if q =>
|
|
28
|
+
if c == '"' and s[i + 1] == '"' => cur += '"'; i++
|
|
29
|
+
else if c == '"' => q = false
|
|
30
|
+
else cur += c
|
|
31
|
+
else if c == '"' => q = true
|
|
32
|
+
else if c == ',' => row.push cur; cur = ''
|
|
33
|
+
else if c == '\n' or c == '\r' =>
|
|
34
|
+
if c == '\r' and s[i + 1] == '\n' => i++
|
|
35
|
+
row.push cur
|
|
36
|
+
rows.push row
|
|
37
|
+
[row, cur] = [[], '']
|
|
38
|
+
else cur += c
|
|
39
|
+
i++
|
|
40
|
+
if cur or row.length => row.push cur; rows.push row
|
|
41
|
+
rows.filter -> it.some (v) -> v.trim! != ''
|
|
42
|
+
cell: (v) ->
|
|
43
|
+
v = if v? => "#v" else ''
|
|
44
|
+
if /[",\n\r]/.exec(v) => "\"#{v.replace(/"/g, '""')}\"" else v
|
|
45
|
+
# rows ( 物件陣列 ) -> csv. 欄位取所有列的聯集, 依第一次出現的順序
|
|
46
|
+
from: (raw = []) ->
|
|
47
|
+
keys = []
|
|
48
|
+
raw.map (r) -> for k of r => if !(k in keys) => keys.push k
|
|
49
|
+
if !keys.length => return ''
|
|
50
|
+
([keys] ++ raw.map((r) -> keys.map (k) -> r[k])).map((r) -> r.map(csv.cell).join \,).join \\n
|
|
51
|
+
# csv -> rows. 看起來是數字的轉成數字, 空格留空字串
|
|
52
|
+
to: (s) ->
|
|
53
|
+
rows = csv.parse s
|
|
54
|
+
if !rows.length => return []
|
|
55
|
+
[head, ...body] = rows
|
|
56
|
+
body.map (r) ->
|
|
57
|
+
Object.fromEntries head.map (h, i) ->
|
|
58
|
+
v = (r[i] or '').trim!
|
|
59
|
+
[h.trim!, (if v != '' and !isNaN(+v) => +v else v)]
|
|
60
|
+
|
|
61
|
+
# ---------------------------------------------------------------- config panel
|
|
62
|
+
is-leaf = (o) -> o and typeof(o) == \object and typeof(o.type) == \string
|
|
63
|
+
defaults = (o) ->
|
|
64
|
+
ret = {}
|
|
65
|
+
for k, v of o =>
|
|
66
|
+
if is-leaf v => (if v.default? => ret[k] = clone v.default)
|
|
67
|
+
else if v and typeof(v) == \object => ret[k] = defaults v
|
|
68
|
+
ret
|
|
69
|
+
get-at = (o, path) -> path.reduce ((a, k) -> (a or {})[k]), o
|
|
70
|
+
patch-of = (path, v) ->
|
|
71
|
+
ret = p = {}
|
|
72
|
+
for k in path.slice(0, -1) => p = p[k] = {}
|
|
73
|
+
p[path[* - 1]] = v
|
|
74
|
+
ret
|
|
75
|
+
|
|
76
|
+
palettes =
|
|
77
|
+
"預設": null
|
|
78
|
+
tableau: <[#4e79a7 #f28e2b #e15759 #76b7b2 #59a14f #edc948 #b07aa1 #ff9da7 #9c755f #bab0ac]>
|
|
79
|
+
"冷色": <[#264653 #2a9d8f #8ab17d #457b9d #1d3557 #a8dadc]>
|
|
80
|
+
"暖色": <[#9b2226 #ae2012 #bb3e03 #ca6702 #ee9b00 #e9d8a6]>
|
|
81
|
+
|
|
82
|
+
control = (def, path) ->
|
|
83
|
+
v = get-at pg.chart.config!, path
|
|
84
|
+
row = el \div, {class: \row}
|
|
85
|
+
row.appendChild el(\label, {title: path.join(\.)}, path[* - 1])
|
|
86
|
+
c = row.appendChild el(\div, {class: \ctrl})
|
|
87
|
+
set = (v) -> pg.set path, v
|
|
88
|
+
switch def.type
|
|
89
|
+
| \number =>
|
|
90
|
+
[min, max, step] = [(def.min ? 0), (def.max ? Math.max(100, (v or 0) * 2)), (def.step ? 1)]
|
|
91
|
+
n = c.appendChild el(\input, {type: \range, min, max, step})
|
|
92
|
+
o = c.appendChild el(\span, {class: \v})
|
|
93
|
+
n.value = v ? min
|
|
94
|
+
o.textContent = n.value
|
|
95
|
+
n.oninput = -> o.textContent = n.value; set +n.value
|
|
96
|
+
| \boolean =>
|
|
97
|
+
n = c.appendChild el(\input, {type: \checkbox})
|
|
98
|
+
n.checked = !!v
|
|
99
|
+
n.onchange = -> set n.checked
|
|
100
|
+
| \choice =>
|
|
101
|
+
n = c.appendChild el(\select)
|
|
102
|
+
(def.values or []).map (o) ->
|
|
103
|
+
[val, name] = if o and typeof(o) == \object => [o.value, o.name] else [o, o]
|
|
104
|
+
n.appendChild el(\option, {value: JSON.stringify(val)}, name)
|
|
105
|
+
n.value = JSON.stringify v
|
|
106
|
+
n.onchange = -> set JSON.parse(n.value)
|
|
107
|
+
| \color =>
|
|
108
|
+
n = c.appendChild el(\input, {type: \color})
|
|
109
|
+
if /^#[0-9a-f]{6}$/i.exec(v or '') => n.value = v
|
|
110
|
+
n.oninput = -> set n.value
|
|
111
|
+
b = c.appendChild el(\button, {}, \預設)
|
|
112
|
+
b.onclick = -> set def.default
|
|
113
|
+
| \format, \text =>
|
|
114
|
+
n = c.appendChild el(\input, {type: \text})
|
|
115
|
+
n.value = v ? ''
|
|
116
|
+
n.onchange = -> set n.value
|
|
117
|
+
| otherwise => return null
|
|
118
|
+
row
|
|
119
|
+
|
|
120
|
+
# 群組攤平成一層 ( legend 寫完整路徑 ), 只有子群組、沒有直接設定項的群組不出現
|
|
121
|
+
build-panel = (o, path, root, fs) ->
|
|
122
|
+
subs = []
|
|
123
|
+
for k, v of o =>
|
|
124
|
+
p = path ++ [k]
|
|
125
|
+
if is-leaf v => (if fs and (r = control v, p) => fs.appendChild r)
|
|
126
|
+
else if v and typeof(v) == \object => subs.push [v, p]
|
|
127
|
+
if fs and fs.querySelector(\.row) => root.appendChild fs
|
|
128
|
+
for [v, p] in subs =>
|
|
129
|
+
g = el \fieldset
|
|
130
|
+
g.appendChild el(\legend, {}, p.join \.)
|
|
131
|
+
build-panel v, p, root, g
|
|
132
|
+
|
|
133
|
+
render-panel = ->
|
|
134
|
+
root = $ \#cfg
|
|
135
|
+
root.textContent = ''
|
|
136
|
+
row = root.appendChild el(\div, {class: \row})
|
|
137
|
+
row.appendChild el(\label, {}, \palette)
|
|
138
|
+
sel = row.appendChild(el \div, {class: \ctrl}).appendChild el(\select)
|
|
139
|
+
for k of palettes => sel.appendChild el(\option, {value: k}, k)
|
|
140
|
+
sel.onchange = ->
|
|
141
|
+
p = palettes[sel.value]
|
|
142
|
+
pg.set [\palette], (if p => {key: sel.value, colors: p} else null)
|
|
143
|
+
# 最上層的設定項放在沒有 legend 的那一組
|
|
144
|
+
build-panel pg.chart.mod.config, [], root, el(\fieldset)
|
|
145
|
+
|
|
146
|
+
# ---------------------------------------------------------------- chart
|
|
147
|
+
redraw = ->
|
|
148
|
+
c = pg.chart
|
|
149
|
+
c.parse!; c.bind!; c.resize!; c.render!
|
|
150
|
+
|
|
151
|
+
pg.set = (path, v) ->
|
|
152
|
+
pg.chart.config patch-of(path, v)
|
|
153
|
+
redraw!
|
|
154
|
+
|
|
155
|
+
# 設定整個換掉: 回到預設再套 cfg
|
|
156
|
+
pg.reset-config = (cfg = {}) ->
|
|
157
|
+
c = pg.chart
|
|
158
|
+
c.cfg = {}
|
|
159
|
+
c.config (mctest.merge defaults(c.mod.config), clone(cfg))
|
|
160
|
+
redraw!
|
|
161
|
+
render-panel!
|
|
162
|
+
|
|
163
|
+
pg.set-data = (d) ->
|
|
164
|
+
$(\#err).textContent = ''
|
|
165
|
+
pg.data = d = clone d
|
|
166
|
+
$(\#csv).value = csv.from d.raw
|
|
167
|
+
$(\#binding).value = JSON.stringify(d.binding or {}, null, 2)
|
|
168
|
+
pg.chart.set-raw (if d.subset? => d else {raw: d.raw, binding: d.binding, subset: null})
|
|
169
|
+
|
|
170
|
+
apply-editor = ->
|
|
171
|
+
$(\#err).textContent = ''
|
|
172
|
+
try
|
|
173
|
+
pg.data = {raw: csv.to($(\#csv).value), binding: JSON.parse($(\#binding).value or '{}')}
|
|
174
|
+
pg.chart.set-raw {raw: pg.data.raw, binding: pg.data.binding, subset: null}
|
|
175
|
+
catch e => $(\#err).textContent = String(e.message or e)
|
|
176
|
+
|
|
177
|
+
set-size = ([w, h]) -> $(\#stage).style <<< {width: "#{w}px", height: "#{h}px"}
|
|
178
|
+
|
|
179
|
+
# 資料來源: mod.sample, 各 suite 的 data. case: 不含 dash 的 test case
|
|
180
|
+
sources = ->
|
|
181
|
+
ret = []
|
|
182
|
+
if pg.chart.mod.sample => ret.push {name: "sample ( mod.sample )", get: -> pg.chart.mod.sample!}
|
|
183
|
+
for s in mctest.suites => for k, v of (s.data or {}) => let v
|
|
184
|
+
ret.push {name: "data: #k", get: -> clone(if typeof(v) == \function => v! else v)}
|
|
185
|
+
ret
|
|
186
|
+
|
|
187
|
+
case-data = (c) ->
|
|
188
|
+
s = c.suite
|
|
189
|
+
d = c.data or Object.keys(s.data or {}).0
|
|
190
|
+
if typeof(d) == \string => d = (s.data or {})[d]
|
|
191
|
+
if typeof(d) == \function => d = d!
|
|
192
|
+
clone d
|
|
193
|
+
|
|
194
|
+
pg.apply-case = (c) ->
|
|
195
|
+
set-size (c.size or c.suite.size)
|
|
196
|
+
pg.reset-config mctest.merge({}, clone(c.suite.config or {}), clone(c.config or {}))
|
|
197
|
+
if (d = case-data c) => pg.set-data d
|
|
198
|
+
$(\#steps).disabled = !c.steps
|
|
199
|
+
pg.case = c
|
|
200
|
+
|
|
201
|
+
# steps 拿到的 ctx 是簡化過的: snap 只是停一下讓人看得到那一格
|
|
202
|
+
pg.run-steps = ->
|
|
203
|
+
if !(c = pg.case and pg.case.steps) => return
|
|
204
|
+
c = [].concat c
|
|
205
|
+
ctx =
|
|
206
|
+
root: $(\#stage), wait: wait, random: mctest.random, drag: mctest.drag
|
|
207
|
+
snap: -> wait 800
|
|
208
|
+
capture: -> Promise.resolve!
|
|
209
|
+
c.reduce ((p, f) -> p.then(-> f pg.chart, ctx).then(-> wait 600)), Promise.resolve!
|
|
210
|
+
.catch (e) -> $(\#err).textContent = String(e.stack or e)
|
|
211
|
+
|
|
212
|
+
mctest.boot!
|
|
213
|
+
.then ->
|
|
214
|
+
$(\#target).textContent = "#{mctest.info.name}@#{mctest.info.version}"
|
|
215
|
+
document.title = "playground · #{mctest.info.name}"
|
|
216
|
+
mctest.manager.get {name: mctest.info.name, version: \main}
|
|
217
|
+
.then (bc) -> bc.create {data: {}}
|
|
218
|
+
.then (bi) -> bi.attach({root: $(\#stage)}).then -> bi.interface!
|
|
219
|
+
.then (chart) ->
|
|
220
|
+
pg.chart = window.chart = chart
|
|
221
|
+
# case 選單
|
|
222
|
+
sel = $ \#case
|
|
223
|
+
cases = mctest.cases.filter -> !it.dash and !it.skip
|
|
224
|
+
sel.appendChild el(\option, {value: ''}, "-- 選一個 case ( #{cases.length} ) --")
|
|
225
|
+
cases.map (c, i) -> sel.appendChild el(\option, {value: i}, c.name + (if c.steps => ' ▶' else ''))
|
|
226
|
+
sel.onchange = -> if sel.value != '' => pg.apply-case cases[+sel.value]
|
|
227
|
+
# 資料選單
|
|
228
|
+
src = $ \#source
|
|
229
|
+
list = sources!
|
|
230
|
+
src.appendChild el(\option, {value: ''}, "-- 換資料 ( 保留設定 ) --")
|
|
231
|
+
list.map (s, i) -> src.appendChild el(\option, {value: i}, s.name)
|
|
232
|
+
src.onchange = ->
|
|
233
|
+
if src.value == '' => return
|
|
234
|
+
try pg.set-data list[+src.value].get! catch e => $(\#err).textContent = String(e.stack or e)
|
|
235
|
+
src.value = ''
|
|
236
|
+
$(\#apply).onclick = apply-editor
|
|
237
|
+
$(\#steps).onclick = pg.run-steps
|
|
238
|
+
$(\#reset).onclick = -> pg.reset-config!
|
|
239
|
+
$(\#dump).onclick = ->
|
|
240
|
+
cfg = pg.chart.config!
|
|
241
|
+
console.log cfg
|
|
242
|
+
$(\#out).textContent = JSON.stringify cfg, null, 2
|
|
243
|
+
$(\#rerender).onclick = redraw
|
|
244
|
+
new ResizeObserver(->
|
|
245
|
+
b = $(\#stage).getBoundingClientRect!
|
|
246
|
+
$(\#size).textContent = "#{Math.round b.width} × #{Math.round b.height} · 拖右下角改大小"
|
|
247
|
+
).observe $(\#stage)
|
|
248
|
+
# 起點: 第一個 case, 沒有就用 sample
|
|
249
|
+
if cases.length => sel.value = 0; pg.apply-case cases.0
|
|
250
|
+
else
|
|
251
|
+
set-size [640, 400]
|
|
252
|
+
pg.reset-config!
|
|
253
|
+
if list.length => pg.set-data list.0.get!
|
|
254
|
+
.catch (e) ->
|
|
255
|
+
$(\#err).textContent = String(e.stack or e)
|
|
256
|
+
console.error e
|
package/src/suite.ls
ADDED
|
@@ -0,0 +1,324 @@
|
|
|
1
|
+
# mctest - makechart 圖表的 test suite engine ( 瀏覽器端 )
|
|
2
|
+
#
|
|
3
|
+
# chart 的 test/index.ls 用 `mctest.suite {...}` 宣告 case, engine 負責:
|
|
4
|
+
# - 每個 case 建一個新的 chart 實例 ( 或一個 @plotdb/dash board ), 套資料與設定, 跑 steps
|
|
5
|
+
# - 動畫一律切到 manual 再 flush 到終點, 所以輸出跟機器快慢無關
|
|
6
|
+
# - 把圖的 DOM 正規化成 markup ( 數字取到小數兩位、一個 tag 一行 ), 跟 test/snapshot 比對
|
|
7
|
+
#
|
|
8
|
+
# 一個 case:
|
|
9
|
+
# name 唯一的名字, 也是 snapshot 的檔名
|
|
10
|
+
# data suite.data 裡的名字, 或直接給 {raw, binding}
|
|
11
|
+
# config chart.config 的內容 ( 會跟 suite.config 深層合併 )
|
|
12
|
+
# size [w, h] px, 預設 suite.size
|
|
13
|
+
# steps [(chart, ctx) -> ...] 依序執行, 每步之後等畫面穩定. 可回傳 promise. 只有一步時可以不包成陣列
|
|
14
|
+
# ctx.snap(label) 等畫面穩定後多存一格 ( 預設只存最後的樣子 ); ctx.capture(label) 不等不 flush,
|
|
15
|
+
# 直接存當下 ( 配 chart.anim.step 驗證動畫中間格 ). ctx.root 是這個 case 的容器
|
|
16
|
+
# dash {def, size} 用 @plotdb/dash 的 board 跑多張圖 ( 測 crossfilter ).
|
|
17
|
+
# 此時 steps 拿到的是 (board, ctx), ctx.chart(id) 取得某個 panel 的圖
|
|
18
|
+
# skip true 時略過
|
|
19
|
+
#
|
|
20
|
+
# suite 層級: data, cases, config, size, chart ( 預設是 package.json 的 name ), normalize ( [[regexp, 取代字串]] ),
|
|
21
|
+
# tolerance ( 數字容許的誤差, 預設 1 ), quiet ( DOM 多久沒變算穩定, 預設 250ms ). 這兩個 case 也可以各自設
|
|
22
|
+
|
|
23
|
+
mctest = {cases: [], suites: []}
|
|
24
|
+
|
|
25
|
+
registry = ({url, name, version, path, type}) ->
|
|
26
|
+
if url => return url
|
|
27
|
+
if type == \block => return "/assets/lib/#name/#{version or \main}/#{path or \index.html}"
|
|
28
|
+
"/assets/lib/#name/#{version or \main}/#{path or (if type == \css => \index.min.css else \index.min.js)}"
|
|
29
|
+
|
|
30
|
+
mctest.manager = mgr = new block.manager {registry}
|
|
31
|
+
|
|
32
|
+
# ---------------------------------------------------------------- helpers
|
|
33
|
+
|
|
34
|
+
mctest.merge = merge = (a = {}, ...bs) ->
|
|
35
|
+
for b in bs => for k, v of (b or {}) =>
|
|
36
|
+
a[k] = if v and typeof(v) == \object and !Array.isArray(v) =>
|
|
37
|
+
merge (if a[k] and typeof(a[k]) == \object and !Array.isArray(a[k]) => a[k] else {}), v
|
|
38
|
+
else v
|
|
39
|
+
a
|
|
40
|
+
|
|
41
|
+
# 參數的所有組合: combo {type: <[column bar]>, multiple: <[stack group]>}
|
|
42
|
+
# -> [{type: \column, multiple: \stack}, ...] 共 4 組
|
|
43
|
+
mctest.combo = (o = {}) ->
|
|
44
|
+
ret = [{}]
|
|
45
|
+
for k, vs of o =>
|
|
46
|
+
nxt = []
|
|
47
|
+
for r in ret => for v in vs =>
|
|
48
|
+
c = {} <<< r
|
|
49
|
+
c[k] = v
|
|
50
|
+
nxt.push c
|
|
51
|
+
ret = nxt
|
|
52
|
+
ret
|
|
53
|
+
|
|
54
|
+
# 組合轉成名字: {type: \column, multiple: \stack} -> "type=column,multiple=stack"
|
|
55
|
+
mctest.label = (o = {}) -> ["#k=#v" for k, v of o].join \,
|
|
56
|
+
|
|
57
|
+
# 固定種子的亂數 ( 產生測試資料用, 每次都一樣 )
|
|
58
|
+
mctest.random = (seed = 1) ->
|
|
59
|
+
s = seed .>>>. 0
|
|
60
|
+
-> (s := (1664525 * s + 1013904223) .>>>. 0) / 4294967296
|
|
61
|
+
|
|
62
|
+
mctest.file = (n) -> n.replace /[^\w.=,+@-]+/g, \_
|
|
63
|
+
|
|
64
|
+
wait = (t = 0) -> new Promise (res) -> setTimeout res, t
|
|
65
|
+
|
|
66
|
+
# 模擬拖曳 ( 例如 brush ). p0 / p1 是 node 內的相對座標 ( 0 ~ 1 ).
|
|
67
|
+
# 跟真的滑鼠一樣 pointer 與 mouse 事件都送: chart.utils.brush 聽 pointer, d3-brush 聽 mouse
|
|
68
|
+
mctest.drag = (node, p0, p1, n = 6) ->
|
|
69
|
+
r = node.getBoundingClientRect!
|
|
70
|
+
# 座標取整: MouseEvent 的 clientX 是整數, PointerEvent 可以有小數, 不取整兩邊收到的位置會不一樣
|
|
71
|
+
pt = ([x, y]) -> {clientX: Math.round(r.left + r.width * x), clientY: Math.round(r.top + r.height * y)}
|
|
72
|
+
opt = {bubbles: true, cancelable: true, view: window, pointerId: 1, isPrimary: true, button: 0, buttons: 1}
|
|
73
|
+
fire = (target, type, p, extra = {}) ->
|
|
74
|
+
o = {} <<< opt <<< pt(p) <<< extra
|
|
75
|
+
target.dispatchEvent new PointerEvent "pointer#type", o
|
|
76
|
+
target.dispatchEvent new MouseEvent "mouse#type", o
|
|
77
|
+
fire node, \down, p0
|
|
78
|
+
for i from 1 to n =>
|
|
79
|
+
fire window, \move, [p0.0 + (p1.0 - p0.0) * i / n, p0.1 + (p1.1 - p0.1) * i / n]
|
|
80
|
+
fire window, \up, p1, {buttons: 0}
|
|
81
|
+
node.dispatchEvent new MouseEvent \click, ({bubbles: true, cancelable: true} <<< pt p1)
|
|
82
|
+
|
|
83
|
+
# ---------------------------------------------------------------- normalize
|
|
84
|
+
|
|
85
|
+
# 每次執行都會變的東西, 換成固定字串. 圖表若有自己的亂數 id, 在 suite.normalize 裡補
|
|
86
|
+
volatile = [
|
|
87
|
+
# ldview 的 scope 屬性名字是亂數
|
|
88
|
+
[/ld-scope-ld-[a-z0-9]+/g, \ld-scope-ld-x]
|
|
89
|
+
# @plotdb/csscope 的 scope 名稱是依賴的路徑編出來的 ( base64, _Q 開頭 ). 換依賴 ( 例如 d3 版換成 lite ) 就會變,
|
|
90
|
+
# 跟畫面無關, 拿掉
|
|
91
|
+
[/\s*\b_Q[A-Za-z0-9_]+/g, '']
|
|
92
|
+
# @plotdb/chart 的 legend id ( Math.random )
|
|
93
|
+
[/(pdlg-[a-z]+-)[a-z0-9]+(-)/g, '$1x$2']
|
|
94
|
+
]
|
|
95
|
+
|
|
96
|
+
# 顏色統一寫成 rgb(): d3 transition 補完會留下 rgb(...), 直接設的是 #hex - 同一個顏色不該算不同
|
|
97
|
+
hex-rgb = (m, h) ->
|
|
98
|
+
if h.length == 3 => h = h.split('').map(-> it + it).join('')
|
|
99
|
+
"rgb(#{parseInt(h.substr(0, 2), 16)}, #{parseInt(h.substr(2, 2), 16)}, #{parseInt(h.substr(4, 2), 16)})"
|
|
100
|
+
volatile.push [/#([0-9a-fA-F]{6}|[0-9a-fA-F]{3})\b(?![0-9a-fA-F])/g, hex-rgb]
|
|
101
|
+
|
|
102
|
+
# transform 統一寫法: d3 的 transform 補間會把結果重排成 translate(x,y) ( 逗號後沒空白 ), 恆等轉換則是空字串
|
|
103
|
+
norm-transform = (m, v) ->
|
|
104
|
+
v = v.replace(/\s*,\s*/g, ',').replace(/\(\s+/g, '(').replace(/\s+\)/g, ')').replace(/\s+/g, ' ').trim!
|
|
105
|
+
if /^translate\(0(,0)?\)$/.test(v) => v = ''
|
|
106
|
+
"transform=\"#v\""
|
|
107
|
+
volatile.push [/transform="([^"]*)"/g, norm-transform]
|
|
108
|
+
# rgb() / rgba() 統一成逗號後一個空白 ( d3 的寫法 )
|
|
109
|
+
volatile.push [/(rgba?)\(\s*([^)]*?)\s*\)/g, (m, f, v) -> "#f(#{v.split(/\s*,\s*/).join(', ')})"]
|
|
110
|
+
|
|
111
|
+
# DOM -> markup. 自己序列化而不用 innerHTML: 屬性依名字排序 ( 設定順序會隨執行順序變, 例如頁面上
|
|
112
|
+
# 第一張圖跟之後的不同 ), 一個 tag 一行方便 diff. 產生的 markup 可以直接塞回 innerHTML 重現畫面
|
|
113
|
+
void-tags = <[area base br col embed hr img input link meta source track wbr]>
|
|
114
|
+
esc-attr = (v) -> v.replace(/&/g, \&).replace(/"/g, \").replace(/</g, \<)
|
|
115
|
+
esc-text = (v) -> v.replace(/&/g, \&).replace(/</g, \<).replace(/>/g, \>)
|
|
116
|
+
mctest.serialize = serialize = (root) ->
|
|
117
|
+
out = []
|
|
118
|
+
walk = (n) ->
|
|
119
|
+
if n.nodeType == 3 =>
|
|
120
|
+
if (t = n.textContent.trim!) => out.push esc-text(t)
|
|
121
|
+
return
|
|
122
|
+
if n.nodeType != 1 => return
|
|
123
|
+
tag = n.tagName
|
|
124
|
+
if !n.namespaceURI or n.namespaceURI == "http://www.w3.org/1999/xhtml" => tag = tag.toLowerCase!
|
|
125
|
+
attrs = Array.from(n.attributes)
|
|
126
|
+
.map -> [it.name, it.value]
|
|
127
|
+
.sort (a, b) -> if a.0 < b.0 => -1 else if a.0 > b.0 => 1 else 0
|
|
128
|
+
.map ([k, v]) -> " #k=\"#{esc-attr v}\""
|
|
129
|
+
.join ''
|
|
130
|
+
out.push "<#tag#attrs>"
|
|
131
|
+
if tag in void-tags => return
|
|
132
|
+
Array.from(n.childNodes).map walk
|
|
133
|
+
out.push "</#tag>"
|
|
134
|
+
Array.from(root.childNodes).map walk
|
|
135
|
+
out.join \\n
|
|
136
|
+
|
|
137
|
+
# 數字取到小數兩位 ( 去掉尾端 0 )
|
|
138
|
+
mctest.normalize = normalize = (node, extra = []) ->
|
|
139
|
+
html = serialize node
|
|
140
|
+
for [re, v] in volatile ++ extra => html = html.replace re, v
|
|
141
|
+
html
|
|
142
|
+
.replace /-?\d+\.\d+(e-?\d+)?/g, (m) ->
|
|
143
|
+
v = +(+m).toFixed(2)
|
|
144
|
+
if v == 0 => \0 else String(v)
|
|
145
|
+
|
|
146
|
+
sep = (label) -> "<!-- mctest:snap #label -->"
|
|
147
|
+
mctest.join-snaps = (snaps) -> snaps.map((s) -> "#{sep s.label}\n#{s.markup}").join("\n")
|
|
148
|
+
mctest.split-snaps = (text) ->
|
|
149
|
+
ret = []
|
|
150
|
+
text.split(/^<!-- mctest:snap (.*?) -->$/m).slice(1).map (v, i, a) ->
|
|
151
|
+
if i % 2 == 0 => ret.push {label: v, markup: (a[i + 1] or '').trim!}
|
|
152
|
+
ret
|
|
153
|
+
|
|
154
|
+
# ---------------------------------------------------------------- settle
|
|
155
|
+
|
|
156
|
+
# 等畫面穩定: 有 anim 的圖直接 flush 到終點; 沒有的 ( 還在用 d3 transition ) 只能等.
|
|
157
|
+
# render 可能是 debounce / ResizeObserver 觸發的, 所以 flush 後要再看 markup 有沒有變
|
|
158
|
+
# 等到 DOM 連續 quiet ms 沒有變動才算穩定 ( 預設 250, 要比圖裡的 debounce 長 - 例如 bar 的 brush
|
|
159
|
+
# 150ms 後才發 filter, board 再重畫 ). 期間每一幀都 flush, 有 anim 的圖補間會直接跳到終點.
|
|
160
|
+
# list 是回傳目前所有圖的 function ( dash 的 panel 圖是非同步建立的, 每次都重抓 ),
|
|
161
|
+
# 新抓到的圖一律切 manual. 沒有 anim 的圖 ( 還在用 d3 transition ) 只能靠 quiet 等它跑完
|
|
162
|
+
settle = (root, list, quiet = 250, limit = 10000) ->
|
|
163
|
+
new Promise (res) ->
|
|
164
|
+
last = performance.now!
|
|
165
|
+
t0 = last
|
|
166
|
+
mo = new MutationObserver -> last := performance.now!
|
|
167
|
+
mo.observe root, {subtree: true, childList: true, attributes: true, characterData: true}
|
|
168
|
+
tick = ->
|
|
169
|
+
charts = list!filter -> it
|
|
170
|
+
charts.map ->
|
|
171
|
+
if !it.anim => return
|
|
172
|
+
if !it.anim._manual => it.anim.manual true
|
|
173
|
+
it.anim.flush!
|
|
174
|
+
now = performance.now!
|
|
175
|
+
if now - last >= quiet or now - t0 > limit =>
|
|
176
|
+
mo.disconnect!
|
|
177
|
+
return res!
|
|
178
|
+
requestAnimationFrame tick
|
|
179
|
+
requestAnimationFrame tick
|
|
180
|
+
|
|
181
|
+
# ---------------------------------------------------------------- suite
|
|
182
|
+
|
|
183
|
+
mctest.suite = (s = {}) ->
|
|
184
|
+
s.size = s.size or [480, 320]
|
|
185
|
+
mctest.suites.push s
|
|
186
|
+
([].concat(s.cases or [])).map (c) ->
|
|
187
|
+
mctest.cases.push ({} <<< c <<< {suite: s, file: mctest.file(c.name)})
|
|
188
|
+
s
|
|
189
|
+
|
|
190
|
+
get-data = (s, d) ->
|
|
191
|
+
if !d => d = Object.keys(s.data or {}).0
|
|
192
|
+
if typeof(d) == \string =>
|
|
193
|
+
if !(s.data and s.data[d]) => throw new Error("[mctest] unknown data `#d`")
|
|
194
|
+
d = s.data[d]
|
|
195
|
+
if typeof(d) == \function => d = d!
|
|
196
|
+
JSON.parse JSON.stringify d
|
|
197
|
+
|
|
198
|
+
chart-ref = (s) -> ({version: \main} <<< (s.chart or {name: mctest.info.name}))
|
|
199
|
+
|
|
200
|
+
make-chart = (s, root) ->
|
|
201
|
+
mgr.get chart-ref(s)
|
|
202
|
+
.then (bc) -> bc.create {data: {}}
|
|
203
|
+
.then (bi) -> bi.attach {root} .then -> bi.interface!
|
|
204
|
+
.then (chart) ->
|
|
205
|
+
if chart.anim => chart.anim.manual true
|
|
206
|
+
chart
|
|
207
|
+
|
|
208
|
+
load-dash = ->
|
|
209
|
+
if mctest._dash => return mctest._dash
|
|
210
|
+
base = "/assets/lib/@plotdb/dash/main/web/static"
|
|
211
|
+
mctest._dash = new Promise (res, rej) ->
|
|
212
|
+
css = document.createElement \link
|
|
213
|
+
css <<< {rel: \stylesheet, href: "#base/css/dash.css"}
|
|
214
|
+
document.head.appendChild css
|
|
215
|
+
js = document.createElement \script
|
|
216
|
+
js.src = "#base/js/dash.js"
|
|
217
|
+
js.onload = -> res window.dash
|
|
218
|
+
js.onerror = -> rej new Error("[mctest] @plotdb/dash not found - link it with `-l @plotdb/dash:<dir>`")
|
|
219
|
+
document.head.appendChild js
|
|
220
|
+
|
|
221
|
+
# 跑一個 case. root 是給它用的容器 ( 大小由這裡設 ). 回傳 {snaps, chart | board}
|
|
222
|
+
mctest.run-case = (c, root) ->
|
|
223
|
+
s = c.suite
|
|
224
|
+
[w, h] = c.size or (c.dash and c.dash.size) or s.size
|
|
225
|
+
root.style <<< {width: "#{w}px", height: "#{h}px"}
|
|
226
|
+
snaps = []
|
|
227
|
+
charts = []
|
|
228
|
+
list = -> charts
|
|
229
|
+
q = c.quiet ? s.quiet
|
|
230
|
+
ctx =
|
|
231
|
+
root: root
|
|
232
|
+
snap: (label) ->
|
|
233
|
+
settle(root, list, q).then -> snaps.push {label: (label or "step#{snaps.length}"), markup: normalize(root, s.normalize)}
|
|
234
|
+
# 不等穩定、不 flush, 直接存當下的樣子 ( 配合 chart.anim.step 驗證動畫的中間格 )
|
|
235
|
+
capture: (label) ->
|
|
236
|
+
snaps.push {label: (label or "frame#{snaps.length}"), markup: normalize(root, s.normalize)}
|
|
237
|
+
Promise.resolve!
|
|
238
|
+
drag: mctest.drag
|
|
239
|
+
wait: wait
|
|
240
|
+
random: mctest.random
|
|
241
|
+
run-steps = (target) ->
|
|
242
|
+
# 先等第一次畫完, step 才找得到節點
|
|
243
|
+
([].concat(c.steps or [])).reduce ((p, f) -> p.then(-> f target, ctx).then -> settle(root, list, q)), settle(root, list, q)
|
|
244
|
+
.then -> snaps.push {label: \final, markup: normalize(root, s.normalize)}
|
|
245
|
+
.then -> {snaps, target}
|
|
246
|
+
if c.dash => return load-dash!then (dash) ->
|
|
247
|
+
board = new dash.board do
|
|
248
|
+
root: root
|
|
249
|
+
manager: mgr
|
|
250
|
+
def: JSON.parse(JSON.stringify(c.dash.def))
|
|
251
|
+
panel: {name: "@plotdb/dash", version: \main, path: "web/static/initiative/1st/block/panel/0.0.1/index.html"}
|
|
252
|
+
ctx.chart = (id) -> ((board.panels.filter(-> it.id == id).0 or {}).itf or {}).chart
|
|
253
|
+
list := -> board.panels.map -> (it.itf or {}).chart
|
|
254
|
+
board.init!then -> settle root, list, q
|
|
255
|
+
.then -> run-steps board
|
|
256
|
+
make-chart s, root
|
|
257
|
+
.then (chart) ->
|
|
258
|
+
charts.push chart
|
|
259
|
+
cfg = merge {}, (s.config or {}), (c.config or {})
|
|
260
|
+
chart.config cfg
|
|
261
|
+
d = get-data s, c.data
|
|
262
|
+
chart.set-raw d.raw, d.binding
|
|
263
|
+
if d.subset => chart.subset.set d.subset
|
|
264
|
+
run-steps chart
|
|
265
|
+
|
|
266
|
+
# 跟 snapshot 比對. 回傳 {status, current, baseline, line, expect, actual, delta}
|
|
267
|
+
# - pass 完全相同
|
|
268
|
+
# - near 結構相同, 數字差都在 tolerance 內 ( 預設 1 ). 不同 DPR / 瀏覽器版本的文字寬度會有小數誤差,
|
|
269
|
+
# html 版面換算到 svg 的位置取整後就會差 1px - 這種不算壞掉, 但會標出來
|
|
270
|
+
# - diff 其他. line / expect / actual 是第一個不同的行
|
|
271
|
+
# - new 還沒有 snapshot
|
|
272
|
+
num = /-?\d+(?:\.\d+)?/g
|
|
273
|
+
near-line = (a, b, tol) ->
|
|
274
|
+
if a.replace(num, \#) != b.replace(num, \#) => return null
|
|
275
|
+
[na, nb] = [(a.match(num) or []), (b.match(num) or [])]
|
|
276
|
+
d = 0
|
|
277
|
+
for v, i in na => d >?= Math.abs(+v - +nb[i])
|
|
278
|
+
if d <= tol => d else null
|
|
279
|
+
|
|
280
|
+
mctest.compare = (c, snaps) ->
|
|
281
|
+
current = mctest.join-snaps snaps
|
|
282
|
+
tol = c.tolerance ? c.suite.tolerance ? 1
|
|
283
|
+
fetch "/api/snapshot/#{c.file}"
|
|
284
|
+
.then (r) -> if r.status == 204 => null else r.text!
|
|
285
|
+
.then (baseline) ->
|
|
286
|
+
if !(baseline?) => return {status: \new, current}
|
|
287
|
+
if baseline.trim! == current.trim! => return {status: \pass, current, baseline}
|
|
288
|
+
a = baseline.trim!split \\n
|
|
289
|
+
b = current.trim!split \\n
|
|
290
|
+
first = null
|
|
291
|
+
delta = 0
|
|
292
|
+
for i from 0 til Math.max(a.length, b.length) =>
|
|
293
|
+
if a[i] == b[i] => continue
|
|
294
|
+
if !(first?) => first = i
|
|
295
|
+
d = if a[i]? and b[i]? => near-line(a[i], b[i], tol) else null
|
|
296
|
+
if !(d?) => return {status: \diff, current, baseline, line: i + 1, expect: a[i], actual: b[i]}
|
|
297
|
+
delta >?= d
|
|
298
|
+
{status: \near, current, baseline, delta, line: first + 1, expect: a[first], actual: b[first]}
|
|
299
|
+
|
|
300
|
+
# 存 snapshot 一律交給 server 用 headless 重跑 ( 見 lib/runner.js ), 不存 UI 所在瀏覽器畫的版本
|
|
301
|
+
mctest.accept = (names) ->
|
|
302
|
+
fetch \/api/accept, {method: \POST, headers: {"Content-Type": "application/json"}, body: JSON.stringify({names})}
|
|
303
|
+
.then (r) -> if r.ok => r.json! else r.text!then -> throw new Error(it)
|
|
304
|
+
|
|
305
|
+
mctest.match = (c, grep, names) ->
|
|
306
|
+
if names => return c.name in names
|
|
307
|
+
if !grep or c.name.indexOf(grep) >= 0 => return true
|
|
308
|
+
try
|
|
309
|
+
new RegExp(grep).test c.name
|
|
310
|
+
catch e
|
|
311
|
+
false
|
|
312
|
+
|
|
313
|
+
mctest.boot = ->
|
|
314
|
+
mgr.init!
|
|
315
|
+
.then -> fetch \/api/info
|
|
316
|
+
.then (r) -> r.json!
|
|
317
|
+
.then (info) -> mctest.info = info
|
|
318
|
+
.then ->
|
|
319
|
+
new Promise (res, rej) ->
|
|
320
|
+
s = document.createElement \script
|
|
321
|
+
s <<< {src: \/test/index.js, onload: res, onerror: -> rej new Error("[mctest] load test/index.js failed")}
|
|
322
|
+
document.head.appendChild s
|
|
323
|
+
|
|
324
|
+
window.mctest = mctest
|