@layerzerolabs/oapp-evm-contracts 0.2.74

package/.turbo/turbo-lint.log

@@ -0,0 +1,56 @@
+
+> @layerzerolabs/oapp-evm-contracts@0.0.0 lint /home/runner/work/monorepo-internal/monorepo-internal/apps/oapp-app/contracts/evm/non-upgradeable
+> solhint --config solhint.config.js 'contracts/**/*.sol' 'test/**/*.sol' --fix --noPrompt
+
+A new version of Solhint is available: 6.2.1
+Please consider updating your Solhint package.
+
+contracts/interfaces/IOAppComposer.sol
+  11:1  warning  Missing @title tag in contract 'IOAppComposer'   use-natspec
+  11:1  warning  Missing @author tag in contract 'IOAppComposer'  use-natspec
+  11:1  warning  Missing @notice tag in contract 'IOAppComposer'  use-natspec
+
+contracts/interfaces/IOAppCore.sol
+   9:1  warning  Missing @author tag in contract 'IOAppCore'                                     use-natspec
+   9:1  warning  Missing @notice tag in contract 'IOAppCore'                                     use-natspec
+  17:5  warning  Missing @notice tag in event 'PeerSet'                                          use-natspec
+  17:5  warning  Missing @param tag in event 'PeerSet'                                           use-natspec
+  17:5  warning  Mismatch in @param names for event 'PeerSet'. Expected: [eid, peer], Found: []  use-natspec
+  17:5  warning  GC: [eid] on Event [PeerSet] could be Indexed                                   gas-indexed-events
+
+contracts/interfaces/IOAppExtended.sol
+  17:1  warning  Code contains empty blocks  no-empty-blocks
+
+contracts/interfaces/IOAppMsgInspection.sol
+  15:5  warning  GC: [msgInspector] on Event [MsgInspectorSet] could be Indexed  gas-indexed-events
+
+contracts/interfaces/IOAppReceiver.sol
+  9:1  warning  Missing @title tag in contract 'IOAppReceiver'   use-natspec
+  9:1  warning  Missing @author tag in contract 'IOAppReceiver'  use-natspec
+  9:1  warning  Missing @notice tag in contract 'IOAppReceiver'  use-natspec
+
+contracts/oapp/libs/OptionsBuilder.sol
+   13:1  warning  Missing @author tag in contract 'OptionsBuilder'                                                                       use-natspec
+   13:1  warning  Missing @notice tag in contract 'OptionsBuilder'                                                                       use-natspec
+   36:5  warning  Missing @notice tag in function 'newOptions'                                                                           use-natspec
+   51:5  warning  Missing @notice tag in function 'addExecutorLzReceiveOption'                                                           use-natspec
+   69:5  warning  Missing @notice tag in function 'addExecutorNativeDropOption'                                                          use-natspec
+   87:5  warning  Missing @notice tag in function 'addExecutorLzReadOption'                                                              use-natspec
+   87:5  warning  Missing @param tag in function 'addExecutorLzReadOption'                                                               use-natspec
+   87:5  warning  Mismatch in @param names for function 'addExecutorLzReadOption'. Expected: [_options, _gas, _size, _value], Found: []  use-natspec
+   87:5  warning  Missing @return tag in function 'addExecutorLzReadOption'                                                              use-natspec
+   87:5  warning  Mismatch in @return count for function 'addExecutorLzReadOption'. Expected: 1, Found: 0                                use-natspec
+  109:5  warning  Missing @notice tag in function 'addExecutorLzComposeOption'                                                           use-natspec
+  124:5  warning  Missing @notice tag in function 'addExecutorOrderedExecutionOption'                                                    use-natspec
+  136:5  warning  Missing @notice tag in function 'addDVNPreCrimeOption'                                                                 use-natspec
+  150:5  warning  Missing @notice tag in function 'addExecutorOption'                                                                    use-natspec
+  173:5  warning  Missing @notice tag in function 'addDVNOption'                                                                         use-natspec
+  195:5  warning  Missing @notice tag in function 'encodeLegacyOptionsType1'                                                             use-natspec
+  207:5  warning  Missing @notice tag in function 'encodeLegacyOptionsType2'                                                             use-natspec
+
+✖ 31 problems (0 errors, 31 warnings)
+
+ -------------------------------------------------------------------------- 
+ ===> Join SOLHINT Community at: https://discord.com/invite/4TYGq3zpjs <=== 
+ -------------------------------------------------------------------------- 
+

