@kecan0406/ttheme 0.1.0

package/ghostty/shaders/cursor_tail.glsl

@@ -0,0 +1,243 @@
+// cursor_tail.glsl — from sahaj-b/ghostty-cursor-shaders (MIT).
+// https://github.com/sahaj-b/ghostty-cursor-shaders
+// See LICENSE in this directory. Local change: DURATION tuned.
+
+// sRGB -> Linear conversion (needed because Ghostty passes sRGB values but the shader pipeline operates in linear color space)
+vec3 sRGBToLinear(vec3 c) {
+    return mix(c / 12.92, pow((c + 0.055) / 1.055, vec3(2.4)), step(vec3(0.04045), c));
+}
+
+// --- CONFIGURATION ---
+vec4 TRAIL_COLOR = vec4(sRGBToLinear(iCurrentCursorColor.rgb), iCurrentCursorColor.a); // for custom color: vec4(0.2, 0.6, 1.0, 0.5); (wrap in sRGBToLinear for correct brightness)
+const float DURATION = 0.05; // in seconds
+const float MAX_TRAIL_LENGTH = 0.2;
+const float THRESHOLD_MIN_DISTANCE = 1.5; // min distance to show trail (units of cursor width)
+const float BLUR = 2.0; // blur size in pixels (for antialiasing)
+
+// --- CONSTANTS for easing functions ---
+const float PI = 3.14159265359;
+const float C1_BACK = 1.70158;
+const float C2_BACK = C1_BACK * 1.525;
+const float C3_BACK = C1_BACK + 1.0;
+const float C4_ELASTIC = (2.0 * PI) / 3.0;
+const float C5_ELASTIC = (2.0 * PI) / 4.5;
+const float SPRING_STIFFNESS = 9.0;
+const float SPRING_DAMPING = 0.9;
+
+// --- EASING FUNCTIONS ---
+
+// // Linear
+// float ease(float x) {
+//     return x;
+// }
+
+// // EaseOutQuad
+// float ease(float x) {
+//     return 1.0 - (1.0 - x) * (1.0 - x);
+// }
+
+// // EaseOutCubic
+// float ease(float x) {
+//     return 1.0 - pow(1.0 - x, 3.0);
+// }
+
+
+// // EaseOutQuart
+// float ease(float x) {
+//     return 1.0 - pow(1.0 - x, 4.0);
+// }
+
+// // EaseOutQuint
+// float ease(float x) {
+//     return 1.0 - pow(1.0 - x, 5.0);
+// }
+
+// // EaseOutSine
+// float ease(float x) {
+//     return sin((x * PI) / 2.0);
+// }
+
+// // EaseOutExpo
+// float ease(float x) {
+//     return x == 1.0 ? 1.0 : 1.0 - pow(2.0, -10.0 * x);
+// }
+
+// EaseOutCirc
+float ease(float x) {
+    return sqrt(1.0 - pow(x - 1.0, 2.0));
+}
+
+// // EaseOutBack
+// float ease(float x) {
+//     return 1.0 + C3_BACK * pow(x - 1.0, 3.0) + C1_BACK * pow(x - 1.0, 2.0);
+// }
+
+// // EaseOutElastic
+// float ease(float x) {
+//     return x == 0.0 ? 0.0
+//          : x == 1.0 ? 1.0
+//                     : pow(2.0, -10.0 * x) * sin((x * 10.0 - 0.75) * C4_ELASTIC) + 1.0;
+// }
+
+// Parametric Spring
+// float ease(float x) {
+//     x = clamp(x, 0.0, 1.0);
+//     float decay = exp(-SPRING_DAMPING * SPRING_STIFFNESS * x);
+//     float freq = sqrt(SPRING_STIFFNESS * (1.0 - SPRING_DAMPING * SPRING_DAMPING));
+//     float osc = cos(freq * 6.283185 * x) + (SPRING_DAMPING * sqrt(SPRING_STIFFNESS) / freq) * sin(freq * 6.283185 * x);
+//     return 1.0 - decay * osc;
+// }
+
+float getSdfRectangle(in vec2 p, in vec2 xy, in vec2 b)
+{
+    vec2 d = abs(p - xy) - b;
+    return length(max(d, 0.0)) + min(max(d.x, d.y), 0.0);
+}
+
+// Based on Inigo Quilez's 2D distance functions article: https://iquilezles.org/articles/distfunctions2d/
+// Potencially optimized by eliminating conditionals and loops to enhance performance and reduce branching
+
+float seg(in vec2 p, in vec2 a, in vec2 b, inout float s, float d) {
+    vec2 e = b - a;
+    vec2 w = p - a;
+    vec2 proj = a + e * clamp(dot(w, e) / dot(e, e), 0.0, 1.0);
+    float segd = dot(p - proj, p - proj);
+    d = min(d, segd);
+
+    float c0 = step(0.0, p.y - a.y);
+    float c1 = 1.0 - step(0.0, p.y - b.y);
+    float c2 = 1.0 - step(0.0, e.x * w.y - e.y * w.x);
+    float allCond = c0 * c1 * c2;
+    float noneCond = (1.0 - c0) * (1.0 - c1) * (1.0 - c2);
+    float flip = mix(1.0, -1.0, step(0.5, allCond + noneCond));
+    s *= flip;
+    return d;
+}
+
+float getSdfParallelogram(in vec2 p, in vec2 v0, in vec2 v1, in vec2 v2, in vec2 v3) {
+    float s = 1.0;
+    float d = dot(p - v0, p - v0);
+
+    d = seg(p, v0, v3, s, d);
+    d = seg(p, v1, v0, s, d);
+    d = seg(p, v2, v1, s, d);
+    d = seg(p, v3, v2, s, d);
+
+    return s * sqrt(d);
+}
+
+vec2 normalize(vec2 value, float isPosition) {
+    return (value * 2.0 - (iResolution.xy * isPosition)) / iResolution.y;
+}
+
+float antialising(float distance) {
+	return 1. - smoothstep(0., normalize(vec2(BLUR, BLUR), 0.).x, distance);
+}
+
+float determineIfTopRightIsLeading(vec2 a, vec2 b) {
+    float condition1 = step(b.x, a.x) * step(a.y, b.y); // a.x < b.x && a.y > b.y
+    float condition2 = step(a.x, b.x) * step(b.y, a.y); // a.x > b.x && a.y < b.y
+
+    // if neither condition is met, return 1 (else case)
+    return 1.0 - max(condition1, condition2);
+}
+
+vec2 getRectangleCenter(vec4 rectangle) {
+    return vec2(rectangle.x + (rectangle.z / 2.), rectangle.y - (rectangle.w / 2.));
+}
+
+
+void mainImage(out vec4 fragColor, in vec2 fragCoord){
+    #if !defined(WEB)
+    fragColor = texture(iChannel0, fragCoord.xy / iResolution.xy);
+    #endif
+
+    // normalization & setup(-1, 1 coords)
+    vec2 vu = normalize(fragCoord, 1.);
+    vec2 offsetFactor = vec2(-.5, 0.5);
+    
+    vec4 currentCursor = vec4(normalize(iCurrentCursor.xy, 1.), normalize(iCurrentCursor.zw, 0.));
+    vec4 previousCursor = vec4(normalize(iPreviousCursor.xy, 1.), normalize(iPreviousCursor.zw, 0.));
+
+    vec2 centerCC = currentCursor.xy - (currentCursor.zw * offsetFactor);
+    vec2 centerCP = previousCursor.xy - (previousCursor.zw * offsetFactor);
+
+    vec2 delta = centerCP - centerCC;
+    float lineLength = length(delta);
+
+     float sdfCurrentCursor = getSdfRectangle(vu, centerCC, currentCursor.zw * 0.5);
+	
+     vec4 newColor = vec4(fragColor);
+	
+     float minDist = currentCursor.w * THRESHOLD_MIN_DISTANCE;
+     float progress = clamp((iTime - iTimeCursorChange) / DURATION, 0.0, 1.0);
+     if (lineLength > minDist) {
+         // ANIMATION logic
+        
+        float head_eased = 0.0;
+        float tail_eased = 0.0;
+
+        float tail_delay_factor = MAX_TRAIL_LENGTH / lineLength;
+
+        float isLongMove = step(MAX_TRAIL_LENGTH, lineLength);
+
+        float head_eased_short = ease(progress);
+        float tail_eased_short = ease(smoothstep(tail_delay_factor, 1.0, progress));
+        float head_eased_long = 1.0;
+        float tail_eased_long = ease(progress);
+
+        head_eased = mix(head_eased_long, head_eased_short, isLongMove);
+        tail_eased = mix(tail_eased_long, tail_eased_short, isLongMove);
+
+        // detect straight moves
+        vec2 delta_abs = abs(centerCC - centerCP); 
+        float threshold = 0.001;
+        float isHorizontal = step(delta_abs.y, threshold);
+        float isVertical = step(delta_abs.x, threshold);
+        float isStraightMove = max(isHorizontal, isVertical);
+
+        // -- Making the parallelogram sdf (diagonal move) --
+
+        // animate the TOP-LEFT corners
+        vec2 head_pos_tl = mix(previousCursor.xy, currentCursor.xy, head_eased);
+        vec2 tail_pos_tl = mix(previousCursor.xy, currentCursor.xy, tail_eased);
+
+        float isTopRightLeading = determineIfTopRightIsLeading(currentCursor.xy, previousCursor.xy);
+        float isBottomLeftLeading = 1.0 - isTopRightLeading;
+        
+        // v0, v1 : "front" of the trail (head)
+        vec2 v0 = vec2(head_pos_tl.x + currentCursor.z * isTopRightLeading, head_pos_tl.y - currentCursor.w);
+        vec2 v1 = vec2(head_pos_tl.x + currentCursor.z * isBottomLeftLeading, head_pos_tl.y);
+        
+        // v2, v3: "back" of the trail (tail)
+        vec2 v2 = vec2(tail_pos_tl.x + currentCursor.z * isBottomLeftLeading, tail_pos_tl.y);
+        vec2 v3 = vec2(tail_pos_tl.x + currentCursor.z * isTopRightLeading, tail_pos_tl.y - previousCursor.w);
+
+        float sdfTrail_diag = getSdfParallelogram(vu, v0, v1, v2, v3);
+
+        // -- Making the rectangle sdf (straight move) --
+
+        vec2 head_center = mix(centerCP, centerCC, head_eased);
+        vec2 tail_center = mix(centerCP, centerCC, tail_eased);
+
+        vec2 min_center = min(head_center, tail_center);
+        vec2 max_center = max(head_center, tail_center);
+        
+        vec2 box_size = (max_center - min_center) + currentCursor.zw;
+        vec2 box_center = (min_center + max_center) * 0.5;
+
+        float sdfTrail_rect = getSdfRectangle(vu, box_center, box_size * 0.5);
+
+        // -- FINAL SELECTING AND DRAWING --
+        float sdfTrail = mix(sdfTrail_diag, sdfTrail_rect, isStraightMove);
+        
+        vec4 trail = TRAIL_COLOR;
+        float trailAlpha = antialising(sdfTrail);
+        newColor = mix(newColor, trail, trailAlpha);
+
+        // punch hole
+        newColor = mix(newColor, fragColor, step(sdfCurrentCursor, 0.));
+    }
+
+    fragColor = newColor;
+}

