@lukso/lsp26-contracts 0.1.2

package/contracts/LSP26FollowerSystem.sol

@@ -0,0 +1,164 @@
+// SPDX-License-Identifier: Apache-2.0
+pragma solidity ^0.8.17;
+
+// interfaces
+import {ILSP26FollowerSystem} from "./ILSP26FollowerSystem.sol";
+import {
+    ILSP1UniversalReceiver
+} from "@lukso/lsp1-contracts/contracts/ILSP1UniversalReceiver.sol";
+
+// libraries
+import {
+    EnumerableSet
+} from "@openzeppelin/contracts/utils/structs/EnumerableSet.sol";
+import {
+    ERC165Checker
+} from "@openzeppelin/contracts/utils/introspection/ERC165Checker.sol";
+
+// constants
+import {
+    _TYPEID_LSP26_FOLLOW,
+    _TYPEID_LSP26_UNFOLLOW
+} from "./LSP26Constants.sol";
+import {
+    _INTERFACEID_LSP1
+} from "@lukso/lsp1-contracts/contracts/LSP1Constants.sol";
+
+// errors
+import {
+    LSP26CannotSelfFollow,
+    LSP26AlreadyFollowing,
+    LSP26NotFollowing
+} from "./LSP26Errors.sol";
+
+contract LSP26FollowerSystem is ILSP26FollowerSystem {
+    using EnumerableSet for EnumerableSet.AddressSet;
+    using ERC165Checker for address;
+
+    mapping(address => EnumerableSet.AddressSet) private _followersOf;
+    mapping(address => EnumerableSet.AddressSet) private _followingsOf;
+
+    // @inheritdoc ILSP26FollowerSystem
+    function follow(address addr) public {
+        _follow(addr);
+    }
+
+    // @inheritdoc ILSP26FollowerSystem
+    function followBatch(address[] memory addresses) public {
+        for (uint256 index = 0; index < addresses.length; ++index) {
+            _follow(addresses[index]);
+        }
+    }
+
+    // @inheritdoc ILSP26FollowerSystem
+    function unfollow(address addr) public {
+        _unfollow(addr);
+    }
+
+    // @inheritdoc ILSP26FollowerSystem
+    function unfollowBatch(address[] memory addresses) public {
+        for (uint256 index = 0; index < addresses.length; ++index) {
+            _unfollow(addresses[index]);
+        }
+    }
+
+    // @inheritdoc ILSP26FollowerSystem
+    function isFollowing(
+        address follower,
+        address addr
+    ) public view returns (bool) {
+        return _followingsOf[follower].contains(addr);
+    }
+
+    // @inheritdoc ILSP26FollowerSystem
+    function followerCount(address addr) public view returns (uint256) {
+        return _followersOf[addr].length();
+    }
+
+    // @inheritdoc ILSP26FollowerSystem
+    function followingCount(address addr) public view returns (uint256) {
+        return _followingsOf[addr].length();
+    }
+
+    // @inheritdoc ILSP26FollowerSystem
+    function getFollowsByIndex(
+        address addr,
+        uint256 startIndex,
+        uint256 endIndex
+    ) public view returns (address[] memory) {
+        uint256 sliceLength = endIndex - startIndex;
+
+        address[] memory followings = new address[](sliceLength);
+
+        for (uint256 index = 0; index < sliceLength; ++index) {
+            followings[index] = _followingsOf[addr].at(startIndex + index);
+        }
+
+        return followings;
+    }
+
+    // @inheritdoc ILSP26FollowerSystem
+    function getFollowersByIndex(
+        address addr,
+        uint256 startIndex,
+        uint256 endIndex
+    ) public view returns (address[] memory) {
+        uint256 sliceLength = endIndex - startIndex;
+
+        address[] memory followers = new address[](sliceLength);
+
+        for (uint256 index = 0; index < sliceLength; ++index) {
+            followers[index] = _followersOf[addr].at(startIndex + index);
+        }
+
+        return followers;
+    }
+
+    function _follow(address addr) internal {
+        if (msg.sender == addr) {
+            revert LSP26CannotSelfFollow();
+        }
+
+        bool isAdded = _followingsOf[msg.sender].add(addr);
+
+        if (!isAdded) {
+            revert LSP26AlreadyFollowing(addr);
+        }
+
+        _followersOf[addr].add(msg.sender);
+
+        emit Follow(msg.sender, addr);
+
+        if (addr.supportsERC165InterfaceUnchecked(_INTERFACEID_LSP1)) {
+            // solhint-disable no-empty-blocks
+            try
+                ILSP1UniversalReceiver(addr).universalReceiver(
+                    _TYPEID_LSP26_FOLLOW,
+                    abi.encodePacked(msg.sender)
+                )
+            {} catch {}
+        }
+    }
+
+    function _unfollow(address addr) internal {
+        bool isRemoved = _followingsOf[msg.sender].remove(addr);
+
+        if (!isRemoved) {
+            revert LSP26NotFollowing(addr);
+        }
+
+        _followersOf[addr].remove(msg.sender);
+
+        emit Unfollow(msg.sender, addr);
+
+        if (addr.supportsERC165InterfaceUnchecked(_INTERFACEID_LSP1)) {
+            // solhint-disable no-empty-blocks
+            try
+                ILSP1UniversalReceiver(addr).universalReceiver(
+                    _TYPEID_LSP26_UNFOLLOW,
+                    abi.encodePacked(msg.sender)
+                )
+            {} catch {}
+        }
+    }
+}

