@lodev09/react-native-true-sheet 4.0.0-beta.0 → 4.0.0-beta.1

package/ios/TrueSheetFooterView.mm

@@ -9,18 +9,22 @@
 #ifdef RCT_NEW_ARCH_ENABLED
 
 #import "TrueSheetFooterView.h"
-#import <react/renderer/components/TrueSheetSpec/ComponentDescriptors.h>
 #import <react/renderer/components/TrueSheetSpec/EventEmitters.h>
 #import <react/renderer/components/TrueSheetSpec/Props.h>
 #import <react/renderer/components/TrueSheetSpec/RCTComponentViewHelpers.h>
+#import <react/renderer/components/TrueSheetSpec/TrueSheetFooterViewComponentDescriptor.h>
+#import <react/renderer/components/TrueSheetSpec/TrueSheetFooterViewShadowNode.h>
 #import "TrueSheetViewController.h"
-#import "utils/LayoutUtil.h"
+#import "utils/UIView+ScrollEdgeInteraction.h"
 
 using namespace facebook::react;
 
 @implementation TrueSheetFooterView {
+  TrueSheetFooterViewShadowNode::ConcreteState::Shared _state;
   CGFloat _lastHeight;
-  BOOL _didInitialLayout;
+  CGFloat _currentKeyboardOffset;
+  CGFloat _bottomInset;
+  BOOL _keyboardVisible;
 }
 
 + (ComponentDescriptorProvider)componentDescriptorProvider {
@@ -32,70 +36,172 @@ using namespace facebook::react;
     static const auto defaultProps = std::make_shared<const TrueSheetFooterViewProps>();
     _props = defaultProps;
 
-    // Set background color to clear by default
     self.backgroundColor = [UIColor clearColor];
+    self.isAccessibilityElement = NO;
 
     _lastHeight = 0;
-    _didInitialLayout = NO;
+    _currentKeyboardOffset = 0;
+    _bottomInset = 0;
+    _keyboardVisible = NO;
   }
   return self;
 }
 