package/LICENSE

@@ -0,0 +1,23 @@
+Copyright (c) 2026 - LayerZero Labs Ltd.
+
+Permission is hereby granted, free of charge, to any
+person obtaining a copy of this software and associated
+documentation files (the "Software"), to deal in the
+Software without restriction, including without
+limitation the rights to use, copy, modify, merge,
+publish, distribute, sublicense, and/or sell copies of
+the Software, and to permit persons to whom the Software
+is furnished to do so, subject to the following
+conditions:
+The above copyright notice and this permission notice
+shall be included in all copies or substantial portions
+of the Software.
+THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF
+ANY KIND, EXPRESS OR IMPLIED, INCLUDING BUT NOT LIMITED
+TO THE WARRANTIES OF MERCHANTABILITY, FITNESS FOR A
+PARTICULAR PURPOSE AND NONINFRINGEMENT. IN NO EVENT
+SHALL THE AUTHORS OR COPYRIGHT HOLDERS BE LIABLE FOR ANY
+CLAIM, DAMAGES OR OTHER LIABILITY, WHETHER IN AN ACTION
+OF CONTRACT, TORT OR OTHERWISE, ARISING FROM, OUT OF OR
+IN CONNECTION WITH THE SOFTWARE OR THE USE OR OTHER
+DEALINGS IN THE SOFTWARE.

package/contracts/interfaces/IOAppAlt.sol

@@ -0,0 +1,20 @@
+// SPDX-License-Identifier: MIT
+pragma solidity ^0.8.22;
+
+/**
+ * @title IOAppAlt
+ * @author LayerZero Labs (@TRileySchwarz, tinom.eth)
+ * @custom:version 1.0.0
+ * @notice Interface for the `OAppAlt` contract.
+ */
+interface IOAppAlt {
+    /**
+     * @dev Thrown when the native token is not set, possibly due to the endpoint not being an `EndpointV2Alt`.
+     */
+    error InvalidNativeToken();
+
+    /**
+     * @dev Thrown when the native fee is paid with `msg.value`.
+     */
+    error OnlyAltToken();
+}

package/contracts/interfaces/IOAppComposer.sol

@@ -0,0 +1,11 @@
+// SPDX-License-Identifier: MIT
+pragma solidity ^0.8.22;
+
+import { ILayerZeroComposer } from "@layerzerolabs/lz-evm-protocol-v2/contracts/interfaces/ILayerZeroComposer.sol";
+
+/**
+ * @title IOAppComposer
+ * @dev This interface defines the OApp Composer, allowing developers to inherit only the OApp package without the protocol.
+ */
+// solhint-disable-next-line no-empty-blocks
+interface IOAppComposer is ILayerZeroComposer {}

package/contracts/interfaces/IOAppCore.sol