package/ghostty/shaders/ripple_cursor.glsl

@@ -0,0 +1,141 @@
+// ripple_cursor.glsl — from sahaj-b/ghostty-cursor-shaders (MIT).
+// https://github.com/sahaj-b/ghostty-cursor-shaders
+// See LICENSE in this directory. Local change: COLOR follows the theme cursor.
+
+// sRGB -> Linear conversion (needed because Ghostty passes sRGB values but the shader pipeline operates in linear color space)
+vec3 sRGBToLinear(vec3 c) {
+    return mix(c / 12.92, pow((c + 0.055) / 1.055, vec3(2.4)), step(vec3(0.04045), c));
+}
+
+// CONFIGURATION
+const float DURATION = 0.15;               // How long the ripple animates (seconds)
+const float MAX_RADIUS = 0.05;             // Max radius in normalized coords (0.5 = 1/4 screen height)
+const float RING_THICKNESS = 0.02;             // Ring width in normalized coords
+const float CURSOR_WIDTH_CHANGE_THRESHOLD = 0.5; // Triggers ripple if cursor width changes by this fraction
+vec4 COLOR = vec4(sRGBToLinear(iCurrentCursorColor.rgb), 1.0); // for custom color: vec4(0.35, 0.36, 0.44, 1.0)
+const float BLUR = 3.0;                    // Blur level in pixels
+const float ANIMATION_START_OFFSET = 0.0;        // Start the ripple slightly progressed (0.0 - 1.0)
+
+
+// Easing functions
+float easeOutQuad(float t) {
+    return 1.0 - (1.0 - t) * (1.0 - t);
+}
+float easeInOutQuad(float t) {
+    return t < 0.5 ? 2.0 * t * t : 1.0 - pow(-2.0 * t + 2.0, 2.0) / 2.0;
+}
+float easeOutCubic(float t) {
+    return 1.0 - pow(1.0 - t, 3.0);
+}
+float easeOutQuart(float t) {
+    return 1.0 - pow(1.0 - t, 4.0);
+}
+float easeOutQuint(float t) {
+    return 1.0 - pow(1.0 - t, 5.0);
+}
+float easeOutExpo(float t) {
+    return t == 1.0 ? 1.0 : 1.0 - pow(2.0, -10.0 * t);
+}
+float easeOutCirc(float t) {
+    return sqrt(1.0 - pow(t - 1.0, 2.0));
+}
+float easeOutSine(float t) {
+    return sin((t * 3.1415916) / 2.0);
+}
+float easeOutElastic(float t) {
+    const float c4 = (2.0 * 3.1415916) / 3.0;
+    return t == 0.0 ? 0.0 : t == 1.0 ? 1.0 : pow(2.0, -10.0 * t) * sin((t * 10.0 - 0.75) * c4) + 1.0;
+}
+float easeOutBounce(float t) {
+    const float n1 = 7.5625;
+    const float d1 = 2.75;
+    if (t < 1.0 / d1) {
+        return n1 * t * t;
+    } else if (t < 2.0 / d1) {
+        return n1 * (t -= 1.5 / d1) * t + 0.75;
+    } else if (t < 2.5 / d1) {
+        return n1 * (t -= 2.25 / d1) * t + 0.9375;
+    } else {
+        return n1 * (t -= 2.625 / d1) * t + 0.984375;
+    }
+}
+float easeOutBack(float t) {
+    const float c1 = 1.70158;
+    const float c3 = c1 + 1.0;
+    return 1.0 + c3 * pow(t - 1.0, 3.0) + c1 * pow(t - 1.0, 2.0);
+}
+
+// Pulse fade functions
+float easeOutPulse(float t) {
+    return t * (2.0 - t);
+}
+float exponentialDecayPulse(float t) {
+    return exp(-3.0 * t) * sin(t * 3.1415916);
+}
+
+vec2 normalize(vec2 value, float isPosition) {
+    return (value * 2.0 - (iResolution.xy * isPosition)) / iResolution.y;
+}
+
+void mainImage(out vec4 fragColor, in vec2 fragCoord){
+    #if !defined(WEB)
+    fragColor = texture(iChannel0, fragCoord.xy / iResolution.xy);
+    #endif
+
+    // Normalization & setup (-1 to 1 coords)
+    vec2 vu = normalize(fragCoord, 1.);
+    vec2 offsetFactor = vec2(-.5, 0.5);
+
+    vec4 currentCursor = vec4(normalize(iCurrentCursor.xy, 1.), normalize(iCurrentCursor.zw, 0.));
+    vec4 previousCursor = vec4(normalize(iPreviousCursor.xy, 1.), normalize(iPreviousCursor.zw, 0.));
+
+    vec2 centerCC = currentCursor.xy - (currentCursor.zw * offsetFactor);
+
+    float cellWidth = max(currentCursor.z, previousCursor.z); // width of the 'block' cursor
+    
+    // check for significant width change
+    float widthChange = abs(currentCursor.z - previousCursor.z);
+    float widthThresholdNorm = cellWidth * CURSOR_WIDTH_CHANGE_THRESHOLD;
+    float isModeChange = step(widthThresholdNorm, widthChange);
+
+
+    // ANIMATION
+    float rippleProgress = (iTime - iTimeCursorChange) / DURATION + ANIMATION_START_OFFSET;
+    // don't clamp yet; we need to know if it's > 1.0 (finished)
+     float isAnimating = 1.0 - step(1.0, rippleProgress); // progress < 1.0 ? 1.0: 0.0
+     
+     if (isModeChange > 0.0 && isAnimating > 0.0) {
+        // Apply easing to progress
+        // float easedProgress = rippleProgress;
+        // float easedProgress = easeOutQuad(rippleProgress);
+        // float easedProgress = easeInOutQuad(rippleProgress);
+        // float easedProgress = easeOutCubic(rippleProgress);
+        // float easedProgress = easeOutQuart(rippleProgress);
+        // float easedProgress = easeOutQuint(rippleProgress);
+        // float easedProgress = easeOutExpo(rippleProgress);
+        float easedProgress = easeOutCirc(rippleProgress);
+        // float easedProgress = easeOutSine(rippleProgress);
+        // float easedProgress = easeOutBack(rippleProgress);
+
+        // RIPPLE CALCULATION
+        float rippleRadius = easedProgress * MAX_RADIUS;
+        
+        // float fade = 1.0; // no fade
+        // float fade = 1.0 - easedProgress; // linear fade
+        float fade = 1.0 - easeOutPulse(rippleProgress);
+        // float fade = 1.0 - exponentialDecayPulse(rippleProgress);
+        
+        // Calculate distance from frag to cursor center
+        float dist = distance(vu, centerCC);
+        
+        float sdfRing = abs(dist - rippleRadius) - RING_THICKNESS * 0.5;
+        
+        // Antialias (1-pixel width in normalized coords)
+        float antiAliasSize = normalize(vec2(BLUR, BLUR), 0.0).x;
+        float ripple = (1.0 - smoothstep(-antiAliasSize, antiAliasSize, sdfRing)) * fade;
+        
+        // Apply ripple effect
+        fragColor = mix(fragColor, COLOR, ripple * COLOR.a);
+    }
+    // else: do nothing, keep original fragColor
+}

