@layerzerolabs/protocol-starknet-v2 0.0.34

package/libs/lz_utils/src/bytes.cairo

@@ -0,0 +1,33 @@
+use starknet::ContractAddress;
+
+// the default is u256 default = 0
+#[derive(Drop, Serde, Default, Copy, Debug, PartialEq, Hash, starknet::Store)]
+pub struct Bytes32 {
+    pub value: u256,
+}
+
+pub impl ContractAddressIntoBytes32 of Into<ContractAddress, Bytes32> {
+    fn into(self: ContractAddress) -> Bytes32 {
+        let contract_address_felt: felt252 = self.into();
+        Bytes32 { value: contract_address_felt.into() }
+    }
+}
+
+pub impl Bytes32TryIntoContractAddress of TryInto<Bytes32, ContractAddress> {
+    fn try_into(self: Bytes32) -> Option<ContractAddress> {
+        let bytes32_felt: felt252 = self.value.try_into()?;
+        bytes32_felt.try_into()
+    }
+}
+
+pub impl Bytes32IntoU256 of Into<Bytes32, u256> {
+    fn into(self: Bytes32) -> u256 {
+        self.value
+    }
+}
+
+pub impl U256IntoBytes32 of Into<u256, Bytes32> {
+    fn into(self: u256) -> Bytes32 {
+        Bytes32 { value: self }
+    }
+}

package/libs/lz_utils/src/error.cairo

@@ -0,0 +1,12 @@
+/// Trait to get the error name for an error code.
+/// This trait is intended to be implemented for enum types.
+pub trait Error<T> {
+    fn name(self: T) -> ByteArray;
+    fn prefix() -> ByteArray;
+}
+
+/// Generic format function that works with any type implementing Error trait
+/// ERROR_CODE::MESSAGE
+pub fn format_error<T, +Error<T>, +Drop<T>>(error: T, message: ByteArray) -> ByteArray {
+    format!("{}_{}::{}", Error::<T>::prefix(), error.name(), message)
+}

package/libs/lz_utils/src/keccak.cairo

@@ -0,0 +1,28 @@
+use core::integer::u128_byte_reverse;
+use core::keccak::compute_keccak_byte_array;
+use crate::bytes::Bytes32;
+
+/// Computes the keccak256 hash of a byte array and returns it as a u256 value
+///
+/// # Arguments
+/// * `arr` - A reference to a byte array to be hashed
+///
+/// # Returns
+/// * `Bytes32` - The keccak256 hash of the input as a u256
+pub fn keccak256(arr: @ByteArray) -> Bytes32 {
+    u256_reverse_endian(compute_keccak_byte_array(arr))
+}
+
+/// Reverses the endianness of a u256 value
+/// This is necessary when working with hashes between Cairo and EVM environments
+///
+/// # Arguments
+/// * `input` - The u256 value to reverse
+///
+/// # Returns
+/// * `Bytes32` - The input with byte order reversed
+pub fn u256_reverse_endian(input: u256) -> Bytes32 {
+    let low = u128_byte_reverse(input.high);
+    let high = u128_byte_reverse(input.low);
+    Bytes32 { value: u256 { low, high } }
+}

package/libs/lz_utils/src/lib.cairo

@@ -0,0 +1,3 @@
+pub mod bytes;
+pub mod error;
+pub mod keccak;

package/libs/multisig/Scarb.lock