@@ -0,0 +1,51 @@
+// SPDX-License-Identifier: MIT
+pragma solidity ^0.8.22;
+
+import { ILayerZeroEndpointV2 } from "@layerzerolabs/lz-evm-protocol-v2/contracts/interfaces/ILayerZeroEndpointV2.sol";
+
+/**
+ * @title IOAppCore
+ */
+interface IOAppCore {
+    // Custom error messages
+    error OnlyPeer(uint32 eid, bytes32 sender);
+    error NoPeer(uint32 eid);
+    error InvalidEndpointCall();
+    error InvalidDelegate();
+
+    // Event emitted when a peer (OApp) is set for a corresponding endpoint
+    event PeerSet(uint32 eid, bytes32 peer);
+
+    /**
+     * @notice Retrieves the OApp version information.
+     * @return senderVersion The version of the OAppSender.sol contract.
+     * @return receiverVersion The version of the OAppReceiver.sol contract.
+     */
+    function oAppVersion() external view returns (uint64 senderVersion, uint64 receiverVersion);
+
+    /**
+     * @notice Retrieves the LayerZero endpoint associated with the OApp.
+     * @return iEndpoint The LayerZero endpoint as an interface.
+     */
+    function endpoint() external view returns (ILayerZeroEndpointV2 iEndpoint);
+
+    /**
+     * @notice Retrieves the peer (OApp) associated with a corresponding endpoint.
+     * @param _eid The endpoint ID.
+     * @return peer The peer address (OApp instance) associated with the corresponding endpoint.
+     */
+    function peers(uint32 _eid) external view returns (bytes32 peer);
+
+    /**
+     * @notice Sets the peer address (OApp instance) for a corresponding endpoint.
+     * @param _eid The endpoint ID.
+     * @param _peer The address of the peer to be associated with the corresponding endpoint.
+     */
+    function setPeer(uint32 _eid, bytes32 _peer) external;
+
+    /**
+     * @notice Sets the delegate address for the OApp Core.
+     * @param _delegate The address of the delegate to be set.
+     */
+    function setDelegate(address _delegate) external;
+}

package/contracts/interfaces/IOAppExtended.sol

@@ -0,0 +1,17 @@
+// SPDX-License-Identifier: MIT
+pragma solidity ^0.8.22;
+
+import { IOAppCore } from "./IOAppCore.sol";
+import { IOAppMsgInspection } from "./IOAppMsgInspection.sol";
+import { IOAppOptionsType3 } from "./IOAppOptionsType3.sol";
+import { IOAppReceiver } from "./IOAppReceiver.sol";
+
+/**
+ * @title IOAppExtended
+ * @author LayerZero Labs (@TRileySchwarz, tinom.eth)
+ * @custom:version 1.0.0
+ * @notice Aggregate interface for extended OApp contracts.
+ * @dev `IOAppReceiver` must precede `IOAppCore` for C3 linearization compatibility with `OApp`,
+ *      where `OAppReceiver`'s linearization places `IOAppReceiver` before `IOAppCore`.
+ */
+interface IOAppExtended is IOAppReceiver, IOAppCore, IOAppOptionsType3, IOAppMsgInspection {}

package/contracts/interfaces/IOAppMsgInspection.sol

@@ -0,0 +1,28 @@
+// SPDX-License-Identifier: MIT
+pragma solidity ^0.8.22;
+
+/**
+ * @title IOAppMsgInspection
+ * @author LayerZero Labs (@TRileySchwarz, tinom.eth)
+ * @custom:version 1.0.0
+ * @notice Interface for the `OAppMsgInspection` contract.
+ */
+interface IOAppMsgInspection {
+    /**
+     * @notice Emitted when a new message inspector is set.
+     * @param msgInspector Address of the new message inspector
+     */
+    event MsgInspectorSet(address msgInspector);
+
+    /**
+     * @notice Retrieves the message inspector address.
+     * @return inspector Address of the message inspector
+     */
+    function msgInspector() external view returns (address inspector);
+
+    /**
+     * @notice Sets the message inspector address.
+     * @param _msgInspector Address of the new message inspector
+     */
+    function setMsgInspector(address _msgInspector) external;
+}

package/contracts/interfaces/IOAppMsgInspector.sol

@@ -0,0 +1,32 @@
+// SPDX-License-Identifier: MIT
+pragma solidity ^0.8.22;
+
+/**
+ * @title IOAppMsgInspector
+ * @author LayerZero Labs (@TRileySchwarz, tinom.eth)
+ * @custom:version 1.0.0
+ * @notice Interface for OApp message inspector contracts.
+ */
+interface IOAppMsgInspector {
+    /**
+     * @notice Emitted when the inspection fails.
+     * @param sender Address of the sender of the message
+     * @param message LayerZero message payload that failed inspection
+     * @param options LayerZero message options that failed inspection
+     */
+    error InspectionFailed(address sender, bytes message, bytes options);
+
+    /**
+     * @notice Allows the inspector to examine LayerZero message contents and optionally throw a revert if invalid.
+     * @dev It may either revert or return a boolean.
+     * @param _sender Address of the sender of the message
+     * @param _message LayerZero message payload to be inspected
+     * @param _options LayerZero message options to be inspected
+     * @return valid A boolean indicating whether the inspection passed (true) or failed (false)
+     */
+    function inspect(
+        address _sender,
+        bytes calldata _message,
+        bytes calldata _options
+    ) external view returns (bool valid);
+}

