@layerzerolabs/oft-evm-contracts 0.2.74

package/artifacts-zk/contracts/libs/OFTComposeMsgCodec.sol/OFTComposeMsgCodec.dbg.json

@@ -0,0 +1,4 @@
+{
+  "_format": "hh-sol-dbg-1",
+  "buildInfo": "../../../build-info/be85166c48418856c8b56dff21efc105.json"
+}

package/artifacts-zk/contracts/libs/OFTComposeMsgCodec.sol/OFTComposeMsgCodec.json

@@ -0,0 +1,11 @@
+{
+  "_format": "hh-zksolc-artifact-1",
+  "contractName": "OFTComposeMsgCodec",
+  "sourceName": "contracts/libs/OFTComposeMsgCodec.sol",
+  "abi": [],
+  "bytecode": "0x00000001012001900000000c0000613d0000008001000039000000400010043f0000000001000416000000000101004b0000000c0000c13d00000020010000390000010000100443000001200000044300000005010000410000000f0001042e000000000100001900000010000104300000000e000004320000000f0001042e0000001000010430000000000000000000000000000000000000000000000000000000020000000000000000000000000000004000000100000000000000000035519ae6770075581a330117a93b2d93129c5b3cd486b7ff9e15a2ea6b4ef814",
+  "deployedBytecode": "0x00000001012001900000000c0000613d0000008001000039000000400010043f0000000001000416000000000101004b0000000c0000c13d00000020010000390000010000100443000001200000044300000005010000410000000f0001042e000000000100001900000010000104300000000e000004320000000f0001042e0000001000010430000000000000000000000000000000000000000000000000000000020000000000000000000000000000004000000100000000000000000035519ae6770075581a330117a93b2d93129c5b3cd486b7ff9e15a2ea6b4ef814",
+  "linkReferences": {},
+  "deployedLinkReferences": {},
+  "factoryDeps": {}
+}

package/artifacts-zk/contracts/libs/OFTMsgCodec.sol/OFTMsgCodec.dbg.json

@@ -0,0 +1,4 @@
+{
+  "_format": "hh-sol-dbg-1",
+  "buildInfo": "../../../build-info/be85166c48418856c8b56dff21efc105.json"
+}

package/artifacts-zk/contracts/libs/OFTMsgCodec.sol/OFTMsgCodec.json

@@ -0,0 +1,11 @@
+{
+  "_format": "hh-zksolc-artifact-1",
+  "contractName": "OFTMsgCodec",
+  "sourceName": "contracts/libs/OFTMsgCodec.sol",
+  "abi": [],
+  "bytecode": "0x00000001012001900000000c0000613d0000008001000039000000400010043f0000000001000416000000000101004b0000000c0000c13d00000020010000390000010000100443000001200000044300000005010000410000000f0001042e000000000100001900000010000104300000000e000004320000000f0001042e00000010000104300000000000000000000000000000000000000000000000000000000200000000000000000000000000000040000001000000000000000000a3a5f3688c77c3177737c078ccad07d7eea2ebfbad2585d54ced6965fc9bba11",
+  "deployedBytecode": "0x00000001012001900000000c0000613d0000008001000039000000400010043f0000000001000416000000000101004b0000000c0000c13d00000020010000390000010000100443000001200000044300000005010000410000000f0001042e000000000100001900000010000104300000000e000004320000000f0001042e00000010000104300000000000000000000000000000000000000000000000000000000200000000000000000000000000000040000001000000000000000000a3a5f3688c77c3177737c078ccad07d7eea2ebfbad2585d54ced6965fc9bba11",
+  "linkReferences": {},
+  "deployedLinkReferences": {},
+  "factoryDeps": {}
+}

package/artifacts-zk/contracts/utils/OFTDecimalUtils.sol/OFTDecimalUtils.dbg.json

@@ -0,0 +1,4 @@
+{
+  "_format": "hh-sol-dbg-1",
+  "buildInfo": "../../../build-info/be85166c48418856c8b56dff21efc105.json"
+}

package/artifacts-zk/contracts/utils/OFTDecimalUtils.sol/OFTDecimalUtils.json

