@layerzerolabs/create3-factory 2.1.23 → 2.1.24

package/CHANGELOG.md

@@ -1,5 +1,11 @@
 # @layerzerolabs/create3-factory
 
+## 2.1.24
+
+### Patch Changes
+
+- c663d78: remove duplicate `sleep` func
+
 ## 2.1.23
 
 ### Patch Changes

package/contracts/Bytes32AddressLib.sol

@@ -0,0 +1,14 @@
+// SPDX-License-Identifier: AGPL-3.0
+pragma solidity >=0.8.0;
+
+/// @notice Library for converting between addresses and bytes32 values.
+/// @author Solmate (https://github.com/transmissions11/solmate/blob/main/src/utils/Bytes32AddressLib.sol)
+library Bytes32AddressLib {
+    function fromLast20Bytes(bytes32 bytesValue) internal pure returns (address) {
+        return address(uint160(uint256(bytesValue)));
+    }
+
+    function fillLast12Bytes(address addressValue) internal pure returns (bytes32) {
+        return bytes32(bytes20(addressValue));
+    }
+}

package/contracts/CREATE3.sol

@@ -0,0 +1,83 @@
+// SPDX-License-Identifier: AGPL-3.0
+pragma solidity >=0.8.0;
+
+import { Bytes32AddressLib } from "./Bytes32AddressLib.sol";
+
+/// @notice Deploy to deterministic addresses without an initcode factor.
+/// @author Solmate (https://github.com/transmissions11/solmate/blob/main/src/utils/CREATE3.sol)
+/// @author Modified from 0xSequence (https://github.com/0xSequence/create3/blob/master/contracts/Create3.sol)
+library CREATE3 {
+    using Bytes32AddressLib for bytes32;
+
+    //--------------------------------------------------------------------------------//
+    // Opcode     | Opcode + Arguments    | Description      | Stack View             //
+    //--------------------------------------------------------------------------------//
+    // 0x36       |  0x36                 | CALLDATASIZE     | size                   //
+    // 0x3d       |  0x3d                 | RETURNDATASIZE   | 0 size                 //
+    // 0x3d       |  0x3d                 | RETURNDATASIZE   | 0 0 size               //
+    // 0x37       |  0x37                 | CALLDATACOPY     |                        //
+    // 0x36       |  0x36                 | CALLDATASIZE     | size                   //
+    // 0x3d       |  0x3d                 | RETURNDATASIZE   | 0 size                 //
+    // 0x34       |  0x34                 | CALLVALUE        | value 0 size           //
+    // 0xf0       |  0xf0                 | CREATE           | newContract            //
+    //--------------------------------------------------------------------------------//
+    // Opcode     | Opcode + Arguments    | Description      | Stack View             //
+    //--------------------------------------------------------------------------------//
+    // 0x67       |  0x67XXXXXXXXXXXXXXXX | PUSH8 bytecode   | bytecode               //
+    // 0x3d       |  0x3d                 | RETURNDATASIZE   | 0 bytecode             //
+    // 0x52       |  0x52                 | MSTORE           |                        //
+    // 0x60       |  0x6008               | PUSH1 08         | 8                      //
+    // 0x60       |  0x6018               | PUSH1 18         | 24 8                   //
+    // 0xf3       |  0xf3                 | RETURN           |                        //
+    //--------------------------------------------------------------------------------//
+    bytes internal constant PROXY_BYTECODE = hex"67_36_3d_3d_37_36_3d_34_f0_3d_52_60_08_60_18_f3";
+
+    bytes32 internal constant PROXY_BYTECODE_HASH = keccak256(PROXY_BYTECODE);
+
+    function deploy(bytes32 salt, bytes memory creationCode, uint256 value) internal returns (address deployed) {
+        bytes memory proxyChildBytecode = PROXY_BYTECODE;
+
+        address proxy;
+        /// @solidity memory-safe-assembly
+        assembly {
+            // Deploy a new contract with our pre-made bytecode via CREATE2.
+            // We start 32 bytes into the code to avoid copying the byte length.
+            proxy := create2(0, add(proxyChildBytecode, 32), mload(proxyChildBytecode), salt)
+        }
+        require(proxy != address(0), "DEPLOYMENT_FAILED");
+
+        deployed = getDeployed(salt);
+        (bool success, ) = proxy.call{ value: value }(creationCode);
+        require(success && deployed.code.length != 0, "INITIALIZATION_FAILED");
+    }
+
+    function getDeployed(bytes32 salt) internal view returns (address) {
+        return getDeployed(salt, address(this));
+    }
+
+    function getDeployed(bytes32 salt, address creator) internal pure returns (address) {
+        address proxy = keccak256(
+            abi.encodePacked(
+                // Prefix:
+                bytes1(0xFF),
+                // Creator:
+                creator,
+                // Salt:
+                salt,
+                // Bytecode hash:
+                PROXY_BYTECODE_HASH
+            )
+        ).fromLast20Bytes();
+
+        return
+            keccak256(
+                abi.encodePacked(
+                    // 0xd6 = 0xc0 (short RLP prefix) + 0x16 (length of: 0x94 ++ proxy ++ 0x01)
+                    // 0x94 = 0x80 + 0x14 (0x14 = the length of an address, 20 bytes, in hex)
+                    hex"d6_94",
+                    proxy,
+                    hex"01" // Nonce of the proxy contract (1)
+                )
+            ).fromLast20Bytes();
+    }
+}