package/contracts/mock/InfiniteLoopURD.sol

@@ -0,0 +1,24 @@
+// SPDX-License-Identifier: Apache-2.0
+pragma solidity ^0.8.17;
+
+// interfaces
+import {
+    ILSP1UniversalReceiver
+} from "@lukso/lsp1-contracts/contracts/ILSP1UniversalReceiver.sol";
+
+contract InfiniteLoopURD is ILSP1UniversalReceiver {
+    uint256 public counter;
+
+    function supportsInterface(bytes4) external pure returns (bool) {
+        return true;
+    }
+
+    function universalReceiver(
+        bytes32,
+        bytes memory
+    ) external payable returns (bytes memory) {
+        while (true) {
+            ++counter;
+        }
+    }
+}

package/contracts/mock/ReturnBomb.sol

@@ -0,0 +1,26 @@
+// SPDX-License-Identifier: Apache-2.0
+pragma solidity ^0.8.17;
+
+// interfaces
+import {
+    ILSP1UniversalReceiver
+} from "@lukso/lsp1-contracts/contracts/ILSP1UniversalReceiver.sol";
+
+contract ReturnBomb is ILSP1UniversalReceiver {
+    uint256 public counter;
+
+    function supportsInterface(bytes4) external pure returns (bool) {
+        return true;
+    }
+
+    function universalReceiver(
+        bytes32,
+        bytes memory
+    ) external payable returns (bytes memory) {
+        ++counter;
+        // solhint-disable-next-line no-inline-assembly
+        assembly {
+            revert(0, 10000)
+        }
+    }
+}

package/contracts/mock/RevertOnFollow.sol

@@ -0,0 +1,20 @@
+// SPDX-License-Identifier: Apache-2.0
+pragma solidity ^0.8.17;
+
+// interfaces
+import {
+    ILSP1UniversalReceiver
+} from "@lukso/lsp1-contracts/contracts/ILSP1UniversalReceiver.sol";
+
+contract RevertOnFollow is ILSP1UniversalReceiver {
+    function supportsInterface(bytes4) external pure returns (bool) {
+        return true;
+    }
+
+    function universalReceiver(
+        bytes32,
+        bytes memory
+    ) external payable returns (bytes memory) {
+        revert("Block LSP1 notifications");
+    }
+}

package/contracts/mock/SelfDestructOnInterfaceCheck.sol

@@ -0,0 +1,23 @@
+// SPDX-License-Identifier: Apache-2.0
+pragma solidity ^0.8.17;
+
+// interfaces
+import {
+    ILSP1UniversalReceiver
+} from "@lukso/lsp1-contracts/contracts/ILSP1UniversalReceiver.sol";
+
+contract SelfDestructOnInterfaceCheck is ILSP1UniversalReceiver {
+    uint256 public counter;
+
+    function supportsInterface(bytes4) external returns (bool) {
+        selfdestruct(payable(msg.sender));
+        return true;
+    }
+
+    function universalReceiver(
+        bytes32,
+        bytes memory
+    ) external payable returns (bytes memory) {
+        return "";
+    }
+}

package/dist/index.cjs

@@ -0,0 +1,12 @@
+'use strict';
+
+const INTERFACE_ID_LSP26 = "0x2b299cea";
+const LSP26_TYPE_IDS = {
+  // keccak256('LSP26FollowerSystem_FollowNotification')
+  LSP26FollowerSystem_FollowNotification: "0x71e02f9f05bcd5816ec4f3134aa2e5a916669537ec6c77fe66ea595fabc2d51a",
+  // keccak256('LSP26FollowerSystem_UnfollowNotification')
+  LSP26FollowerSystem_UnfollowNotification: "0x9d3c0b4012b69658977b099bdaa51eff0f0460f421fba96d15669506c00d1c4f"
+};
+
+exports.INTERFACE_ID_LSP26 = INTERFACE_ID_LSP26;
+exports.LSP26_TYPE_IDS = LSP26_TYPE_IDS;

package/dist/index.d.cts

