@javascriptcommon/react-native-google-mobile-ads 16.3.3

package/ios/RNGoogleMobileAds/RNGoogleMobileAdsFullScreenAd.mm

@@ -0,0 +1,220 @@
+/**
+ * Copyright (c) 2016-present Invertase Limited & Contributors
+ *
+ * Licensed under the Apache License, Version 2.0 (the "License");
+ * you may not use this library except in compliance with the License.
+ * You may obtain a copy of the License at
+ *
+ *   http://www.apache.org/licenses/LICENSE-2.0
+ *
+ * Unless required by applicable law or agreed to in writing, software
+ * distributed under the License is distributed on an "AS IS" BASIS,
+ * WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
+ * See the License for the specific language governing permissions and
+ * limitations under the License.
+ *
+ */
+
+#if !TARGET_OS_MACCATALYST
+
+#import "RNGoogleMobileAdsFullScreenAd.h"
+#import "RNGoogleMobileAdsCommon.h"
+
+@implementation RNGoogleMobileAdsFullScreenAd
+
+- (instancetype)init {
+  if (self = [super init]) {
+    _adMap = [NSMutableDictionary new];
+    _delegateMap = [NSMutableDictionary new];
+  }
+  return self;
+}
+
+- (void)dealloc {
+  [self invalidate];
+}
+
+- (void)invalidate {
+  [_adMap removeAllObjects];
+  [_delegateMap removeAllObjects];
+}
+
+- (NSString *)getAdEventName {
+  @throw [NSException exceptionWithName:@"MethodNotImplemented"
+                                 reason:@"Method `getAdEventName` must be overridden"
+                               userInfo:nil];
+}
+
+- (void)loadAd:(NSString *)adUnitId
+            adRequest:(GAMRequest *)adRequest
+    completionHandler:
+        (void (^)(id<GADFullScreenPresentingAd> ad, NSError *error))completionHandler {
+  @throw [NSException exceptionWithName:@"MethodNotImplemented"
+                                 reason:@"Method `loadAd` must be overridden"
+                               userInfo:nil];
+}
+
+- (void)sendAdEvent:(NSString *)type
+          requestId:(int)requestId
+           adUnitId:(NSString *)adUnitId
+              error:(NSDictionary *)error
+               data:(NSDictionary *)data {
+  [RNGoogleMobileAdsCommon sendAdEvent:[self getAdEventName]
+                             requestId:@(requestId)
+                                  type:type
+                              adUnitId:adUnitId
+                                 error:error
+                                  data:data];
+}
+
+- (void)loadWithRequestId:(int)requestId
+                 adUnitId:(NSString *)adUnitId
+         adRequestOptions:(NSDictionary *)adRequestOptions {
+  GAMRequest *adRequest = [RNGoogleMobileAdsCommon buildAdRequest:adRequestOptions];
+  RNGoogleMobileAdsFullScreenContentDelegate *delegate =
+      [[RNGoogleMobileAdsFullScreenContentDelegate alloc] initWithAdEventName:[self getAdEventName]
+                                                                    requestId:requestId
+                                                                     adUnitId:adUnitId];
+
+  __weak __typeof(self) weakSelf = self;
+  [self loadAd:adUnitId
+              adRequest:adRequest
+      completionHandler:^(id<GADFullScreenPresentingAd> ad, NSError *error) {
+        if (error) {
+          NSDictionary *codeAndMessage =
+              [RNGoogleMobileAdsCommon getCodeAndMessageFromAdError:error];
+          [weakSelf sendAdEvent:GOOGLE_MOBILE_ADS_EVENT_ERROR
+                      requestId:requestId
+                       adUnitId:adUnitId
+                          error:codeAndMessage
+                           data:nil];
+          return;
+        }
+
+        NSString *eventType = GOOGLE_MOBILE_ADS_EVENT_LOADED;
+        NSDictionary *data = nil;
+
+        // Set up paid event handler
+        GADPaidEventHandler paidEventHandler = ^(GADAdValue *value) {
+          [weakSelf sendAdEvent:@"paid"
+                      requestId:requestId
+                       adUnitId:adUnitId
+                          error:nil
+                           data:@{
+                             @"value" : value.value,
+                             @"precision" : @(value.precision),
+                             @"currency" : value.currencyCode
+                           }];
+        };
+
+        if ([ad isKindOfClass:[GADRewardedAd class]]) {
+          [(GADRewardedAd *)ad setPaidEventHandler:paidEventHandler];
+        } else if ([ad isKindOfClass:[GADRewardedInterstitialAd class]]) {
+          [(GADRewardedInterstitialAd *)ad setPaidEventHandler:paidEventHandler];
+        } else if ([ad isKindOfClass:[GADInterstitialAd class]]) {
+          [(GADInterstitialAd *)ad setPaidEventHandler:paidEventHandler];
+        } else if ([ad isKindOfClass:[GADAppOpenAd class]]) {
+          [(GADAppOpenAd *)ad setPaidEventHandler:paidEventHandler];
+        }
+
+        if ([ad isKindOfClass:[GADRewardedAd class]] ||
+            [ad isKindOfClass:[GADRewardedInterstitialAd class]]) {
+          NSDictionary *serverSideVerificationOptions =
+              adRequestOptions[@"serverSideVerificationOptions"];
+          if (serverSideVerificationOptions) {
+            GADServerSideVerificationOptions *options =
+                [[GADServerSideVerificationOptions alloc] init];
+            options.userIdentifier = serverSideVerificationOptions[@"userId"];
+            options.customRewardString = serverSideVerificationOptions[@"customData"];
+
+            if ([ad isKindOfClass:[GADRewardedAd class]]) {
+              [(GADRewardedAd *)ad setServerSideVerificationOptions:options];
+            } else if ([ad isKindOfClass:[GADRewardedInterstitialAd class]]) {
+              [(GADRewardedInterstitialAd *)ad setServerSideVerificationOptions:options];
+            }
+          }
+
+          eventType = GOOGLE_MOBILE_ADS_EVENT_REWARDED_LOADED;
+          GADAdReward *adReward =
+              [(GADRewardedAd *)ad adReward] ?: [(GADRewardedInterstitialAd *)ad adReward];
+          data = @{@"type" : adReward.type, @"amount" : adReward.amount};
+        }
+
+        if ([ad isKindOfClass:[GAMInterstitialAd class]]) {
+          [(GAMInterstitialAd *)ad setAppEventDelegate:delegate];
+        }
+
+        ad.fullScreenContentDelegate = delegate;
+        weakSelf.adMap[@(requestId)] = ad;
+        weakSelf.delegateMap[@(requestId)] = delegate;
+
+        [weakSelf sendAdEvent:eventType requestId:requestId adUnitId:adUnitId error:nil data:data];
+      }];
+}
+
+- (void)showWithRequestId:(int)requestId
+                 adUnitId:(NSString *)adUnitId
+              showOptions:(NSDictionary *)showOptions
+                  resolve:(RCTPromiseResolveBlock)resolve
+                   reject:(RCTPromiseRejectBlock)reject {
+  UIViewController *viewController = [RNGoogleMobileAdsCommon currentViewController];
+  if (!viewController) {
+    [RNSharedUtils
+        rejectPromiseWithUserInfo:reject
+                         userInfo:@{
+                           @"code" : @"nil-vc",
+                           @"message" :
+                               @"Ad attempted to show but the current View Controller was nil."
+                         }];
+    return;
+  }
+
+  id<GADFullScreenPresentingAd> ad = self.adMap[@(requestId)];
+  if (!ad) {
+    [RNSharedUtils rejectPromiseWithUserInfo:reject
+                                    userInfo:@{
+                                      @"code" : @"not-ready",
+                                      @"message" : @"Ad attempted to show but was not ready."
+                                    }];
+    return;
+  }
+
+  if ([ad isKindOfClass:[GADAppOpenAd class]]) {
+    [(GADAppOpenAd *)ad presentFromRootViewController:viewController];
+  } else if ([ad isKindOfClass:[GADInterstitialAd class]]) {
+    [(GADInterstitialAd *)ad presentFromRootViewController:viewController];
+  } else if ([ad isKindOfClass:[GADRewardedAd class]]) {
+    [(GADRewardedAd *)ad presentFromRootViewController:viewController
+                              userDidEarnRewardHandler:^{
+                                NSDictionary *rewardData = @{
+                                  @"type" : [(GADRewardedAd *)ad adReward].type,
+                                  @"amount" : [(GADRewardedAd *)ad adReward].amount
+                                };
+                                [self sendAdEvent:GOOGLE_MOBILE_ADS_EVENT_REWARDED_EARNED_REWARD
+                                        requestId:requestId
+                                         adUnitId:adUnitId
+                                            error:nil
+                                             data:rewardData];
+                              }];
+  } else if ([ad isKindOfClass:[GADRewardedInterstitialAd class]]) {
+    [(GADRewardedInterstitialAd *)ad
+        presentFromRootViewController:viewController
+             userDidEarnRewardHandler:^{
+               NSDictionary *rewardData = @{
+                 @"type" : [(GADRewardedInterstitialAd *)ad adReward].type,
+                 @"amount" : [(GADRewardedInterstitialAd *)ad adReward].amount
+               };
+               [self sendAdEvent:GOOGLE_MOBILE_ADS_EVENT_REWARDED_EARNED_REWARD
+                       requestId:requestId
+                        adUnitId:adUnitId
+                           error:nil
+                            data:rewardData];
+             }];
+  }
+
+  resolve(nil);
+}
+
+@end
+
+#endif

