@lukso/lsp23-contracts 0.15.0-rc.0

package/contracts/ILSP23LinkedContractsFactory.sol

@@ -0,0 +1,192 @@
+// SPDX-License-Identifier: Apache-2.0
+pragma solidity ^0.8.4;
+
+interface ILSP23LinkedContractsFactory {
+    /**
+     * @dev Emitted when a primary and secondary contract are deployed.
+     * @param primaryContract Address of the deployed primary contract.
+     * @param secondaryContract Address of the deployed secondary contract.
+     * @param primaryContractDeployment Parameters used for the primary contract deployment.
+     * @param secondaryContractDeployment Parameters used for the secondary contract deployment.
+     * @param postDeploymentModule Address of the post-deployment module.
+     * @param postDeploymentModuleCalldata Calldata passed to the post-deployment module.
+     */
+    event DeployedContracts(
+        address indexed primaryContract,
+        address indexed secondaryContract,
+        PrimaryContractDeployment primaryContractDeployment,
+        SecondaryContractDeployment secondaryContractDeployment,
+        address postDeploymentModule,
+        bytes postDeploymentModuleCalldata
+    );
+
+    /**
+     * @dev Emitted when proxies of a primary and secondary contract are deployed.
+     * @param primaryContract Address of the deployed primary contract proxy.
+     * @param secondaryContract Address of the deployed secondary contract proxy.
+     * @param primaryContractDeploymentInit Parameters used for the primary contract proxy deployment.
+     * @param secondaryContractDeploymentInit Parameters used for the secondary contract proxy deployment.
+     * @param postDeploymentModule Address of the post-deployment module.
+     * @param postDeploymentModuleCalldata Calldata passed to the post-deployment module.
+     */
+    event DeployedERC1167Proxies(
+        address indexed primaryContract,
+        address indexed secondaryContract,
+        PrimaryContractDeploymentInit primaryContractDeploymentInit,
+        SecondaryContractDeploymentInit secondaryContractDeploymentInit,
+        address postDeploymentModule,
+        bytes postDeploymentModuleCalldata
+    );
+
+    /**
+     * @param salt A unique value used to ensure each created proxies are unique (used for deterministic deployments).
+     * @param fundingAmount The value to be sent with the deployment transaction.
+     * @param creationBytecode The bytecode of the contract with the constructor params.
+     */
+    struct PrimaryContractDeployment {
+        bytes32 salt;
+        uint256 fundingAmount;
+        bytes creationBytecode;
+    }
+
+    /**
+     * @param fundingAmount The value to be sent with the deployment transaction.
+     * @param creationBytecode The bytecode for contract creation, up to but not including the primary contract address (if it needs to be appended).
+     * @param addPrimaryContractAddress If set to `true`, this will append the primary contract's address + the `extraConstructorParams` to the `creationBytecode`.
+     * @param extraConstructorParams Params to be appended to the `creationBytecode` (after the primary contract address) if `addPrimaryContractAddress` is set to `true`.
+     */
+    struct SecondaryContractDeployment {
+        uint256 fundingAmount;
+        bytes creationBytecode;
+        bool addPrimaryContractAddress;
+        bytes extraConstructorParams;
+    }
+
+    /**
+     * @param salt A unique value used to ensure each created proxies are unique. (Can be used to deploy the contract at a desired address.)
+     * @param fundingAmount The value to be sent with the deployment transaction.
+     * @param implementationContract The address of the contract that will be used as a base contract for the proxy.
+     * @param initializationCalldata The calldata used to initialize the contract.
+     */
+    struct PrimaryContractDeploymentInit {
+        bytes32 salt;
+        uint256 fundingAmount;
+        address implementationContract;
+        bytes initializationCalldata;
+    }
+
+    /**
+     * @param fundingAmount The value to be sent with the deployment transaction.
+     * @param implementationContract The address of the contract that will be used as a base contract for the proxy.
+     * @param initializationCalldata Initialization calldata up to, but not including, the primary contract address (if it needs to be appended).
+     * @param addPrimaryContractAddress If set to `true`, this will append the primary contract's address + the `extraInitializationParams` to the `initializationCalldata`.
+     * @param extraInitializationParams Params to be appended to the `initializationCalldata` (after the primary contract address) if `addPrimaryContractAddress` is set to `true`
+     */
+    struct SecondaryContractDeploymentInit {
+        uint256 fundingAmount;
+        address implementationContract;
+        bytes initializationCalldata;
+        bool addPrimaryContractAddress;
+        bytes extraInitializationParams;
+    }
+
+    /**
+     * @dev Deploys a primary and a secondary linked contract.
+     * @notice Contracts deployed. Contract Address: `primaryContractAddress`. Primary Contract Address: `primaryContractAddress`
+     *
+     * @param primaryContractDeployment Contains the needed parameter to deploy a contract. (`salt`, `fundingAmount`, `creationBytecode`)
+     * @param secondaryContractDeployment Contains the needed parameter to deploy the secondary contract. (`fundingAmount`, `creationBytecode`, `addPrimaryContractAddress`, `extraConstructorParams`)
+     * @param postDeploymentModule The optional module to be executed after deployment
+     * @param postDeploymentModuleCalldata The data to be passed to the post deployment module
+     *
+     * @return primaryContractAddress The address of the primary contract.
+     * @return secondaryContractAddress The address of the secondary contract.
+     */
+    function deployContracts(
+        PrimaryContractDeployment calldata primaryContractDeployment,
+        SecondaryContractDeployment calldata secondaryContractDeployment,
+        address postDeploymentModule,
+        bytes calldata postDeploymentModuleCalldata
+    )
+        external
+        payable
+        returns (
+            address primaryContractAddress,
+            address secondaryContractAddress
+        );
+
+    /**
+     * @dev Deploys ERC1167 proxies of a primary contract and a secondary linked contract
+     * @notice Contract proxies deployed. Primary Proxy Address: `primaryContractAddress`. Secondary Contract Proxy Address: `secondaryContractAddress`
+     *
+     * @param primaryContractDeploymentInit Contains the needed parameters to deploy a proxy contract. (`salt`, `fundingAmount`, `implementationContract`, `initializationCalldata`)
+     * @param secondaryContractDeploymentInit Contains the needed parameters to deploy the secondary proxy contract. (`fundingAmount`, `implementationContract`, `initializationCalldata`, `addPrimaryContractAddress`, `extraInitializationParams`)
+     * @param postDeploymentModule The optional module to be executed after deployment.
+     * @param postDeploymentModuleCalldata The data to be passed to the post deployment module.
+     *
+     * @return primaryContractAddress The address of the deployed primary contract proxy
+     * @return secondaryContractAddress The address of the deployed secondary contract proxy
+     */
+    function deployERC1167Proxies(
+        PrimaryContractDeploymentInit calldata primaryContractDeploymentInit,
+        SecondaryContractDeploymentInit
+            calldata secondaryContractDeploymentInit,
+        address postDeploymentModule,
+        bytes calldata postDeploymentModuleCalldata
+    )
+        external
+        payable
+        returns (
+            address primaryContractAddress,
+            address secondaryContractAddress
+        );
+
+    /**
+     * @dev Computes the addresses of a primary contract and a secondary linked contract
+     *
+     * @param primaryContractDeployment Contains the needed parameter to deploy the primary contract. (`salt`, `fundingAmount`, `creationBytecode`)
+     * @param secondaryContractDeployment Contains the needed parameter to deploy the secondary contract. (`fundingAmount`, `creationBytecode`, `addPrimaryContractAddress`, `extraConstructorParams`)
+     * @param postDeploymentModule The optional module to be executed after deployment
+     * @param postDeploymentModuleCalldata The data to be passed to the post deployment module
+     *
+     * @return primaryContractAddress The address of the deployed primary contract.
+     * @return secondaryContractAddress The address of the deployed secondary contract.
+     */
+    function computeAddresses(
+        PrimaryContractDeployment calldata primaryContractDeployment,
+        SecondaryContractDeployment calldata secondaryContractDeployment,
+        address postDeploymentModule,
+        bytes calldata postDeploymentModuleCalldata
+    )
+        external
+        view
+        returns (
+            address primaryContractAddress,
+            address secondaryContractAddress
+        );
+
+    /**
+     * @dev Computes the addresses of a primary and a secondary linked contracts ERC1167 proxies to be created
+     *
+     * @param primaryContractDeploymentInit Contains the needed parameters to deploy a primary proxy contract. (`salt`, `fundingAmount`, `implementationContract`, `initializationCalldata`)
+     * @param secondaryContractDeploymentInit Contains the needed parameters to deploy the secondary proxy contract. (`fundingAmount`, `implementationContract`, `initializationCalldata`, `addPrimaryContractAddress`, `extraInitializationParams`)
+     * @param postDeploymentModule The optional module to be executed after deployment.
+     * @param postDeploymentModuleCalldata The data to be passed to the post deployment module.
+     *
+     * @return primaryContractAddress The address of the deployed primary contract proxy
+     * @return secondaryContractAddress The address of the deployed secondary contract proxy
+     */
+    function computeERC1167Addresses(
+        PrimaryContractDeploymentInit calldata primaryContractDeploymentInit,
+        SecondaryContractDeploymentInit
+            calldata secondaryContractDeploymentInit,
+        address postDeploymentModule,
+        bytes calldata postDeploymentModuleCalldata
+    )
+        external
+        view
+        returns (
+            address primaryContractAddress,
+            address secondaryContractAddress
+        );
+}