package/contracts/CREATE3Factory.sol

@@ -0,0 +1,26 @@
+// SPDX-License-Identifier: AGPL-3.0
+pragma solidity ^0.8.13;
+
+import { CREATE3 } from "./CREATE3.sol";
+
+import { ICREATE3Factory } from "./ICREATE3Factory.sol";
+
+/// @title Factory for deploying contracts to deterministic addresses via CREATE3
+/// @author zefram.eth
+/// @notice Enables deploying contracts using CREATE3. Each deployer (msg.sender) has
+/// its own namespace for deployed addresses.
+contract CREATE3Factory is ICREATE3Factory {
+    /// @inheritdoc	ICREATE3Factory
+    function deploy(bytes32 salt, bytes memory creationCode) external payable override returns (address deployed) {
+        // hash salt with the deployer address to give each deployer its own namespace
+        salt = keccak256(abi.encodePacked(msg.sender, salt));
+        return CREATE3.deploy(salt, creationCode, msg.value);
+    }
+
+    /// @inheritdoc	ICREATE3Factory
+    function getDeployed(address deployer, bytes32 salt) external view override returns (address deployed) {
+        // hash salt with the deployer address to give each deployer its own namespace
+        salt = keccak256(abi.encodePacked(deployer, salt));
+        return CREATE3.getDeployed(salt);
+    }
+}

package/contracts/ICREATE3Factory.sol

@@ -0,0 +1,22 @@
+// SPDX-License-Identifier: AGPL-3.0
+pragma solidity >=0.6.0;
+
+/// @title Factory for deploying contracts to deterministic addresses via CREATE3
+/// @author zefram.eth
+/// @notice Enables deploying contracts using CREATE3. Each deployer (msg.sender) has
+/// its own namespace for deployed addresses.
+interface ICREATE3Factory {
+    /// @notice Deploys a contract using CREATE3
+    /// @dev The provided salt is hashed together with msg.sender to generate the final salt
+    /// @param salt The deployer-specific salt for determining the deployed contract's address
+    /// @param creationCode The creation code of the contract to deploy
+    /// @return deployed The address of the deployed contract
+    function deploy(bytes32 salt, bytes memory creationCode) external payable returns (address deployed);
+
+    /// @notice Predicts the address of a deployed contract
+    /// @dev The provided salt is hashed together with the deployer address to generate the final salt
+    /// @param deployer The deployer account that will call deploy()
+    /// @param salt The deployer-specific salt for determining the deployed contract's address
+    /// @return deployed The address of the contract that will be deployed
+    function getDeployed(address deployer, bytes32 salt) external view returns (address deployed);
+}

package/package.json

@@ -1,6 +1,6 @@
 {
   "name": "@layerzerolabs/create3-factory",
-  "version": "2.1.23",
+  "version": "2.1.24",
   "license": "AGPL-3.0",
   "exports": {
     ".": {
@@ -13,6 +13,7 @@
   "main": "dist/index.js",
   "types": "dist/index.d.ts",
   "files": [
+    "contracts/**/*",
     "deployments/**/*"
   ],
   "scripts": {
@@ -35,15 +36,15 @@
     "@ethersproject/abi": "^5.7.0",
     "@ethersproject/providers": "^5.7.0",
     "@layerzerolabs/hardhat-config": "^0.0.0",
-    "@layerzerolabs/hardhat-tron": "^2.1.23",
-    "@layerzerolabs/lz-definitions": "^2.1.23",
-    "@layerzerolabs/lz-utilities": "^2.1.23",
-    "@layerzerolabs/ops-cli": "^2.1.23",
-    "@layerzerolabs/ops-core": "^2.1.23",
-    "@layerzerolabs/ops-plugin-core": "^2.1.23",
-    "@layerzerolabs/ops-utilities": "^2.1.23",
-    "@layerzerolabs/tsup-config-next": "^2.1.23",
-    "@layerzerolabs/typescript-config-next": "^2.1.23",
+    "@layerzerolabs/hardhat-tron": "^2.1.24",
+    "@layerzerolabs/lz-definitions": "^2.1.24",
+    "@layerzerolabs/lz-utilities": "^2.1.24",
+    "@layerzerolabs/ops-cli": "^2.1.24",
+    "@layerzerolabs/ops-core": "^2.1.24",
+    "@layerzerolabs/ops-plugin-core": "^2.1.24",
+    "@layerzerolabs/ops-utilities": "^2.1.24",
+    "@layerzerolabs/tsup-config-next": "^2.1.24",
+    "@layerzerolabs/typescript-config-next": "^2.1.24",
     "@matterlabs/hardhat-zksync-deploy": "^0.6.5",
     "@matterlabs/hardhat-zksync-solc": "^1.0.3",
     "@nomicfoundation/hardhat-chai-matchers": "^1.0.6",