@leonsilicon/react-native-wishlist 0.0.0

package/ios/MGTemplateContainerComponent.mm

@@ -0,0 +1,105 @@
+#import "MGTemplateContainerComponent.h"
+#import <react/renderer/components/wishlist/ComponentDescriptors.h>
+#import "MGTemplateContainerComponentDescriptor.h"
+#import "MGTemplateContainerShadowNode.h"
+#import "RCTFabricComponentsPlugins.h"
+
+using namespace facebook::react;
+
+static std::vector<std::string> parseTemplateNames(std::string const &namesJson)
+{
+  if (namesJson.empty()) {
+    return {};
+  }
+
+  NSString *jsonString = [NSString stringWithUTF8String:namesJson.c_str()];
+  NSData *jsonData = [jsonString dataUsingEncoding:NSUTF8StringEncoding];
+  if (!jsonData) {
+    return {};
+  }
+
+  NSError *error = nil;
+  id parsed = [NSJSONSerialization JSONObjectWithData:jsonData options:0 error:&error];
+  if (error || ![parsed isKindOfClass:NSArray.class]) {
+    return {};
+  }
+
+  NSArray *names = (NSArray *)parsed;
+  std::vector<std::string> result;
+  result.reserve(names.count);
+  for (id name in names) {
+    if ([name isKindOfClass:NSString.class]) {
+      result.emplace_back([(NSString *)name UTF8String]);
+    }
+  }
+  return result;
+}
+
+@implementation MGTemplateContainerComponent {
+  MGTemplateContainerShadowNode::ConcreteState::Shared _state;
+  MGWishListComponent *_wishList;
+}
+
+- (instancetype)initWithFrame:(CGRect)frame
+{
+  if (self = [super initWithFrame:frame]) {
+    static const auto defaultProps = std::make_shared<const MGTemplateContainerProps>();
+    _props = defaultProps;
+  }
+
+  return self;
+}
+
+- (void)setWishlist:(MGWishListComponent *)wishList
+{
+  _wishList = wishList;
+  [self updateWishlist];
+}
+
+#pragma mark - RCTComponentViewProtocol
+
++ (facebook::react::ComponentDescriptorProvider)componentDescriptorProvider
+{
+  return facebook::react::concreteComponentDescriptorProvider<
+      facebook::react::MGTemplateContainerComponentDescriptor>();
+}
+
+- (void)updateProps:(Props::Shared const &)props oldProps:(Props::Shared const &)oldProps
+{
+  [super updateProps:props oldProps:oldProps];
+  [self updateWishlist];
+}
+
+- (void)updateState:(State::Shared const &)state oldState:(State::Shared const &)oldState
+{
+  auto templateState = std::static_pointer_cast<MGTemplateContainerShadowNode::ConcreteState const>(state);
+  _state = templateState;
+  [self updateWishlist];
+}
+
+- (void)prepareForRecycle
+{
+  [super prepareForRecycle];
+
+  _wishList = nil;
+  _state.reset();
+}
+
+- (void)updateWishlist
+{
+  if (!_wishList || !_state) {
+    return;
+  }
+  auto props = std::static_pointer_cast<const MGTemplateContainerProps>(_props);
+  auto state = std::static_pointer_cast<MGTemplateContainerShadowNode::ConcreteState const>(_state);
+  [_wishList setWishlistId:props->wishlistId];
+  [_wishList setInflatorId:props->inflatorId];
+  [_wishList setTemplates:state->getData().getTemplates() withNames:parseTemplateNames(props->names)];
+}
+
+@end
+
+Class<RCTComponentViewProtocol> MGTemplateContainerCls(void)
+{
+  return MGTemplateContainerComponent.class;
+}

package/ios/MGTemplateInterceptorComponent.h

@@ -0,0 +1,9 @@
+#import <React-RCTFabric/React/RCTViewComponentView.h>
+
+NS_ASSUME_NONNULL_BEGIN
+
+@interface MGTemplateInterceptorComponent : RCTViewComponentView
+
+@end
+
+NS_ASSUME_NONNULL_END