package/contracts/IPostDeploymentModule.sol

@@ -0,0 +1,18 @@
+// SPDX-License-Identifier: Apache-2.0
+pragma solidity ^0.8.4;
+
+interface IPostDeploymentModule {
+    /**
+     * @dev Executes post-deployment logic for the primary and secondary contracts.
+     * @notice This function can be used to perform any additional setup or configuration after the primary and secondary contracts have been deployed.
+     *
+     * @param primaryContract The address of the deployed primary contract.
+     * @param secondaryContract The address of the deployed secondary contract.
+     * @param calldataToPostDeploymentModule Calldata to be passed for the post-deployment execution.
+     */
+    function executePostDeployment(
+        address primaryContract,
+        address secondaryContract,
+        bytes calldata calldataToPostDeploymentModule
+    ) external;
+}

package/contracts/LSP23Errors.sol

@@ -0,0 +1,24 @@
+// SPDX-License-Identifier: Apache-2.0
+pragma solidity ^0.8.4;
+
+/**
+ * @dev Reverts when the `msg.value` sent is not equal to the sum of value used for the deployment of the contract & its owner contract.
+ * @notice Invalid value sent.
+ */
+error InvalidValueSum();
+
+/**
+ * @dev Reverts when the deployment & intialization of the contract has failed.
+ * @notice Failed to deploy & initialize the Primary Contract Proxy. Error: `errorData`.
+ *
+ * @param errorData Potentially information about why the deployment & intialization have failed.
+ */
+error PrimaryContractProxyInitFailureError(bytes errorData);
+
+/**
+ * @dev Reverts when the deployment & intialization of the secondary contract has failed.
+ * @notice Failed to deploy & initialize the Secondary Contract Proxy. Error: `errorData`.
+ *
+ * @param errorData Potentially information about why the deployment & intialization have failed.
+ */
+error SecondaryContractProxyInitFailureError(bytes errorData);