package/contracts/interfaces/IOAppOptionsType3.sol

@@ -0,0 +1,65 @@
+// SPDX-License-Identifier: MIT
+pragma solidity ^0.8.22;
+
+/**
+ * @title IOAppOptionsType3
+ * @author LayerZero Labs
+ * @custom:version 1.0.0
+ * @notice Interface for the `IOAppOptionsType3` contract.
+ */
+interface IOAppOptionsType3 {
+    /**
+     * @notice Struct representing enforced option parameters.
+     * @param eid Endpoint ID
+     * @param msgType OApp message type
+     * @param options Additional options
+     */
+    struct EnforcedOptionParam {
+        uint32 eid;
+        uint16 msgType;
+        bytes options;
+    }
+
+    /**
+     * @notice Thrown when invalid options are provided.
+     * @param options Invalid options
+     */
+    error InvalidOptions(bytes options);
+
+    /**
+     * @notice Emitted when enforced options are set.
+     * @param _enforcedOptions Array of enforced options
+     */
+    event EnforcedOptionSet(EnforcedOptionParam[] _enforcedOptions);
+
+    /**
+     * @notice Returns the enforced options for a given endpoint ID and message type.
+     * @param _eid Endpoint ID
+     * @param _msgType Message type, as defined by the OApp
+     * @return options Enforced options
+     */
+    function enforcedOptions(uint32 _eid, uint16 _msgType) external view returns (bytes memory options);
+
+    /**
+     * @notice Combines options for a given endpoint and message type.
+     * @param _eid Endpoint ID
+     * @param _msgType Message type, as defined by the OApp
+     * @param _extraOptions Additional options passed by the caller
+     * @return options Combination of caller specified options AND enforced options
+     */
+    function combineOptions(
+        uint32 _eid,
+        uint16 _msgType,
+        bytes calldata _extraOptions
+    ) external view returns (bytes memory options);
+
+    /**
+     * @notice Sets enforced options for specific endpoint and message type combinations.
+     * @dev Provides a way for the OApp to enforce things like paying for minimum destination `lzReceive` gas amounts.
+     * @dev These enforced options can vary as the potential options/execution on the remote may differ as per the
+     *      `msgType`. E.g., the amount of `lzReceive` gas necessary to deliver a `lzCompose` message adds overhead you
+     *      don't want to pay if you are only sending a standard message such as `lzReceive` WITHOUT `sendCompose`.
+     * @param _enforcedOptions Array of enforced options
+     */
+    function setEnforcedOptions(EnforcedOptionParam[] calldata _enforcedOptions) external;
+}

package/contracts/interfaces/IOAppReceiver.sol

@@ -0,0 +1,28 @@
+// SPDX-License-Identifier: MIT
+pragma solidity ^0.8.22;
+
+import {
+    ILayerZeroReceiver,
+    Origin
+} from "@layerzerolabs/lz-evm-protocol-v2/contracts/interfaces/ILayerZeroReceiver.sol";
+
+interface IOAppReceiver is ILayerZeroReceiver {
+    /**
+     * @notice Indicates whether an address is an approved composeMsg sender to the Endpoint.
+     * @param _origin The origin information containing the source endpoint and sender address.
+     *  - srcEid: The source chain endpoint ID.
+     *  - sender: The sender address on the src chain.
+     *  - nonce: The nonce of the message.
+     * @param _message The lzReceive payload.
+     * @param _sender The sender address.
+     * @return isSender Is a valid sender.
+     *
+     * @dev Applications can optionally choose to implement a separate composeMsg sender that is NOT the bridging layer.
+     * @dev The default sender IS the OAppReceiver implementer.
+     */
+    function isComposeMsgSender(
+        Origin calldata _origin,
+        bytes calldata _message,
+        address _sender
+    ) external view returns (bool isSender);
+}