package/ios/MGTemplateInterceptorComponent.mm

@@ -0,0 +1,72 @@
+#import "MGTemplateInterceptorComponent.h"
+#import <react/renderer/components/wishlist/ComponentDescriptors.h>
+#import <react/renderer/components/wishlist/Props.h>
+#import "MGTemplateContainerComponent.h"
+#import "MGWishListComponent.h"
+#import "RCTFabricComponentsPlugins.h"
+
+using namespace facebook::react;
+
+@implementation MGTemplateInterceptorComponent {
+  MGWishListComponent *_wishlist;
+}
+
+#pragma mark - RCTComponentViewProtocol
+
++ (facebook::react::ComponentDescriptorProvider)componentDescriptorProvider
+{
+  return facebook::react::concreteComponentDescriptorProvider<
+      facebook::react::MGTemplateInterceptorComponentDescriptor>();
+}
+
+/*
+ * Called for mounting (attaching) a child component view inside `self`
+ * component view.
+ * Receiver must add `childComponentView` as a subview.
+ */
+- (void)mountChildComponentView:(UIView<RCTComponentViewProtocol> *)childComponentView index:(NSInteger)index
+{
+  if ([childComponentView isKindOfClass:[MGTemplateContainerComponent class]]) {
+    MGTemplateContainerComponent *container = (MGTemplateContainerComponent *)childComponentView;
+    if (_wishlist != nil) {
+      [container setWishlist:_wishlist];
+    }
+    return;
+  }
+  if ([childComponentView isKindOfClass:[MGWishListComponent class]]) {
+    _wishlist = (MGWishListComponent *)childComponentView;
+  }
+  [super mountChildComponentView:childComponentView index:index];
+}
+
+/*
+ * Called for unmounting (detaching) a child component view from `self`
+ * component view.
+ * Receiver must remove `childComponentView` as a subview.
+ */
+- (void)unmountChildComponentView:(UIView<RCTComponentViewProtocol> *)childComponentView index:(NSInteger)index
+{
+  if ([childComponentView isKindOfClass:[MGWishListComponent class]]) {
+    _wishlist = nil;
+  }
+  if ([childComponentView isKindOfClass:[MGTemplateContainerComponent class]]) {
+    return;
+  }
+  [super unmountChildComponentView:childComponentView index:index];
+}
+
+#pragma clang diagnostic push
+#pragma clang diagnostic ignored "-Wobjc-missing-super-calls"
+- (void)updateProps:(Props::Shared const &)props oldProps:(Props::Shared const &)oldProps
+{
+  auto wProps = std::static_pointer_cast<const MGTemplateInterceptorProps>(props);
+  _props = wProps;
+}
+#pragma clang diagnostic pop
+
+@end
+
+Class<RCTComponentViewProtocol> MGTemplateInterceptorCls(void)
+{
+  return MGTemplateInterceptorComponent.class;
+}

package/ios/MGWishListComponent.h

@@ -0,0 +1,17 @@
+#import <Foundation/Foundation.h>
+#import <React-RCTFabric/React/RCTScrollViewComponentView.h>
+#import <React-RCTFabric/React/RCTViewComponentView.h>
+#include <react/renderer/components/wishlist/RCTComponentViewHelpers.h>
+
+NS_ASSUME_NONNULL_BEGIN
+
+@interface MGWishListComponent : RCTScrollViewComponentView <RCTMGWishlistViewProtocol>
+
+- (void)setTemplates:(std::vector<std::shared_ptr<facebook::react::ShadowNode const>>)templates
+           withNames:(std::vector<std::string>)names;
+- (void)setInflatorId:(std::string)inflatorId;
+- (void)setWishlistId:(std::string)wishlistId;
+
+@end
+
+NS_ASSUME_NONNULL_END

package/ios/MGWishListComponent.mm