@@ -0,0 +1,172 @@
+# Code generated by scarb DO NOT EDIT.
+version = 1
+
+[[package]]
+name = "enumerable_set"
+version = "0.1.0"
+
+[[package]]
+name = "lz_utils"
+version = "0.1.0"
+
+[[package]]
+name = "multisig"
+version = "0.1.0"
+dependencies = [
+ "enumerable_set",
+ "lz_utils",
+ "snforge_std",
+ "starkware_utils",
+ "starkware_utils_testing",
+]
+
+[[package]]
+name = "openzeppelin"
+version = "2.0.0"
+source = "registry+https://scarbs.xyz/"
+checksum = "sha256:5e4fdecc957cfca7854d95912dc72d9f725517c063b116512900900add29fd77"
+dependencies = [
+ "openzeppelin_access",
+ "openzeppelin_account",
+ "openzeppelin_finance",
+ "openzeppelin_governance",
+ "openzeppelin_introspection",
+ "openzeppelin_merkle_tree",
+ "openzeppelin_presets",
+ "openzeppelin_security",
+ "openzeppelin_token",
+ "openzeppelin_upgrades",
+ "openzeppelin_utils",
+]
+
+[[package]]
+name = "openzeppelin_access"
+version = "2.0.0"
+source = "registry+https://scarbs.xyz/"
+checksum = "sha256:511681dd26d814ee2bc996d44ff8cb4aaa5ae9d14272130def7eb901cf004850"
+dependencies = [
+ "openzeppelin_introspection",
+]
+
+[[package]]
+name = "openzeppelin_account"
+version = "2.0.0"
+source = "registry+https://scarbs.xyz/"
+checksum = "sha256:fb3381c50d68b028d3801feb43df378e2bd62137b6884844f8f60aefe796188b"
+dependencies = [
+ "openzeppelin_introspection",
+ "openzeppelin_utils",
+]
+
+[[package]]
+name = "openzeppelin_finance"
+version = "2.0.0"
+source = "registry+https://scarbs.xyz/"
+checksum = "sha256:e9456ef69502a87c4c99bf50145351b50950f8b11244847d92935c466c4ba787"
+dependencies = [
+ "openzeppelin_access",
+ "openzeppelin_token",
+]
+
+[[package]]
+name = "openzeppelin_governance"
+version = "2.0.0"
+source = "registry+https://scarbs.xyz/"
+checksum = "sha256:056e6d6f3d48193b53f06283884f8a9675f986fc85425f6a40e8c1aeb3b3ecfa"
+dependencies = [
+ "openzeppelin_access",
+ "openzeppelin_account",
+ "openzeppelin_introspection",
+ "openzeppelin_token",
+ "openzeppelin_utils",
+]
+
+[[package]]
+name = "openzeppelin_introspection"
+version = "2.0.0"
+source = "registry+https://scarbs.xyz/"
+checksum = "sha256:87773ed6cd2318f169283ecbbb161890d1996260a80302d81ec45b70ee5e54c1"
+
+[[package]]
+name = "openzeppelin_merkle_tree"
+version = "2.0.0"
+source = "registry+https://scarbs.xyz/"
+checksum = "sha256:47f80c9ce59557774243214f8e75c5e866f30f3d8daa755855f6ffd01c89ca89"
+
+[[package]]
+name = "openzeppelin_presets"
+version = "2.0.0"
+source = "registry+https://scarbs.xyz/"
+checksum = "sha256:36c761ee923f1dc0887c0eab8c224b49ac242dbfe9163fbb0b08562042ab3d98"
+dependencies = [
+ "openzeppelin_access",
+ "openzeppelin_account",
+ "openzeppelin_finance",
+ "openzeppelin_introspection",
+ "openzeppelin_token",
+ "openzeppelin_upgrades",
+ "openzeppelin_utils",
+]
+
+[[package]]
+name = "openzeppelin_security"
+version = "2.0.0"
+source = "registry+https://scarbs.xyz/"
+checksum = "sha256:902932ec296c2f400e0ac7c579edeaafd6067b6ce6d9854c1191de28e396ffe3"
+
+[[package]]
+name = "openzeppelin_token"
+version = "2.0.0"
+source = "registry+https://scarbs.xyz/"
+checksum = "sha256:6fe61f63b5a6706018265fb7373b6e5bd3ff829bdc760b2b90296b1e708d180c"
+dependencies = [
+ "openzeppelin_access",
+ "openzeppelin_account",
+ "openzeppelin_introspection",
+ "openzeppelin_utils",
+]
+
+[[package]]
+name = "openzeppelin_upgrades"
+version = "2.0.0"
+source = "registry+https://scarbs.xyz/"
+checksum = "sha256:560d57a9c3f3ec5a476e82fec8963c93c8df63a4ff9ff134f64ab8383bde3c61"
+
+[[package]]
+name = "openzeppelin_utils"
+version = "2.0.0"
+source = "registry+https://scarbs.xyz/"
+checksum = "sha256:bf799c794139837f397975ffdf6a7ed5032d198bbf70e87a8f44f144a9dfc505"
+
+[[package]]
+name = "snforge_scarb_plugin"
+version = "0.48.0"
+source = "registry+https://scarbs.xyz/"
+checksum = "sha256:8630dcf3fa4df36a3d45e6a2d053cf84c548ab154e829fece99373ae5852921c"
+
+[[package]]
+name = "snforge_std"
+version = "0.48.0"
+source = "registry+https://scarbs.xyz/"
+checksum = "sha256:981139c83359089540652c44f4a1a888c77409eedaa148377927cc63a604b67b"
+dependencies = [
+ "snforge_scarb_plugin",
+]
+
+[[package]]
+name = "starkware_utils"
+version = "1.0.0"
+source = "git+https://github.com/starkware-libs/starkware-starknet-utils?rev=8a5af9509d93815542b8a701cee22a1b9ec1fe34#8a5af9509d93815542b8a701cee22a1b9ec1fe34"
+dependencies = [
+ "openzeppelin",
+]
+
+[[package]]
+name = "starkware_utils_testing"
+version = "1.0.0"
+source = "git+https://github.com/starkware-libs/starkware-starknet-utils?rev=8a5af9509d93815542b8a701cee22a1b9ec1fe34#8a5af9509d93815542b8a701cee22a1b9ec1fe34"
+dependencies = [
+ "openzeppelin",
+ "snforge_std",
+ "starkware_utils",
+]

