@kmugalkhod/lightcode 0.17.2 → 0.18.0

package/assets/grammars/python/highlights.scm

@@ -1,443 +0,0 @@
-; From tree-sitter-python licensed under MIT License
-; Copyright (c) 2016 Max Brunsfeld
-; Variables
-(identifier) @variable
-
-; Reset highlighting in f-string interpolations
-(interpolation) @none
-
-; Identifier naming conventions
-((identifier) @type
-  (#lua-match? @type "^[A-Z].*[a-z]"))
-
-((identifier) @constant
-  (#lua-match? @constant "^[A-Z][A-Z_0-9]*$"))
-
-((identifier) @constant.builtin
-  (#lua-match? @constant.builtin "^__[a-zA-Z0-9_]*__$"))
-
-((identifier) @constant.builtin
-  (#any-of? @constant.builtin
-    ; https://docs.python.org/3/library/constants.html
-    "NotImplemented" "Ellipsis" "quit" "exit" "copyright" "credits" "license"))
-
-"_" @character.special ; match wildcard
-
-((assignment
-  left: (identifier) @type.definition
-  (type
-    (identifier) @_annotation))
-  (#eq? @_annotation "TypeAlias"))
-
-((assignment
-  left: (identifier) @type.definition
-  right: (call
-    function: (identifier) @_func))
-  (#any-of? @_func "TypeVar" "NewType"))
-
-; Function definitions
-(function_definition
-  name: (identifier) @function)
-
-(type
-  (identifier) @type)
-
-(type
-  (subscript
-    (identifier) @type)) ; type subscript: Tuple[int]
-
-((call
-  function: (identifier) @_isinstance
-  arguments: (argument_list
-    (_)
-    (identifier) @type))
-  (#eq? @_isinstance "isinstance"))
-
-; Literals
-(none) @constant.builtin
-
-[
-  (true)
-  (false)
-] @boolean
-
-(integer) @number
-
-(float) @number.float
-
-(comment) @comment @spell
-
-((module
-  .
-  (comment) @keyword.directive @nospell)
-  (#lua-match? @keyword.directive "^#!/"))
-
-(string) @string
-
-[
-  (escape_sequence)
-  (escape_interpolation)
-] @string.escape
-
-; doc-strings
-(expression_statement
-  (string
-    (string_content) @spell) @string.documentation)
-
-; Tokens
-[
-  "-"
-  "-="
-  ":="
-  "!="
-  "*"
-  "**"
-  "**="
-  "*="
-  "/"
-  "//"
-  "//="
-  "/="
-  "&"
-  "&="
-  "%"
-  "%="
-  "^"
-  "^="
-  "+"
-  "+="
-  "<"
-  "<<"
-  "<<="
-  "<="
-  "<>"
-  "="
-  "=="
-  ">"
-  ">="
-  ">>"
-  ">>="
-  "@"
-  "@="
-  "|"
-  "|="
-  "~"
-  "->"
-] @operator
-
-; Keywords
-[
-  "and"
-  "in"
-  "is"
-  "not"
-  "or"
-  "is not"
-  "not in"
-  "del"
-] @keyword.operator
-
-[
-  "def"
-  "lambda"
-] @keyword.function
-
-[
-  "assert"
-  "exec"
-  "global"
-  "nonlocal"
-  "pass"
-  "print"
-  "with"
-  "as"
-] @keyword
-
-[
-  "type"
-  "class"
-] @keyword.type
-
-[
-  "async"
-  "await"
-] @keyword.coroutine
-
-[
-  "return"
-  "yield"
-] @keyword.return
-
-(yield
-  "from" @keyword.return)
-
-(future_import_statement
-  "from" @keyword.import
-  "__future__" @module.builtin)
-
-(import_from_statement
-  "from" @keyword.import)
-
-"import" @keyword.import
-
-(aliased_import
-  "as" @keyword.import)
-
-(wildcard_import
-  "*" @character.special)
-
-(import_statement
-  name: (dotted_name
-    (identifier) @module))
-
-(import_statement
-  name: (aliased_import
-    name: (dotted_name
-      (identifier) @module)
-    alias: (identifier) @module))
-
-(import_from_statement
-  module_name: (dotted_name
-    (identifier) @module))
-
-(import_from_statement
-  module_name: (relative_import
-    (dotted_name
-      (identifier) @module)))
-
-[
-  "if"
-  "elif"
-  "else"
-  "match"
-  "case"
-] @keyword.conditional
-
-[
-  "for"
-  "while"
-  "break"
-  "continue"
-] @keyword.repeat
-
-[
-  "try"
-  "except"
-  "except*"
-  "raise"
-  "finally"
-] @keyword.exception
-
-(raise_statement
-  "from" @keyword.exception)
-
-(try_statement
-  (else_clause
-    "else" @keyword.exception))
-
-[
-  "("
-  ")"
-  "["
-  "]"
-  "{"
-  "}"
-] @punctuation.bracket
-
-(interpolation
-  "{" @punctuation.special
-  "}" @punctuation.special)
-
-(type_conversion) @function.macro
-
-[
-  ","
-  "."
-  ":"
-  ";"
-  (ellipsis)
-] @punctuation.delimiter
-
-((identifier) @type.builtin
-  (#any-of? @type.builtin
-    ; https://docs.python.org/3/library/exceptions.html
-    "BaseException" "Exception" "ArithmeticError" "BufferError" "LookupError" "AssertionError"
-    "AttributeError" "EOFError" "FloatingPointError" "GeneratorExit" "ImportError"
-    "ModuleNotFoundError" "IndexError" "KeyError" "KeyboardInterrupt" "MemoryError" "NameError"
-    "NotImplementedError" "OSError" "OverflowError" "RecursionError" "ReferenceError" "RuntimeError"
-    "StopIteration" "StopAsyncIteration" "SyntaxError" "IndentationError" "TabError" "SystemError"
-    "SystemExit" "TypeError" "UnboundLocalError" "UnicodeError" "UnicodeEncodeError"
-    "UnicodeDecodeError" "UnicodeTranslateError" "ValueError" "ZeroDivisionError" "EnvironmentError"
-    "IOError" "WindowsError" "BlockingIOError" "ChildProcessError" "ConnectionError"
-    "BrokenPipeError" "ConnectionAbortedError" "ConnectionRefusedError" "ConnectionResetError"
-    "FileExistsError" "FileNotFoundError" "InterruptedError" "IsADirectoryError"
-    "NotADirectoryError" "PermissionError" "ProcessLookupError" "TimeoutError" "Warning"
-    "UserWarning" "DeprecationWarning" "PendingDeprecationWarning" "SyntaxWarning" "RuntimeWarning"
-    "FutureWarning" "ImportWarning" "UnicodeWarning" "BytesWarning" "ResourceWarning"
-    ; https://docs.python.org/3/library/stdtypes.html
-    "bool" "int" "float" "complex" "list" "tuple" "range" "str" "bytes" "bytearray" "memoryview"
-    "set" "frozenset" "dict" "type" "object"))
-
-; Normal parameters
-(parameters
-  (identifier) @variable.parameter)
-
-; Lambda parameters
-(lambda_parameters
-  (identifier) @variable.parameter)
-
-(lambda_parameters
-  (tuple_pattern
-    (identifier) @variable.parameter))
-
-; Default parameters
-(keyword_argument
-  name: (identifier) @variable.parameter)
-
-; Naming parameters on call-site
-(default_parameter
-  name: (identifier) @variable.parameter)
-
-(typed_parameter
-  (identifier) @variable.parameter)
-
-(typed_default_parameter
-  name: (identifier) @variable.parameter)
-
-; Variadic parameters *args, **kwargs
-(parameters
-  (list_splat_pattern ; *args
-    (identifier) @variable.parameter))
-
-(parameters
-  (dictionary_splat_pattern ; **kwargs
-    (identifier) @variable.parameter))
-
-; Typed variadic parameters
-(parameters
-  (typed_parameter
-    (list_splat_pattern ; *args: type
-      (identifier) @variable.parameter)))
-
-(parameters
-  (typed_parameter
-    (dictionary_splat_pattern ; *kwargs: type
-      (identifier) @variable.parameter)))
-
-; Lambda parameters
-(lambda_parameters
-  (list_splat_pattern
-    (identifier) @variable.parameter))
-
-(lambda_parameters
-  (dictionary_splat_pattern
-    (identifier) @variable.parameter))
-
-((identifier) @variable.builtin
-  (#eq? @variable.builtin "self"))
-
-((identifier) @variable.builtin
-  (#eq? @variable.builtin "cls"))
-
-; After @type.builtin bacause builtins (such as `type`) are valid as attribute name
-((attribute
-  attribute: (identifier) @variable.member)
-  (#lua-match? @variable.member "^[%l_].*$"))
-
-; Class definitions
-(class_definition
-  name: (identifier) @type)
-
-(class_definition
-  body: (block
-    (function_definition
-      name: (identifier) @function.method)))
-
-(class_definition
-  superclasses: (argument_list
-    (identifier) @type))
-
-((class_definition
-  body: (block
-    (expression_statement
-      (assignment
-        left: (identifier) @variable.member))))
-  (#lua-match? @variable.member "^[%l_].*$"))
-
-((class_definition
-  body: (block
-    (expression_statement
-      (assignment
-        left: (_
-          (identifier) @variable.member)))))
-  (#lua-match? @variable.member "^[%l_].*$"))
-
-((class_definition
-  (block
-    (function_definition
-      name: (identifier) @constructor)))
-  (#any-of? @constructor "__new__" "__init__"))
-
-; Function calls
-(call
-  function: (identifier) @function.call)
-
-(call
-  function: (attribute
-    attribute: (identifier) @function.method.call))
-
-((call
-  function: (identifier) @constructor)
-  (#lua-match? @constructor "^%u"))
-
-((call
-  function: (attribute
-    attribute: (identifier) @constructor))
-  (#lua-match? @constructor "^%u"))
-
-; Builtin functions
-((call
-  function: (identifier) @function.builtin)
-  (#any-of? @function.builtin
-    "abs" "all" "any" "ascii" "bin" "bool" "breakpoint" "bytearray" "bytes" "callable" "chr"
-    "classmethod" "compile" "complex" "delattr" "dict" "dir" "divmod" "enumerate" "eval" "exec"
-    "filter" "float" "format" "frozenset" "getattr" "globals" "hasattr" "hash" "help" "hex" "id"
-    "input" "int" "isinstance" "issubclass" "iter" "len" "list" "locals" "map" "max" "memoryview"
-    "min" "next" "object" "oct" "open" "ord" "pow" "print" "property" "range" "repr" "reversed"
-    "round" "set" "setattr" "slice" "sorted" "staticmethod" "str" "sum" "super" "tuple" "type"
-    "vars" "zip" "__import__"))
-
-; Regex from the `re` module
-(call
-  function: (attribute
-    object: (identifier) @_re)
-  arguments: (argument_list
-    .
-    (string
-      (string_content) @string.regexp))
-  (#eq? @_re "re"))
-
-; Decorators
-((decorator
-  "@" @attribute)
-  (#set! priority 101))
-
-(decorator
-  (identifier) @attribute)
-
-(decorator
-  (attribute
-    attribute: (identifier) @attribute))
-
-(decorator
-  (call
-    (identifier) @attribute))
-
-(decorator
-  (call
-    (attribute
-      attribute: (identifier) @attribute)))
-
-((decorator
-  (identifier) @attribute.builtin)
-  (#any-of? @attribute.builtin "classmethod" "property" "staticmethod"))

package/assets/grammars/rust/highlights.scm

@@ -1,159 +0,0 @@
-; Identifiers
-
-(type_identifier) @type
-(primitive_type) @type.builtin
-(field_identifier) @property
-
-; Identifier conventions
-
-; Assume all-caps names are constants
-((identifier) @constant
- (#match? @constant "^[A-Z][A-Z\\d_]+$'"))
-
-; Assume uppercase names are enum constructors
-((identifier) @constructor
- (#match? @constructor "^[A-Z]"))
-
-; Assume that uppercase names in paths are types
-((scoped_identifier
-  path: (identifier) @type)
- (#match? @type "^[A-Z]"))
-((scoped_identifier
-  path: (scoped_identifier
-    name: (identifier) @type))
- (#match? @type "^[A-Z]"))
-((scoped_type_identifier
-  path: (identifier) @type)
- (#match? @type "^[A-Z]"))
-((scoped_type_identifier
-  path: (scoped_identifier
-    name: (identifier) @type))
- (#match? @type "^[A-Z]"))
-
-; Assume all qualified names in struct patterns are enum constructors. (They're
-; either that, or struct names; highlighting both as constructors seems to be
-; the less glaring choice of error, visually.)
-(struct_pattern
-  type: (scoped_type_identifier
-    name: (type_identifier) @constructor))
-
-; Function calls
-
-(call_expression
-  function: (identifier) @function)
-(call_expression
-  function: (field_expression
-    field: (field_identifier) @function.method))
-(call_expression
-  function: (scoped_identifier
-    "::"
-    name: (identifier) @function))
-
-(generic_function
-  function: (identifier) @function)
-(generic_function
-  function: (scoped_identifier
-    name: (identifier) @function))
-(generic_function
-  function: (field_expression
-    field: (field_identifier) @function.method))
-
-(macro_invocation
-  macro: (identifier) @function.macro
-  "!" @function.macro)
-
-; Function definitions
-
-(function_item (identifier) @function)
-(function_signature_item (identifier) @function)
-
-(line_comment) @comment
-(block_comment) @comment
-
-(line_comment (doc_comment)) @comment.documentation
-(block_comment (doc_comment)) @comment.documentation
-
-"(" @punctuation.bracket
-")" @punctuation.bracket
-"[" @punctuation.bracket
-"]" @punctuation.bracket
-"{" @punctuation.bracket
-"}" @punctuation.bracket
-
-(type_arguments
-  "<" @punctuation.bracket
-  ">" @punctuation.bracket)
-(type_parameters
-  "<" @punctuation.bracket
-  ">" @punctuation.bracket)
-
-"::" @punctuation.delimiter
-":" @punctuation.delimiter
-"." @punctuation.delimiter
-"," @punctuation.delimiter
-";" @punctuation.delimiter
-
-(parameter (identifier) @variable.parameter)
-
-(lifetime (identifier) @label)
-
-"as" @keyword
-"async" @keyword
-"await" @keyword
-"break" @keyword
-"const" @keyword
-"continue" @keyword
-"default" @keyword
-"dyn" @keyword
-"else" @keyword
-"enum" @keyword
-"extern" @keyword
-"fn" @keyword
-"for" @keyword
-"if" @keyword
-"impl" @keyword
-"in" @keyword
-"let" @keyword
-"loop" @keyword
-"macro_rules!" @keyword
-"match" @keyword
-"mod" @keyword
-"move" @keyword
-"pub" @keyword
-"ref" @keyword
-"return" @keyword
-"static" @keyword
-"struct" @keyword
-"trait" @keyword
-"type" @keyword
-"union" @keyword
-"unsafe" @keyword
-"use" @keyword
-"where" @keyword
-"while" @keyword
-"yield" @keyword
-(crate) @keyword
-(mutable_specifier) @keyword
-(use_list (self) @keyword)
-(scoped_use_list (self) @keyword)
-(scoped_identifier (self) @keyword)
-(super) @keyword
-
-(self) @variable.builtin
-
-(char_literal) @string
-(string_literal) @string
-(raw_string_literal) @string
-
-(boolean_literal) @constant.builtin
-(integer_literal) @constant.builtin
-(float_literal) @constant.builtin
-
-(escape_sequence) @escape
-
-(attribute_item) @attribute
-(inner_attribute_item) @attribute
-
-"*" @operator
-"&" @operator
-"'" @operator

package/assets/grammars/yaml/highlights.scm

@@ -1,99 +0,0 @@
-(boolean_scalar) @boolean
-
-(null_scalar) @constant.builtin
-
-(double_quote_scalar) @string
-
-(single_quote_scalar) @string
-
-((block_scalar) @string
-  (#set! priority 99))
-
-(string_scalar) @string
-
-(escape_sequence) @string.escape
-
-(integer_scalar) @number
-
-(float_scalar) @number
-
-(comment) @comment @spell
-
-[
-  (anchor_name)
-  (alias_name)
-] @label
-
-(tag) @type
-
-[
-  (yaml_directive)
-  (tag_directive)
-  (reserved_directive)
-] @keyword.directive
-
-(block_mapping_pair
-  key: (flow_node
-    [
-      (double_quote_scalar)
-      (single_quote_scalar)
-    ] @property))
-
-(block_mapping_pair
-  key: (flow_node
-    (plain_scalar
-      (string_scalar) @property)))
-
-(flow_mapping
-  (_
-    key: (flow_node
-      [
-        (double_quote_scalar)
-        (single_quote_scalar)
-      ] @property)))
-
-(flow_mapping
-  (_
-    key: (flow_node
-      (plain_scalar
-        (string_scalar) @property))))
-
-[
-  ","
-  "-"
-  ":"
-  ">"
-  "?"
-  "|"
-] @punctuation.delimiter
-
-[
-  "["
-  "]"
-  "{"
-  "}"
-] @punctuation.bracket
-
-[
-  "*"
-  "&"
-  "---"
-  "..."
-] @punctuation.special
-
-; help deal with for yaml's norway problem https://www.bram.us/2022/01/11/yaml-the-norway-problem/
-; only using `true` and `false`, since Treesitter parser targets YAML spec 1.2 https://github.com/nvim-treesitter/nvim-treesitter/pull/7512#issuecomment-2565397302
-(block_mapping_pair
-  value: (block_node
-    (block_sequence
-      (block_sequence_item
-        (flow_node
-          (plain_scalar
-            (string_scalar) @boolean
-            (#any-of? @boolean "TRUE" "FALSE" "True" "False")))))))
-
-(block_mapping_pair
-  value: (flow_node
-    (plain_scalar
-      (string_scalar) @boolean
-      (#any-of? @boolean "TRUE" "FALSE" "True" "False"))))