@interactive-inc/claude-funnel 0.7.1 → 0.8.1

package/dist/highlights-x6tmsnaa.scm

@@ -0,0 +1,115 @@
+; Query from: https://raw.githubusercontent.com/nvim-treesitter/nvim-treesitter/99ddf573531c4dbe53f743ecbc1595af5eb1d32f/queries/markdown_inline/highlights.scm
+; From MDeiml/tree-sitter-markdown
+(code_span) @markup.raw @nospell
+
+(emphasis) @markup.italic
+
+(strong_emphasis) @markup.strong
+
+(strikethrough) @markup.strikethrough
+
+(shortcut_link
+  (link_text) @nospell)
+
+[
+  (backslash_escape)
+  (hard_line_break)
+] @string.escape
+
+; Conceal codeblock and text style markers
+([
+  (code_span_delimiter)
+  (emphasis_delimiter)
+] @conceal
+  (#set! conceal ""))
+
+; Inline links - style all parts
+(inline_link
+  ["[" "(" ")"] @markup.link)
+
+(inline_link
+  "]" @markup.link.bracket.close)
+
+; Conceal opening bracket
+((inline_link
+  "[" @conceal)
+  (#set! conceal ""))
+
+; Conceal closing bracket with space replacement
+((inline_link
+  "]" @conceal)
+  (#set! conceal " "))
+
+; Conceal image links
+(image
+  [
+    "!"
+    "["
+    "]"
+    "("
+    (link_destination)
+    ")"
+  ] @markup.link
+  (#set! conceal ""))
+
+; Conceal full reference links
+(full_reference_link
+  [
+    "["
+    "]"
+    (link_label)
+  ] @markup.link
+  (#set! conceal ""))
+
+; Conceal collapsed reference links
+(collapsed_reference_link
+  [
+    "["
+    "]"
+  ] @markup.link
+  (#set! conceal ""))
+
+; Conceal shortcut links
+(shortcut_link
+  [
+    "["
+    "]"
+  ] @markup.link
+  (#set! conceal ""))
+
+[
+  (link_destination)
+  (uri_autolink)
+] @markup.link.url @nospell
+
+[
+  (link_label)
+  (link_text)
+  (link_title)
+  (image_description)
+] @markup.link.label
+
+; Replace common HTML entities.
+((entity_reference) @character.special
+  (#eq? @character.special " ")
+  (#set! conceal ""))
+
+((entity_reference) @character.special
+  (#eq? @character.special "<")
+  (#set! conceal "<"))
+
+((entity_reference) @character.special
+  (#eq? @character.special "&gt;")
+  (#set! conceal ">"))
+
+((entity_reference) @character.special
+  (#eq? @character.special "&amp;")
+  (#set! conceal "&"))
+
+((entity_reference) @character.special
+  (#eq? @character.special "&quot;")
+  (#set! conceal "\""))
+
+((entity_reference) @character.special
+  (#any-of? @character.special "&ensp;" "&emsp;")
+  (#set! conceal " "))

package/dist/index.d.ts

@@ -0,0 +1,36 @@
+export * from "./funnel";
+export * from "./engine/channels/channels";
+export * from "./engine/claude/claude";
+export * from "./engine/mcp/mcp";
+export * from "./engine/profiles/profiles";
+export * from "./engine/settings/settings-reader";
+export * from "./engine/settings/settings-store";
+export * from "./engine/settings/mock-settings-reader";
+export * from "./engine/settings/settings-schema";
+export * from "./engine/fs/file-system";
+export * from "./engine/fs/node-file-system";
+export * from "./engine/fs/memory-file-system";
+export * from "./engine/process/process-runner";
+export * from "./engine/process/node-process-runner";
+export * from "./engine/process/memory-process-runner";
+export * from "./engine/logger/logger";
+export * from "./engine/logger/node-logger";
+export * from "./engine/logger/memory-logger";
+export * from "./engine/logger/noop-logger";
+export * from "./engine/time/clock";
+export * from "./engine/time/node-clock";
+export * from "./engine/time/memory-clock";
+export * from "./engine/id/id-generator";
+export * from "./engine/id/node-id-generator";
+export * from "./engine/id/memory-id-generator";
+export * from "./connectors/connector-factory";
+export * from "./connectors/connector-config-schema";
+export * from "./connectors/connector-listener";
+export * from "./connectors/schedule-connector-schema";
+export * from "./connectors/slack-connector-schema";
+export * from "./gateway/gateway";
+export * from "./gateway/gateway-server";
+export * from "./gateway/broadcaster";
+export * from "./gateway/funnel-event-store";
+export * from "./gateway/listener-supervisor";
+export * from "./gateway/listeners-client";