package/libs/multisig/Scarb.toml

@@ -0,0 +1,23 @@
+[package]
+name = "multisig"
+version = "0.1.0"
+edition = "2024_07"
+
+# See more keys and their definitions at https://docs.swmansion.com/scarb/docs/reference/manifest.html
+
+[dependencies]
+starknet = "2.12.0"
+starkware_utils = { git = "https://github.com/starkware-libs/starkware-starknet-utils", rev = "8a5af9509d93815542b8a701cee22a1b9ec1fe34" }
+enumerable_set = { path = "../enumerable_set" }
+lz_utils = { path = "../lz_utils" }
+
+[dev-dependencies]
+snforge_std = "0.48.0"
+assert_macros = "2.12.0"
+starkware_utils_testing = { git = "https://github.com/starkware-libs/starkware-starknet-utils", rev = "8a5af9509d93815542b8a701cee22a1b9ec1fe34" }
+
+[scripts]
+test = "snforge test"
+
+[tool.scarb]
+allow-prebuilt-plugins = ["snforge_scarb_plugin", "snforge_std"]

package/libs/multisig/src/errors.cairo

@@ -0,0 +1,84 @@
+use lz_utils::error::{Error, format_error};
+use starknet::EthAddress;
+use starknet::secp256_trait::Signature;
+
+#[derive(Drop)]
+pub enum MultisigError {
+    TotalSignersLessThanThreshold,
+    OnlyMultisig,
+    ZeroThreshold,
+    InvalidSigner,
+    SignerAlreadyAdded,
+    SignerNotFound,
+    SignatureError,
+    UnsortedSigners,
+    ThresholdGreaterThanMaxThreshold,
+    InvalidSignature,
+}
+
+impl ErrorNameImpl of Error<MultisigError> {
+    fn prefix() -> ByteArray {
+        "LZ_MULTISIG"
+    }
+
+    fn name(self: MultisigError) -> ByteArray {
+        match self {
+            MultisigError::TotalSignersLessThanThreshold => "TOTAL_SIGNERS_LESS_THAN_THRESHOLD",
+            MultisigError::OnlyMultisig => "ONLY_MULTISIG",
+            MultisigError::ZeroThreshold => "ZERO_THRESHOLD",
+            MultisigError::InvalidSigner => "INVALID_SIGNER",
+            MultisigError::SignerAlreadyAdded => "SIGNER_ALREADY_ADDED",
+            MultisigError::SignerNotFound => "SIGNER_NOT_FOUND",
+            MultisigError::SignatureError => "SIGNATURE_ERROR",
+            MultisigError::UnsortedSigners => "UNSORTED_SIGNERS",
+            MultisigError::ThresholdGreaterThanMaxThreshold => "THRESHOLD_GREATER_THAN_MAX_THRESHOLD",
+            MultisigError::InvalidSignature => "INVALID_SIGNATURE",
+        }
+    }
+}
+
+
+/// Error messages for the Multisig component
+
+pub fn err_total_signers_less_than_threshold(total_signers: u32, threshold: u32) -> ByteArray {
+    let message = format!("total_signers: {:?}, threshold: {:?}", total_signers, threshold);
+    format_error(MultisigError::TotalSignersLessThanThreshold, message)
+}
+
+pub fn err_only_multisig() -> ByteArray {
+    format_error(MultisigError::OnlyMultisig, "")
+}
+
+pub fn err_zero_threshold() -> ByteArray {
+    format_error(MultisigError::ZeroThreshold, "")
+}
+
+pub fn err_invalid_signer() -> ByteArray {
+    format_error(MultisigError::InvalidSigner, "")
+}
+
+pub fn err_signer_already_added(signer: EthAddress) -> ByteArray {
+    format_error(MultisigError::SignerAlreadyAdded, format!("signer: {:?}", signer))
+}
+
+pub fn err_signer_not_found(signer: EthAddress) -> ByteArray {
+    format_error(MultisigError::SignerNotFound, format!("signer: {:?}", signer))
+}
+
+pub fn err_signature_error() -> ByteArray {
+    format_error(MultisigError::SignatureError, "")
+}
+
+pub fn err_invalid_signature(signature: @Signature) -> ByteArray {
+    format_error(MultisigError::InvalidSignature, format!("signature: {:?}", signature))
+}
+
+pub fn err_unsorted_signers() -> ByteArray {
+    format_error(MultisigError::UnsortedSigners, "")
+}
+
+pub fn err_threshold_greater_than_max_threshold(threshold: u32) -> ByteArray {
+    format_error(
+        MultisigError::ThresholdGreaterThanMaxThreshold, format!("threshold: {:?}", threshold),
+    )
+}

