@keep-network/tbtc-v2 0.1.1-dev.0 → 0.1.1-dev.4

package/contracts/vault/TBTCVault.sol

@@ -0,0 +1,128 @@
+// SPDX-License-Identifier: MIT
+
+// ██████████████     ▐████▌     ██████████████
+// ██████████████     ▐████▌     ██████████████
+//               ▐████▌    ▐████▌
+//               ▐████▌    ▐████▌
+// ██████████████     ▐████▌     ██████████████
+// ██████████████     ▐████▌     ██████████████
+//               ▐████▌    ▐████▌
+//               ▐████▌    ▐████▌
+//               ▐████▌    ▐████▌
+//               ▐████▌    ▐████▌
+//               ▐████▌    ▐████▌
+//               ▐████▌    ▐████▌
+
+pragma solidity 0.8.4;
+
+import "./IVault.sol";
+import "../bank/Bank.sol";
+import "../token/TBTC.sol";
+
+/// @title TBTC application vault
+/// @notice TBTC is a fully Bitcoin-backed ERC-20 token pegged to the price of
+///         Bitcoin. It facilitates Bitcoin holders to act on the Ethereum
+///         blockchain and access the decentralized finance (DeFi) ecosystem.
+///         TBTC Vault mints and redeems TBTC based on Bitcoin balances in the
+///         Bank.
+/// @dev TBTC Vault is the owner of TBTC token contract and is the only contract
+///      minting the token.
+contract TBTCVault is IVault {
+    Bank public bank;
+    TBTC public tbtcToken;
+
+    event Minted(address indexed to, uint256 amount);
+
+    event Redeemed(address indexed from, uint256 amount);
+
+    modifier onlyBank() {
+        require(msg.sender == address(bank), "Caller is not the Bank");
+        _;
+    }
+
+    constructor(Bank _bank, TBTC _tbtcToken) {
+        require(
+            address(_bank) != address(0),
+            "Bank can not be the zero address"
+        );
+
+        require(
+            address(_tbtcToken) != address(0),
+            "TBTC token can not be the zero address"
+        );
+
+        bank = _bank;
+        tbtcToken = _tbtcToken;
+    }
+
+    /// @notice Transfers the given `amount` of the Bank balance from caller
+    ///         to TBTC Vault, and mints `amount` of TBTC to the caller.
+    /// @dev TBTC Vault must have an allowance for caller's balance in the Bank
+    ///      for at least `amount`.
+    /// @param amount Amount of TBTC to mint
+    function mint(uint256 amount) external {
+        address minter = msg.sender;
+        require(
+            bank.balanceOf(minter) >= amount,
+            "Amount exceeds balance in the bank"
+        );
+        _mint(minter, amount);
+        bank.transferBalanceFrom(minter, address(this), amount);
+    }
+
+    /// @notice Mints the same amount of TBTC as the deposited amount for each
+    ///         depositor in the array. Can only be called by the Bank after the
+    ///         Bridge swept deposits and Bank increased balance for the
+    ///         vault.
+    /// @dev Fails if `depositors` array is empty. Expects the length of
+    ///      `depositors` and `depositedAmounts` is the same.
+    function onBalanceIncreased(
+        address[] calldata depositors,
+        uint256[] calldata depositedAmounts
+    ) external override onlyBank {
+        require(depositors.length != 0, "No depositors specified");
+        for (uint256 i = 0; i < depositors.length; i++) {
+            _mint(depositors[i], depositedAmounts[i]);
+        }
+    }
+
+    /// @notice Burns `amount` of TBTC from the caller's account and transfers
+    ///         `amount` back to the caller's balance in the Bank.
+    /// @dev Caller must have at least `amount` of TBTC approved to
+    ///       TBTC Vault.
+    /// @param amount Amount of TBTC to redeem
+    function redeem(uint256 amount) external {
+        _redeem(msg.sender, amount);
+    }
+
+    /// @notice Burns `amount` of TBTC from the caller's account and transfers
+    ///         `amount` back to the caller's balance in the Bank.
+    /// @dev This function is doing the same as `redeem` but it allows to
+    ///      execute redemption without an additional approval transaction.
+    ///      The function can be called only via `approveAndCall` of TBTC token.
+    /// @param from TBTC token holder executing redemption
+    /// @param amount Amount of TBTC to redeem
+    /// @param token TBTC token address
+    function receiveApproval(
+        address from,
+        uint256 amount,
+        address token,
+        bytes calldata
+    ) external {
+        require(token == address(tbtcToken), "Token is not TBTC");
+        require(msg.sender == token, "Only TBTC caller allowed");
+        _redeem(from, amount);
+    }
+
+    // slither-disable-next-line calls-loop
+    function _mint(address minter, uint256 amount) internal {
+        emit Minted(minter, amount);
+        tbtcToken.mint(minter, amount);
+    }
+
+    function _redeem(address redeemer, uint256 amount) internal {
+        emit Redeemed(redeemer, amount);
+        tbtcToken.burnFrom(redeemer, amount);
+        bank.transferBalance(redeemer, amount);
+    }
+}

package/deploy/00_resolve_tbtc_v1_token.ts