package/package.json

@@ -0,0 +1,43 @@
+{
+  "name": "@kecan0406/ttheme",
+  "version": "0.1.0",
+  "type": "module",
+  "bin": {
+    "ttheme": "bin/ttheme.js"
+  },
+  "files": [
+    "bin",
+    "dist",
+    "shell",
+    "ghostty/shaders"
+  ],
+  "description": "Character terminal palettes for ghostty, kitty, alacritty, wezterm and iTerm2",
+  "license": "MIT",
+  "author": "kecan0406",
+  "repository": {
+    "type": "git",
+    "url": "git+https://github.com/kecan0406/ttheme.git"
+  },
+  "homepage": "https://github.com/kecan0406/ttheme#readme",
+  "bugs": "https://github.com/kecan0406/ttheme/issues",
+  "keywords": [
+    "terminal",
+    "theme",
+    "ghostty",
+    "kitty",
+    "alacritty",
+    "wezterm",
+    "iterm2"
+  ],
+  "devDependencies": {
+    "@biomejs/biome": "^2.3.0",
+    "@clack/prompts": "^1.7.0",
+    "@types/bun": "^1.3.0",
+    "commander": "^15.0.0",
+    "typescript": "^5.8.2"
+  },
+  "engines": {
+    "bun": ">=1.3",
+    "node": ">=20.11"
+  }
+}