package/libs/multisig/src/events.cairo

@@ -0,0 +1,13 @@
+use starknet::EthAddress;
+
+#[derive(Drop, Debug, PartialEq, starknet::Event)]
+pub struct ThresholdSet {
+    pub threshold: u32,
+}
+
+#[derive(Drop, Debug, PartialEq, starknet::Event)]
+pub struct SignerSet {
+    #[key]
+    pub signer: EthAddress,
+    pub active: bool,
+}

package/libs/multisig/src/interface.cairo

@@ -0,0 +1,73 @@
+use starknet::EthAddress;
+use starknet::secp256_trait::Signature;
+
+/// Multisig
+/// Multisig contract interface for a multisig component
+/// Designed to be used by contracts requiring multi-signature verification with ECDSA verification
+/// Addresses are held as u256 integers but are converted as Bytes from the `alexandria_bytes`
+/// crate to allow better byte manipulation
+#[starknet::interface]
+pub trait IMultisig<TContractState> {
+    /// Allows the Multisig contract to update the signature threshold
+    /// This function can only be called by the MultiSig contract itself
+    ///
+    /// # Arguments
+    ///
+    /// * `threshold`: The new threshold for the Multisig contract
+    fn set_threshold(ref self: TContractState, threshold: u32);
+
+    /// Gets the current signature threshold for the multisig contract
+    ///
+    /// # Returns
+    ///
+    /// * The current threshold as a u32
+    fn get_threshold(self: @TContractState) -> u32;
+
+    /// Adds or removes a signer from this Multisig
+    /// Only callable via the Multisig contract itself
+    ///
+    /// # Arguments
+    ///
+    /// * `signer`: The address of the signer to add or remove
+    /// * `active`: True to add signer, false to remove signer
+    fn set_signer(ref self: TContractState, signer: EthAddress, active: bool);
+
+    /// Checks if a given address is in the set of signers.
+    ///
+    /// # Arguments
+    ///
+    /// * `signer`: The address to check
+    ///
+    /// # Returns
+    ///
+    /// True if the address is in the set of signers, false otherwise.
+    fn is_signer(self: @TContractState, signer: EthAddress) -> bool;
+
+    /// Returns the list of all active signers
+    ///
+    /// # Returns
+    /// An array of addresses representing the current set of signers.
+    fn get_signers(self: @TContractState) -> Array<EthAddress>;
+
+    /// Returns the total number of active signers.
+    ///
+    /// # Returns
+    ///
+    /// The total number of signers currently active.
+    fn total_signers(self: @TContractState) -> u32;
+
+    /// Verifies a list of signatures against a digest
+    ///
+    /// # Arguments
+    ///
+    /// * `digest`: The digest to verify the signatures against
+    /// * `signatures`: The list of signatures to verify
+    fn verify_signatures(self: @TContractState, digest: u256, signatures: Span<Signature>);
+
+    /// Returns the maximum threshold for the multisig
+    ///
+    /// # Returns
+    ///
+    /// The maximum threshold for the multisig
+    fn get_max_threshold(self: @TContractState) -> u32;
+}

package/libs/multisig/src/lib.cairo

@@ -0,0 +1,7 @@
+pub mod errors;
+pub mod events;
+pub mod interface;
+pub mod multisig;
+
+// Re-export commonly used types for easier access
+pub use crate::multisig::MultisigComponent;