@@ -0,0 +1,7 @@
+declare const INTERFACE_ID_LSP26 = "0x2b299cea";
+declare const LSP26_TYPE_IDS: {
+    readonly LSP26FollowerSystem_FollowNotification: "0x71e02f9f05bcd5816ec4f3134aa2e5a916669537ec6c77fe66ea595fabc2d51a";
+    readonly LSP26FollowerSystem_UnfollowNotification: "0x9d3c0b4012b69658977b099bdaa51eff0f0460f421fba96d15669506c00d1c4f";
+};
+
+export { INTERFACE_ID_LSP26, LSP26_TYPE_IDS };

package/dist/index.d.mts

@@ -0,0 +1,7 @@
+declare const INTERFACE_ID_LSP26 = "0x2b299cea";
+declare const LSP26_TYPE_IDS: {
+    readonly LSP26FollowerSystem_FollowNotification: "0x71e02f9f05bcd5816ec4f3134aa2e5a916669537ec6c77fe66ea595fabc2d51a";
+    readonly LSP26FollowerSystem_UnfollowNotification: "0x9d3c0b4012b69658977b099bdaa51eff0f0460f421fba96d15669506c00d1c4f";
+};
+
+export { INTERFACE_ID_LSP26, LSP26_TYPE_IDS };

package/dist/index.d.ts

@@ -0,0 +1,7 @@
+declare const INTERFACE_ID_LSP26 = "0x2b299cea";
+declare const LSP26_TYPE_IDS: {
+    readonly LSP26FollowerSystem_FollowNotification: "0x71e02f9f05bcd5816ec4f3134aa2e5a916669537ec6c77fe66ea595fabc2d51a";
+    readonly LSP26FollowerSystem_UnfollowNotification: "0x9d3c0b4012b69658977b099bdaa51eff0f0460f421fba96d15669506c00d1c4f";
+};
+
+export { INTERFACE_ID_LSP26, LSP26_TYPE_IDS };

package/dist/index.mjs

@@ -0,0 +1,9 @@
+const INTERFACE_ID_LSP26 = "0x2b299cea";
+const LSP26_TYPE_IDS = {
+  // keccak256('LSP26FollowerSystem_FollowNotification')
+  LSP26FollowerSystem_FollowNotification: "0x71e02f9f05bcd5816ec4f3134aa2e5a916669537ec6c77fe66ea595fabc2d51a",
+  // keccak256('LSP26FollowerSystem_UnfollowNotification')
+  LSP26FollowerSystem_UnfollowNotification: "0x9d3c0b4012b69658977b099bdaa51eff0f0460f421fba96d15669506c00d1c4f"
+};
+
+export { INTERFACE_ID_LSP26, LSP26_TYPE_IDS };

package/package.json

@@ -0,0 +1,55 @@
+{
+  "name": "@lukso/lsp26-contracts",
+  "version": "0.1.2",
+  "description": "Package for the LSP26 Follower System standard",
+  "license": "Apache-2.0",
+  "author": "",
+  "main": "./dist/index.cjs",
+  "module": "./dist/index.mjs",
+  "typings": "./dist/index.d.ts",
+  "exports": {
+    ".": {
+      "require": "./dist/index.cjs",
+      "import": "./dist/index.mjs",
+      "types": "./dist/index.d.ts"
+    },
+    "./artifacts/*": "./artifacts/*",
+    "./package.json": "./package.json"
+  },
+  "keywords": [
+    "LUKSO",
+    "LSP",
+    "Blockchain",
+    "Standards",
+    "Smart Contracts",
+    "Ethereum",
+    "EVM",
+    "Solidity"
+  ],
+  "files": [
+    "contracts/**/*.sol",
+    "!contracts/Mocks/**/*.sol",
+    "artifacts/*.json",
+    "dist",
+    "types",
+    "!types/factories",
+    "./README.md"
+  ],
+  "scripts": {
+    "build": "hardhat compile --show-stack-traces",
+    "build:js": "unbuild",
+    "build:types": "npx wagmi generate",
+    "clean": "hardhat clean && rm -Rf dist/ cache/ node_modules/ .turbo/ types/ typechain/ build/ artifacts/",
+    "format": "prettier --write .",
+    "lint": "eslint . --ext .ts,.js",
+    "lint:solidity": "solhint 'contracts/**/*.sol' && prettier --check 'contracts/**/*.sol'",
+    "test": "hardhat test --no-compile tests/*.test.ts",
+    "test:coverage": "hardhat coverage",
+    "package": "hardhat prepare-package"
+  },
+  "dependencies": {
+    "@openzeppelin/contracts": "^4.9.6",
+    "@lukso/lsp0-contracts": "~0.15.0",
+    "@lukso/lsp1-contracts": "~0.15.0"
+  }
+}