package/shell/adapters/_osc.zsh

@@ -0,0 +1,35 @@
+__tt_osc_apply() {
+  local -a p=(${=1})
+  (( ${#p} >= 20 )) || return 1
+
+  [[ $p[1] != - ]] && printf '\033]11;%s\033\\' "$p[1]"
+  printf '\033]10;%s\033\\\033]12;%s\033\\\033]17;%s\033\\' "$p[2]" "$p[3]" "$p[4]"
+
+  local osc4="" i
+  for i in {0..15}; do osc4+=";$i;$p[i+5]"; done
+  printf '\033]4%s\033\\' "$osc4"
+}
+
+__tt_apply() { __tt_osc_apply "$@" }
+
+__tt_query_bg() {
+  local saved resp fd
+  exec {fd}<>/dev/tty 2>/dev/null || return 1
+
+  saved=$(stty -g <&$fd 2>/dev/null)
+  if [[ -z $saved ]]; then
+    exec {fd}>&-
+    return 1
+  fi
+
+  stty raw -echo min 0 time 3 <&$fd 2>/dev/null
+  printf '\033]11;?\033\\' >&$fd
+  IFS= read -r -k 40 -u $fd resp 2>/dev/null
+  stty "$saved" <&$fd 2>/dev/null
+  exec {fd}>&-
+
+  [[ $resp == *rgb:* ]] || return 1
+  local -a parts=(${(s:/:)${resp#*rgb:}})
+  (( ${#parts} >= 3 )) || return 1
+  printf '#%s%s%s' "${parts[1]:0:2}" "${parts[2]:0:2}" "${parts[3]:0:2}"
+}

package/shell/adapters/kitty.zsh

@@ -0,0 +1,30 @@
+if (( $+commands[kitten] )); then
+  __tt_kitty() { kitten @ "$@" }
+elif (( $+commands[kitty] )); then
+  __tt_kitty() { kitty @ "$@" }
+else
+  __tt_kitty() { return 1 }
+fi
+
+__tt_kitty_args() {
+  local -a p=(${=1})
+  (( ${#p} >= 20 )) || return 1
+  reply=(
+    foreground=$p[2]
+    cursor=$p[3]
+    cursor_text_color=$p[1]
+    selection_background=$p[4]
+    selection_foreground=$p[2]
+  )
+  [[ $p[1] != - ]] && reply+=(background=$p[1])
+  local i
+  for i in {0..15}; do reply+=("color$i=$p[i+5]"); done
+}
+
+__tt_apply() {
+  local -a reply
+  __tt_kitty_args "$1" || return 1
+  __tt_kitty set-colors -- "${reply[@]}" 2>/dev/null && return 0
+
+  __tt_osc_apply "$1"
+}

package/shell/launch-tab.zsh

@@ -0,0 +1,11 @@
+#!/bin/zsh -f
+
+source ${0:A:h}/ttheme.zsh
+
+if [[ ${TTHEME_TAB_PALETTE:-seq} != off ]]; then
+  __tt_next
+  __tt_apply "$REPLY"
+  export TTHEME_SPEC=$REPLY
+fi
+
+exec /bin/zsh -l