package/ios/RNGoogleMobileAds/RNGoogleMobileAdsFullScreenContentDelegate.h

@@ -0,0 +1,36 @@
+/**
+ * Copyright (c) 2016-present Invertase Limited & Contributors
+ *
+ * Licensed under the Apache License, Version 2.0 (the "License");
+ * you may not use this library except in compliance with the License.
+ * You may obtain a copy of the License at
+ *
+ *   http://www.apache.org/licenses/LICENSE-2.0
+ *
+ * Unless required by applicable law or agreed to in writing, software
+ * distributed under the License is distributed on an "AS IS" BASIS,
+ * WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
+ * See the License for the specific language governing permissions and
+ * limitations under the License.
+ *
+ */
+
+#if !TARGET_OS_MACCATALYST
+
+#import <Foundation/Foundation.h>
+#import <GoogleMobileAds/GoogleMobileAds.h>
+
+@interface RNGoogleMobileAdsFullScreenContentDelegate
+    : NSObject <GADFullScreenContentDelegate, GADAppEventDelegate>
+
+@property(nonatomic, strong, readonly) NSString *adEventName;
+@property(nonatomic, assign, readonly) int requestId;
+@property(nonatomic, strong, readonly) NSString *adUnitId;
+
+- (instancetype)initWithAdEventName:(NSString *)adEventName
+                          requestId:(int)requestId
+                           adUnitId:(NSString *)adUnitId;
+
+@end
+
+#endif