package/contracts/LSP23LinkedContractsFactory.sol

@@ -0,0 +1,396 @@
+// SPDX-License-Identifier: Apache-2.0
+pragma solidity ^0.8.4;
+
+import {Create2} from "@openzeppelin/contracts/utils/Create2.sol";
+import {Clones} from "@openzeppelin/contracts/proxy/Clones.sol";
+import {IPostDeploymentModule} from "./IPostDeploymentModule.sol";
+import {ILSP23LinkedContractsFactory} from "./ILSP23LinkedContractsFactory.sol";
+import {
+    InvalidValueSum,
+    PrimaryContractProxyInitFailureError,
+    SecondaryContractProxyInitFailureError
+} from "./LSP23Errors.sol";
+
+contract LSP23LinkedContractsFactory is ILSP23LinkedContractsFactory {
+    /**
+     * @inheritdoc ILSP23LinkedContractsFactory
+     */
+    function deployContracts(
+        PrimaryContractDeployment calldata primaryContractDeployment,
+        SecondaryContractDeployment calldata secondaryContractDeployment,
+        address postDeploymentModule,
+        bytes calldata postDeploymentModuleCalldata
+    )
+        public
+        payable
+        override
+        returns (
+            address primaryContractAddress,
+            address secondaryContractAddress
+        )
+    {
+        /* check that the msg.value is equal to the sum of the values of the primary and secondary contracts */
+        if (
+            msg.value !=
+            primaryContractDeployment.fundingAmount +
+                secondaryContractDeployment.fundingAmount
+        ) {
+            revert InvalidValueSum();
+        }
+
+        primaryContractAddress = _deployPrimaryContract(
+            primaryContractDeployment,
+            secondaryContractDeployment,
+            postDeploymentModule,
+            postDeploymentModuleCalldata
+        );
+
+        secondaryContractAddress = _deploySecondaryContract(
+            secondaryContractDeployment,
+            primaryContractAddress
+        );
+
+        emit DeployedContracts(
+            primaryContractAddress,
+            secondaryContractAddress,
+            primaryContractDeployment,
+            secondaryContractDeployment,
+            postDeploymentModule,
+            postDeploymentModuleCalldata
+        );
+
+        /* execute the post deployment logic in the postDeploymentModule if postDeploymentModule is not address(0) */
+        if (postDeploymentModule != address(0)) {
+            /* execute the post deployment module logic in the postDeploymentModule */
+            IPostDeploymentModule(postDeploymentModule).executePostDeployment(
+                primaryContractAddress,
+                secondaryContractAddress,
+                postDeploymentModuleCalldata
+            );
+        }
+    }
+
+    /**
+     * @inheritdoc ILSP23LinkedContractsFactory
+     */
+    function deployERC1167Proxies(
+        PrimaryContractDeploymentInit calldata primaryContractDeploymentInit,
+        SecondaryContractDeploymentInit
+            calldata secondaryContractDeploymentInit,
+        address postDeploymentModule,
+        bytes calldata postDeploymentModuleCalldata
+    )
+        public
+        payable
+        override
+        returns (
+            address primaryContractAddress,
+            address secondaryContractAddress
+        )
+    {
+        /* check that the msg.value is equal to the sum of the values of the primary and secondary contracts */
+        if (
+            msg.value !=
+            primaryContractDeploymentInit.fundingAmount +
+                secondaryContractDeploymentInit.fundingAmount
+        ) {
+            revert InvalidValueSum();
+        }
+
+        /* deploy the primary contract proxy with the primaryContractGeneratedSalt */
+        primaryContractAddress = _deployAndInitializePrimaryContractProxy(
+            primaryContractDeploymentInit,
+            secondaryContractDeploymentInit,
+            postDeploymentModule,
+            postDeploymentModuleCalldata
+        );
+
+        /* deploy the secondary contract proxy */
+        secondaryContractAddress = _deployAndInitializeSecondaryContractProxy(
+            secondaryContractDeploymentInit,
+            primaryContractAddress
+        );
+
+        emit DeployedERC1167Proxies(
+            primaryContractAddress,
+            secondaryContractAddress,
+            primaryContractDeploymentInit,
+            secondaryContractDeploymentInit,
+            postDeploymentModule,
+            postDeploymentModuleCalldata
+        );
+
+        /* execute the post deployment logic in the postDeploymentModule if postDeploymentModule is not address(0) */
+        if (postDeploymentModule != address(0)) {
+            /* execute the post deployment logic in the postDeploymentModule */
+            IPostDeploymentModule(postDeploymentModule).executePostDeployment(
+                primaryContractAddress,
+                secondaryContractAddress,
+                postDeploymentModuleCalldata
+            );
+        }
+    }
+
+    /**
+     * @inheritdoc ILSP23LinkedContractsFactory
+     */
+    function computeAddresses(
+        PrimaryContractDeployment calldata primaryContractDeployment,
+        SecondaryContractDeployment calldata secondaryContractDeployment,
+        address postDeploymentModule,
+        bytes calldata postDeploymentModuleCalldata
+    )
+        public
+        view
+        override
+        returns (
+            address primaryContractAddress,
+            address secondaryContractAddress
+        )
+    {
+        bytes32 primaryContractGeneratedSalt = _generatePrimaryContractSalt(
+            primaryContractDeployment,
+            secondaryContractDeployment,
+            postDeploymentModule,
+            postDeploymentModuleCalldata
+        );
+
+        primaryContractAddress = Create2.computeAddress(
+            primaryContractGeneratedSalt,
+            keccak256(primaryContractDeployment.creationBytecode)
+        );
+
+        bytes memory secondaryContractByteCodeWithAllParams;
+        if (secondaryContractDeployment.addPrimaryContractAddress) {
+            secondaryContractByteCodeWithAllParams = abi.encodePacked(
+                secondaryContractDeployment.creationBytecode,
+                abi.encode(primaryContractAddress),
+                secondaryContractDeployment.extraConstructorParams
+            );
+        } else {
+            secondaryContractByteCodeWithAllParams = secondaryContractDeployment
+                .creationBytecode;
+        }
+
+        secondaryContractAddress = Create2.computeAddress(
+            keccak256(abi.encodePacked(primaryContractAddress)),
+            keccak256(secondaryContractByteCodeWithAllParams)
+        );
+    }
+
+    /**
+     * @inheritdoc ILSP23LinkedContractsFactory
+     */
+    function computeERC1167Addresses(
+        PrimaryContractDeploymentInit calldata primaryContractDeploymentInit,
+        SecondaryContractDeploymentInit
+            calldata secondaryContractDeploymentInit,
+        address postDeploymentModule,
+        bytes calldata postDeploymentModuleCalldata
+    )
+        public
+        view
+        override
+        returns (
+            address primaryContractAddress,
+            address secondaryContractAddress
+        )
+    {
+        bytes32 primaryContractGeneratedSalt = _generatePrimaryContractProxySalt(
+                primaryContractDeploymentInit,
+                secondaryContractDeploymentInit,
+                postDeploymentModule,
+                postDeploymentModuleCalldata
+            );
+
+        primaryContractAddress = Clones.predictDeterministicAddress(
+            primaryContractDeploymentInit.implementationContract,
+            primaryContractGeneratedSalt
+        );
+
+        secondaryContractAddress = Clones.predictDeterministicAddress(
+            secondaryContractDeploymentInit.implementationContract,
+            keccak256(abi.encodePacked(primaryContractAddress))
+        );
+    }
+
+    function _deployPrimaryContract(
+        PrimaryContractDeployment calldata primaryContractDeployment,
+        SecondaryContractDeployment calldata secondaryContractDeployment,
+        address postDeploymentModule,
+        bytes calldata postDeploymentModuleCalldata
+    ) internal returns (address primaryContractAddress) {
+        bytes32 primaryContractGeneratedSalt = _generatePrimaryContractSalt(
+            primaryContractDeployment,
+            secondaryContractDeployment,
+            postDeploymentModule,
+            postDeploymentModuleCalldata
+        );
+
+        /* deploy the primary contract */
+        primaryContractAddress = Create2.deploy(
+            primaryContractDeployment.fundingAmount,
+            primaryContractGeneratedSalt,
+            primaryContractDeployment.creationBytecode
+        );
+    }
+
+    function _deploySecondaryContract(
+        SecondaryContractDeployment calldata secondaryContractDeployment,
+        address primaryContractAddress
+    ) internal returns (address secondaryContractAddress) {
+        /**
+         * If `addPrimaryContractAddress` is `true`, the following will be appended to the constructor params:
+         * - The primary contract address
+         * - `extraConstructorParams`
+         */
+        bytes memory secondaryContractByteCode = secondaryContractDeployment
+            .creationBytecode;
+
+        if (secondaryContractDeployment.addPrimaryContractAddress) {
+            secondaryContractByteCode = abi.encodePacked(
+                secondaryContractByteCode,
+                abi.encode(primaryContractAddress),
+                secondaryContractDeployment.extraConstructorParams
+            );
+        }
+
+        secondaryContractAddress = Create2.deploy(
+            secondaryContractDeployment.fundingAmount,
+            keccak256(abi.encodePacked(primaryContractAddress)),
+            secondaryContractByteCode
+        );
+    }
+
+    function _deployAndInitializePrimaryContractProxy(
+        PrimaryContractDeploymentInit calldata primaryContractDeploymentInit,
+        SecondaryContractDeploymentInit
+            calldata secondaryContractDeploymentInit,
+        address postDeploymentModule,
+        bytes calldata postDeploymentModuleCalldata
+    ) internal returns (address primaryContractAddress) {
+        bytes32 primaryContractGeneratedSalt = _generatePrimaryContractProxySalt(
+                primaryContractDeploymentInit,
+                secondaryContractDeploymentInit,
+                postDeploymentModule,
+                postDeploymentModuleCalldata
+            );
+
+        /* deploy the primary contract proxy with the primaryContractGeneratedSalt */
+        primaryContractAddress = Clones.cloneDeterministic(
+            primaryContractDeploymentInit.implementationContract,
+            primaryContractGeneratedSalt
+        );
+
+        /* initialize the primary contract proxy */
+        (bool success, bytes memory returnedData) = primaryContractAddress.call{
+            value: primaryContractDeploymentInit.fundingAmount
+        }(primaryContractDeploymentInit.initializationCalldata);
+        if (!success) {
+            revert PrimaryContractProxyInitFailureError(returnedData);
+        }
+    }
+
+    function _deployAndInitializeSecondaryContractProxy(
+        SecondaryContractDeploymentInit
+            calldata secondaryContractDeploymentInit,
+        address primaryContractAddress
+    ) internal returns (address secondaryContractAddress) {
+        /* deploy the secondary contract proxy with the primaryContractGeneratedSalt */
+        secondaryContractAddress = Clones.cloneDeterministic(
+            secondaryContractDeploymentInit.implementationContract,
+            keccak256(abi.encodePacked(primaryContractAddress))
+        );
+
+        /**
+         * If `addPrimaryContractAddress` is `true`, the following will be appended to the `initializationCalldata`:
+         * - The primary contract address
+         * - `extraInitializationBytes`
+         */
+        bytes
+            memory secondaryInitializationBytes = secondaryContractDeploymentInit
+                .initializationCalldata;
+
+        if (secondaryContractDeploymentInit.addPrimaryContractAddress) {
+            secondaryInitializationBytes = abi.encodePacked(
+                secondaryInitializationBytes,
+                abi.encode(primaryContractAddress),
+                secondaryContractDeploymentInit.extraInitializationParams
+            );
+        }
+
+        /* initialize the primary contract proxy */
+        (bool success, bytes memory returnedData) = secondaryContractAddress
+            .call{value: secondaryContractDeploymentInit.fundingAmount}(
+            secondaryInitializationBytes
+        );
+        if (!success) {
+            revert SecondaryContractProxyInitFailureError(returnedData);
+        }
+    }
+
+    function _generatePrimaryContractSalt(
+        PrimaryContractDeployment calldata primaryContractDeployment,
+        SecondaryContractDeployment calldata secondaryContractDeployment,
+        address postDeploymentModule,
+        bytes calldata postDeploymentModuleCalldata
+    ) internal pure virtual returns (bytes32 primaryContractGeneratedSalt) {
+        /* generate salt for the primary contract
+         *  the salt is generated by hashing the following elements:
+         *   - the salt
+         *   - the secondary contract bytecode
+         *   - the secondary addPrimaryContractAddress boolean
+         *   - the secondary extraConstructorParams
+         *   - the postDeploymentModule address
+         *   - the postDeploymentModuleCalldata
+         *
+         */
+        primaryContractGeneratedSalt = keccak256(
+            abi.encode(
+                primaryContractDeployment.salt,
+                secondaryContractDeployment.creationBytecode,
+                secondaryContractDeployment.addPrimaryContractAddress,
+                secondaryContractDeployment.extraConstructorParams,
+                postDeploymentModule,
+                postDeploymentModuleCalldata
+            )
+        );
+    }
+
+    function _generatePrimaryContractProxySalt(
+        PrimaryContractDeploymentInit calldata primaryContractDeploymentInit,
+        SecondaryContractDeploymentInit
+            calldata secondaryContractDeploymentInit,
+        address postDeploymentModule,
+        bytes calldata postDeploymentModuleCalldata
+    )
+        internal
+        pure
+        virtual
+        returns (bytes32 primaryContractProxyGeneratedSalt)
+    {
+        /**
+         * Generate the salt for the primary contract
+         * The salt is generated by hashing the following elements:
+         *  - the salt
+         *  - the secondary implementation contract address
+         *  - the secondary contract initialization calldata
+         *  - the secondary contract addPrimaryContractAddress boolean
+         *  - the secondary contract extra initialization params (if any)
+         *  - the postDeploymentModule address
+         *  - the callda to the post deployment module
+         *
+         */
+        primaryContractProxyGeneratedSalt = keccak256(
+            abi.encode(
+                primaryContractDeploymentInit.salt,
+                secondaryContractDeploymentInit.implementationContract,
+                secondaryContractDeploymentInit.initializationCalldata,
+                secondaryContractDeploymentInit.addPrimaryContractAddress,
+                secondaryContractDeploymentInit.extraInitializationParams,
+                postDeploymentModule,
+                postDeploymentModuleCalldata
+            )
+        );
+    }
+}