-- (void)setupConstraintsWithHeight:(CGFloat)height {
-  UIView *parentView = self.superview;
-  if (!parentView) {
+- (void)updateState:(const State::Shared &)state oldState:(const State::Shared &)oldState {
+  _state = std::static_pointer_cast<TrueSheetFooterViewShadowNode::ConcreteState const>(state);
+}
+
+// Tells the shadow node to pad the footer's bottom edge with the sheet's
+// bottom safe-area inset — the footer owns the sheet's bottom edge, so it
+// absorbs the inset and its background fills it.
+- (void)setBottomInset:(CGFloat)bottomInset {
+  if (_bottomInset == bottomInset) {
+    return;
+  }
+  _bottomInset = bottomInset;
+  [self pushBottomInsetState];
+}
+
+// Skipped while the keyboard is open — an absolute footer rises above the
+// keyboard, so the inset would leave a gap.
+- (void)setKeyboardVisible:(BOOL)keyboardVisible {
+  if (_keyboardVisible == keyboardVisible) {
     return;
   }
+  _keyboardVisible = keyboardVisible;
+  [self pushBottomInsetState];
+}
 
-  // Remove existing constraints before applying new ones
-  [LayoutUtil unpinView:self];
+- (void)pushBottomInsetState {
+  if (!_state) {
+    return;
+  }
 
-  // Pin footer to bottom and sides of container with specific height
-  [LayoutUtil pinView:self
-         toParentView:parentView
-                edges:UIRectEdgeLeft | UIRectEdgeRight | UIRectEdgeBottom
-               height:height];
+  TrueSheetFooterViewState newState;
+  newState.bottomInset = _keyboardVisible ? 0 : _bottomInset;
+  newState.initialized = true;
+  // Immediate so the inset lands before anything reads the footer's height —
+  // the async path races the keyboard caret scroll and detent setup, leaving
+  // them an inset stale (same reason Android bridges through
+  // TrueSheetStateUpdater).
+  _state->updateState(std::move(newState), EventQueue::UpdateMode::unstable_Immediate);
+}
 
-  _lastHeight = height;
+// Height the footer occupies above the keyboard — its layout height minus the
+// safe-area inset it drops while the keyboard is open.
+- (CGFloat)keyboardOcclusionHeight {
+  return MAX(0, _lastHeight - (_keyboardVisible ? 0 : _bottomInset));
 }
 
-- (void)didMoveToSuperview {
-  [super didMoveToSuperview];
+#pragma mark - Accessibility
 
-  // Setup footer constraints when added to container
-  if (self.superview) {
-    CGFloat initialHeight = self.frame.size.height;
-    [self setupConstraintsWithHeight:initialHeight];
+- (NSArray *)accessibilityElements {
+  NSMutableArray *elements = [NSMutableArray array];
+  [self collectAccessibilityElementsFromView:self into:elements];
+  if (elements.count > 0) {
+    return elements;
   }
+
+  return [super accessibilityElements];
 }
 
+- (void)collectAccessibilityElementsFromView:(UIView *)view into:(NSMutableArray *)elements {
+  for (UIView *subview in view.subviews) {
+    if (subview.isAccessibilityElement || subview.accessibilityLabel || subview.accessibilityIdentifier) {
+      [elements addObject:subview];
+    } else if (subview.accessibilityElements.count > 0) {
+      [elements addObjectsFromArray:subview.accessibilityElements];
+    } else {
+      [self collectAccessibilityElementsFromView:subview into:elements];
+    }
+  }
+}
+
+#pragma mark - Layout
+
 - (void)updateLayoutMetrics:(const facebook::react::LayoutMetrics &)layoutMetrics
            oldLayoutMetrics:(const facebook::react::LayoutMetrics &)oldLayoutMetrics {
-  CGFloat height = layoutMetrics.frame.size.height;
-
-  // On initial layout, call super to let React Native position the view
-  // After that, we use Auto Layout constraints instead
-  if (!_didInitialLayout) {
-    [super updateLayoutMetrics:layoutMetrics oldLayoutMetrics:oldLayoutMetrics];
-    _didInitialLayout = YES;
-  }
+  [super updateLayoutMetrics:layoutMetrics oldLayoutMetrics:oldLayoutMetrics];
 
-  // Update footer constraints when height changes
+  CGFloat height = layoutMetrics.frame.size.height;
   if (height != _lastHeight) {
-    [self setupConstraintsWithHeight:height];
+    _lastHeight = height;
+    [self.delegate footerViewDidChangeSize:CGSizeMake(layoutMetrics.frame.size.width, height)];
   }
 }
 
 - (void)prepareForRecycle {
   [super prepareForRecycle];
 
-  // Remove footer constraints
-  [LayoutUtil unpinView:self];
+  if (@available(iOS 26.0, *)) {
+    [self cleanupEdgeInteraction];
+  }
 
+  self.transform = CGAffineTransformIdentity;
+  _state = nullptr;
   _lastHeight = 0;
-  _didInitialLayout = NO;
+  _currentKeyboardOffset = 0;
+  _bottomInset = 0;
+  _keyboardVisible = NO;
+}
+
+#pragma mark - TrueSheetKeyboardObserverDelegate
+
+// Yoga owns the footer's frame (pinned to the container's bottom edge), so the
+// keyboard slide is carried by a transform instead of layout. Only an absolute
+// footer floats above the keyboard — a relative footer stays in the layout
+// flow behind it.
+- (void)keyboardWillShow:(CGFloat)height duration:(NSTimeInterval)duration curve:(UIViewAnimationOptions)curve {
+  if (!self.keyboardObserver.viewController.absoluteFooter) {
+    return;
+  }
+
+  [self setKeyboardVisible:YES];
+
+  CGFloat keyboardOffset = self.keyboardObserver.viewController.footerKeyboardOffset;
+  CGFloat slide = MAX(0, height + keyboardOffset);
+  _currentKeyboardOffset = slide;
+
+  [UIView animateWithDuration:duration
+                        delay:0
+                      options:curve | UIViewAnimationOptionBeginFromCurrentState
+                   animations:^{
+                     self.transform = CGAffineTransformMakeTranslation(0, -slide);
+                   }
+                   completion:nil];
+}
+
+- (void)keyboardWillHide:(NSTimeInterval)duration curve:(UIViewAnimationOptions)curve {
+  [self setKeyboardVisible:NO];
+  _currentKeyboardOffset = 0;
+
+  [UIView animateWithDuration:duration
+                        delay:0
+                      options:curve | UIViewAnimationOptionBeginFromCurrentState
+                   animations:^{
+                     self.transform = CGAffineTransformIdentity;
+                   }
+                   completion:nil];
+}
+
+- (void)applyKeyboardOffset {
+  CGFloat height = self.keyboardObserver.currentHeight;
+  if (height <= 0 || !self.keyboardObserver.viewController.absoluteFooter) {
+    return;
+  }
+
+  [self setKeyboardVisible:YES];
+
+  CGFloat keyboardOffset = self.keyboardObserver.viewController.footerKeyboardOffset;
+  CGFloat slide = MAX(0, height + keyboardOffset);
+  _currentKeyboardOffset = slide;
+  self.transform = CGAffineTransformMakeTranslation(0, -slide);
 }
 
 @end
 
+Class<RCTComponentViewProtocol> TrueSheetFooterViewCls(void) {
+  return TrueSheetFooterView.class;
+}
+
 #endif

package/ios/{events/OnDidDismissEvent.h → TrueSheetHeaderView.h}

@@ -8,19 +8,22 @@
 
 #ifdef RCT_NEW_ARCH_ENABLED
 
-#import <Foundation/Foundation.h>
-#import <react/renderer/components/TrueSheetSpec/EventEmitters.h>
-
-using namespace facebook::react;
+#import <React/RCTViewComponentView.h>
+#import <UIKit/UIKit.h>
 
 NS_ASSUME_NONNULL_BEGIN
 
-@interface OnDidDismissEvent : NSObject
+@protocol TrueSheetHeaderViewDelegate <NSObject>
+@optional
+- (void)headerViewDidChangeSize:(CGSize)size;
+@end
+
+@interface TrueSheetHeaderView : RCTViewComponentView
 
-+ (void)emit:(std::shared_ptr<const facebook::react::EventEmitter>)eventEmitter;
+@property (nonatomic, weak, nullable) id<TrueSheetHeaderViewDelegate> delegate;
 
 @end
 
 NS_ASSUME_NONNULL_END
 
-#endif  // RCT_NEW_ARCH_ENABLED
+#endif

package/ios/TrueSheetHeaderView.mm

@@ -0,0 +1,64 @@
+//
+//  Created by Jovanni Lo (@lodev09)
+//  Copyright (c) 2024-present. All rights reserved.
+//
+//  This source code is licensed under the MIT license found in the
+//  LICENSE file in the root directory of this source tree.
+//
+
+#ifdef RCT_NEW_ARCH_ENABLED
+
+#import "TrueSheetHeaderView.h"
+#import <react/renderer/components/TrueSheetSpec/ComponentDescriptors.h>
+#import <react/renderer/components/TrueSheetSpec/EventEmitters.h>
+#import <react/renderer/components/TrueSheetSpec/Props.h>
+#import <react/renderer/components/TrueSheetSpec/RCTComponentViewHelpers.h>
+#import "utils/UIView+ScrollEdgeInteraction.h"
+
+using namespace facebook::react;
+
+@implementation TrueSheetHeaderView {
+  CGSize _lastSize;
+}
+
++ (ComponentDescriptorProvider)componentDescriptorProvider {
+  return concreteComponentDescriptorProvider<TrueSheetHeaderViewComponentDescriptor>();
+}
+
+- (instancetype)initWithFrame:(CGRect)frame {
+  if (self = [super initWithFrame:frame]) {
+    static const auto defaultProps = std::make_shared<const TrueSheetHeaderViewProps>();
+    _props = defaultProps;
+
+    _lastSize = CGSizeZero;
+  }
+  return self;
+}
+
+- (void)updateLayoutMetrics:(const facebook::react::LayoutMetrics &)layoutMetrics
+           oldLayoutMetrics:(const facebook::react::LayoutMetrics &)oldLayoutMetrics {
+  [super updateLayoutMetrics:layoutMetrics oldLayoutMetrics:oldLayoutMetrics];
+
+  CGSize newSize = CGSizeMake(layoutMetrics.frame.size.width, layoutMetrics.frame.size.height);
+
+  if (!CGSizeEqualToSize(newSize, _lastSize)) {
+    _lastSize = newSize;
+    [self.delegate headerViewDidChangeSize:newSize];
+  }
+}
+
+- (void)prepareForRecycle {
+  [super prepareForRecycle];
+  _lastSize = CGSizeZero;
+  if (@available(iOS 26.0, *)) {
+    [self cleanupEdgeInteraction];
+  }
+}
+
+@end
+
+Class<RCTComponentViewProtocol> TrueSheetHeaderViewCls(void) {
+  return TrueSheetHeaderView.class;
+}
+
+#endif

package/ios/TrueSheetModule.mm

@@ -14,6 +14,7 @@
 #import "TrueSheetModule.h"
 #import <React/RCTUtils.h>
 #import "TrueSheetView.h"
+#import "TrueSheetViewController.h"
 
 #import <TrueSheetSpec/TrueSheetSpec.h>
 
@@ -46,6 +47,7 @@ RCT_EXPORT_MODULE(TrueSheetModule)
 
 - (void)presentByRef:(double)viewTag
                index:(double)index
+            animated:(BOOL)animated
              resolve:(RCTPromiseResolveBlock)resolve
               reject:(RCTPromiseRejectBlock)reject {
   RCTExecuteOnMainQueue(^{
@@ -57,7 +59,7 @@ RCT_EXPORT_MODULE(TrueSheetModule)
     }
 
     [trueSheetView presentAtIndex:(NSInteger)index
-                         animated:YES
+                         animated:animated
                        completion:^(BOOL success, NSError *_Nullable error) {
                          if (success) {
                            resolve(nil);
@@ -68,7 +70,10 @@ RCT_EXPORT_MODULE(TrueSheetModule)
   });
 }
 
-- (void)dismissByRef:(double)viewTag resolve:(RCTPromiseResolveBlock)resolve reject:(RCTPromiseRejectBlock)reject {
+- (void)dismissByRef:(double)viewTag
+            animated:(BOOL)animated
+             resolve:(RCTPromiseResolveBlock)resolve
+              reject:(RCTPromiseRejectBlock)reject {
   RCTExecuteOnMainQueue(^{
     TrueSheetView *trueSheetView = [TrueSheetModule getTrueSheetViewByTag:@((NSInteger)viewTag)];
 
@@ -77,7 +82,7 @@ RCT_EXPORT_MODULE(TrueSheetModule)
       return;
     }
 
-    [trueSheetView dismissAnimated:YES
+    [trueSheetView dismissAnimated:animated
                         completion:^(BOOL success, NSError *_Nullable error) {
                           if (success) {
                             resolve(nil);
@@ -88,12 +93,94 @@ RCT_EXPORT_MODULE(TrueSheetModule)
   });
 }
 
+- (void)dismissStackByRef:(double)viewTag
+                 animated:(BOOL)animated
+                  resolve:(RCTPromiseResolveBlock)resolve
+                   reject:(RCTPromiseRejectBlock)reject {
+  RCTExecuteOnMainQueue(^{
+    TrueSheetView *trueSheetView = [TrueSheetModule getTrueSheetViewByTag:@((NSInteger)viewTag)];
+
+    if (!trueSheetView) {
+      reject(@"SHEET_NOT_FOUND", [NSString stringWithFormat:@"No sheet found with tag %d", (int)viewTag], nil);
+      return;
+    }
+
+    [trueSheetView
+      dismissStackAnimated:animated
+                completion:^(BOOL success, NSError *_Nullable error) {
+                  if (success) {
+                    resolve(nil);
+                  } else {
+                    reject(@"DISMISS_FAILED", error.localizedDescription ?: @"Failed to dismiss stack", error);
+                  }
+                }];
+  });
+}
+
 - (void)resizeByRef:(double)viewTag
               index:(double)index
             resolve:(RCTPromiseResolveBlock)resolve
              reject:(RCTPromiseRejectBlock)reject {
-  // Resize is just present with a different index
-  [self presentByRef:viewTag index:index resolve:resolve reject:reject];
+  RCTExecuteOnMainQueue(^{
+    TrueSheetView *trueSheetView = [TrueSheetModule getTrueSheetViewByTag:@((NSInteger)viewTag)];
+
+    if (!trueSheetView) {
+      reject(@"SHEET_NOT_FOUND", [NSString stringWithFormat:@"No sheet found with tag %d", (int)viewTag], nil);
+      return;
+    }
+
+    [trueSheetView resizeToIndex:(NSInteger)index
+                      completion:^(BOOL success, NSError *_Nullable error) {
+                        if (success) {
+                          resolve(nil);
+                        } else {
+                          reject(@"RESIZE_FAILED", error.localizedDescription ?: @"Failed to resize sheet", error);
+                        }
+                      }];
+  });
+}
+
+- (void)handleBackPress:(double)viewTag resolve:(RCTPromiseResolveBlock)resolve reject:(RCTPromiseRejectBlock)reject {
+  // No-op on iOS — no hardware back button
+  resolve(nil);
+}
+
+- (void)dismissAll:(BOOL)animated resolve:(RCTPromiseResolveBlock)resolve reject:(RCTPromiseRejectBlock)reject {
+  RCTExecuteOnMainQueue(^{
+    @synchronized(viewRegistry) {
+      // Find the root presented sheet (one without a parent TrueSheet)
+      TrueSheetView *rootSheet = nil;
+
+      for (TrueSheetView *view in viewRegistry.allValues) {
+        if (!view.viewController.isPresented) {
+          continue;
+        }
+
+        UIViewController *presenter = view.viewController.presentingViewController;
+        BOOL hasParentSheet = [presenter isKindOfClass:[TrueSheetViewController class]];
+
+        if (!hasParentSheet) {
+          rootSheet = view;
+          break;
+        }
+      }
+
+      if (!rootSheet) {
+        resolve(nil);
+        return;
+      }
+
+      [rootSheet emitDismissedPosition];
+      [rootSheet dismissAnimated:animated
+                      completion:^(BOOL success, NSError *_Nullable error) {
+                        if (success) {
+                          resolve(nil);
+                        } else {
+                          reject(@"DISMISS_FAILED", error.localizedDescription ?: @"Failed to dismiss sheets", error);
+                        }
+                      }];
+    }
+  });
 }
 
 #pragma mark - Helper Methods

package/ios/TrueSheetPeekView.h

@@ -0,0 +1,32 @@
+//
+//  Created by Jovanni Lo (@lodev09)
+//  Copyright (c) 2024-present. All rights reserved.
+//
+//  This source code is licensed under the MIT license found in the
+//  LICENSE file in the root directory of this source tree.
+//
+
+#ifdef RCT_NEW_ARCH_ENABLED
+
+#import <React/RCTViewComponentView.h>
+#import <UIKit/UIKit.h>
+
+NS_ASSUME_NONNULL_BEGIN
+
+@class TrueSheetPeekView;
+
+@protocol TrueSheetPeekViewDelegate <NSObject>
+@optional
+- (void)peekViewDidChangeSize:(CGSize)size;
+- (void)peekViewWillDetach:(TrueSheetPeekView *)peekView;
+@end
+
+@interface TrueSheetPeekView : RCTViewComponentView
+
+@property (nonatomic, weak, nullable) id<TrueSheetPeekViewDelegate> delegate;
+
+@end
+
+NS_ASSUME_NONNULL_END
+
+#endif

package/ios/TrueSheetPeekView.mm

@@ -0,0 +1,99 @@
+//
+//  Created by Jovanni Lo (@lodev09)
+//  Copyright (c) 2024-present. All rights reserved.
+//
+//  This source code is licensed under the MIT license found in the
+//  LICENSE file in the root directory of this source tree.
+//
+
+#ifdef RCT_NEW_ARCH_ENABLED
+
+#import "TrueSheetPeekView.h"
+#import <react/renderer/components/TrueSheetSpec/ComponentDescriptors.h>
+#import <react/renderer/components/TrueSheetSpec/EventEmitters.h>
+#import <react/renderer/components/TrueSheetSpec/Props.h>
+#import <react/renderer/components/TrueSheetSpec/RCTComponentViewHelpers.h>
+#import "TrueSheetContainerView.h"
+
+using namespace facebook::react;
+
+@implementation TrueSheetPeekView {
+  CGRect _lastFrame;
+}
+
++ (ComponentDescriptorProvider)componentDescriptorProvider {
+  return concreteComponentDescriptorProvider<TrueSheetPeekViewComponentDescriptor>();
+}
+
+- (instancetype)initWithFrame:(CGRect)frame {
+  if (self = [super initWithFrame:frame]) {
+    static const auto defaultProps = std::make_shared<const TrueSheetPeekViewProps>();
+    _props = defaultProps;
+
+    _lastFrame = CGRectZero;
+  }
+  return self;
+}
+
+/**
+ * Peek can be nested anywhere within the content, so it attaches itself to the
+ * nearest container instead of being mounted by it. The container also searches
+ * for it when the content mounts to cover the initial (bottom-up) mount order.
+ */
+- (void)attachToContainerView {
+  if (self.delegate) {
+    return;
+  }
+
+  UIView *view = self.superview;
+  while (view && ![view isKindOfClass:[TrueSheetContainerView class]]) {
+    view = view.superview;
+  }
+
+  if (view) {
+    [(TrueSheetContainerView *)view attachPeekView:self];
+  }
+}
+
+- (void)didMoveToSuperview {
+  [super didMoveToSuperview];
+  if (self.superview) {
+    [self attachToContainerView];
+  }
+}
+
+- (void)didMoveToWindow {
+  [super didMoveToWindow];
+  if (self.window) {
+    [self attachToContainerView];
+  }
+}
+
+- (void)updateLayoutMetrics:(const facebook::react::LayoutMetrics &)layoutMetrics
+           oldLayoutMetrics:(const facebook::react::LayoutMetrics &)oldLayoutMetrics {
+  [super updateLayoutMetrics:layoutMetrics oldLayoutMetrics:oldLayoutMetrics];
+
+  // Compare the whole frame — the peek's offset within the content affects
+  // the peek detent, so position changes matter too.
+  CGRect newFrame = CGRectMake(layoutMetrics.frame.origin.x, layoutMetrics.frame.origin.y,
+    layoutMetrics.frame.size.width, layoutMetrics.frame.size.height);
+
+  if (!CGRectEqualToRect(newFrame, _lastFrame)) {
+    _lastFrame = newFrame;
+    [self.delegate peekViewDidChangeSize:newFrame.size];
+  }
+}
+
+- (void)prepareForRecycle {
+  [super prepareForRecycle];
+  _lastFrame = CGRectZero;
+  [self.delegate peekViewWillDetach:self];
+}
+
+@end
+
+Class<RCTComponentViewProtocol> TrueSheetPeekViewCls(void) {
+  return TrueSheetPeekView.class;
+}
+
+#endif

package/ios/TrueSheetView.h

@@ -23,21 +23,7 @@ typedef void (^TrueSheetCompletionBlock)(BOOL success, NSError *_Nullable error)
 
 @interface TrueSheetView : RCTViewComponentView
 
-///**
-// * The view controller managing the sheet presentation
-// * Exposed so container can access it
-// */
-//@property (nonatomic, readonly, strong) TrueSheetViewController *controller;
-//
-///**
-// * Whether the sheet is currently presented
-// */
-//@property (nonatomic, readonly) BOOL isPresented;
-//
-///**
-// * The currently active detent index
-// */
-//@property (nonatomic, readonly, strong, nullable) NSNumber *activeIndex;
+@property (nonatomic, readonly) TrueSheetViewController *viewController;
 
 // TurboModule methods
 - (void)presentAtIndex:(NSInteger)index
@@ -46,6 +32,12 @@ typedef void (^TrueSheetCompletionBlock)(BOOL success, NSError *_Nullable error)
 
 - (void)dismissAnimated:(BOOL)animated completion:(nullable TrueSheetCompletionBlock)completion;
 
+- (void)emitDismissedPosition;
+
+- (void)resizeToIndex:(NSInteger)index completion:(nullable TrueSheetCompletionBlock)completion;
+
+- (void)dismissStackAnimated:(BOOL)animated completion:(nullable TrueSheetCompletionBlock)completion;
+
 @end
 
 NS_ASSUME_NONNULL_END