package/ios/RNGoogleMobileAds/RNGoogleMobileAdsFullScreenContentDelegate.mm

@@ -0,0 +1,80 @@
+/**
+ * Copyright (c) 2016-present Invertase Limited & Contributors
+ *
+ * Licensed under the Apache License, Version 2.0 (the "License");
+ * you may not use this library except in compliance with the License.
+ * You may obtain a copy of the License at
+ *
+ *   http://www.apache.org/licenses/LICENSE-2.0
+ *
+ * Unless required by applicable law or agreed to in writing, software
+ * distributed under the License is distributed on an "AS IS" BASIS,
+ * WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
+ * See the License for the specific language governing permissions and
+ * limitations under the License.
+ *
+ */
+
+#if !TARGET_OS_MACCATALYST
+
+#import "RNGoogleMobileAdsFullScreenContentDelegate.h"
+#import "RNGoogleMobileAdsCommon.h"
+
+@implementation RNGoogleMobileAdsFullScreenContentDelegate
+
+- (instancetype)initWithAdEventName:(NSString *)adEventName
+                          requestId:(int)requestId
+                           adUnitId:(NSString *)adUnitId {
+  if (self = [super init]) {
+    _adEventName = adEventName;
+    _requestId = requestId;
+    _adUnitId = adUnitId;
+  }
+  return self;
+}
+
+- (void)adWillPresentFullScreenContent:(id<GADFullScreenPresentingAd>)ad {
+  [self sendAdEventWithType:GOOGLE_MOBILE_ADS_EVENT_OPENED error:nil data:nil];
+}
+
+- (void)ad:(id<GADFullScreenPresentingAd>)ad
+    didFailToPresentFullScreenContentWithError:(NSError *)error {
+  NSDictionary *errorInfo = [RNGoogleMobileAdsCommon getCodeAndMessageFromAdError:error];
+  [self sendAdEventWithType:GOOGLE_MOBILE_ADS_EVENT_ERROR error:errorInfo data:nil];
+}
+
+- (void)adDidDismissFullScreenContent:(id<GADFullScreenPresentingAd>)ad {
+  [self sendAdEventWithType:GOOGLE_MOBILE_ADS_EVENT_CLOSED error:nil data:nil];
+}
+
+- (void)adDidRecordClick:(id<GADFullScreenPresentingAd>)ad {
+  [self sendAdEventWithType:GOOGLE_MOBILE_ADS_EVENT_CLICKED error:nil data:nil];
+}
+
+- (void)adDidRecordImpression:(id<GADFullScreenPresentingAd>)ad {
+  // Not implemented yet
+}
+
+- (void)interstitialAd:(GADInterstitialAd *)interstitialAd
+    didReceiveAppEvent:(NSString *)name
+              withInfo:(nullable NSString *)info {
+  NSDictionary *data = @{@"name" : name, @"data" : info ?: @""};
+  [self sendAdEventWithType:GOOGLE_MOBILE_ADS_EVENT_APP_EVENT error:nil data:data];
+}
+
+#pragma mark - Private
+
+- (void)sendAdEventWithType:(NSString *)type
+                      error:(nullable NSDictionary *)error
+                       data:(nullable NSDictionary *)data {
+  [RNGoogleMobileAdsCommon sendAdEvent:self.adEventName
+                             requestId:@(self.requestId)
+                                  type:type
+                              adUnitId:self.adUnitId
+                                 error:error
+                                  data:data];
+}
+
+@end
+
+#endif