package/contracts/oapp/libs/OptionsBuilder.sol

@@ -0,0 +1,217 @@
+// SPDX-License-Identifier: MIT
+pragma solidity ^0.8.22;
+
+import { ExecutorOptions } from "@layerzerolabs/lz-evm-messagelib-v2/contracts/libs/ExecutorOptions.sol";
+import { DVNOptions } from "@layerzerolabs/lz-evm-messagelib-v2/contracts/uln/libs/DVNOptions.sol";
+import { SafeCast } from "@openzeppelin/contracts/utils/math/SafeCast.sol";
+import { BytesLib } from "solidity-bytes-utils/contracts/BytesLib.sol";
+
+/**
+ * @title OptionsBuilder
+ * @dev Library for building and encoding various message options.
+ */
+library OptionsBuilder {
+    using SafeCast for uint256;
+    using BytesLib for bytes;
+
+    // Constants for options types
+    uint16 internal constant TYPE_1 = 1; // legacy options type 1
+    uint16 internal constant TYPE_2 = 2; // legacy options type 2
+    uint16 internal constant TYPE_3 = 3;
+
+    // Custom error message
+    error InvalidSize(uint256 max, uint256 actual);
+    error InvalidOptionType(uint16 optionType);
+
+    // Modifier to ensure only options of type 3 are used
+    modifier onlyType3(bytes memory _options) {
+        if (_options.toUint16(0) != TYPE_3) revert InvalidOptionType(_options.toUint16(0));
+        _;
+    }
+
+    /**
+     * @dev Creates a new options container with type 3.
+     * @return options The newly created options container.
+     */
+    function newOptions() internal pure returns (bytes memory) {
+        return abi.encodePacked(TYPE_3);
+    }
+
+    /**
+     * @dev Adds an executor LZ receive option to the existing options.
+     * @param _options The existing options container.
+     * @param _gas The gasLimit used on the lzReceive() function in the OApp.
+     * @param _value The msg.value passed to the lzReceive() function in the OApp.
+     * @return options The updated options container.
+     *
+     * @dev When multiples of this option are added, they are summed by the executor
+     * eg. if (_gas: 200k, and _value: 1 ether) AND (_gas: 100k, _value: 0.5 ether) are sent in an option to the LayerZeroEndpoint,
+     * that becomes (300k, 1.5 ether) when the message is executed on the remote lzReceive() function.
+     */
+    function addExecutorLzReceiveOption(
+        bytes memory _options,
+        uint128 _gas,
+        uint128 _value
+    ) internal pure onlyType3(_options) returns (bytes memory) {
+        bytes memory option = ExecutorOptions.encodeLzReceiveOption(_gas, _value);
+        return addExecutorOption(_options, ExecutorOptions.OPTION_TYPE_LZRECEIVE, option);
+    }
+
+    /**
+     * @dev Adds an executor native drop option to the existing options.
+     * @param _options The existing options container.
+     * @param _amount The amount for the native value that is airdropped to the 'receiver'.
+     * @param _receiver The receiver address for the native drop option.
+     * @return options The updated options container.
+     *
+     * @dev When multiples of this option are added, they are summed by the executor on the remote chain.
+     */
+    function addExecutorNativeDropOption(
+        bytes memory _options,
+        uint128 _amount,
+        bytes32 _receiver
+    ) internal pure onlyType3(_options) returns (bytes memory) {
+        bytes memory option = ExecutorOptions.encodeNativeDropOption(_amount, _receiver);
+        return addExecutorOption(_options, ExecutorOptions.OPTION_TYPE_NATIVE_DROP, option);
+    }
+
+    // /**
+    //  * @dev Adds an executor native drop option to the existing options.
+    //  * @param _options The existing options container.
+    //  * @param _amount The amount for the native value that is airdropped to the 'receiver'.
+    //  * @param _receiver The receiver address for the native drop option.
+    //  * @return options The updated options container.
+    //  *
+    //  * @dev When multiples of this option are added, they are summed by the executor on the remote chain.
+    //  */
+    function addExecutorLzReadOption(
+        bytes memory _options,
+        uint128 _gas,
+        uint32 _size,
+        uint128 _value
+    ) internal pure onlyType3(_options) returns (bytes memory) {
+        bytes memory option = ExecutorOptions.encodeLzReadOption(_gas, _size, _value);
+        return addExecutorOption(_options, ExecutorOptions.OPTION_TYPE_LZREAD, option);
+    }
+
+    /**
+     * @dev Adds an executor LZ compose option to the existing options.
+     * @param _options The existing options container.
+     * @param _index The index for the lzCompose() function call.
+     * @param _gas The gasLimit for the lzCompose() function call.
+     * @param _value The msg.value for the lzCompose() function call.
+     * @return options The updated options container.
+     *
+     * @dev When multiples of this option are added, they are summed PER index by the executor on the remote chain.
+     * @dev If the OApp sends N lzCompose calls on the remote, you must provide N incremented indexes starting with 0.
+     * ie. When your remote OApp composes (N = 3) messages, you must set this option for index 0,1,2
+     */
+    function addExecutorLzComposeOption(
+        bytes memory _options,
+        uint16 _index,
+        uint128 _gas,
+        uint128 _value
+    ) internal pure onlyType3(_options) returns (bytes memory) {
+        bytes memory option = ExecutorOptions.encodeLzComposeOption(_index, _gas, _value);
+        return addExecutorOption(_options, ExecutorOptions.OPTION_TYPE_LZCOMPOSE, option);
+    }
+
+    /**
+     * @dev Adds an executor ordered execution option to the existing options.
+     * @param _options The existing options container.
+     * @return options The updated options container.
+     */
+    function addExecutorOrderedExecutionOption(
+        bytes memory _options
+    ) internal pure onlyType3(_options) returns (bytes memory) {
+        return addExecutorOption(_options, ExecutorOptions.OPTION_TYPE_ORDERED_EXECUTION, bytes(""));
+    }
+
+    /**
+     * @dev Adds a DVN pre-crime option to the existing options.
+     * @param _options The existing options container.
+     * @param _dvnIdx The DVN index for the pre-crime option.
+     * @return options The updated options container.
+     */
+    function addDVNPreCrimeOption(
+        bytes memory _options,
+        uint8 _dvnIdx
+    ) internal pure onlyType3(_options) returns (bytes memory) {
+        return addDVNOption(_options, _dvnIdx, DVNOptions.OPTION_TYPE_PRECRIME, bytes(""));
+    }
+
+    /**
+     * @dev Adds an executor option to the existing options.
+     * @param _options The existing options container.
+     * @param _optionType The type of the executor option.
+     * @param _option The encoded data for the executor option.
+     * @return options The updated options container.
+     */
+    function addExecutorOption(
+        bytes memory _options,
+        uint8 _optionType,
+        bytes memory _option
+    ) internal pure onlyType3(_options) returns (bytes memory) {
+        return
+            abi.encodePacked(
+                _options,
+                ExecutorOptions.WORKER_ID,
+                _option.length.toUint16() + 1, // +1 for optionType
+                _optionType,
+                _option
+            );
+    }
+
+    /**
+     * @dev Adds a DVN option to the existing options.
+     * @param _options The existing options container.
+     * @param _dvnIdx The DVN index for the DVN option.
+     * @param _optionType The type of the DVN option.
+     * @param _option The encoded data for the DVN option.
+     * @return options The updated options container.
+     */
+    function addDVNOption(
+        bytes memory _options,
+        uint8 _dvnIdx,
+        uint8 _optionType,
+        bytes memory _option
+    ) internal pure onlyType3(_options) returns (bytes memory) {
+        return
+            abi.encodePacked(
+                _options,
+                DVNOptions.WORKER_ID,
+                _option.length.toUint16() + 2, // +2 for optionType and dvnIdx
+                _dvnIdx,
+                _optionType,
+                _option
+            );
+    }
+
+    /**
+     * @dev Encodes legacy options of type 1.
+     * @param _executionGas The gasLimit value passed to lzReceive().
+     * @return legacyOptions The encoded legacy options.
+     */
+    function encodeLegacyOptionsType1(uint256 _executionGas) internal pure returns (bytes memory) {
+        if (_executionGas > type(uint128).max) revert InvalidSize(type(uint128).max, _executionGas);
+        return abi.encodePacked(TYPE_1, _executionGas);
+    }
+
+    /**
+     * @dev Encodes legacy options of type 2.
+     * @param _executionGas The gasLimit value passed to lzReceive().
+     * @param _nativeForDst The amount of native air dropped to the receiver.
+     * @param _receiver The _nativeForDst receiver address.
+     * @return legacyOptions The encoded legacy options of type 2.
+     */
+    function encodeLegacyOptionsType2(
+        uint256 _executionGas,
+        uint256 _nativeForDst,
+        bytes memory _receiver // @dev Use bytes instead of bytes32 in legacy type 2 for _receiver.
+    ) internal pure returns (bytes memory) {
+        if (_executionGas > type(uint128).max) revert InvalidSize(type(uint128).max, _executionGas);
+        if (_nativeForDst > type(uint128).max) revert InvalidSize(type(uint128).max, _nativeForDst);
+        if (_receiver.length > 32) revert InvalidSize(32, _receiver.length);
+        return abi.encodePacked(TYPE_2, _executionGas, _nativeForDst, _receiver);
+    }
+}