@@ -13,7 +13,7 @@ const func: DeployFunction = async function (hre: HardhatRuntimeEnvironment) {
   } else if (hre.network.name !== "hardhat") {
     throw new Error("deployed TBTCToken contract not found")
   } else {
-    log(`deploying TBTCToken stub`)
+    log("deploying TBTCToken stub")
 
     await deployments.deploy("TBTCToken", {
       contract: "TestERC20",

package/export.json

@@ -336,7 +336,7 @@
               "type": "address"
             }
           ],
-          "name": "nonces",
+          "name": "nonce",
           "outputs": [
             {
               "internalType": "uint256",
@@ -464,7 +464,7 @@
           "inputs": [
             {
               "internalType": "address",
-              "name": "sender",
+              "name": "spender",
               "type": "address"
             },
             {
@@ -812,7 +812,7 @@
               "type": "address"
             }
           ],
-          "name": "nonces",
+          "name": "nonce",
           "outputs": [
             {
               "internalType": "uint256",
@@ -991,7 +991,7 @@
           "inputs": [
             {
               "internalType": "address",
-              "name": "sender",
+              "name": "spender",
               "type": "address"
             },
             {

package/package.json

@@ -1,6 +1,6 @@
 {
   "name": "@keep-network/tbtc-v2",
-  "version": "0.1.1-dev.0+main.9543288af260644336e2012f667d7d343661e128",
+  "version": "0.1.1-dev.4+main.eb81aee2070bc7ec075c974011ac571313a5bfd7",
   "license": "MIT",
   "files": [
     "artifacts/",
@@ -11,15 +11,16 @@
     "export.json"
   ],
   "scripts": {
+    "clean": "hardhat clean",
     "build": "hardhat compile",
     "deploy": "hardhat deploy --export export.json",
     "format": "npm run lint && prettier --check .",
     "format:fix": "npm run lint:fix && prettier --write .",
-    "lint": "npm run lint:js && npm run lint:sol",
-    "lint:js": "eslint .",
+    "lint": "npm run lint:eslint && npm run lint:sol",
+    "lint:fix": "npm run lint:fix:eslint && npm run lint:fix:sol",
+    "lint:eslint": "eslint .",
+    "lint:fix:eslint": "eslint . --fix",
     "lint:sol": "solhint 'contracts/**/*.sol'",
-    "lint:fix": "npm run lint:fix:js && npm run lint:fix:sol",
-    "lint:fix:js": "eslint . --fix",
     "lint:fix:sol": "solhint 'contracts/**/*.sol' --fix",
     "test": "hardhat test",
     "prepublishOnly": "./scripts/prepare-artifacts.sh --network $npm_config_network"
@@ -28,28 +29,36 @@
     "@keep-network/tbtc": ">1.1.2-dev <1.1.2-ropsten",
     "@openzeppelin/contracts": "^4.1.0",
     "@tenderly/hardhat-tenderly": "^1.0.12",
-    "@thesis/solidity-contracts": "github:thesis/solidity-contracts#507c647"
+    "@thesis/solidity-contracts": "github:thesis/solidity-contracts#4985bcf"
   },
   "devDependencies": {
-    "@keep-network/hardhat-helpers": "^0.2.0-pre",
+    "@keep-network/hardhat-helpers": "0.4.1-pre.1",
     "@keep-network/hardhat-local-networks-config": "^0.1.0-pre.0",
     "@nomiclabs/hardhat-ethers": "^2.0.2",
     "@nomiclabs/hardhat-etherscan": "^2.1.4",
     "@nomiclabs/hardhat-waffle": "^2.0.1",
+    "@thesis-co/eslint-config": "github:thesis/eslint-config",
+    "@typechain/ethers-v5": "^7.2.0",
+    "@typechain/hardhat": "^2.3.1",
+    "@types/chai": "^4.2.22",
+    "@types/mocha": "^9.0.0",
+    "@types/node": "^16.10.5",
     "chai": "^4.3.4",
-    "eslint": "^7.27.0",
-    "eslint-config-keep": "github:keep-network/eslint-config-keep#0.3.0",
-    "ethereum-waffle": "^3.3.0",
-    "ethers": "^5.3.0",
-    "hardhat": "^2.3.0",
+    "eslint": "^7.30.0",
+    "eslint-config-keep": "github:keep-network/eslint-config-keep#0c27ade",
+    "eslint-plugin-import": "^2.18.2",
+    "ethereum-waffle": "^3.4.0",
+    "ethers": "^5.4.7",
+    "hardhat": "^2.6.4",
     "hardhat-deploy": "^0.8.11",
     "hardhat-gas-reporter": "^1.0.4",
     "prettier": "^2.3.0",
     "prettier-plugin-solidity": "^1.0.0-beta.11 ",
     "solhint": "^3.3.6",
     "solhint-config-keep": "github:keep-network/solhint-config-keep",
-    "ts-node": "^10.1.0",
-    "typescript": "^4.3.5"
+    "ts-node": "^10.2.1",
+    "typechain": "^5.2.0",
+    "typescript": "^4.4.3"
   },
   "engines": {
     "node": ">= 14.0.0"