package/ios/RNGoogleMobileAds/RNGoogleMobileAdsInterstitialModule.h

@@ -0,0 +1,36 @@
+/**
+ * Copyright (c) 2016-present Invertase Limited & Contributors
+ *
+ * Licensed under the Apache License, Version 2.0 (the "License");
+ * you may not use this library except in compliance with the License.
+ * You may obtain a copy of the License at
+ *
+ *   http://www.apache.org/licenses/LICENSE-2.0
+ *
+ * Unless required by applicable law or agreed to in writing, software
+ * distributed under the License is distributed on an "AS IS" BASIS,
+ * WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
+ * See the License for the specific language governing permissions and
+ * limitations under the License.
+ *
+ */
+
+#if !TARGET_OS_MACCATALYST
+
+#import <Foundation/Foundation.h>
+
+#ifdef RCT_NEW_ARCH_ENABLED
+
+#import <RNGoogleMobileAdsSpec/RNGoogleMobileAdsSpec.h>
+@interface RNGoogleMobileAdsInterstitialModule : NSObject <NativeInterstitialModuleSpec>
+
+#else
+
+#import <React/RCTBridgeModule.h>
+@interface RNGoogleMobileAdsInterstitialModule : NSObject <RCTBridgeModule>
+
+#endif
+
+@end
+
+#endif

package/ios/RNGoogleMobileAds/RNGoogleMobileAdsInterstitialModule.mm