@@ -0,0 +1,67 @@
+{
+  "_format": "hh-zksolc-artifact-1",
+  "contractName": "OFTDecimalUtils",
+  "sourceName": "contracts/utils/OFTDecimalUtils.sol",
+  "abi": [
+    {
+      "inputs": [
+        {
+          "internalType": "uint256",
+          "name": "amountSD",
+          "type": "uint256"
+        }
+      ],
+      "name": "AmountSDOverflowed",
+      "type": "error"
+    },
+    {
+      "inputs": [],
+      "name": "InvalidLocalDecimals",
+      "type": "error"
+    },
+    {
+      "inputs": [],
+      "name": "decimalConversionRate",
+      "outputs": [
+        {
+          "internalType": "uint256",
+          "name": "rate",
+          "type": "uint256"
+        }
+      ],
+      "stateMutability": "view",
+      "type": "function"
+    },
+    {
+      "inputs": [],
+      "name": "localDecimals",
+      "outputs": [
+        {
+          "internalType": "uint8",
+          "name": "ld",
+          "type": "uint8"
+        }
+      ],
+      "stateMutability": "view",
+      "type": "function"
+    },
+    {
+      "inputs": [],
+      "name": "sharedDecimals",
+      "outputs": [
+        {
+          "internalType": "uint8",
+          "name": "sd",
+          "type": "uint8"
+        }
+      ],
+      "stateMutability": "view",
+      "type": "function"
+    }
+  ],
+  "bytecode": "0x",
+  "deployedBytecode": "0x",
+  "linkReferences": {},
+  "deployedLinkReferences": {},
+  "factoryDeps": {}
+}

package/contracts/interfaces/IOFT.sol