package/contracts/modules/README.md

@@ -0,0 +1,23 @@
+# LSP23 Linked Contracts Deployment Module
+
+This folder contains modules related to the deployment of LSP23 Linked Contracts. The modules are essential for initializing and post-deploying actions for Universal Profiles.
+
+## Modules
+
+- **UniversalProfileInitPostDeploymentModule**: This module is responsible for the initial setup after the deployment of a Universal Profile Init contract.
+
+  - **Standardized Address**: `0x000000000066093407b6704B89793beFfD0D8F00`
+  - **Standardized Salt**: `0x12a6712f113536d8b01d99f72ce168c7e10901240d73e80eeb821d01aa4c2b1a`
+  - [More Details](./deployment-UP-init-module.md)
+
+- **UniversalProfilePostDeploymentModule**: This module is responsible for the initial setup after the deployment of a Universal Profile contract.
+  - **Standardized Address**: `0x0000005aD606bcFEF9Ea6D0BbE5b79847054BcD7`
+  - **Standardized Salt**: `0x42ff55d7957589c62da54a4368b10a2bc549f2038bbb6880ec6b3e0ecae2ba58`
+  - [More Details](./deployment-UP-module.md)
+
+## Setup
+
+Before deploying any of these modules, make sure that the following contracts are already deployed on the same network:
+
+- [Nick's Factory contract](https://github.com/Arachnid/deterministic-deployment-proxy/tree/master)
+- [LSP23 Linked Contracts Factory](https://github.com/lukso-network/LIPs/blob/main/LSPs/LSP-23-LinkedContractsFactory.md#lsp23linkedcontractsfactory-deployment)