@@ -0,0 +1,106 @@
+/**
+ * Copyright (c) 2016-present Invertase Limited & Contributors
+ *
+ * Licensed under the Apache License, Version 2.0 (the "License");
+ * you may not use this library except in compliance with the License.
+ * You may obtain a copy of the License at
+ *
+ *   http://www.apache.org/licenses/LICENSE-2.0
+ *
+ * Unless required by applicable law or agreed to in writing, software
+ * distributed under the License is distributed on an "AS IS" BASIS,
+ * WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
+ * See the License for the specific language governing permissions and
+ * limitations under the License.
+ *
+ */
+
+#if !TARGET_OS_MACCATALYST
+
+#import "RNGoogleMobileAdsInterstitialModule.h"
+#import <GoogleMobileAds/GoogleMobileAds.h>
+#ifdef RCT_NEW_ARCH_ENABLED
+#import "RNGoogleMobileAdsSpec.h"
+#endif
+#import "RNGoogleMobileAdsCommon.h"
+#import "RNGoogleMobileAdsFullScreenAd.h"
+
+@interface RNGoogleMobileAdsInterstitialAd : RNGoogleMobileAdsFullScreenAd
+
+@end
+
+@implementation RNGoogleMobileAdsInterstitialAd
+
+- (NSString *)getAdEventName {
+  return GOOGLE_MOBILE_ADS_EVENT_INTERSTITIAL;
+}
+
+- (void)loadAd:(NSString *)adUnitId
+            adRequest:(GAMRequest *)adRequest
+    completionHandler:
+        (void (^)(GAMInterstitialAd *_Nullable ad, NSError *_Nullable error))completionHandler {
+  [GAMInterstitialAd loadWithAdManagerAdUnitID:adUnitId
+                                       request:adRequest
+                             completionHandler:completionHandler];
+}
+
+@end
+
+@implementation RNGoogleMobileAdsInterstitialModule {
+  RNGoogleMobileAdsInterstitialAd *_ad;
+}
+
+RCT_EXPORT_MODULE();
+
+- (dispatch_queue_t)methodQueue {
+  return dispatch_get_main_queue();
+}
+
++ (BOOL)requiresMainQueueSetup {
+  return YES;
+}
+
+RCT_EXPORT_METHOD(interstitialLoad
+                  : (double)requestId adUnitId
+                  : (NSString *)adUnitId requestOptions
+                  : (NSDictionary *)requestOptions) {
+  [_ad loadWithRequestId:requestId adUnitId:adUnitId adRequestOptions:requestOptions];
+}
+
+RCT_EXPORT_METHOD(interstitialShow
+                  : (double)requestId adUnitId
+                  : (NSString *)adUnitId showOptions
+                  : (NSDictionary *)showOptions resolve
+                  : (RCTPromiseResolveBlock)resolve reject
+                  : (RCTPromiseRejectBlock)reject) {
+  [_ad showWithRequestId:requestId
+                adUnitId:adUnitId
+             showOptions:showOptions
+                 resolve:resolve
+                  reject:reject];
+}
+
+RCT_EXPORT_METHOD(invalidate) { [_ad invalidate]; }
+
+#ifdef RCT_NEW_ARCH_ENABLED
+- (std::shared_ptr<facebook::react::TurboModule>)getTurboModule:
+    (const facebook::react::ObjCTurboModule::InitParams &)params {
+  return std::make_shared<facebook::react::NativeInterstitialModuleSpecJSI>(params);
+}
+#endif
+
+- (instancetype)init {
+  self = [super init];
+  if (self) {
+    _ad = [[RNGoogleMobileAdsInterstitialAd alloc] init];
+  }
+  return self;
+}
+
+- (void)dealloc {
+  [self invalidate];
+}
+
+@end
+
+#endif

package/ios/RNGoogleMobileAds/RNGoogleMobileAdsMediaView.h