package/foundry.toml

@@ -0,0 +1,20 @@
+[profile.default]
+solc = '0.8.22'
+verbosity = 3
+src = "contracts"
+test = "test"
+out = "artifacts"
+cache_path = "cache"
+libs = ['node_modules', 'node_modules/@layerzerolabs/toolbox-foundry/lib']
+optimizer = true
+optimizer_runs = 200
+
+remappings = [
+    'ds-test/=node_modules/@layerzerolabs/toolbox-foundry/lib/ds-test/',
+    'forge-std/=node_modules/@layerzerolabs/toolbox-foundry/lib/forge-std/',
+    '@openzeppelin/=node_modules/@openzeppelin/',
+    '@layerzerolabs/=node_modules/@layerzerolabs/',
+]
+
+[fuzz]
+runs = 1000

package/package.json

@@ -0,0 +1,37 @@
+{
+  "name": "@layerzerolabs/oapp-evm-contracts",
+  "version": "0.2.74",
+  "private": false,
+  "description": "LayerZero Labs reference EVM OApp implementation",
+  "license": "MIT",
+  "devDependencies": {
+    "@layerzerolabs/lz-evm-messagelib-v2": "3.0.167",
+    "@layerzerolabs/lz-evm-protocol-v2": "3.0.167",
+    "@layerzerolabs/lz-evm-v1-0.7": "3.0.167",
+    "@layerzerolabs/test-devtools-evm-foundry": "8.0.1",
+    "@layerzerolabs/toolbox-foundry": "^0.1.13",
+    "@openzeppelin/contracts": "^5.0.2",
+    "@openzeppelin/contracts-upgradeable": "^5.0.2",
+    "ethers": "^5.8.0",
+    "solhint": "^6.0.1",
+    "solidity-bytes-utils": "^0.8.4",
+    "@layerzerolabs/solhint-configuration": "0.2.74",
+    "@layerzerolabs/tsup-configuration": "0.2.74",
+    "@layerzerolabs/vm-tooling-evm": "0.2.74",
+    "@layerzerolabs/typescript-configuration": "0.2.74"
+  },
+  "publishConfig": {
+    "access": "restricted",
+    "registry": "https://registry.npmjs.org/"
+  },
+  "externalRepoConfig": {
+    "targets": [
+      "audit-external",
+      "monorepo-external"
+    ]
+  },
+  "scripts": {
+    "clean-artifacts": "rm -rf artifacts* cache hh-cache*",
+    "lint": "solhint --config solhint.config.js 'contracts/**/*.sol' 'test/**/*.sol' --fix --noPrompt"
+  }
+}

package/solhint.config.js

@@ -0,0 +1,3 @@
+const baseConfig = require('@layerzerolabs/solhint-configuration');
+
+module.exports = baseConfig;