@@ -0,0 +1,158 @@
+// SPDX-License-Identifier: MIT
+pragma solidity ^0.8.22;
+
+import {
+    MessagingReceipt,
+    MessagingFee
+} from "@layerzerolabs/lz-evm-protocol-v2/contracts/interfaces/ILayerZeroEndpointV2.sol";
+
+/**
+ * @dev Struct representing token parameters for the OFT send() operation.
+ */
+struct SendParam {
+    uint32 dstEid; // Destination endpoint ID.
+    bytes32 to; // Recipient address.
+    uint256 amountLD; // Amount to send in local decimals.
+    uint256 minAmountLD; // Minimum amount to send in local decimals.
+    bytes extraOptions; // Additional options supplied by the caller to be used in the LayerZero message.
+    bytes composeMsg; // The composed message for the send() operation.
+    bytes oftCmd; // The OFT command to be executed, unused in default OFT implementations.
+}
+
+/**
+ * @dev Struct representing OFT limit information.
+ * @dev These amounts can change dynamically and are up the specific oft implementation.
+ */
+struct OFTLimit {
+    uint256 minAmountLD; // Minimum amount in local decimals that can be sent to the recipient.
+    uint256 maxAmountLD; // Maximum amount in local decimals that can be sent to the recipient.
+}
+
+/**
+ * @dev Struct representing OFT receipt information.
+ */
+struct OFTReceipt {
+    uint256 amountSentLD; // Amount of tokens ACTUALLY debited from the sender in local decimals.
+    // @dev In non-default implementations, the amountReceivedLD COULD differ from this value.
+    uint256 amountReceivedLD; // Amount of tokens to be received on the remote side.
+}
+
+/**
+ * @dev Struct representing OFT fee details.
+ * @dev Future proof mechanism to provide a standardized way to communicate fees to things like a UI.
+ */
+struct OFTFeeDetail {
+    int256 feeAmountLD; // Amount of the fee in local decimals.
+    string description; // Description of the fee.
+}
+
+/**
+ * @title IOFT
+ * @dev Interface for the OftChain (OFT) token.
+ * @dev Does not inherit ERC20 to accommodate usage by OFTAdapter as well.
+ * @dev This specific interface ID is '0x02e49c2c'.
+ */
+interface IOFT {
+    // Custom error messages
+    error InvalidLocalDecimals();
+    error SlippageExceeded(uint256 amountLD, uint256 minAmountLD);
+    error AmountSDOverflowed(uint256 amountSD);
+
+    // Events
+    event OFTSent(
+        bytes32 indexed guid, // GUID of the OFT message.
+        uint32 dstEid, // Destination Endpoint ID.
+        address indexed fromAddress, // Address of the sender on the src chain.
+        uint256 amountSentLD, // Amount of tokens sent in local decimals.
+        uint256 amountReceivedLD // Amount of tokens received in local decimals.
+    );
+    event OFTReceived(
+        bytes32 indexed guid, // GUID of the OFT message.
+        uint32 srcEid, // Source Endpoint ID.
+        address indexed toAddress, // Address of the recipient on the dst chain.
+        uint256 amountReceivedLD // Amount of tokens received in local decimals.
+    );
+
+    /**
+     * @notice Retrieves interfaceID and the version of the OFT.
+     * @return interfaceId The interface ID.
+     * @return version The version.
+     *
+     * @dev interfaceId: This specific interface ID is '0x02e49c2c'.
+     * @dev version: Indicates a cross-chain compatible msg encoding with other OFTs.
+     * @dev If a new feature is added to the OFT cross-chain msg encoding, the version will be incremented.
+     * ie. localOFT version(x,1) CAN send messages to remoteOFT version(x,1)
+     */
+    function oftVersion() external view returns (bytes4 interfaceId, uint64 version);
+
+    /**
+     * @notice Retrieves the address of the token associated with the OFT.
+     * @return tokenAddress The address of the ERC20 token implementation.
+     */
+    function token() external view returns (address tokenAddress);
+
+    /**
+     * @notice Indicates whether the OFT contract requires approval of the 'token()' to send.
+     * @return requiresApproval Needs approval of the underlying token implementation.
+     *
+     * @dev Allows things like wallet implementers to determine integration requirements,
+     * without understanding the underlying token implementation.
+     */
+    function approvalRequired() external view returns (bool requiresApproval);
+
+    /**
+     * @notice Retrieves the shared decimals of the OFT.
+     * @return sd The shared decimals of the OFT.
+     */
+    function sharedDecimals() external view returns (uint8 sd);
+
+    /**
+     * @notice Provides the fee breakdown and settings data for an OFT. Unused in the default implementation.
+     * @param _sendParam The parameters for the send operation.
+     * @return oftLimit The OFT limit information.
+     * @return oftFeeDetails The details of OFT fees.
+     * @return oftReceipt The OFT receipt information.
+     */
+    function quoteOFT(
+        SendParam calldata _sendParam
+    )
+        external
+        view
+        returns (OFTLimit memory oftLimit, OFTFeeDetail[] memory oftFeeDetails, OFTReceipt memory oftReceipt);
+
+    /**
+     * @notice Provides a quote for the send() operation.
+     * @param _sendParam The parameters for the send() operation.
+     * @param _payInLzToken Flag indicating whether the caller is paying in the LZ token.
+     * @return msgFee The calculated LayerZero messaging fee from the send() operation.
+     *
+     * @dev MessagingFee: LayerZero msg fee
+     *  - nativeFee: The native fee.
+     *  - lzTokenFee: The lzToken fee.
+     */
+    function quoteSend(
+        SendParam calldata _sendParam,
+        bool _payInLzToken
+    ) external view returns (MessagingFee memory msgFee);
+
+    /**
+     * @notice Executes the send() operation.
+     * @param _sendParam The parameters for the send operation.
+     * @param _fee The fee information supplied by the caller.
+     *      - nativeFee: The native fee.
+     *      - lzTokenFee: The lzToken fee.
+     * @param _refundAddress The address to receive any excess funds from fees etc. on the src.
+     * @return msgReceipt The LayerZero messaging receipt from the send() operation.
+     * @return oftReceipt The OFT receipt information.
+     *
+     * @dev MessagingReceipt: LayerZero msg receipt
+     *  - guid: The unique identifier for the sent message.
+     *  - nonce: The nonce of the sent message.
+     *  - fee: The LayerZero fee incurred for the message.
+     */
+    function send(
+        SendParam calldata _sendParam,
+        MessagingFee calldata _fee,
+        address _refundAddress
+    ) external payable returns (MessagingReceipt memory msgReceipt, OFTReceipt memory oftReceipt);
+}

package/contracts/interfaces/IOFTDecimalUtils.sol