@@ -0,0 +1,52 @@
+/**
+ * Copyright (c) 2016-present Invertase Limited & Contributors
+ *
+ * Licensed under the Apache License, Version 2.0 (the "License");
+ * you may not use this library except in compliance with the License.
+ * You may obtain a copy of the License at
+ *
+ *   http://www.apache.org/licenses/LICENSE-2.0
+ *
+ * Unless required by applicable law or agreed to in writing, software
+ * distributed under the License is distributed on an "AS IS" BASIS,
+ * WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
+ * See the License for the specific language governing permissions and
+ * limitations under the License.
+ *
+ */
+
+#import <GoogleMobileAds/GADNativeAd.h>
+#import <React/RCTBridge.h>
+#import <React/RCTUIManager.h>
+
+#ifdef RCT_NEW_ARCH_ENABLED
+#import <React/RCTViewComponentView.h>
+#else
+#import <React/RCTView.h>
+#endif
+
+NS_ASSUME_NONNULL_BEGIN
+
+#ifdef RCT_NEW_ARCH_ENABLED
+@interface RNGoogleMobileAdsMediaView : RCTViewComponentView
+
+// this setters/getters here are provided by RCTViewComponentView super, we just narrow the type.
+@property(nonatomic, strong, nullable) GADMediaView *contentView;
+#else
+@interface RNGoogleMobileAdsMediaView : GADMediaView
+
+- (instancetype)initWithBridge:(RCTBridge *)bridge;
+#endif
+
+@property(nonatomic, copy) NSString *responseId;
+@property(nonatomic, copy) NSString *resizeMode;
+
+@end
+
+#ifndef RCT_NEW_ARCH_ENABLED
+@interface RNGoogleMobileAdsMediaViewManager : RCTViewManager
+
+@end
+#endif
+
+NS_ASSUME_NONNULL_END

package/ios/RNGoogleMobileAds/RNGoogleMobileAdsMediaView.mm

