@kecan0406/ttheme 1.1.4 → 1.1.6

package/shell/ttheme.zsh

@@ -3,6 +3,7 @@ typeset -g TTHEME_HOME=${${(%):-%x}:A:h} TTHEME_PALETTES_AT=""
 zmodload -F zsh/stat b:zstat 2>/dev/null
 
 __tt_palettes_load() {
+  emulate -L zsh ${=${options[xtrace]:#off}:+-o xtrace}
   local -a at
   unset TTHEME_PALETTE TTHEME_GROUP TTHEME_CATALOG TTHEME_NATIVE TTHEME_SRC
   source $TTHEME_HOME/palettes.zsh || return 1
@@ -11,6 +12,7 @@ __tt_palettes_load() {
 }
 
 __tt_fresh() {
+  emulate -L zsh ${=${options[xtrace]:#off}:+-o xtrace}
   local -a at
   local was=$TTHEME_STARTUP
   if ! zstat -F %s.%N -A at +mtime -- $TTHEME_HOME/palettes.zsh 2>/dev/null; then
@@ -64,6 +66,7 @@ typeset -g TTHEME_PIN="" TTHEME_PIN_SPEC="" TTHEME_BASE_SPEC=""
 __tt_tilde() { REPLY=${1/#$HOME\//\~/} }
 
 __tt_pins_load() {
+  emulate -L zsh ${=${options[xtrace]:#off}:+-o xtrace}
   setopt localoptions extendedglob
   local raw="" line key name
   [[ -r $TTHEME_PINS_FILE ]] && raw="$(<$TTHEME_PINS_FILE)"
@@ -74,6 +77,7 @@ __tt_pins_load() {
     line=${line%%[[:space:]]##}
     [[ $line == [~/]*[[:space:]]* ]] || continue
     name=${line##*[[:space:]]} key=${${line%[[:space:]]*}%%[[:space:]]##}
+    [[ $key == \~ ]] && key=$HOME
     TTHEME_PINS[${key/#\~\//$HOME/}]=$name
     [[ -n ${TTHEME_PALETTE[$name]} ]] || print -u2 "ttheme: unknown palette '$name' pinned to $key"
   done
@@ -93,27 +97,30 @@ __tt_pins_load
 
 typeset -g TTHEME_STATE_DIR=${XDG_STATE_HOME:-$HOME/.local/state}/ttheme
 
-if [[ $TERM_PROGRAM == WarpTerminal ]]; then
-  typeset -g TTHEME_ADAPTER=warp
-elif [[ -n $GHOSTTY_RESOURCES_DIR || $TERM_PROGRAM == ghostty ]]; then
-  typeset -g TTHEME_ADAPTER=ghostty
-elif [[ -n $KITTY_WINDOW_ID ]]; then
-  typeset -g TTHEME_ADAPTER=kitty
-elif [[ -n $WEZTERM_PANE ]]; then
-  typeset -g TTHEME_ADAPTER=wezterm
-elif [[ -n $ALACRITTY_WINDOW_ID ]]; then
-  typeset -g TTHEME_ADAPTER=alacritty
-elif [[ -n $ITERM_SESSION_ID || $TERM_PROGRAM == iTerm.app ]]; then
-  typeset -g TTHEME_ADAPTER=iterm2
-elif [[ $TERM_PROGRAM == Apple_Terminal ]]; then
-  typeset -g TTHEME_ADAPTER=terminal-app
-elif [[ -n $WT_SESSION && -z $TERM_PROGRAM ]]; then
-  typeset -g TTHEME_ADAPTER=windows-terminal
-elif [[ $TERM == foot* ]]; then
-  typeset -g TTHEME_ADAPTER=foot
-else
-  typeset -g TTHEME_ADAPTER=unknown
-fi
+() {
+  emulate -L zsh ${=${options[xtrace]:#off}:+-o xtrace}
+  if [[ $TERM_PROGRAM == WarpTerminal ]]; then
+    typeset -g TTHEME_ADAPTER=warp
+  elif [[ -n $GHOSTTY_RESOURCES_DIR || $TERM_PROGRAM == ghostty ]]; then
+    typeset -g TTHEME_ADAPTER=ghostty
+  elif [[ -n $KITTY_WINDOW_ID ]]; then
+    typeset -g TTHEME_ADAPTER=kitty
+  elif [[ -n $WEZTERM_PANE ]]; then
+    typeset -g TTHEME_ADAPTER=wezterm
+  elif [[ -n $ALACRITTY_WINDOW_ID ]]; then
+    typeset -g TTHEME_ADAPTER=alacritty
+  elif [[ -n $ITERM_SESSION_ID || $TERM_PROGRAM == iTerm.app ]]; then
+    typeset -g TTHEME_ADAPTER=iterm2
+  elif [[ $TERM_PROGRAM == Apple_Terminal ]]; then
+    typeset -g TTHEME_ADAPTER=terminal-app
+  elif [[ -n $WT_SESSION && -z $TERM_PROGRAM ]]; then
+    typeset -g TTHEME_ADAPTER=windows-terminal
+  elif [[ $TERM == foot* ]]; then
+    typeset -g TTHEME_ADAPTER=foot
+  else
+    typeset -g TTHEME_ADAPTER=unknown
+  fi
+}
 
 typeset -g TTHEME_GHOSTTY_PID="" TTHEME_TMUX=0 TTHEME_MUXED=0
 
@@ -151,6 +158,18 @@ __tt_active() {
 typeset -g TTHEME_HEARD=""
 typeset -gi TTHEME_RECHECK=0 TTHEME_FOCUS=0
 
+__tt_put() {
+  local f=${1:A}
+  shift
+  if zmodload -F zsh/files b:zf_mv 2>/dev/null; then
+    print -rl -- "$@" >| $f.$$ && zf_mv -f -- $f.$$ $f && return 0
+  else
+    print -rl -- "$@" >| $f.$$ && command mv -f -- $f.$$ $f && return 0
+  fi
+  command rm -f -- $f.$$ 2>/dev/null
+  return 1
+}
+
 __tt_recall() {
   local f=$TTHEME_STATE_DIR/colors.$TTHEME_ADAPTER line
   REPLY=""
@@ -165,7 +184,7 @@ __tt_remember() {
   [[ -n $1 && -z $TTHEME_PAINTED ]] && (( ! TTHEME_TMUX )) || return 0
   [[ -r $f && "$(<$f)" == "$line" ]] && return 0
   [[ -d $TTHEME_STATE_DIR ]] || mkdir -p $TTHEME_STATE_DIR 2>/dev/null
-  print -r -- "$line" 2>/dev/null > $f
+  __tt_put $f "$line" 2>/dev/null
 }
 
 __tt_listen() {
@@ -274,11 +293,12 @@ __tt_dir_rule() {
     [[ -n ${TTHEME_PALETTE[$TTHEME_PINS[$k]]} ]] || continue
     base=${${k%/\*\*}:A}
     if [[ $k == *"/**" ]]; then
-      [[ $p == "$base" || $p == "$base"/* ]] || continue
+      [[ $p == "$base" || $p == "${base%/}"/* ]] || continue
     else
       [[ $p == "$base" ]] || continue
     fi
-    (( ${#base} > bestlen )) && { best=$k; bestlen=${#base} }
+    (( ${#base} > bestlen )) || [[ ${#base} == $bestlen && $k != *"/**" ]] || continue
+    best=$k bestlen=${#base}
   done
   [[ -n $best ]] || return 1
   REPLY=$best
@@ -304,6 +324,7 @@ __tt_dir_sync() {
 }
 
 __tt_chpwd() {
+  emulate -L zsh ${=${options[xtrace]:#off}:+-o xtrace}
   __tt_pins_load
   __tt_dir_sync
 }
@@ -316,11 +337,17 @@ __tt_sync() {
   __tt_shown "$REPLY" && __tt_reload
 }
 
-__tt_precmd() { __tt_sync }
+__tt_precmd() {
+  emulate -L zsh ${=${options[xtrace]:#off}:+-o xtrace}
+  __tt_sync
+}
 
 __tt_focus_on() { printf '\e[?1004h' }
 
-__tt_preexec() { printf '\e[?1004l' }
+__tt_preexec() {
+  emulate -L zsh ${=${options[xtrace]:#off}:+-o xtrace}
+  printf '\e[?1004l'
+}
 
 __tt_rewear() {
   local REPLY
@@ -332,6 +359,7 @@ __tt_rewear() {
 }
 
 __tt_focus() {
+  emulate -L zsh ${=${options[xtrace]:#off}:+-o xtrace}
   __tt_fresh
   if (( TTHEME_TMUX )); then
     __tt_rewear
@@ -340,17 +368,25 @@ __tt_focus() {
   fi
 }
 
-__tt_mux() { [[ ${${(z)3}[1]:t} == tmux ]] && TTHEME_MUXED=1 }
+__tt_mux() {
+  emulate -L zsh ${=${options[xtrace]:#off}:+-o xtrace}
+  [[ ${${(z)3}[1]:t} == tmux ]] && TTHEME_MUXED=1
+}
 
 __tt_unmux() {
+  emulate -L zsh ${=${options[xtrace]:#off}:+-o xtrace}
   (( TTHEME_MUXED )) || return 0
   __tt_rewear force
   TTHEME_MUXED=0
 }
 
-__tt_blur() { : }
+__tt_blur() {
+  emulate -L zsh ${=${options[xtrace]:#off}:+-o xtrace}
+  :
+}
 
 __tt_line_init() {
+  emulate -L zsh ${=${options[xtrace]:#off}:+-o xtrace}
   (( TTHEME_RECHECK )) && __tt_recheck
   __tt_typed
   (( TTHEME_FOCUS )) && __tt_focus_on
@@ -385,56 +421,673 @@ __tt_pins_write() {
     return 0
   fi
   mkdir -p ${TTHEME_PINS_FILE:h} || return 1
-  print -rl -- "${lines[@]}" > $TTHEME_PINS_FILE || return 1
+  __tt_put $TTHEME_PINS_FILE "${lines[@]}" || return 1
   TTHEME_PINS_RAW="$(<$TTHEME_PINS_FILE)"
 }
 
+__tt_pin_base() { REPLY=${${${1%/\*\*}:-/}:a} }
+
+__tt_dir_label() {
+  if [[ $1 == "${HOME:a}" ]]; then
+    REPLY='~'
+  else
+    __tt_tilde "$1"
+  fi
+}
+
+__tt_pin_scope() {
+  if [[ $1 == *"/**" ]]; then
+    REPLY="and below"
+  else
+    REPLY="this directory"
+  fi
+}
+
+__tt_repo() {
+  local at=${1:a}
+  while [[ $at != / ]]; do
+    [[ -e $at/.git ]] && break
+    at=${at:h}
+  done
+  [[ $at != / && $at != "${HOME:a}" ]] || return 1
+  REPLY=$at
+}
+
+__tt_pin_cover() {
+  local k b best=""
+  local -i len=-1
+  for k in ${(k)TTHEME_PINS}; do
+    [[ $k == /* && $k == *"/**" && -n ${TTHEME_PALETTE[$TTHEME_PINS[$k]]} ]] || continue
+    __tt_pin_base "$k"
+    b=$REPLY
+    [[ $1 == "$b" || $1 == "${b%/}"/* ]] || continue
+    (( ${#b} > len )) && { best=$k len=${#b} }
+  done
+  [[ -n $best ]] || return 1
+  REPLY=$best
+}
+
+__tt_pin_scopes() {
+  local d=${1:a} k
+  plabel=(" This directory " " And below ") pkeys=("$d" "${d%/}/**") pkdef=2
+  if __tt_repo "$d" && [[ $REPLY != "$d" ]]; then
+    plabel+=(" Repository ") pkeys+=("$REPLY/**")
+  fi
+  for k in ${(k)TTHEME_PINS}; do
+    [[ $k == /* ]] || continue
+    __tt_pin_base "$k"
+    [[ $REPLY == "$d" ]] || continue
+    if [[ $k == *"/**" ]]; then pkdef=2; else pkdef=1; fi
+  done
+}
+
 __tt_pin_save() {
-  local name=$1 key=$PWD REPLY
-  (( $2 == 2 )) && key="$PWD/**"
-  unset "TTHEME_PINS[$PWD]" "TTHEME_PINS[$PWD/**]"
+  local name=$1 key=$2 k base spec REPLY
+  __tt_pin_base "$key"
+  base=$REPLY
+  for k in ${(k)TTHEME_PINS}; do
+    [[ $k == /* ]] || continue
+    __tt_pin_base "$k"
+    [[ $REPLY == "$base" ]] && unset "TTHEME_PINS[$k]"
+  done
   TTHEME_PINS[$key]=$name
   if ! __tt_pins_write; then
     print -u2 "ttheme pin: could not write $TTHEME_PINS_FILE"
     return 1
   fi
   [[ -n $TTHEME_PIN ]] || TTHEME_BASE_SPEC=$3
-  TTHEME_PIN=$key TTHEME_PIN_SPEC=${TTHEME_PALETTE[$name]}
-  __tt_tilde "$key"
+  if __tt_dir_rule "$PWD"; then
+    spec=${TTHEME_PALETTE[$TTHEME_PINS[$REPLY]]}
+    TTHEME_PIN=$REPLY TTHEME_PIN_SPEC=$spec
+  else
+    spec=$TTHEME_BASE_SPEC
+    TTHEME_PIN="" TTHEME_PIN_SPEC=""
+  fi
+  if [[ $spec != "$TTHEME_SPEC" ]]; then
+    if [[ -n $spec ]]; then
+      __tt_apply "$spec"
+    else
+      __tt_osc_reset
+    fi
+    TTHEME_SPEC=$spec
+  fi
+  __tt_dir_label "$base"
+  k=$REPLY
+  __tt_pin_scope "$key"
   if __tt_color; then
-    printf '\033[2mPinned · %s → %s\033[0m\n' "$REPLY" "$name"
+    printf '\033[2mPinned · %s → %s · %s\033[0m\n' "$name" "$k" "$REPLY"
   else
-    print -r -- "Pinned · $REPLY → $name"
+    print -r -- "Pinned · $name → $k · $REPLY"
+  fi
+  if [[ $TTHEME_PIN != "$key" ]]; then
+    __tt_here_line Here
+    print -r -- "$REPLY"
   fi
 }
 
-__tt_unpin() {
-  local key REPLY
-  for key in "$PWD" "$PWD/**"; do
-    [[ -n ${TTHEME_PINS[$key]} ]] || continue
-    unset "TTHEME_PINS[$key]"
-    if ! __tt_pins_write; then
-      print -u2 "ttheme unpin: could not write $TTHEME_PINS_FILE"
-      return 1
-    fi
-    __tt_dir_sync
-    __tt_tilde "$key"
+__tt_unpin_drop() {
+  local k REPLY where
+  local -a gone=()
+  for k in "$@"; do
+    [[ -n ${TTHEME_PINS[$k]} ]] || continue
+    __tt_pin_base "$k"
+    __tt_dir_label "$REPLY"
+    where=$REPLY
+    __tt_pin_scope "$k"
+    gone+=("Unpinned · ${TTHEME_PINS[$k]} on $where · $REPLY")
+    unset "TTHEME_PINS[$k]"
+  done
+  if ! __tt_pins_write; then
+    print -u2 "ttheme unpin: could not write $TTHEME_PINS_FILE"
+    return 1
+  fi
+  __tt_dir_sync
+  for k in $gone; do
     if __tt_color; then
-      printf '\033[2mUnpinned · %s\033[0m\n' "$REPLY"
+      print -r -- $'\e[2m'"$k"$'\e[0m'
     else
-      print -r -- "Unpinned · $REPLY"
+      print -r -- "$k"
     fi
-    return 0
   done
-  if __tt_dir_rule "$PWD"; then
-    __tt_tilde "$REPLY"
-    print -u2 "ttheme unpin: nothing pinned here — $REPLY covers this directory"
+  __tt_here_line Here
+  print -r -- "$REPLY"
+}
+
+__tt_unpin_then() {
+  local k
+  local -A TTHEME_PINS=("${(@kv)TTHEME_PINS}")
+  for k in "${@:2}"; do
+    unset "TTHEME_PINS[$k]"
+  done
+  __tt_here_fit "Then here" $1
+}
+
+__tt_key() {
+  local c seq=""
+  REPLY=""
+  read -sk 1 c || return 1
+  case $c in
+    $'\e')
+      if ! read -sk 1 -t 0.05 c; then
+        REPLY=esc
+      elif [[ $c == '[' || $c == O ]]; then
+        while read -sk 1 -t 0.05 c; do
+          seq+=$c
+          [[ $c == [A-Za-z~] ]] && break
+        done
+        case $seq in
+          C) REPLY=right ;;
+          D) REPLY=left ;;
+          Z) REPLY=stab ;;
+          *) REPLY=nop ;;
+        esac
+      else
+        REPLY=nop
+      fi
+      ;;
+    $'\t') REPLY=tab ;;
+    $'\r'|$'\n') REPLY=enter ;;
+    q|$'\x03') REPLY=esc ;;
+    *) REPLY=$c ;;
+  esac
+}
+
+__tt_unpin_block() {
+  local b=$'\e[1m' d=$'\e[2m' z=$'\e[0m' on=$'\e[7;1m' bar plain keys top k home=${HOME:a} here=${PWD:a} htip="" REPLY
+  local -A own=() below=() parent=() mark=() tstrip=()
+  local -a roots=() lp=() lpw=() ll=() lat=() lpal=() lnote=() lflag=() reply gone=(${(f)drops[$1]})
+  local -i i width=$(( (COLUMNS > 0 ? COLUMNS : 80) - 1 )) room=$(( (LINES > 0 ? LINES : 24) - 3 ))
+  (( color )) || b= d= z= on=
+  if (( color )); then
+    bar=$'\e[7;1m UNPIN \e[0m ' plain="  UNPIN  "
   else
+    bar="[UNPIN]" plain=$bar
+  fi
+  for (( i = 1; i <= ${#lab}; i++ )); do
+    plain+=" ${lab[i]}"
+    if (( i != $1 )); then
+      bar+=" "$d${lab[i]}$z
+    elif (( color )); then
+      bar+=" "$on${lab[i]}$z
+    else
+      bar+=" [${${lab[i]# }% }]"
+    fi
+  done
+  keys="←→ choose · enter unpin · esc keep"
+  (( ${(m)#plain} + 3 + ${(m)#keys} <= width )) && bar+="   "$d$keys$z
+  __tt_clip "$bar" $width
+  bar=$REPLY
+  for k in $gone; do
+    __tt_pin_base "$k"
+    mark[$REPLY]=drop
+  done
+  top=${PWD:a}
+  [[ -n $cover ]] && __tt_pin_base "$cover" && top=$REPLY
+  __tt_map_build "$top"
+  __tt_map_fit $width
+  (( ${#reply} > room )) && reply=("${(@)reply[1,room-1]}" "   …")
+  block=("$bar" "${reply[@]}")
+  __tt_unpin_then $width $gone
+  block+=("${reply[@]}")
+}
+
+__tt_unpin_paint() {
+  local out=$'\r'
+  (( $1 > 1 )) && out+=$'\e['$(( $1 - 1 ))'A'
+  out+=${(pj:\e[K\n:)block}$'\e[K\e[J'
+  print -rn -- "$out"
+}
+
+__tt_unpin_choose() {
+  local tty="" REPLY
+  local -i n=0 at=1
+  local -a block=()
+  chosen=0
+  {
+    tty=$(stty -g 2>/dev/null && stty -echo -icanon min 1 time 0 2>/dev/null)
+    print -rn -- $'\e[?25l'
+    while :; do
+      __tt_unpin_block $at
+      __tt_unpin_paint $n
+      n=${#block}
+      __tt_key || break
+      case $REPLY in
+        left|stab) at=$(( (at + ${#lab} - 2) % ${#lab} + 1 )) ;;
+        right|tab) at=$(( at % ${#lab} + 1 )) ;;
+        enter) chosen=$at; break ;;
+        esc) break ;;
+      esac
+    done
+  } always {
+    REPLY=$'\r'
+    (( n > 1 )) && REPLY+=$'\e['$(( n - 1 ))'A'
+    print -rn -- "$REPLY"$'\e[J\e[?25h'
+    [[ -n $tty ]] && stty "$tty" 2>/dev/null
+  }
+  (( chosen ))
+}
+
+__tt_unpin_options() {
+  local d=${PWD:a} k REPLY
+  local -a both
+  mine=() under=() lab=() drops=() cover=""
+  for k in ${(k)TTHEME_PINS}; do
+    [[ $k == /* ]] || continue
+    __tt_pin_base "$k"
+    if [[ $REPLY == "$d" ]]; then
+      mine+=("$k")
+    elif [[ $REPLY == "${d%/}"/* ]]; then
+      under+=("$k")
+    fi
+  done
+  [[ $d != / ]] && __tt_pin_cover "${d:h}" && cover=$REPLY
+  if (( ${#mine} )); then
+    lab+=(" This directory ") drops+=("${(pj:\n:)mine}")
+  fi
+  if (( ${#under} )); then
+    both=($mine $under)
+    lab+=(" And below ") drops+=("${(pj:\n:)both}")
+  fi
+  if [[ -n $cover ]]; then
+    __tt_pin_base "$cover"
+    __tt_dir_label "$REPLY"
+    lab+=(" $REPLY ") drops+=("$cover")
+  fi
+  return 0
+}
+
+__tt_unpin() {
+  emulate -L zsh ${=${options[xtrace]:#off}:+-o xtrace}
+  local d k cover="" REPLY
+  local -a mine=() under=() lab=() drops=()
+  local -i chosen=0 color=0
+  __tt_color && color=1
+  __tt_pins_load
+  if (( $# )); then
+    d=$1
+    [[ $d == \~ || $d == \~/* ]] && d=$HOME${d#\~}
+    d=${d:a}
+    for k in ${(k)TTHEME_PINS}; do
+      [[ $k == /* ]] || continue
+      __tt_pin_base "$k"
+      [[ $REPLY == "$d" ]] && mine+=("$k")
+    done
+    if (( ${#mine} )); then
+      __tt_unpin_drop $mine
+      return
+    fi
+    __tt_dir_label "$d"
+    k=$REPLY
+    if __tt_pin_cover "$d"; then
+      __tt_pin_base "$REPLY"
+      __tt_dir_label "$REPLY"
+      print -u2 -r -- "ttheme unpin: nothing pinned to $k — the pin on $REPLY and below covers it"
+    else
+      print -u2 -r -- "ttheme unpin: nothing pinned to $k"
+    fi
+    return 1
+  fi
+  __tt_unpin_options
+  if (( ! ${#lab} )); then
     print -u2 "ttheme unpin: nothing pinned here"
+    return 1
+  fi
+  if (( ${#lab} == 1 && ${#mine} )); then
+    __tt_unpin_drop $mine
+    return
+  fi
+  if [[ ! -t 0 || ! -t 1 ]]; then
+    if (( ${#mine} )); then
+      __tt_unpin_drop $mine
+      return
+    fi
+    if [[ -n $cover ]]; then
+      __tt_pin_base "$cover"
+      __tt_dir_label "$REPLY"
+      print -u2 -r -- "ttheme unpin: nothing pinned here — the pin on $REPLY and below covers it: ttheme unpin $REPLY"
+    elif (( ${#under} == 1 )); then
+      print -u2 -r -- "ttheme unpin: nothing pinned here — 1 pin below it: ttheme pins maps it"
+    else
+      print -u2 -r -- "ttheme unpin: nothing pinned here — ${#under} pins below it: ttheme pins maps them"
+    fi
+    return 1
   fi
+  __tt_unpin_choose || return 1
+  __tt_unpin_drop ${(f)drops[chosen]}
+}
+
+__tt_clip() {
+  local c out=""
+  local -i i n=${#1} w=0 cw
+  REPLY=$1
+  for (( i = 1; i <= n; i++ )); do
+    c=${1[i]}
+    if [[ $c == $'\e' ]]; then
+      while (( i < n )) && [[ ${1[i]} != [A-Za-z] || ${1[i]} == $'\e' ]]; do (( i++ )); done
+      continue
+    fi
+    (( w += ${(m)#c} ))
+  done
+  (( w <= $2 )) && return 0
+  w=0
+  for (( i = 1; i <= n; i++ )); do
+    c=${1[i]}
+    if [[ $c == $'\e' ]]; then
+      out+=$c
+      while (( i < n )); do
+        (( i++ ))
+        out+=${1[i]}
+        [[ ${1[i]} == [A-Za-z] ]] && break
+      done
+      continue
+    fi
+    cw=${(m)#c}
+    (( w + cw > $2 - 1 )) && break
+    out+=$c
+    (( w += cw ))
+  done
+  REPLY=$out…
+  [[ $1 == *$'\e'* ]] && REPLY+=$'\e[0m'
   return 1
 }
 
+__tt_map_tip() {
+  local -a p=(${=TTHEME_PALETTE[$1]})
+  local c=${p[3]#\#}
+  REPLY=""
+  (( color && ${#p} >= 20 )) || return 0
+  printf -v REPLY '\e[38;2;%d;%d;%dm' $((16#${c:0:2})) $((16#${c:2:2})) $((16#${c:4:2}))
+}
+
+__tt_map_chip() {
+  local -a p=(${=TTHEME_PALETTE[$1]})
+  local bg=${p[1]#\#} fg=${p[2]#\#}
+  if (( ! color )); then
+    printf -v REPLY '%-*s' $2 "$1"
+  elif (( ${#p} >= 20 )); then
+    printf -v REPLY '\e[48;2;%d;%d;%d;38;2;%d;%d;%dm %-*s \e[0m' $((16#${bg:0:2})) $((16#${bg:2:2})) $((16#${bg:4:2})) \
+      $((16#${fg:0:2})) $((16#${fg:2:2})) $((16#${fg:4:2})) $2 "$1"
+  else
+    printf -v REPLY '\e[2m %-*s \e[0m' $2 "$1"
+  fi
+}
+
+__tt_here_line() {
+  local rule name where
+  if ! __tt_dir_rule "$PWD"; then
+    reply=("$1 · no pin" "the tab's own palette")
+    REPLY="$1 · no pin — the tab's own palette"
+    return 0
+  fi
+  rule=$REPLY name=$TTHEME_PINS[$REPLY]
+  __tt_pin_base "$rule"
+  if [[ ${REPLY:A} == "${PWD:A}" ]]; then
+    where="this directory"
+  else
+    __tt_dir_label "$REPLY"
+    where=$REPLY
+  fi
+  [[ $rule == *"/**" ]] && where+=" and below"
+  __tt_map_chip "$name" ${#name}
+  reply=("$1 · $REPLY" "pinned to $where")
+  REPLY="$1 · $REPLY pinned to $where"
+}
+
+__tt_here_fit() {
+  __tt_here_line "$1"
+  __tt_clip "$REPLY" $2 && { reply=("$REPLY"); return 0 }
+  __tt_clip "${reply[1]}" $2
+  reply[1]=$REPLY
+  __tt_clip "  ${reply[2]}" $2
+  reply[2]=$REPLY
+}
+
+__tt_map_under() {
+  local b name
+  local -i len=-1
+  REPLY=""
+  for b in ${(k)below}; do
+    name=${below[$b]}
+    [[ -n ${TTHEME_PALETTE[$name]} && ( $1 == "$b" || $1 == "${b%/}"/* ) ]] || continue
+    (( ${#b} > len )) && { REPLY=$name len=${#b} }
+  done
+}
+
+__tt_map_link() {
+  local at=$1 root=/
+  if [[ -n $top ]]; then
+    root=$top
+  elif [[ $at == "$home" || $at == "$home"/* ]]; then
+    root=$home
+  fi
+  (( ${roots[(Ie)$root]} )) || roots+=("$root")
+  while [[ $at != "$root" && -z ${parent[$at]} ]]; do
+    parent[$at]=${at:h}
+    at=${at:h}
+  done
+}
+
+__tt_map_chain() {
+  local at=$1 lbl=$2
+  local -a ks
+  while [[ -z ${own[$at]}${below[$at]} && $at != "$here" ]]; do
+    ks=(${(k)parent[(Re)$at]})
+    (( ${#ks} == 1 )) || break
+    at=$ks[1] lbl+=/${at:t}
+  done
+  reply=("$at" "${lbl:-/}")
+}
+
+__tt_map_line() {
+  local at=$1 name=${own[$1]:-${below[$1]}} note="" flag=""
+  if [[ -n $name ]]; then
+    if [[ -n ${own[$at]} ]]; then
+      note="this directory"
+      [[ -n ${below[$at]} ]] && note+=" · ${below[$at]} below"
+    else
+      note="and below"
+    fi
+    [[ -n ${TTHEME_PALETTE[$name]} ]] || flag="not installed"
+    [[ -d $at ]] || flag+="${flag:+ · }no such directory"
+  fi
+  lp+=("$2") lpw+=($3) ll+=("$4") lat+=("$at") lpal+=("$name") lnote+=("$note") lflag+=("$flag")
+}
+
+__tt_map_walk() {
+  local at=$1 pre=$2 tip z=$'\e[0m' REPLY
+  local -i i
+  local -a ks=(${(oi)${(k)parent[(Re)$1]}}) reply
+  (( color )) || z=
+  __tt_map_under "$at"
+  __tt_map_tip "$REPLY"
+  tip=$REPLY
+  (( color )) && [[ -z $tip ]] && tip=$'\e[2m'
+  for (( i = 1; i <= ${#ks}; i++ )); do
+    __tt_map_chain "$ks[i]" "${ks[i]:t}"
+    if (( i < ${#ks} )); then
+      __tt_map_line "$reply[1]" "$pre$tip├─ $z" $(( $3 + 3 )) "$reply[2]"
+      __tt_map_walk "$reply[1]" "$pre$tip│  $z" $(( $3 + 3 ))
+    else
+      __tt_map_line "$reply[1]" "$pre$tip└─ $z" $(( $3 + 3 )) "$reply[2]"
+      __tt_map_walk "$reply[1]" "$pre   " $(( $3 + 3 ))
+    fi
+  done
+}
+
+__tt_map_build() {
+  local top=$1 k base root REPLY
+  local -a order=()
+  own=() below=() parent=() roots=() lp=() lpw=() ll=() lat=() lpal=() lnote=() lflag=() htip=""
+  for k in ${(k)TTHEME_PINS}; do
+    [[ $k == /* ]] || continue
+    __tt_pin_base "$k"
+    base=$REPLY
+    if [[ $k == *"/**" ]]; then
+      below[$base]=$TTHEME_PINS[$k]
+    else
+      own[$base]=$TTHEME_PINS[$k]
+    fi
+    [[ -z $top || $base == "$top" || $base == "${top%/}"/* ]] && __tt_map_link "$base"
+  done
+  [[ -z $top || $here == "$top" || $here == "${top%/}"/* ]] && __tt_map_link "$here"
+  __tt_dir_rule "$PWD" && __tt_map_tip "$TTHEME_PINS[$REPLY]" && htip=$REPLY
+  if [[ -n $top ]]; then
+    order=("$top")
+  else
+    (( ${roots[(Ie)$home]} )) && order+=("$home")
+    [[ $home != / ]] && (( ${roots[(Ie)/]} )) && order+=(/)
+  fi
+  for root in $order; do
+    if [[ $root == / ]]; then
+      __tt_map_chain / ""
+    else
+      __tt_dir_label "$root"
+      __tt_map_chain "$root" "$REPLY"
+    fi
+    __tt_map_line "$reply[1]" "" 0 "$reply[2]"
+    __tt_map_walk "$reply[1]" "" 0
+  done
+}
+
+__tt_map_fit() {
+  local b=$'\e[1m' d=$'\e[2m' y=$'\e[33m' r=$'\e[31m' z=$'\e[0m' lab line tag tip note REPLY
+  local -i width=$1 i lvl maxw namew need wr cap
+  local -a lw=() rw=() cut=()
+  (( color )) || b= d= y= r= z=
+  reply=()
+  for (( i = 1; i <= ${#ll}; i++ )); do
+    lw+=($(( lpw[i] + ${(m)#ll[i]} )))
+    [[ ${lat[i]} == "$here" ]] && (( lw[i] += 7 ))
+    (( ${#lpal[i]} > namew )) && namew=${#lpal[i]}
+  done
+  for (( lvl = 0; lvl < 4; lvl++ )); do
+    rw=() maxw=0 need=0
+    for (( i = 1; i <= ${#ll}; i++ )); do
+      wr=0
+      if [[ -n $lpal[i] ]]; then
+        wr=$(( 2 + namew + 2 * color ))
+        (( lvl == 0 && color )) && (( wr += 13 ))
+        note=${lnote[i]}
+        (( lvl == 2 )) && note=${${note//this directory/only}//and below/below}
+        (( lvl < 3 )) && (( wr += 2 + ${(m)#note} ))
+        [[ -n $lflag[i] ]] && (( wr += 3 + ${(m)#lflag[i]} ))
+        tag=${mark[$lat[i]]}
+        [[ $tag == new ]] && (( wr += 5 ))
+        [[ $tag == drop ]] && (( wr += 9 ))
+        (( lw[i] > maxw )) && maxw=$lw[i]
+      fi
+      rw+=($wr)
+    done
+    for (( i = 1; i <= ${#ll}; i++ )); do
+      if (( rw[i] )); then
+        (( maxw + rw[i] > need )) && need=$(( maxw + rw[i] ))
+      else
+        (( lw[i] > need )) && need=$lw[i]
+      fi
+    done
+    (( need <= width )) && break
+  done
+  (( lvl > 3 )) && lvl=3
+  cut=()
+  if (( need > width )); then
+    cap=0
+    for (( i = 1; i <= ${#ll}; i++ )); do
+      (( rw[i] > cap )) && cap=$rw[i]
+    done
+    cap=$(( width - cap ))
+    maxw=0
+    for (( i = 1; i <= ${#ll}; i++ )); do
+      wr=$(( rw[i] ? cap : width ))
+      lab=${ll[i]}
+      if (( lw[i] > wr )); then
+        while [[ -n $lab ]] && (( lw[i] - ${(m)#ll[i]} + ${(m)#lab} + 1 > wr )); do
+          lab=${lab[2,-1]}
+        done
+        lab=…$lab
+        lw[i]=$(( lw[i] - ${(m)#ll[i]} + ${(m)#lab} ))
+      fi
+      cut+=("$lab")
+      (( rw[i] && lw[i] > maxw )) && maxw=$lw[i]
+    done
+  else
+    cut=("${ll[@]}")
+  fi
+  for (( i = 1; i <= ${#ll}; i++ )); do
+    if [[ -n $lpal[i] ]]; then
+      line=${lp[i]}$b${cut[i]}$z
+    else
+      line=${lp[i]}$d${cut[i]}$z
+    fi
+    [[ ${lat[i]} == "$here" ]] && line+=" "$htip$b"← here"$z
+    if [[ -n $lpal[i] ]]; then
+      __tt_map_chip "$lpal[i]" $namew
+      line+=${(l:maxw - lw[i] + 2:: :)}$REPLY
+      if (( lvl == 0 && color )); then
+        if [[ -n ${TTHEME_PALETTE[$lpal[i]]} ]]; then
+          [[ -n ${tstrip[$lpal[i]]} ]] || __tt_pv_strip "$lpal[i]"
+          line+="  "${tstrip[$lpal[i]]}
+        else
+          line+=${(l:13:: :)}
+        fi
+      fi
+      note=${lnote[i]}
+      (( lvl == 2 )) && note=${${note//this directory/only}//and below/below}
+      (( lvl < 3 )) && line+="  "$d$note$z
+      [[ -n $lflag[i] ]] && line+=$y" · "$lflag[i]$z
+      tag=${mark[$lat[i]]}
+      if [[ $tag == new ]]; then
+        __tt_map_tip "$lpal[i]"
+        line+="  "$b$REPLY"new"$z
+      elif [[ $tag == drop ]]; then
+        line+="  "$r"✕ unpin"$z
+      fi
+    fi
+    while [[ $line == *' ' ]]; do line=${line% }; done
+    reply+=("$line")
+  done
+}
+
+__tt_map_tree() {
+  local home=${HOME:a} here=${PWD:a} htip="" REPLY
+  local -A own=() below=() parent=() mark=() tstrip=()
+  local -a roots=() lp=() lpw=() ll=() lat=() lpal=() lnote=() lflag=() reply
+  local -i width=$(( COLUMNS > 0 ? COLUMNS : 80 ))
+  __tt_map_build ""
+  __tt_map_fit $width
+  print -rl -- "${reply[@]}"
+  print
+  __tt_here_line Here
+  __tt_clip "$REPLY" $width
+  print -r -- "$REPLY"
+  __tt_tilde "$TTHEME_PINS_FILE"
+  if (( color )); then
+    __tt_clip $'\e[2m'"ttheme pin picks one here · ttheme unpin drops one · $REPLY"$'\e[0m' $width
+  else
+    __tt_clip "ttheme pin picks one here · ttheme unpin drops one · $REPLY" $width
+  fi
+  print -r -- "$REPLY"
+}
+
+__tt_pins_map() {
+  emulate -L zsh ${=${options[xtrace]:#off}:+-o xtrace}
+  local k REPLY
+  local -i color=0
+  __tt_pins_load
+  if [[ ! -t 1 ]]; then
+    for k in ${(oi)${(k)TTHEME_PINS}}; do
+      __tt_tilde "$k"
+      print -r -- "$REPLY"$'\t'"$TTHEME_PINS[$k]"
+    done
+    return 0
+  fi
+  if (( ! ${#TTHEME_PINS} )); then
+    print -r -- 'No pins yet — `ttheme pin` picks a palette for this directory'
+    return 0
+  fi
+  __tt_color && color=1
+  __tt_map_tree
+}
+
 __tt_keep() {
   local note
   note=$(__tt_cli default "$1") || return 1
@@ -577,7 +1230,7 @@ __tt_config() {
   local blur
   if [[ ! -e $TTHEME_CONFIG ]]; then
     mkdir -p ${TTHEME_CONFIG:h} || return 1
-    print -r -- "$TTHEME_CONFIG_TEMPLATE" > $TTHEME_CONFIG
+    __tt_put $TTHEME_CONFIG "$TTHEME_CONFIG_TEMPLATE"
   fi
   blur=${(M)${(@f)"$(<$TTHEME_CONFIG)"}:#': ${TTHEME_BG_BLUR:='*}
   ${=${VISUAL:-${EDITOR:-vi}}} $TTHEME_CONFIG || return
@@ -607,7 +1260,7 @@ __tt_config_write() {
   local -i i
   if [[ ! -e $TTHEME_CONFIG ]]; then
     mkdir -p ${TTHEME_CONFIG:h} 2>/dev/null || return 1
-    print -r -- "$TTHEME_CONFIG_TEMPLATE" 2>/dev/null > $TTHEME_CONFIG || return 1
+    __tt_put $TTHEME_CONFIG "$TTHEME_CONFIG_TEMPLATE" 2>/dev/null || return 1
   fi
   [[ -r $TTHEME_CONFIG && -w $TTHEME_CONFIG ]] || return 1
   for line in "${(@f)$(<$TTHEME_CONFIG)}"; do
@@ -631,7 +1284,7 @@ __tt_config_write() {
     __tt_config_line $name ${want[$name]}
     out+=("" "$doc" "$REPLY")
   done
-  print -rl -- "${out[@]}" 2>/dev/null > $TTHEME_CONFIG
+  __tt_put $TTHEME_CONFIG "${out[@]}" 2>/dev/null
 }
 
 __tt_resolve() {
@@ -679,16 +1332,45 @@ __tt_rotate() {
   __tt_announce
 }
 
+__tt_pv_norm() { REPLY=${(L)1//[^[:alnum:]]/} }
+
+__tt_pv_seek() {
+  local t part key REPLY
+  for t in ${(k)TTHEME_PALETTE}; do
+    key=""
+    for part in "$t" "${TTHEME_GROUP[$t]:-Other}" "${TTHEME_NATIVE[$t]}" "${TTHEME_CATALOG[$t]}" "${(@s:|:)TTHEME_NATIVE_NAMES[$t]}" "${TTHEME_CHARACTER[$t]}"; do
+      [[ -n $part ]] || continue
+      __tt_pv_norm "$part"
+      key+="|$REPLY"
+    done
+    pvseek[$t]=$key
+  done
+}
+
+__tt_pv_alias() {
+  REPLY=""
+  [[ -n $nflt && -n $2 ]] || return 0
+  local main
+  __tt_pv_norm "$1"
+  main=$REPLY
+  __tt_pv_norm "$2"
+  [[ $main != *$nflt* && $REPLY == *$nflt* ]] && REPLY=$2 || REPLY=""
+  return 0
+}
+
 __tt_pv_rows() {
   rtype=() rval=() rcnt=()
-  local g t c gm ruled=""
+  local g t c ruled="" nflt="" REPLY
   local -a ts cs loose inside
+  if [[ -n $flt ]]; then
+    (( ${#pvseek} )) || __tt_pv_seek
+    __tt_pv_norm "$flt"
+    nflt=$REPLY
+  fi
   for g in $groups; do
     ts=()
-    gm=""
-    [[ -n $flt && ${(L)g} == *$flt* ]] && gm=1
     for t in ${=gthemes[$g]}; do
-      [[ -z $flt || -n $gm || $t == *$flt* || ${(L)TTHEME_CATALOG[$t]} == *$flt* ]] && ts+=($t)
+      [[ -z $flt || ${pvseek[$t]} == *$nflt* ]] && ts+=($t)
     done
     [[ -n $flt ]] && (( ! ${#ts} )) && continue
     if [[ $g == *@* && -z $ruled ]]; then
@@ -753,9 +1435,16 @@ __tt_pv_goto() {
   cur=1
 }
 
+__tt_pv_shows() {
+  REPLY=${bgview[$1]:-$1}
+  [[ -n $tune && $1 == "$tune" ]] && REPLY=$tpick
+  return 0
+}
+
 __tt_pv_focus() {
   [[ ${rtype[cur]} == thm ]] || return 0
-  (( resized )) || [[ ${rval[cur]} == "$bgname" ]] || __tt_pv_bg_show "${rval[cur]}"
+  __tt_pv_shows ${rval[cur]}
+  (( resized )) || [[ $REPLY == "$bgname" ]] || __tt_pv_bg_show "$REPLY"
   local spec=${TTHEME_PALETTE[${rval[cur]}]}
   [[ $spec == "$applied" ]] && return 0
   __tt_pv_paint "$spec"
@@ -854,8 +1543,20 @@ __tt_pv_hl() {
   REPLY=${t[1,${#pre}]}$'\e[1;4m'$ac${t[${#pre}+1,${#pre}+${#flt}]}$'\e[22;24;39m'$2${t[${#pre}+${#flt}+1,-1]}
 }
 
+__tt_pv_fit() {
+  local extra=$1
+  REPLY=""
+  [[ -n $extra ]] || return 0
+  while [[ -n $extra ]] && (( ${(m)#extra} + 3 > w )); do
+    extra=${extra[1,-2]}
+  done
+  [[ -n $extra ]] || return 0
+  (( w -= ${(m)#extra} + 2 ))
+  REPLY="  "$d$extra$r
+}
+
 __tt_pv_row() {
-  local t=${rval[$1]} b=$'\e[1m' d=$'\e[2m' r=$'\e[22;24;39m' z=$'\e[0m' on="" gut="  " base="" lead=$'\e[2m' mark=" " name arrow=▸ ind="   "
+  local t=${rval[$1]} b=$'\e[1m' d=$'\e[2m' r=$'\e[22;24;39m' z=$'\e[0m' on="" gut="  " base="" lead=$'\e[2m' mark=" " name arrow=▸ ind="   " hl extra part
   local -i w
   (( color )) || b= d= r= z= lead=
   if (( $1 == cur )); then
@@ -878,9 +1579,13 @@ __tt_pv_row() {
       lead=""
     fi
     __tt_pv_hl "$name" "$base"
+    hl=$REPLY
     w=$(( lw - 6 - ${(m)#name} - ${#rcnt[$1]} ))
+    __tt_pv_alias "$t" "${TTHEME_NATIVE[${${=gthemes[$t]}[1]}]}"
+    __tt_pv_fit "$REPLY"
+    extra=$REPLY
     (( w < 1 )) && w=1
-    REPLY=$gut$on" "$lead$arrow$r" "$base$REPLY$r${(l:w:: :)}$d${rcnt[$1]}$r" "$z
+    REPLY=$gut$on" "$lead$arrow$r" "$base$hl$r$extra${(l:w:: :)}$d${rcnt[$1]}$r" "$z
     return 0
   fi
   if [[ ${rtype[$1]} == cat ]]; then
@@ -907,16 +1612,36 @@ __tt_pv_row() {
   name=${t##*/}
   [[ -n ${TTHEME_CATALOG[$t]} && ${TTHEME_GROUP[$t]} == *@* ]] && ind="     "
   __tt_pv_hl "$name" "$base"
+  hl=$REPLY
+  extra=""
+  for part in "${(@s:|:)TTHEME_NATIVE_NAMES[$t]}" "${TTHEME_CHARACTER[$t]}"; do
+    __tt_pv_alias "$name" "$part"
+    [[ -n $REPLY ]] && { extra=$REPLY; break }
+  done
   if (( color )); then
     [[ -n ${tstrip[$t]} ]] || __tt_pv_strip $t
     w=$(( lw - 16 - ${#ind} - ${#name} ))
+    __tt_pv_fit "$extra"
     (( w < 1 )) && w=1
-    REPLY=$gut$on"$ind$mark $base$REPLY$r${(l:w:: :)}${tstrip[$t]} "$z
+    REPLY=$gut$on"$ind$mark $base$hl$r$REPLY${(l:w:: :)}${tstrip[$t]} "$z
   else
-    REPLY="$gut$ind$mark $REPLY"
+    REPLY="$gut$ind$mark $hl${extra:+  $extra}"
   fi
 }
 
+__tt_pv_bg_title() {
+  local by=${bgby[$tpick]} ref=${bgfrom[$tpick]} url=${bgurl[$tpick]} mark="" sgr=""
+  local -i room=$1
+  [[ -n $ref && $url == http(s|)://* ]] && (( ${TTHEME_LINKS[(Ie)$TTHEME_ADAPTER]} )) && mark="⧉ "
+  REPLY=Background${by:+ · $by}${ref:+ · $mark$ref}$2
+  (( ${#REPLY} > room )) && REPLY=Background${by:+ · $by}
+  (( ${#REPLY} > room )) && REPLY=Background
+  [[ -n $mark && $REPLY == *"$mark$ref"* ]] || return 0
+  (( color )) && [[ -n ${TTHEME_SITE_ANSI[${ref%% *}]} ]] && sgr=$'\e[3'${TTHEME_SITE_ANSI[${ref%% *}]}m
+  REPLY=${REPLY/"$mark$ref"/$sgr⧉${sgr:+$'\e[39m'} $'\e]8;;'$url$'\e\\'$ref$'\e]8;;\e\\'}
+  return 0
+}
+
 __tt_pv_head() {
   local b=$'\e[1m' d=$'\e[2m' z=$'\e[0m' right=$6
   (( color )) || b= d= z=
@@ -939,17 +1664,21 @@ __tt_pv_foot() {
   if (( help )); then
     badge=KEYS right=$b"? esc"$z$d" close"$z
   elif [[ -n $pick ]]; then
-    local a=$plabel[1] c=$plabel[2]
-    if (( color )); then
-      if (( pk == 1 )); then a=$on$a$z c=$d$c$z; else a=$d$a$z c=$on$c$z; fi
-    else
-      if (( pk == 1 )); then a="[${${a# }% }]"; else c="[${${c# }% }]"; fi
-    fi
-    badge=APPLY lead="$pick → $a $c"
+    badge=APPLY lead="$pick →"
+    for (( i = 1; i <= ${#plabel}; i++ )); do
+      if (( i != pk )); then
+        lead+=" "$d${plabel[i]}$z
+      elif (( color )); then
+        lead+=" "$on${plabel[i]}$z
+      else
+        lead+=" [${${plabel[i]# }% }]"
+      fi
+    done
     if [[ $mode == pin ]]; then
-      __tt_tilde "$PWD"
+      badge=PIN
+      __tt_pin_base "${pkeys[pk]}"
+      __tt_dir_label "$REPLY"
       note=$REPLY
-      (( pk == 2 )) && note+="/**"
     elif (( pk == 1 )); then
       note="Until this tab closes"
     else
@@ -958,14 +1687,14 @@ __tt_pv_foot() {
     kk=(enter) kl=(confirm)
     right=$b"esc"$z$d" back"$z
   elif [[ -n $tune ]]; then
-    badge=TUNE kk=(↑↓ ←→) kl=(field step)
+    badge=TUNE kk=(↑↓ ←→ '=' +) kl=(field step reset "reset all")
     if (( tf == 2 )); then
       kl[2]=move kk+=(1-9) kl+=(place)
     else
       kk+=(⇧←→) kl+=(×10)
     fi
-    kk+=(space '=' enter)
-    if (( bgoff[$tune] )); then kl+=(show default keep); else kl+=(hide default keep); fi
+    kk+=(space enter)
+    if (( bgoff[$tpick] )); then kl+=(show keep); else kl+=(hide keep); fi
     __tt_pv_bg_images $tune
     (( REPLY > 1 )) && { kk+=(', .' D); kl+=("image ×$REPLY" remove) }
     __tt_pv_bg_findable $tune && { kk+=(f); kl+=(find) }
@@ -991,6 +1720,7 @@ __tt_pv_foot() {
       elif __tt_pv_bg_findable ${rval[cur]}; then
         kk+=(tab) kl+=("find bg")
       fi
+      (( split )) && { kk+=(⇧←→); kl+=(example) }
       [[ -n $flt ]] && { kk+=(bksp); kl+=(edit) }
     fi
     kk+=('?') kl+=(keys)
@@ -1050,15 +1780,17 @@ __tt_pv_foot() {
 __tt_pv_help() {
   local back="the tab" z=$'\e[0m' b=$'\e[1m' blank
   [[ -n ${TTHEME_PALETTE[$cn]} ]] && back=$cn
-  local -a hk=(Move Series Filter Apply) hv=(
+  local -a hk=(Move Series Filter "" Example Apply) hv=(
     "↑↓  home  end  pgup  pgdn"
     "←→  ·  enter or space on a series"
-    "a-z 0-9 -  ·  bksp  ·  ctrl-u clears"
+    "Any text  ·  bksp  ·  ctrl-u clears"
+    "Names and titles, in Japanese too"
+    "⇧←→  ${(Lj:, :)TTHEME_SCENES}"
     "enter  ·  esc restores $back"
   )
   if (( bgcw )); then
-    hk+=("Tune bg" "" "" "" "")
-    hv+=("tab  ·  finds one on the boorus, or takes your own, if none" "↑↓ field  ←→ step  ⇧←→ ×10  1-9 place" "space hides  ·  = default  ·  f adds one from the boorus or your own" "enter keeps  ·  esc undoes" ",  .  other saved images  ·  D removes this one")
+    hk+=("Tune bg" "" "" "" "" "")
+    hv+=("tab  ·  finds one on the boorus, or takes your own, if none" "↑↓ field  ←→ step  ⇧←→ ×10  1-9 place" "=  resets a field  ·  +  resets all" "space hides  ·  enter keeps  ·  esc undoes" ",  .  other pictures  ·  D removes one" "f  adds one from the boorus or your own")
   fi
   hk+=(Config "")
   hv+=("alt-c  ·  ↑↓ setting  ←→ value" "enter saves  ·  esc undoes")
@@ -1090,45 +1822,82 @@ __tt_pv_help() {
 }
 
 __tt_pv_specimen() {
-  local -a sp=(${=applied}) ln=() fg=()
+  local -a sp=(${=applied}) lines parts
   (( ${#sp} >= 20 )) || return 0
-  local z=$'\e[0m' d=$'\e[2m' sel cu cell line="" lo hi pr bd
-  local -i i r cw=4
+  local z=$'\e[0m' d=$'\e[2m' cell hex fore line text piece role tabs="" built="" key="$applied|$painted|$scene|$sw|$sc|$ph"
+  local -A rs=(p "" d $'\e[2m' b $'\e[1m')
+  local -i i r=6 cw=4 k n=${#TTHEME_SCENES} at
+  (( n )) || return 0
+  if [[ $key == "$pvscene" ]]; then
+    out+=$pvscenes
+    return 0
+  fi
+  at=$(( (scene % n + n) % n + 1 ))
   if [[ $applied == "$painted" ]]; then
-    fg=($'\e[31m' $'\e[32m' $'\e[33m' $'\e[34m' $'\e[35m') bd=$'\e[1;34m'
+    for (( i = 0; i < 16; i++ )); do
+      k=$(( i < 8 ? 30 + i : 82 + i ))
+      rs[$i]=$'\e['$k'm' rs[B$i]=$'\e[1;'$k'm' rs[K$i]=$'\e[30;'$(( k + 10 ))'m'
+    done
   else
-    for i in 6 7 8 9 10 17; do
-      lo=${sp[i]#\#}
-      printf -v cell '\e[38;2;%d;%d;%dm' $((16#${lo:0:2})) $((16#${lo:2:2})) $((16#${lo:4:2}))
-      fg+=($cell)
+    fore=${sp[5]#\#}
+    for (( i = 0; i < 16; i++ )); do
+      hex=${sp[i+5]#\#}
+      printf -v cell '\e[38;2;%d;%d;%dm' $((16#${hex:0:2})) $((16#${hex:2:2})) $((16#${hex:4:2}))
+      rs[$i]=$cell
+      printf -v cell '\e[38;2;%d;%d;%d;48;2;%d;%d;%dm' $((16#${fore:0:2})) $((16#${fore:2:2})) $((16#${fore:4:2})) \
+        $((16#${hex:0:2})) $((16#${hex:2:2})) $((16#${hex:4:2}))
+      rs[K$i]=$cell
+      hex=${sp[(i < 8 ? i + 13 : i + 5)]#\#}
+      printf -v cell '\e[1;38;2;%d;%d;%dm' $((16#${hex:0:2})) $((16#${hex:2:2})) $((16#${hex:4:2}))
+      rs[B$i]=$cell
+    done
+  fi
+  printf -v cell '\e[48;2;%d;%d;%dm' $((16#${sp[4]:1:2})) $((16#${sp[4]:3:2})) $((16#${sp[4]:5:2}))
+  rs[s]=$cell
+  printf -v cell '\e[48;2;%d;%d;%dm' $((16#${sp[3]:1:2})) $((16#${sp[3]:3:2})) $((16#${sp[3]:5:2}))
+  rs[c]=$cell
+  if (( ${#${(j:  :)TTHEME_SCENES}} <= sw )); then
+    for (( k = 1; k <= n; k++ )); do
+      (( k > 1 )) && tabs+="  "
+      if (( k == at )); then
+        tabs+=$'\e[1m'$ac$TTHEME_SCENES[k]$z
+      else
+        tabs+=$d$TTHEME_SCENES[k]$z
+      fi
     done
-    bd=$'\e[1m'$fg[6]
+  else
+    tabs=$'\e[1m'$ac$TTHEME_SCENES[at]$z"  "$d"$at/$n"$z
   fi
-  pr=$fg[2]'❯'$z' '
+  built+=$'\e[2;'$sc'H'$tabs
   (( sw < 44 )) && cw=3
   (( sw >= 56 )) && cw=$(( (sw + 1) / 8 - 1 ))
   (( cw > 7 )) && cw=7
-  printf -v sel '\e[48;2;%d;%d;%dm' $((16#${sp[4]:1:2})) $((16#${sp[4]:3:2})) $((16#${sp[4]:5:2}))
-  printf -v cu '\e[48;2;%d;%d;%dm' $((16#${sp[3]:1:2})) $((16#${sp[3]:3:2})) $((16#${sp[3]:5:2}))
+  line=""
   for (( i = 0; i < 8; i++ )); do
-    lo=${sp[i+5]#\#} hi=${sp[i+13]#\#}
+    fore=${sp[i+5]#\#} hex=${sp[i+13]#\#}
     printf -v cell '\e[38;2;%d;%d;%d;48;2;%d;%d;%dm%s\e[0m ' \
-      $((16#${lo:0:2})) $((16#${lo:2:2})) $((16#${lo:4:2})) \
-      $((16#${hi:0:2})) $((16#${hi:2:2})) $((16#${hi:4:2})) "${(l:cw::▀:)}"
+      $((16#${fore:0:2})) $((16#${fore:2:2})) $((16#${fore:4:2})) \
+      $((16#${hex:0:2})) $((16#${hex:2:2})) $((16#${hex:4:2})) "${(l:cw::▀:)}"
     line+=$cell
   done
-  out+=$'\e[4;'$sc'H'$line
-  ln=($bd'~/code/demo'$z$d' on '$z$fg[5]'main'$fg[2]' +2'$fg[3]' ~1'$z "${pr}git status -sb")
-  (( sw >= 44 )) && ln+=('## '$fg[2]'main'$z'...'$fg[1]'origin/main'$fg[3]' [ahead 1]'$z)
-  ln+=($fg[1]' M'$z' src/main.rs' $fg[1]'??'$z' notes.md' "")
-  (( sw >= 44 )) && ln+=("${pr}ls" $bd'docs'$z'  '$bd'src'$z'  '$bd'tests'$z'  Cargo.toml  README.md' "")
-  ln+=("${pr}cargo test" $fg[2]' ✓'$z' parses config' $fg[1]' ✗'$z' renders frame')
-  (( sw >= 44 )) && ln[-1]+=$d'  expected '$z$fg[2]'3'$z$d', received '$z$fg[1]'2'$z
-  ln+=("" "${pr}echo ${sel}selected text${z} ${cu} ${z}")
-  for (( r = 1; r <= ${#ln}; r++ )); do
-    (( r + 5 < ph )) || break
-    out+=$'\e['$(( r + 5 ))';'$sc'H'${ln[r]}
+  built+=$'\e[4;'$sc'H'$line
+  lines=("${(@P)${:-TTHEME_SCENE_$at}}")
+  for line in "${lines[@]}"; do
+    [[ $line == «w»* ]] && (( sw < 44 )) && continue
+    [[ $line == «n»* ]] && (( sw >= 44 )) && continue
+    (( r < ph )) || break
+    parts=("${(@s:«:)line}")
+    text=$parts[1]
+    for piece in "${(@)parts[2,-1]}"; do
+      role=${piece%%»*}
+      [[ $role == [wn] ]] && role=p
+      text+=$z${rs[${role:-p}]}${piece#*»}
+    done
+    built+=$'\e['$r';'$sc'H'$text$z
+    (( ++r ))
   done
+  pvscene=$key pvscenes=$built
+  out+=$built
 }
 
 __tt_pv_tune() {
@@ -1137,8 +1906,8 @@ __tt_pv_tune() {
   local name
   case $key in
     $'\x03') return 1 ;;
-    up) (( tf > 1 )) && tf=$(( tf - 1 )) ;;
-    down) (( tf < 3 )) && tf=$(( tf + 1 )) ;;
+    up) tf=$(( tf > 1 ? tf - 1 : 3 )) ;;
+    down) tf=$(( tf < 3 ? tf + 1 : 1 )) ;;
     left|right|sleft|sright)
       [[ $key == *left ]] && n=-1
       [[ $key == s* ]] && (( tf != 2 )) && n=$(( n * 10 ))
@@ -1149,32 +1918,54 @@ __tt_pv_tune() {
       __tt_pv_bg_adjust at $key
       ;;
     ' ') __tt_pv_bg_adjust on ;;
-    '=') __tt_pv_bg_adjust def ;;
-    ',') __tt_pv_bg_image prev ;;
-    '.') __tt_pv_bg_image next ;;
-    D) __tt_pv_bg_image drop ;;
+    '=') __tt_pv_bg_adjust def $tf ;;
+    '+') __tt_pv_bg_adjust def ;;
+    ',') __tt_pv_bg_pick -1 ;;
+    '.') __tt_pv_bg_pick 1 ;;
+    D) __tt_pv_bg_drop ;;
     f)
       __tt_pv_bg_findable $tune || return 0
       name=$tune
       __tt_pv_untune
       __tt_pv_bg_find $name
-      tune=$name tf=1 tsnap="${bgsize[$name]} ${bgpos[$name]} ${bgop[$name]} ${bgoff[$name]}"
-      ;;
-    $'\r'|$'\n')
-      if [[ "${bgsize[$tune]} ${bgpos[$tune]} ${bgop[$tune]} ${bgoff[$tune]}" != "$tsnap" ]]; then
-        bgedit[$tune]=1 msg="Kept · saved when preview closes" msgt=200
-      fi
-      tune=""
+      __tt_pv_tune_open $name
       ;;
+    $'\r'|$'\n') __tt_pv_tune_keep ;;
     esc) __tt_pv_untune ;;
     '?') help=1 ;;
   esac
   return 0
 }
 
+__tt_pv_tune_keep() {
+  local img was=${bgview[$tune]:-$tune}
+  local -i changed=0
+  for img in ${(k)tsnaps}; do
+    [[ "${bgsize[$img]} ${bgpos[$img]} ${bgop[$img]} ${bgoff[$img]}" == "${tsnaps[$img]}" ]] && continue
+    bgedit[$img]=1 changed=1
+  done
+  if [[ $tpick != "$was" ]]; then
+    changed=1
+    if [[ $tpick == "$tune" ]]; then
+      unset "bgview[$tune]" "bgswap[$tune]"
+    else
+      bgview[$tune]=$tpick bgswap[$tune]=${tpick##*:}
+    fi
+  fi
+  (( changed )) && msg="Kept · saved when preview closes" msgt=200
+  __tt_pv_bg_strip_off
+  tune="" tpick="" tsnaps=() bgname=""
+}
+
 __tt_pv_untune() {
-  local -a s=(${=tsnap})
-  bgsize[$tune]=$s[1] bgpos[$tune]=$s[2] bgop[$tune]=$s[3] bgoff[$tune]=$s[4] bgname="" tune=""
+  local img
+  local -a s
+  for img in ${(k)tsnaps}; do
+    s=(${=tsnaps[$img]})
+    bgsize[$img]=$s[1] bgpos[$img]=$s[2] bgop[$img]=$s[3] bgoff[$img]=$s[4]
+  done
+  __tt_pv_bg_strip_off
+  tune="" tpick="" tsnaps=() bgname=""
 }
 
 __tt_pv_regroup() {
@@ -1190,8 +1981,8 @@ __tt_pv_regroup() {
 __tt_pv_conf() {
   case $key in
     $'\x03') return 1 ;;
-    up) (( cf > 1 )) && cf=$(( cf - 1 )) ;;
-    down) (( cf < ${#cvars} )) && cf=$(( cf + 1 )) ;;
+    up) cf=$(( cf > 1 ? cf - 1 : ${#cvars} )) ;;
+    down) cf=$(( cf < ${#cvars} ? cf + 1 : 1 )) ;;
     left|sleft) __tt_pv_conf_step -1 ;;
     right|sright) __tt_pv_conf_step 1 ;;
     $'\r'|$'\n') __tt_pv_conf_save ;;
@@ -1318,24 +2109,89 @@ __tt_pv_conf_panel() {
 }
 
 __tt_pv_flush() {
+  local REPLY
   print -rn -- "$out"
   if (( wiped )); then
     local bn=$bgname
-    [[ ${rtype[cur]} == thm ]] && bn=${rval[cur]}
+    if [[ ${rtype[cur]} == thm ]]; then
+      __tt_pv_shows ${rval[cur]}
+      bn=$REPLY
+    fi
     [[ -n $bn ]] && __tt_pv_bg_show "$bn" 1
   fi
-  printf '\e[?2026l'
+  if [[ -n $bgstrip ]]; then
+    __tt_pv_bg_strip ${=bgstrip}
+  elif (( ${#bgthumb} )); then
+    __tt_pv_bg_strip_off
+  fi
+  printf '\e[1;%dH\e[?2026l' $(( 4 + ${(m)#flt} ))
+}
+
+__tt_pv_reach() {
+  local key=${pkeys[pk]} base top k home=${HOME:a} here=${PWD:a} htip="" d=$'\e[2m' z=$'\e[0m' REPLY
+  local -A own=() below=() parent=() mark=() tstrip=()
+  local -a roots=() lp=() lpw=() ll=() lat=() lpal=() lnote=() lflag=() reply was=()
+  local -A TTHEME_PINS=("${(@kv)TTHEME_PINS}")
+  local -i room=$2
+  (( color )) || d= z=
+  (( room < 2 )) && room=2
+  __tt_pin_base "$key"
+  base=$REPLY
+  for k in ${(k)TTHEME_PINS}; do
+    [[ $k == /* ]] || continue
+    __tt_pin_base "$k"
+    [[ $REPLY == "$base" ]] || continue
+    if [[ $k != "$key" || $TTHEME_PINS[$k] != "$pick" ]]; then
+      __tt_pin_scope "$k"
+      was+=("${TTHEME_PINS[$k]} · $REPLY")
+    fi
+    unset "TTHEME_PINS[$k]"
+  done
+  TTHEME_PINS[$key]=$pick
+  top=$base
+  [[ $base != / ]] && __tt_pin_cover "${base:h}" && __tt_pin_base "$REPLY" && top=$REPLY
+  mark[$base]=new
+  __tt_map_build "$top"
+  __tt_map_fit $1
+  (( ${#reply} > room )) && reply=("${(@)reply[1,room-1]}" "   …")
+  reach=("${reply[@]}" "")
+  __tt_dir_label "$base"
+  base=$REPLY
+  for k in $was; do
+    __tt_clip "${d}Replaces ${k% · *} on $base · ${k##* · }$z" $1
+    reach+=("$REPLY")
+  done
+  __tt_pin_scope "$key"
+  __tt_clip "→ $base · $REPLY" $(( $1 - ${(m)#pick} - 2 ))
+  rsub=$REPLY
+  __tt_here_fit "Then here" $1
+  reach+=("${reply[@]}")
 }
 
 __tt_pv_draw() {
-  local out line cnt ex ag="" acat="" ac="" sb="" dd="" zz="" state=on src="" REPLY
+  local out line cnt ex ag="" acat="" ac="" sb="" dd="" zz="" state=on src="" nflt="" rsub="" REPLY
   local -i lw sw split sc se=$(( pw - 2 )) h k i N=${#rval} mt=${#TTHEME_ORDER} wiped=0
+  local -a held
+  bgstrip=""
+  if [[ -n $flt ]]; then
+    __tt_pv_norm "$flt"
+    nflt=$REPLY
+  fi
   __tt_pv_lw
   lw=$reply[1] sw=$reply[2]
   split=$(( sw > 0 )) sc=$(( pw - 1 - sw ))
   h=$(( ph - 5 ))
   [[ -n $tune ]] && (( ! split )) && h=$(( ph - 14 ))
   (( conf && ! split )) && h=$(( ph - 12 ))
+  reach=()
+  if [[ -n $pick && $mode == pin ]]; then
+    if (( split )); then
+      __tt_pv_reach $sw $(( ph - 6 ))
+    else
+      __tt_pv_reach $se $(( ph - 13 ))
+      h=$(( ph - 6 - ${#reach} ))
+    fi
+  fi
   (( h < 1 )) && h=1
   (( cur < top )) && top=$cur
   (( cur >= top + h )) && top=$(( cur - h + 1 ))
@@ -1407,7 +2263,7 @@ __tt_pv_draw() {
   [[ -n $flt ]] && tail=$'\e['$(( lw - ${#cnt} ))'G'$cnt
   if [[ $1 == hint ]] && (( ! wiped )); then
     print -rn -- $'\e[H\e[0m\e['$lw'X'$line$tail
-    printf '\e[?2026l'
+    printf '\e[1;%dH\e[?2026l' $(( 4 + ${(m)#flt} ))
     return 0
   fi
   out+=$line$'\e[K'$tail$'\n\e[K\n'
@@ -1433,13 +2289,16 @@ __tt_pv_draw() {
     if (( help && sw >= 48 )); then
       __tt_pv_head 1 $sc $se Keys
       __tt_pv_help
+    elif (( ${#reach} )); then
+      __tt_pv_head 1 $sc $se "$pick" "$rsub"
+      for (( k = 1; k <= ${#reach} && k + 2 < ph; k++ )); do
+        out+=$'\e['$(( k + 2 ))';'$sc'H'${reach[k]}
+      done
     elif [[ -n $tune ]]; then
-      (( bgoff[$tune] )) && state=off
-      src=Background
-      [[ -n ${bgfrom[$tune]} ]] && src+=" · ${bgfrom[$tune]}"
-      (( ${#tune} + ${#src} + 6 > sw )) && src=Background
-      __tt_pv_head 1 $sc $se $tune "$src" $state
-      __tt_pv_bg_panel $tune 4 $sc $se
+      (( bgoff[$tpick] )) && state=off
+      __tt_pv_bg_title $(( sw - ${#tune} - 6 ))
+      __tt_pv_head 1 $sc $se $tune "$REPLY" $state
+      __tt_pv_bg_panel $tpick 4 $sc $se
     elif (( conf )); then
       __tt_tilde "$TTHEME_CONFIG"
       src=$REPLY
@@ -1454,13 +2313,23 @@ __tt_pv_draw() {
     fi
     (( help && sw < 48 )) && __tt_pv_help
   else
-    if [[ -n $tune ]]; then
-      (( bgoff[$tune] )) && state=off
-      src=Background
-      [[ -n ${bgfrom[$tune]} ]] && src+=" · ${bgfrom[$tune]}"
-      (( ${#tune} + ${#src} + 6 > lw )) && src=Background
-      __tt_pv_head $(( ph - 9 )) 1 $lw $tune "$src" $state
-      __tt_pv_bg_panel $tune $(( ph - 8 )) 1 $lw
+    if (( ${#reach} )); then
+      __tt_pv_head $(( ph - 1 - ${#reach} )) 1 $se "$pick" "$rsub"
+      for (( k = 1; k <= ${#reach}; k++ )); do
+        out+=$'\e['$(( ph - 1 - ${#reach} + k ))';1H'${reach[k]}
+      done
+    elif [[ -n $tune ]]; then
+      (( bgoff[$tpick] )) && state=off
+      held=(${=bgpics[$tune]})
+      src=""
+      if (( ${#held} > 1 )); then
+        k=${held[(Ie)${${tpick#$tune}#:}]}
+        (( k )) || k=${held[(Ie)${bgact[$tune]}]}
+        src=" · $k/${#held}"
+      fi
+      __tt_pv_bg_title $(( lw - ${#tune} - 6 )) "$src"
+      __tt_pv_head $(( ph - 9 )) 1 $lw $tune "$REPLY" $state
+      __tt_pv_bg_panel $tpick $(( ph - 8 )) 1 $lw
     elif (( conf )); then
       __tt_pv_head $(( ph - 7 )) 1 $lw Config
       __tt_pv_conf_panel $(( ph - 6 )) 1 $lw
@@ -1594,6 +2463,7 @@ __tt_pv_read() {
     "6~") key=pgdn ;;
     "1;2C") key=sright ;;
     "1;2D") key=sleft ;;
+    Z) key=stab ;;
     *) key=nop ;;
   esac
 }
@@ -1602,7 +2472,8 @@ __tt_pv_pick() {
   case $key in
     $'\x03') return 1 ;;
     esc) pick="" ;;
-    left|right|$'\t') pk=$(( 3 - pk )) ;;
+    left|stab) pk=$(( (pk + ${#plabel} - 2) % ${#plabel} + 1 )) ;;
+    right|$'\t') pk=$(( pk % ${#plabel} + 1 )) ;;
     $'\r'|$'\n')
       sel=$pick picked=$pk
       return 1
@@ -1662,29 +2533,50 @@ __tt_pv_handle() {
         __tt_pv_toggle
       fi
       ;;
-    up) (( cur > 1 )) && cur=$(( cur - 1 )); [[ ${rtype[cur]} == rule ]] && cur=$(( cur - 1 )) ;;
-    down) (( cur < ${#rval} )) && cur=$(( cur + 1 )); [[ ${rtype[cur]} == rule ]] && cur=$(( cur + 1 )) ;;
+    up)
+      if (( cur > 1 )); then
+        cur=$(( cur - 1 ))
+        [[ ${rtype[cur]} == rule ]] && cur=$(( cur - 1 ))
+      elif (( ${#rval} )); then
+        cur=${#rval}
+      fi
+      ;;
+    down)
+      if (( cur < ${#rval} )); then
+        cur=$(( cur + 1 ))
+        [[ ${rtype[cur]} == rule ]] && cur=$(( cur + 1 ))
+      elif (( ${#rval} )); then
+        cur=1
+      fi
+      ;;
     right) [[ ${rtype[cur]} == (hdr|cat) && -z ${exp[${rval[cur]}]} ]] && __tt_pv_toggle ;;
     left) __tt_pv_left ;;
     home) cur=1 ;;
     end) (( ${#rval} )) && cur=${#rval} ;;
     pgup)
-      cur=$(( cur - ph + 5 ))
-      (( cur < 1 )) && cur=1
-      [[ ${rtype[cur]} == rule ]] && cur=$(( cur - 1 ))
+      if (( cur <= 1 )); then
+        (( ${#rval} )) && cur=${#rval}
+      else
+        cur=$(( cur - ph + 5 ))
+        (( cur < 1 )) && cur=1
+        [[ ${rtype[cur]} == rule ]] && cur=$(( cur - 1 ))
+      fi
       ;;
     pgdn)
-      cur=$(( cur + ph - 5 ))
-      (( cur > ${#rval} )) && cur=${#rval}
-      (( cur < 1 )) && cur=1
-      [[ ${rtype[cur]} == rule ]] && cur=$(( cur + 1 ))
+      if (( cur >= ${#rval} )); then
+        cur=1
+      else
+        cur=$(( cur + ph - 5 ))
+        (( cur > ${#rval} )) && cur=${#rval}
+        [[ ${rtype[cur]} == rule ]] && cur=$(( cur + 1 ))
+      fi
       ;;
     ' ') [[ ${rtype[cur]} == (hdr|cat) ]] && __tt_pv_toggle ;;
     $'\t')
       [[ ${rtype[cur]} == thm ]] || return 0
       name=${rval[cur]}
       if __tt_pv_bg_state $name || { __tt_pv_bg_findable $name && __tt_pv_bg_find $name }; then
-        tune=$name tf=1 tsnap="${bgsize[$name]} ${bgpos[$name]} ${bgop[$name]} ${bgoff[$name]}"
+        __tt_pv_tune_open $name
       elif __tt_pv_bg_findable $name; then
         :
       elif (( bgcw )); then
@@ -1698,6 +2590,8 @@ __tt_pv_handle() {
       done
       ;;
     '?') help=1 ;;
+    sleft) (( --scene )) ;;
+    sright) (( ++scene )) ;;
     $'\x7f'|$'\x08')
       if [[ -n $flt ]]; then
         name=""
@@ -1707,9 +2601,9 @@ __tt_pv_handle() {
         __tt_pv_first "$name"
       fi
       ;;
-    [a-zA-Z0-9-])
+    [[:print:]])
       __tt_pv_lw
-      (( ${#flt} >= reply[1] - 12 )) && return 0
+      (( ${(m)#flt} + ${(m)#key} > reply[1] - 12 )) && return 0
       name=""
       [[ ${rtype[cur]} == thm ]] && name=${rval[cur]}
       flt+=${(L)key}
@@ -1721,19 +2615,21 @@ __tt_pv_handle() {
 }
 
 __tt_preview() {
-  emulate -L zsh
-  local mode=$1
+  emulate -L zsh ${=${options[xtrace]:#off}:+-o xtrace}
+  local mode=$1 pdir=${2:-$PWD}
   if [[ ! -t 0 || ! -t 1 ]]; then
     print -u2 "ttheme ${mode:-preview}: needs a terminal"
     return 1
   fi
   local orig=$TTHEME_SPEC applied=$TTHEME_SPEC painted=$TTHEME_SPEC flt="" sel="" cn="" cdot="" key="" REPLY="" cur=1 top=1 color=0 pw=80 ph=24 resized=1 expal="" exgrp="" exnext=0 gstep=0 gseed=0 tick=0
   local pick="" pk=1 pkdef=1 picked=0 canpick=0 bgcw=0 bgch=0 bgname="" bgshown="" bginc="" osd="" osdt=0
-  local tune="" tsnap="" tf=1 help=0 msg="" msgt=0 an="" bgrel=0 bgmx=0 bgmy=0 bganchor=0 bgcut="" bgnext=0 bgbytes=0
+  local tune="" tpick="" tf=1 help=0 msg="" msgt=0 an="" bgrel=0 bgmx=0 bgmy=0 bganchor=0 bgcut="" bgnext=0 bgbytes=0 bgstrip="" pvscene="" pvscenes=""
+  local -i scene=0
   local -a bgorder=()
-  local -A bgfrom=() bgsent=() bgcost=() bgdim=() bgsrc=() bgfill=() bgfocus=() bgsize=() bgpos=() bgop=() bgdef=() bgoff=() bgbase=() bgload=() bgshot=() bgshotkey=() bgedit=() bgtunef=() bgofff=() bgimages=()
+  local -A bgfrom=() bgurl=() bgby=() bgsent=() bgcost=() bgdim=() bgsrc=() bgfill=() bgfocus=() bgsize=() bgpos=() bgop=() bgdef=() bgoff=() bgbase=() bgload=() bgshot=() bgshotkey=() bgedit=() bgtunef=() bgofff=() bgimages=()
+  local -A bgpic=() bgpics=() bgact=() bgview=() bgswap=() bgthumb=() tsnaps=() pvseek=()
   local conf=0 cf=1
-  local -a plabel=(" This tab " " Default ") csnap=()
+  local -a plabel=(" This tab " " Default ") pkeys=() reach=() csnap=()
   local -a cvars=(TTHEME_TAB_PALETTE TTHEME_ANNOUNCE TTHEME_FX TTHEME_SORT TTHEME_BG_BLUR) clabel=("New tabs" Announce "Search fx" Sort Blur)
   local -a cchoice=("off seq" "1 0" "typewriter decode glitch" "abc series" "0 1 2 3 4") cshow=("off seq" "on off" "typewriter decode glitch" "abc series" "off 1px 2px 3px 4px")
   local -A cnote=(
@@ -1745,7 +2641,7 @@ __tt_preview() {
     TTHEME_BG_BLUR:2 "Pictures soften behind the text" TTHEME_BG_BLUR:3 "Pictures blur behind the text"
     TTHEME_BG_BLUR:4 "Pictures blur well behind the text"
   )
-  [[ $mode == pin ]] && pkdef=2 plabel=(" This directory " " And below ")
+  [[ $mode == pin ]] && __tt_pin_scopes "$pdir"
   [[ $mode == init ]] && pkdef=2
   __tt_pv_canpick
   __tt_pv_size
@@ -1761,8 +2657,8 @@ __tt_preview() {
   {
     tty=$(stty -g 2>/dev/null && stty -echo -icanon min 1 time 0 2>/dev/null)
     TTHEME_RAW=$(( ${#tty} > 0 ))
-    printf '\e[?2026h\e[?1049h\e[?7l\e[?25l'
     __tt_pv_bg_open
+    printf '\e[?2026h\e[?1049h\e[?7l\e[?25l'
     while :; do
       printf '\e[?2026h'
       if (( tick )); then
@@ -1805,23 +2701,26 @@ __tt_preview() {
     __tt_pv_bg_save
     if [[ -n $spec ]]; then
       TTHEME_SPEC=$spec
-      __tt_announce
       if [[ $mode == pin ]]; then
-        __tt_pin_save "$sel" $picked "$orig"
-        __tt_shown "$sel" && __tt_reload
+        __tt_pin_save "$sel" "${pkeys[picked]}" "$orig"
+        [[ $TTHEME_SPEC == "$orig" ]] || __tt_announce
+        __tt_sync
       elif (( picked == 2 )); then
+        __tt_announce
         __tt_keep "$sel"
       else
+        __tt_announce
         __tt_shown "$sel" force && __tt_reload
       fi
     else
-      (( ${#bgedit} )) && [[ -n ${TTHEME_PALETTE[$cn]} ]] && { __tt_shown "$cn" && __tt_reload }
+      (( ${#bgedit} + ${#bgswap} )) && [[ -n ${TTHEME_PALETTE[$cn]} ]] && { __tt_shown "$cn" && __tt_reload }
     fi
   }
   return 0
 }
 
 ttheme() {
+  emulate -L zsh ${=${options[xtrace]:#off}:+-o xtrace}
   if (( $# > 1 && ${${argv[2,-1]}[(I)(-h|--help)]} )); then
     __tt_verb_help $1
     return
@@ -1868,17 +2767,25 @@ ttheme() {
       __tt_resolve "$2" || return 1
       __tt_keep "$REPLY" ;;
     preview) __tt_preview ;;
-    pin) __tt_preview pin ;;
-    unpin) __tt_unpin ;;
+    pin)
+      if [[ -n $2 ]]; then
+        REPLY=$2
+        [[ $REPLY == \~ || $REPLY == \~/* ]] && REPLY=$HOME${REPLY#\~}
+        [[ -d $REPLY ]] || { print -u2 -r -- "ttheme pin: no such directory: $2"; return 1 }
+      fi
+      __tt_preview pin ${REPLY:+${REPLY:a}} ;;
+    unpin) __tt_unpin "${@:2}" ;;
+    pins) __tt_pins_map ;;
   esac
 }
 
-if (( $+functions[compdef] )); then
+if (( ${+functions[compdef]} )); then
   __tt_complete() {
+    emulate -L zsh ${=${options[xtrace]:#off}:+-o xtrace}
     local -a reply
     if (( CURRENT == 2 )); then
       compadd -- $TTHEME_VERBS help
-    elif [[ $words[2] == remove || ( $words[2] == (use|default|edit|check|share) && CURRENT == 3 ) ]]; then
+    elif [[ $words[2] == remove || ( $words[2] == (use|default|edit|check|share) && $CURRENT == 3 ) ]]; then
       compadd -- $TTHEME_ORDER
     elif [[ $words[2] == new && $words[CURRENT-1] == --from ]]; then
       compadd -- $TTHEME_ORDER
@@ -1886,9 +2793,11 @@ if (( $+functions[compdef] )); then
       _files -/
     elif [[ $words[2] == new ]]; then
       compadd -- --from --in
-    elif [[ $words[2] == market && CURRENT == 3 ]]; then
+    elif [[ $words[2] == market && $CURRENT == 3 ]]; then
       compadd -- add remove search init
-    elif [[ $words[2] == market && $words[3] == (add|init) && CURRENT == 4 ]]; then
+    elif [[ $words[2] == market && $words[3] == (add|init) && $CURRENT == 4 ]]; then
+      _files -/
+    elif [[ $words[2] == (pin|unpin) && $CURRENT == 3 ]]; then
       _files -/
     elif [[ $words[2] == add && $words[CURRENT-1] == --market ]]; then
       _files -/
@@ -1900,7 +2809,9 @@ if (( $+functions[compdef] )); then
   compdef __tt_complete ttheme
 fi
 
-if __tt_active; then
+() {
+  emulate -L zsh ${=${options[xtrace]:#off}:+-o xtrace}
+  __tt_active || return 0
   [[ -n $TMUX ]] && __tt_tmux
   () {
     local REPLY
@@ -1933,9 +2844,10 @@ if __tt_active; then
     __tt_sync
   fi
   __tt_announce
-fi
+}
 
 () {
+  emulate -L zsh ${=${options[xtrace]:#off}:+-o xtrace}
   local f
   for f in $TTHEME_HOME/ttheme.zsh $TTHEME_HOME/palettes.zsh $TTHEME_HOME/adapters/_osc.zsh $TTHEME_HOME/adapters/_bg.zsh $TTHEME_HOME/adapters/$TTHEME_ADAPTER.zsh; do
     [[ -r $f && ! $f.zwc -nt $f ]] || continue