@@ -0,0 +1,39 @@
+// SPDX-License-Identifier: MIT
+pragma solidity ^0.8.22;
+
+/**
+ * @title IOFTDecimalUtils
+ * @author LayerZero Labs (tinom.eth)
+ * @custom:version 1.0.0
+ * @notice Interface for OFT decimal conversion utilities.
+ */
+interface IOFTDecimalUtils {
+    /**
+     * @notice Thrown when shared decimals exceed local decimals.
+     */
+    error InvalidLocalDecimals();
+
+    /**
+     * @notice Thrown when the amount in shared decimals overflows `uint64`.
+     * @param amountSD Amount in shared decimals
+     */
+    error AmountSDOverflowed(uint256 amountSD);
+
+    /**
+     * @notice Returns the local decimals for tokens on this chain.
+     * @return ld Local decimals
+     */
+    function localDecimals() external view returns (uint8 ld);
+
+    /**
+     * @notice Returns the shared decimals for cross-chain messaging.
+     * @return sd Shared decimals
+     */
+    function sharedDecimals() external view returns (uint8 sd);
+
+    /**
+     * @notice Returns the conversion rate to convert from local to shared decimals.
+     * @return rate Conversion rate
+     */
+    function decimalConversionRate() external view returns (uint256 rate);
+}

package/contracts/interfaces/IOFTExtended.sol

@@ -0,0 +1,17 @@
+// SPDX-License-Identifier: MIT
+pragma solidity ^0.8.22;
+
+import { IOAppExtended } from "@layerzerolabs/oapp-evm-contracts/contracts/interfaces/IOAppExtended.sol";
+import { IFeeConfig } from "@layerzerolabs/utils-evm-contracts/contracts/interfaces/IFeeConfig.sol";
+import { IFeeHandler } from "@layerzerolabs/utils-evm-contracts/contracts/interfaces/IFeeHandler.sol";
+import { IPauseByID } from "@layerzerolabs/utils-evm-contracts/contracts/interfaces/IPauseByID.sol";
+import { IRateLimiter } from "@layerzerolabs/utils-evm-contracts/contracts/interfaces/IRateLimiter.sol";
+import { IOFT } from "./IOFT.sol";
+
+/**
+ * @title IOFTExtended
+ * @author LayerZero Labs (@TRileySchwarz, tinom.eth)
+ * @custom:version 1.0.0
+ * @notice Interface for extended OFT contracts with fee, pause, and rate limiter functionality.
+ */
+interface IOFTExtended is IOFT, IOAppExtended, IFeeConfig, IFeeHandler, IPauseByID, IRateLimiter {}

package/contracts/libs/OFTComposeMsgCodec.sol