@@ -0,0 +1,155 @@
+/**
+ * Copyright (c) 2016-present Invertase Limited & Contributors
+ *
+ * Licensed under the Apache License, Version 2.0 (the "License");
+ * you may not use this library except in compliance with the License.
+ * You may obtain a copy of the License at
+ *
+ *   http://www.apache.org/licenses/LICENSE-2.0
+ *
+ * Unless required by applicable law or agreed to in writing, software
+ * distributed under the License is distributed on an "AS IS" BASIS,
+ * WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
+ * See the License for the specific language governing permissions and
+ * limitations under the License.
+ *
+ */
+
+#import "RNGoogleMobileAdsMediaView.h"
+#import "RNGoogleMobileAdsNativeModule.h"
+
+#ifdef RCT_NEW_ARCH_ENABLED
+#import <react/renderer/components/RNGoogleMobileAdsSpec/ComponentDescriptors.h>
+#import <react/renderer/components/RNGoogleMobileAdsSpec/EventEmitters.h>
+#import <react/renderer/components/RNGoogleMobileAdsSpec/Props.h>
+#import <react/renderer/components/RNGoogleMobileAdsSpec/RCTComponentViewHelpers.h>
+
+#import "RCTFabricComponentsPlugins.h"
+#endif
+
+@interface RCTBridge (Private)
++ (RCTBridge *)currentBridge;
+@end
+
+#ifdef RCT_NEW_ARCH_ENABLED
+using namespace facebook::react;
+
+@interface RNGoogleMobileAdsMediaView () <RCTRNGoogleMobileAdsMediaViewViewProtocol>
+@end
+#endif
+
+@implementation RNGoogleMobileAdsMediaView {
+  __weak RCTBridge *_bridge;
+  __weak RNGoogleMobileAdsNativeModule *_nativeModule;
+  GADMediaView *_mediaView;
+  UIViewContentMode _contentMode;
+}
+
+#ifdef RCT_NEW_ARCH_ENABLED
+#pragma mark - Fabric specific
+
+@dynamic contentView;  // provided by superclass, but we narrow the type in our declaration
+
+- (instancetype)initWithFrame:(CGRect)frame {
+  if (self = [super initWithFrame:frame]) {
+    static const auto defaultProps = std::make_shared<const RNGoogleMobileAdsBannerViewProps>();
+    _props = defaultProps;
+
+    _bridge = [RCTBridge currentBridge];
+    _nativeModule = [_bridge moduleForClass:RNGoogleMobileAdsNativeModule.class];
+    _mediaView = [[GADMediaView alloc] init];
+    _contentMode = UIViewContentModeScaleAspectFill;
+    self.contentView = _mediaView;
+  }
+
+  return self;
+}
+
+#pragma mark - RCTComponentViewProtocol
+
++ (ComponentDescriptorProvider)componentDescriptorProvider {
+  return concreteComponentDescriptorProvider<RNGoogleMobileAdsMediaViewComponentDescriptor>();
+}
+
++ (BOOL)shouldBeRecycled {
+  return NO;
+}
+
+- (void)updateProps:(Props::Shared const &)props oldProps:(Props::Shared const &)oldProps {
+  const auto &oldViewProps =
+      *std::static_pointer_cast<RNGoogleMobileAdsMediaViewProps const>(_props);
+  const auto &newViewProps =
+      *std::static_pointer_cast<RNGoogleMobileAdsMediaViewProps const>(props);
+
+  if (oldViewProps.responseId != newViewProps.responseId) {
+    NSString *responseId = [[NSString alloc] initWithUTF8String:newViewProps.responseId.c_str()];
+    [self setResponseId:responseId];
+  }
+
+  if (oldViewProps.resizeMode != newViewProps.resizeMode) {
+    NSString *resizeMode = [[NSString alloc] initWithUTF8String:newViewProps.resizeMode.c_str()];
+    [self setResizeMode:resizeMode];
+  }
+
+  [super updateProps:props oldProps:oldProps];
+}
+
+#else
+#pragma mark - Paper specific
+
+- (instancetype)initWithBridge:(RCTBridge *)bridge {
+  if (self = [super init]) {
+    _bridge = bridge;
+    _nativeModule = [_bridge moduleForClass:RNGoogleMobileAdsNativeModule.class];
+    _mediaView = self;
+  }
+  return self;
+}
+
+#endif  // RCT_NEW_ARCH_ENABLED
+
+#pragma mark - Common logics
+
+- (void)setResponseId:(NSString *)responseId {
+  _responseId = responseId;
+  GADNativeAd *nativeAd = [_nativeModule nativeAdForResponseId:responseId];
+  _mediaView.mediaContent = nativeAd.mediaContent;
+  _mediaView.contentMode = _contentMode;
+}
+
+- (void)setResizeMode:(NSString *)resizeMode {
+  _resizeMode = resizeMode;
+  if ([resizeMode isEqualToString:@"cover"]) {
+    _contentMode = UIViewContentModeScaleAspectFill;
+  } else if ([resizeMode isEqualToString:@"contain"]) {
+    _contentMode = UIViewContentModeScaleAspectFit;
+  } else if ([resizeMode isEqualToString:@"stretch"]) {
+    _contentMode = UIViewContentModeScaleToFill;
+  }
+  _mediaView.contentMode = _contentMode;
+}
+
+@end
+
+#ifndef RCT_NEW_ARCH_ENABLED
+
+@implementation RNGoogleMobileAdsMediaViewManager
+
+RCT_EXPORT_MODULE(RNGoogleMobileAdsMediaView)
+
+RCT_EXPORT_VIEW_PROPERTY(responseId, NSString)
+RCT_EXPORT_VIEW_PROPERTY(resizeMode, NSString)
+
+- (UIView *)view {
+  return [[RNGoogleMobileAdsMediaView alloc] initWithBridge:self.bridge];
+}
+
+@end
+
+#endif
+
+#ifdef RCT_NEW_ARCH_ENABLED
+Class<RCTComponentViewProtocol> RNGoogleMobileAdsMediaViewCls(void) {
+  return RNGoogleMobileAdsMediaView.class;
+}
+#endif