@@ -0,0 +1,187 @@
+#import "MGWishListComponent.h"
+#import <React/RCTConversions.h>
+#import <React/RCTImageResponseDelegate.h>
+#import <React/RCTImageResponseObserverProxy.h>
+
+#import <React/RCTBridgeModule.h>
+#import <React/RCTComponentViewFactory.h>
+#import <react/renderer/components/rncore/EventEmitters.h>
+#import <react/renderer/components/rncore/Props.h>
+#include <react/renderer/components/wishlist/Props.h>
+#include <react/renderer/components/wishlist/ShadowNodes.h>
+#import "MGOrchestrator.h"
+#import "MGWishlistComponentDescriptor.h"
+#import "RCTFabricComponentsPlugins.h"
+#include "WishlistDefine.h"
+
+#define MG_INITIAL_CONTENT_SIZE 100000
+
+using namespace facebook::react;
+
+@interface RCTScrollViewComponentView (MGWishList)
+
+- (void)scrollViewDidScroll:(UIScrollView *)sv;
+
+@end
+
+@implementation MGWishListComponent {
+  MGWishlistShadowNode::ConcreteState::Shared _state;
+  std::string _inflatorId;
+  std::string _wishlistId;
+  MGOrchestrator *_orchestrator;
+  std::shared_ptr<const MGWishlistEventEmitter> _emitter;
+  int _initialIndex;
+  BOOL _ignoreScrollEvents;
+}
+
+- (instancetype)initWithFrame:(CGRect)frame
+{
+  if (self = [super initWithFrame:frame]) {
+    self.clipsToBounds = YES;
+    self.scrollView.showsVerticalScrollIndicator = NO;
+    self.scrollView.clipsToBounds = YES;
+    _ignoreScrollEvents = NO;
+  }
+  return self;
+}
+
+- (void)mountChildComponentView:(UIView<RCTComponentViewProtocol> *)childComponentView index:(NSInteger)index
+{
+  [super mountChildComponentView:childComponentView index:index];
+}
+
+- (void)setInflatorId:(std::string)nextInflatorId
+{
+  _inflatorId = nextInflatorId;
+}
+
+- (void)setWishlistId:(std::string)wishlistId
+{
+  _wishlistId = wishlistId;
+}
+
+- (BOOL)scrollViewShouldScrollToTop:(UIScrollView *)scrollView
+{
+  [self scrollToItem:0 animated:YES]; // Maybe it would be better to scroll to initial (which is not always 0)
+  return NO;
+}
+
+- (void)setTemplates:(std::vector<std::shared_ptr<facebook::react::ShadowNode const>>)templates
+           withNames:(std::vector<std::string>)names
+{
+  if (!_orchestrator) {
+    self.scrollView.contentSize = CGSizeMake(self.frame.size.width, MG_INITIAL_CONTENT_SIZE);
+    self.scrollView.contentOffset = CGPointMake(0, MG_INITIAL_CONTENT_SIZE / 2);
+
+    std::shared_ptr<MGViewportCarerImpl> viewportCarer = _state->getData().viewportCarer;
+    _orchestrator = [[MGOrchestrator alloc] initWith:self wishlistId:_wishlistId viewportCarer:viewportCarer];
+  }
+
+  [_orchestrator
+      renderAsyncWithDimensions:{(float)self.scrollView.frame.size.width, (float)self.scrollView.frame.size.height}
+             initialContentSize:MG_INITIAL_CONTENT_SIZE
+                   initialIndex:_initialIndex
+                      templates:templates
+                          names:names
+                     inflatorId:_inflatorId];
+}
+
+#pragma mark - RCTComponentViewProtocol
+
++ (ComponentDescriptorProvider)componentDescriptorProvider
+{
+  return concreteComponentDescriptorProvider<MGWishlistComponentDescriptor>();
+}
+
+#pragma clang diagnostic push
+#pragma clang diagnostic ignored "-Wobjc-missing-super-calls"
+- (void)updateProps:(Props::Shared const &)props oldProps:(Props::Shared const &)oldProps
+{
+  std::shared_ptr<const MGWishlistProps> wProps = std::static_pointer_cast<const MGWishlistProps>(props);
+  _initialIndex = wProps->initialIndex;
+
+  _props = wProps;
+}
+#pragma clang diagnostic pop
+
+- (void)updateState:(State::Shared const &)state oldState:(State::Shared const &)oldState
+{
+  // Updating content size or offset can trigger scroll events but we do not want to
+  // process those as they can have invalid offset or were already processed.
+  _ignoreScrollEvents = YES;
+
+  assert(std::dynamic_pointer_cast<MGWishlistShadowNode::ConcreteState const>(state));
+  _state = std::static_pointer_cast<MGWishlistShadowNode::ConcreteState const>(state);
+  auto &data = _state->getData();
+
+  CGSize contentSize = RCTCGSizeFromSize(data.contentBoundingRect.size);
+  self.contentView.frame = CGRect{RCTCGPointFromPoint(data.contentBoundingRect.origin), contentSize};
+  self.scrollView.contentSize = contentSize;
+
+#if MG_WISHLIST_DEBUG
+  std::cout << "updateState {offset: " << data.contentOffset << ", contentHeight: " << contentSize.height << "}"
+            << std::endl;
+#endif
+
+  if (data.contentOffset != MG_NO_OFFSET) {
+    [self.scrollView setContentOffset:{0, data.contentOffset} animated:NO];
+    data.viewportCarer->didUpdateContentOffset();
+  }
+
+  _ignoreScrollEvents = NO;
+}
+
+#pragma clang diagnostic push
+#pragma clang diagnostic ignored "-Wobjc-missing-super-calls"
+- (void)updateEventEmitter:(EventEmitter::Shared const &)eventEmitter
+{
+  _emitter = std::static_pointer_cast<MGWishlistEventEmitter const>(eventEmitter);
+}
+#pragma clang diagnostic pop
+
+- (void)scrollViewDidScroll:(UIScrollView *)scrollView
+{
+  if (_ignoreScrollEvents) {
+    return;
+  }
+
+  [_orchestrator didScrollAsyncWithDimensions:{(float)scrollView.frame.size.width, (float)scrollView.frame.size.height}
+                                contentOffset:scrollView.contentOffset.y
+                                   inflatorId:_inflatorId];
+}
+
+- (void)prepareForRecycle
+{
+  _state.reset();
+  _orchestrator = nil;
+  [super prepareForRecycle];
+}
+
+- (void)setBridge:(RCTBridge *)bridge
+{
+  // TODO here you can intercept uiManager by registering fake surface
+  // bridge.surfacePresentsr
+}
+
+- (void)handleCommand:(const NSString *)commandName args:(const NSArray *)args
+{
+  RCTMGWishlistHandleCommand(self, commandName, args);
+}
+
+- (void)scrollToItem:(NSInteger)index animated:(BOOL)animated
+{
+  if (animated && _orchestrator != nil) {
+    [_orchestrator scrollToItem:index];
+  }
+
+  if (!animated) {
+    // TODO (restart Wishlist with different initial index)
+  }
+}
+
+@end
+
+Class<RCTComponentViewProtocol> MGWishlistCls(void)
+{
+  return MGWishListComponent.class;
+}

package/ios/MGWishlistManager.h

@@ -0,0 +1,21 @@
+#import <React/RCTViewManager.h>
+#import <wishlist/wishlist.h>
+
+NS_ASSUME_NONNULL_BEGIN
+
+@interface MGWishlistManager : NSObject <NativeWishlistManagerSpec>
+@end
+
+@interface MGWishlistComponentManager : RCTViewManager
+@end
+
+@interface MGTemplateContainerManager : RCTViewManager
+@end
+
+@interface MGTemplateInterceptorManager : RCTViewManager
+@end
+
+@interface MGContentContainerManager : RCTViewManager
+@end
+
+NS_ASSUME_NONNULL_END