@@ -0,0 +1,90 @@
+// SPDX-License-Identifier: MIT
+pragma solidity ^0.8.22;
+
+library OFTComposeMsgCodec {
+    // Offset constants for decoding composed messages
+    uint8 private constant NONCE_OFFSET = 8;
+    uint8 private constant SRC_EID_OFFSET = 12;
+    uint8 private constant AMOUNT_LD_OFFSET = 44;
+    uint8 private constant COMPOSE_FROM_OFFSET = 76;
+
+    /**
+     * @dev Encodes a OFT composed message.
+     * @param _nonce The nonce value.
+     * @param _srcEid The source endpoint ID.
+     * @param _amountLD The amount in local decimals.
+     * @param _composeMsg The composed message.
+     * @return _msg The encoded Composed message.
+     */
+    function encode(
+        uint64 _nonce,
+        uint32 _srcEid,
+        uint256 _amountLD,
+        bytes memory _composeMsg // 0x[composeFrom][composeMsg]
+    ) internal pure returns (bytes memory _msg) {
+        _msg = abi.encodePacked(_nonce, _srcEid, _amountLD, _composeMsg);
+    }
+
+    /**
+     * @dev Retrieves the nonce for the composed message.
+     * @param _msg The message.
+     * @return The nonce value.
+     */
+    function nonce(bytes calldata _msg) internal pure returns (uint64) {
+        return uint64(bytes8(_msg[:NONCE_OFFSET]));
+    }
+
+    /**
+     * @dev Retrieves the source endpoint ID for the composed message.
+     * @param _msg The message.
+     * @return The source endpoint ID.
+     */
+    function srcEid(bytes calldata _msg) internal pure returns (uint32) {
+        return uint32(bytes4(_msg[NONCE_OFFSET:SRC_EID_OFFSET]));
+    }
+
+    /**
+     * @dev Retrieves the amount in local decimals from the composed message.
+     * @param _msg The message.
+     * @return The amount in local decimals.
+     */
+    function amountLD(bytes calldata _msg) internal pure returns (uint256) {
+        return uint256(bytes32(_msg[SRC_EID_OFFSET:AMOUNT_LD_OFFSET]));
+    }
+
+    /**
+     * @dev Retrieves the composeFrom value from the composed message.
+     * @param _msg The message.
+     * @return The composeFrom value.
+     */
+    function composeFrom(bytes calldata _msg) internal pure returns (bytes32) {
+        return bytes32(_msg[AMOUNT_LD_OFFSET:COMPOSE_FROM_OFFSET]);
+    }
+
+    /**
+     * @dev Retrieves the composed message.
+     * @param _msg The message.
+     * @return The composed message.
+     */
+    function composeMsg(bytes calldata _msg) internal pure returns (bytes memory) {
+        return _msg[COMPOSE_FROM_OFFSET:];
+    }
+
+    /**
+     * @dev Converts an address to bytes32.
+     * @param _addr The address to convert.
+     * @return The bytes32 representation of the address.
+     */
+    function addressToBytes32(address _addr) internal pure returns (bytes32) {
+        return bytes32(uint256(uint160(_addr)));
+    }
+
+    /**
+     * @dev Converts bytes32 to an address.
+     * @param _b The bytes32 value to convert.
+     * @return The address representation of bytes32.
+     */
+    function bytes32ToAddress(bytes32 _b) internal pure returns (address) {
+        return address(uint160(uint256(_b)));
+    }
+}

package/contracts/libs/OFTMsgCodec.sol

@@ -0,0 +1,82 @@
+// SPDX-License-Identifier: MIT
+pragma solidity ^0.8.22;
+
+library OFTMsgCodec {
+    // Offset constants for encoding and decoding OFT messages
+    uint8 private constant SEND_TO_OFFSET = 32;
+    uint8 private constant SEND_AMOUNT_SD_OFFSET = 40;
+
+    /**
+     * @dev Encodes an OFT LayerZero message.
+     * @param _sendTo The recipient address.
+     * @param _amountShared The amount in shared decimals.
+     * @param _composeMsg The composed message.
+     * @return _msg The encoded message.
+     * @return hasCompose A boolean indicating whether the message has a composed payload.
+     */
+    function encode(
+        bytes32 _sendTo,
+        uint64 _amountShared,
+        bytes memory _composeMsg
+    ) internal view returns (bytes memory _msg, bool hasCompose) {
+        hasCompose = _composeMsg.length > 0;
+        // @dev Remote chains will want to know the composed function caller ie. msg.sender on the src.
+        _msg = hasCompose
+            ? abi.encodePacked(_sendTo, _amountShared, addressToBytes32(msg.sender), _composeMsg)
+            : abi.encodePacked(_sendTo, _amountShared);
+    }
+
+    /**
+     * @dev Checks if the OFT message is composed.
+     * @param _msg The OFT message.
+     * @return A boolean indicating whether the message is composed.
+     */
+    function isComposed(bytes calldata _msg) internal pure returns (bool) {
+        return _msg.length > SEND_AMOUNT_SD_OFFSET;
+    }
+
+    /**
+     * @dev Retrieves the recipient address from the OFT message.
+     * @param _msg The OFT message.
+     * @return The recipient address.
+     */
+    function sendTo(bytes calldata _msg) internal pure returns (bytes32) {
+        return bytes32(_msg[:SEND_TO_OFFSET]);
+    }
+
+    /**
+     * @dev Retrieves the amount in shared decimals from the OFT message.
+     * @param _msg The OFT message.
+     * @return The amount in shared decimals.
+     */
+    function amountSD(bytes calldata _msg) internal pure returns (uint64) {
+        return uint64(bytes8(_msg[SEND_TO_OFFSET:SEND_AMOUNT_SD_OFFSET]));
+    }
+
+    /**
+     * @dev Retrieves the composed message from the OFT message.
+     * @param _msg The OFT message.
+     * @return The composed message.
+     */
+    function composeMsg(bytes calldata _msg) internal pure returns (bytes memory) {
+        return _msg[SEND_AMOUNT_SD_OFFSET:];
+    }
+
+    /**
+     * @dev Converts an address to bytes32.
+     * @param _addr The address to convert.
+     * @return The bytes32 representation of the address.
+     */
+    function addressToBytes32(address _addr) internal pure returns (bytes32) {
+        return bytes32(uint256(uint160(_addr)));
+    }
+
+    /**
+     * @dev Converts bytes32 to an address.
+     * @param _b The bytes32 value to convert.
+     * @return The address representation of bytes32.
+     */
+    function bytes32ToAddress(bytes32 _b) internal pure returns (address) {
+        return address(uint160(uint256(_b)));
+    }
+}

