@latticexyz/world-modules 2.0.12-main-ecc8f658 → 2.0.12-type-resolutions-effc7ab1

package/src/modules/keyswithvalue/getKeysWithValue.sol

@@ -1,58 +0,0 @@
-// SPDX-License-Identifier: MIT
-pragma solidity >=0.8.24;
-
-import { IStore } from "@latticexyz/store/src/IStore.sol";
-import { EncodedLengths } from "@latticexyz/store/src/EncodedLengths.sol";
-import { ResourceId } from "@latticexyz/store/src/ResourceId.sol";
-
-import { MODULE_NAMESPACE } from "./constants.sol";
-import { KeysWithValue } from "./tables/KeysWithValue.sol";
-import { getTargetTableId } from "./getTargetTableId.sol";
-
-/**
- * Get a list of keys with the given value.
- *
- * Note: this util can only be called within the context of a Store (e.g. from a System or Module).
- * For usage outside of a Store, use the overload that takes an explicit store argument.
- */
-function getKeysWithValue(
-  ResourceId tableId,
-  bytes memory staticData,
-  EncodedLengths encodedLengths,
-  bytes memory dynamicData
-) view returns (bytes32[] memory keysWithValue) {
-  // Get the corresponding reverse mapping table
-  ResourceId keysWithValueTableId = getTargetTableId(MODULE_NAMESPACE, tableId);
-
-  // Get the keys with the given value
-  bytes memory value;
-  if (dynamicData.length > 0) {
-    value = abi.encodePacked(staticData, encodedLengths, dynamicData);
-  } else {
-    value = staticData;
-  }
-  keysWithValue = KeysWithValue.get(keysWithValueTableId, keccak256(value));
-}
-
-/**
- * Get a list of keys with the given value for the given store.
- */
-function getKeysWithValue(
-  IStore store,
-  ResourceId tableId,
-  bytes memory staticData,
-  EncodedLengths encodedLengths,
-  bytes memory dynamicData
-) view returns (bytes32[] memory keysWithValue) {
-  // Get the corresponding reverse mapping table
-  ResourceId keysWithValueTableId = getTargetTableId(MODULE_NAMESPACE, tableId);
-
-  // Get the keys with the given value
-  bytes memory value;
-  if (dynamicData.length > 0) {
-    value = abi.encodePacked(staticData, encodedLengths, dynamicData);
-  } else {
-    value = staticData;
-  }
-  keysWithValue = KeysWithValue.get(store, keysWithValueTableId, keccak256(value));
-}

package/src/modules/keyswithvalue/getTargetTableId.sol

@@ -1,32 +0,0 @@
-// SPDX-License-Identifier: MIT
-pragma solidity >=0.8.24;
-
-import { TYPE_BITS } from "@latticexyz/store/src/ResourceId.sol";
-import { ResourceId, WorldResourceIdInstance, NAME_BITS } from "@latticexyz/world/src/WorldResourceId.sol";
-import { RESOURCE_TABLE } from "@latticexyz/world/src/worldResourceTypes.sol";
-
-uint256 constant MODULE_NAMESPACE_BITS = 7 * 8;
-uint256 constant TABLE_NAMESPACE_BITS = 7 * 8;
-uint256 constant TABLE_NAME_BITS = 16 * 8;
-
-/**
- * Get a deterministic selector for the reverse mapping table for the given source table.
- * The selector is constructed as follows:
- *  - The first 2 bytes are the resource type
- *  - The next 7 bytes are the module namespace
- *  - The next 7 bytes are the first 7 bytes of the source table namespace
- *    -- This is to avoid collisions between tables with the same name in different namespaces
- *       (Note that collisions are still possible if the first 7 bytes of the namespace are the same, in which case installing the module fails)
- *  - The last 16 bytes are the source table name
- */
-function getTargetTableId(bytes7 moduleNamespace, ResourceId sourceTableId) pure returns (ResourceId) {
-  bytes16 tableName = WorldResourceIdInstance.getName(sourceTableId);
-  bytes7 sourceTableNamespace = bytes7(WorldResourceIdInstance.getNamespace(sourceTableId));
-  return
-    ResourceId.wrap(
-      bytes32(RESOURCE_TABLE) |
-        (bytes32(moduleNamespace) >> TYPE_BITS) |
-        (bytes32(sourceTableNamespace) >> (TYPE_BITS + MODULE_NAMESPACE_BITS)) |
-        (bytes32(tableName) >> (TYPE_BITS + MODULE_NAMESPACE_BITS + TABLE_NAMESPACE_BITS))
-    );
-}