package/contracts/utils/OFTDecimalUtils.sol

@@ -0,0 +1,88 @@
+// SPDX-License-Identifier: MIT
+pragma solidity ^0.8.22;
+
+import { IOFTDecimalUtils } from "../interfaces/IOFTDecimalUtils.sol";
+
+/**
+ * @title OFTDecimalUtils
+ * @author LayerZero Labs (@TRileySchwarz, tinom.eth)
+ * @custom:version 1.0.0
+ * @notice Abstract contract that implements decimal conversion utilities between local and shared decimals.
+ * @dev It can be inherited in either upgradeable or non-upgradeable contracts.
+ */
+abstract contract OFTDecimalUtils is IOFTDecimalUtils {
+    /// @dev Immutable variable for local decimals.
+    uint8 private immutable LOCAL_DECIMALS;
+
+    /// @dev Immutable variable for shared decimals.
+    uint8 private immutable SHARED_DECIMALS;
+
+    /// @dev Immutable variable for the conversion rate between local and shared decimals.
+    uint256 private immutable DECIMAL_CONVERSION_RATE;
+
+    /**
+     * @dev Sets immutable variables.
+     * @dev Reverts if the shared decimals are greater than the local decimals.
+     * @param _localDecimals Local decimals for tokens on this chain
+     * @param _sharedDecimals Shared decimals for cross-chain messaging
+     */
+    constructor(uint8 _localDecimals, uint8 _sharedDecimals) {
+        if (_sharedDecimals > _localDecimals) revert InvalidLocalDecimals();
+
+        LOCAL_DECIMALS = _localDecimals;
+        SHARED_DECIMALS = _sharedDecimals;
+        DECIMAL_CONVERSION_RATE = 10 ** (_localDecimals - _sharedDecimals);
+    }
+
+    /**
+     * @inheritdoc IOFTDecimalUtils
+     */
+    function localDecimals() public view virtual returns (uint8 ld) {
+        return LOCAL_DECIMALS;
+    }
+
+    /**
+     * @inheritdoc IOFTDecimalUtils
+     */
+    function sharedDecimals() public view virtual returns (uint8 sd) {
+        return SHARED_DECIMALS;
+    }
+
+    /**
+     * @inheritdoc IOFTDecimalUtils
+     */
+    function decimalConversionRate() public view virtual returns (uint256 rate) {
+        return DECIMAL_CONVERSION_RATE;
+    }
+
+    /**
+     * @notice Removes dust from the given local decimal amount.
+     * @dev Prevents the loss of dust when moving amounts between chains with different decimals.
+     * @param _amountLD Amount in local decimals
+     * @return amountLD Amount after removing dust
+     */
+    function _removeDust(uint256 _amountLD) internal view virtual returns (uint256 amountLD) {
+        return (_amountLD / DECIMAL_CONVERSION_RATE) * DECIMAL_CONVERSION_RATE;
+    }
+
+    /**
+     * @notice Converts an amount from shared decimals into local decimals.
+     * @param _amountSD Amount in shared decimals
+     * @return amountLD Amount in local decimals
+     */
+    function _toLD(uint64 _amountSD) internal view virtual returns (uint256 amountLD) {
+        return _amountSD * DECIMAL_CONVERSION_RATE;
+    }
+
+    /**
+     * @notice Converts an amount from local decimals into shared decimals.
+     * @dev Reverts if the amount in shared decimals overflows `uint64`.
+     * @param _amountLD Amount in local decimals
+     * @return amountSD Amount in shared decimals
+     */
+    function _toSD(uint256 _amountLD) internal view virtual returns (uint64 amountSD) {
+        uint256 _amountSD = _amountLD / DECIMAL_CONVERSION_RATE;
+        if (_amountSD > type(uint64).max) revert AmountSDOverflowed(_amountSD);
+        return uint64(_amountSD);
+    }
+}

package/foundry.toml

@@ -0,0 +1,21 @@
+[profile.default]
+solc = '0.8.22'
+verbosity = 3
+src = "contracts"
+test = "test"
+out = "artifacts"
+cache_path = "cache"
+libs = ['node_modules', 'node_modules/@layerzerolabs/toolbox-foundry/lib']
+optimizer = true
+optimizer_runs = 200
+
+remappings = [
+    'ds-test/=node_modules/@layerzerolabs/toolbox-foundry/lib/ds-test/',
+    'forge-std/=node_modules/@layerzerolabs/toolbox-foundry/lib/forge-std/',
+    'solidity-bytes-utils/contracts/=node_modules/@layerzerolabs/toolbox-foundry/lib/solidity-bytes-utils/',
+    '@openzeppelin/=node_modules/@openzeppelin/',
+    '@layerzerolabs/=node_modules/@layerzerolabs/',
+]
+
+[fuzz]
+runs = 1000

package/package.json

@@ -0,0 +1,44 @@
+{
+  "name": "@layerzerolabs/oft-evm-contracts",
+  "version": "0.2.74",
+  "private": false,
+  "description": "LayerZero Labs reference EVM OFT implementation",
+  "license": "MIT",
+  "devDependencies": {
+    "@layerzerolabs/lz-evm-messagelib-v2": "3.0.167",
+    "@layerzerolabs/lz-evm-protocol-v2": "3.0.167",
+    "@layerzerolabs/lz-evm-v1-0.7": "3.0.167",
+    "@layerzerolabs/test-devtools-evm-foundry": "8.0.1",
+    "@layerzerolabs/toolbox-foundry": "^0.1.13",
+    "@openzeppelin/contracts": "^5.0.2",
+    "@openzeppelin/contracts-upgradeable": "^5.0.2",
+    "ethers": "^5.8.0",
+    "solhint": "^6.0.1",
+    "@layerzerolabs/oapp-evm-contracts": "0.2.74",
+    "@layerzerolabs/tsup-configuration": "0.2.74",
+    "@layerzerolabs/typescript-configuration": "0.2.74",
+    "@layerzerolabs/utils-evm-contracts": "0.2.74",
+    "@layerzerolabs/solhint-configuration": "0.2.74",
+    "@layerzerolabs/vm-tooling-evm": "0.2.74"
+  },
+  "publishConfig": {
+    "access": "restricted",
+    "registry": "https://registry.npmjs.org/"
+  },
+  "externalRepoConfig": {
+    "targets": [
+      "audit-external",
+      "monorepo-external"
+    ]
+  },
+  "scripts": {
+    "build": "pnpm compile:evm && pnpm compile:zksync && pnpm compile:tron",
+    "clean": "rm -rf ./node_modules .turbo ./dist && pnpm generated:clean",
+    "compile:evm": "pnpm lz-tool hardhat compile --config /hardhat/hardhat.default.config.js",
+    "compile:tron": "pnpm lz-tool hardhat compile --config /hardhat/hardhat.default.config.js --network tron-mainnet",
+    "compile:zksync": "pnpm lz-tool hardhat compile --config /hardhat/hardhat.default.config.js --network zksync-mainnet",
+    "generated:clean": "rm -rf ./artifacts ./artifacts-tron ./artifacts-zk ./hh-cache ./hh-cache-tron ./hh-cache-zk",
+    "lint": "solhint --config solhint.config.js 'contracts/**/*.sol' 'test/**/*.sol' --fix --noPrompt",
+    "test": "pnpm lz-tool forge test"
+  }
+}

package/solhint.config.js

@@ -0,0 +1,3 @@
+const baseConfig = require('@layerzerolabs/solhint-configuration');
+
+module.exports = baseConfig;