@hyperlane-xyz/core 5.4.1 → 5.4.2-superchain.0

package/contracts/hooks/SuperchainHook.sol

@@ -0,0 +1,82 @@
+// SPDX-License-Identifier: MIT OR Apache-2.0
+pragma solidity >=0.8.0;
+
+/*@@@@@@@       @@@@@@@@@
+ @@@@@@@@@       @@@@@@@@@
+  @@@@@@@@@       @@@@@@@@@
+   @@@@@@@@@       @@@@@@@@@
+    @@@@@@@@@@@@@@@@@@@@@@@@@
+     @@@@@  HYPERLANE  @@@@@@@
+    @@@@@@@@@@@@@@@@@@@@@@@@@
+   @@@@@@@@@       @@@@@@@@@
+  @@@@@@@@@       @@@@@@@@@
+ @@@@@@@@@       @@@@@@@@@
+@@@@@@@@@       @@@@@@@@*/
+
+// ============ Internal Imports ============
+import {AbstractPostDispatchHook, AbstractMessageIdAuthHook} from "./libs/AbstractMessageIdAuthHook.sol";
+import {StandardHookMetadata} from "./libs/StandardHookMetadata.sol";
+import {TypeCasts} from "../libs/TypeCasts.sol";
+import {IPostDispatchHook} from "../interfaces/hooks/IPostDispatchHook.sol";
+
+// ============ External Imports ============
+import {IL2toL2CrossDomainMessenger} from "../interfaces/optimism/IL2toL2CrossDomainMessenger.sol";
+
+/**
+ * @title SuperchainHook
+ * @notice Message hook to send messages to L2 using the native Superchain interop.
+ */
+contract SuperchainHook is AbstractMessageIdAuthHook {
+    using StandardHookMetadata for bytes;
+    // ============ Constants ============
+
+    // precompile contract on L2 for sending messages to L2
+    IL2toL2CrossDomainMessenger public immutable messenger;
+    // Immutable quote amount
+    uint32 public immutable GAS_QUOTE;
+
+    // ============ Constructor ============
+
+    constructor(
+        address _mailbox,
+        uint32 _destinationDomain,
+        bytes32 _ism,
+        address _messenger,
+        uint32 _gasQuote
+    ) AbstractMessageIdAuthHook(_mailbox, _destinationDomain, _ism) {
+        GAS_QUOTE = _gasQuote;
+        messenger = IL2toL2CrossDomainMessenger(_messenger);
+    }
+
+    /// @inheritdoc IPostDispatchHook
+    function hookType() external pure override returns (uint8) {
+        return uint8(IPostDispatchHook.Types.SUPERCHAIN);
+    }
+
+    /// @inheritdoc AbstractPostDispatchHook
+    function _quoteDispatch(
+        bytes calldata,
+        bytes calldata
+    ) internal view override returns (uint256) {
+        // TODO: Request from a IGP as a child hook like https://github.com/hyperlane-xyz/hyperlane-monorepo/blob/9093369186993468571b5d411e712ddd9a30c98c/solidity/contracts/hooks/ArbL2ToL1Hook.sol#L85
+        return GAS_QUOTE;
+    }
+
+    // ============ Internal functions ============
+
+    /// @inheritdoc AbstractMessageIdAuthHook
+    function _sendMessageId(
+        bytes calldata metadata,
+        bytes memory payload
+    ) internal override {
+        require(
+            msg.value >= metadata.msgValue(0) + GAS_QUOTE,
+            "SuperchainHook: insufficient msg.value"
+        );
+        messenger.sendMessage(
+            destinationDomain,
+            TypeCasts.bytes32ToAddress(ism),
+            payload
+        );
+    }
+}

package/contracts/interfaces/IInterchainSecurityModule.sol

@@ -14,7 +14,8 @@ interface IInterchainSecurityModule {
         ARB_L2_TO_L1,
         WEIGHTED_MERKLE_ROOT_MULTISIG,
         WEIGHTED_MESSAGE_ID_MULTISIG,
-        OP_L2_TO_L1
+        OP_L2_TO_L1,
+        SUPERCHAIN
     }
 
     /**

package/contracts/interfaces/hooks/IPostDispatchHook.sol

@@ -27,7 +27,8 @@ interface IPostDispatchHook {
         LAYER_ZERO_V1,
         RATE_LIMITED,
         ARB_L2_TO_L1,
-        OP_L2_TO_L1
+        OP_L2_TO_L1,
+        SUPERCHAIN
     }
 
     /**

package/contracts/interfaces/optimism/ICrossL2Inbox.sol

@@ -0,0 +1,60 @@
+// SPDX-License-Identifier: MIT
+pragma solidity ^0.8.0;
+
+/// @title ICrossL2Inbox
+/// @notice Interface for the CrossL2Inbox contract.
+interface ICrossL2Inbox {
+    /// @notice The struct for a pointer to a message payload in a remote (or local) chain.
+    struct Identifier {
+        address origin;
+        uint256 blockNumber;
+        uint256 logIndex;
+        uint256 timestamp;
+        uint256 chainId;
+    }
+
+    /// @notice Returns the interop start timestamp.
+    /// @return interopStart_ interop start timestamp.
+    function interopStart() external view returns (uint256 interopStart_);
+
+    /// @notice Returns the origin address of the Identifier.
+    /// @return origin_ The origin address of the Identifier.
+    function origin() external view returns (address origin_);
+
+    /// @notice Returns the block number of the Identifier.
+    /// @return blockNumber_ The block number of the Identifier.
+    function blockNumber() external view returns (uint256 blockNumber_);
+
+    /// @notice Returns the log index of the Identifier.
+    /// @return logIndex_ The log index of the Identifier.
+    function logIndex() external view returns (uint256 logIndex_);
+
+    /// @notice Returns the timestamp of the Identifier.
+    /// @return timestamp_ The timestamp of the Identifier.
+    function timestamp() external view returns (uint256 timestamp_);
+
+    /// @notice Returns the chain ID of the Identifier.
+    /// @return chainId_ The chain ID of the Identifier.
+    function chainId() external view returns (uint256 chainId_);
+
+    /// @notice Executes a cross chain message on the destination chain.
+    /// @param _id An Identifier pointing to the initiating message.
+    /// @param _target Account that is called with _msg.
+    /// @param _msg The message payload, matching the initiating message.
+    function executeMessage(
+        ICrossL2Inbox.Identifier calldata _id,
+        address _target,
+        bytes calldata _msg
+    ) external payable;
+
+    /// @notice Validates a cross chain message on the destination chain
+    ///         and emits an ExecutingMessage event. This function is useful
+    ///         for applications that understand the schema of the _message payload and want to
+    ///         process it in a custom way.
+    /// @param _id      Identifier of the message.
+    /// @param _msgHash Hash of the message payload to call target with.
+    function validateMessage(
+        Identifier calldata _id,
+        bytes32 _msgHash
+    ) external;
+}

package/contracts/interfaces/optimism/IL2toL2CrossDomainMessenger.sol

@@ -0,0 +1,68 @@
+// SPDX-License-Identifier: MIT
+pragma solidity ^0.8.0;
+
+import {ICrossL2Inbox} from "./ICrossL2Inbox.sol";
+
+/// @title IL2ToL2CrossDomainMessenger
+/// @notice Interface for the L2ToL2CrossDomainMessenger contract.
+interface IL2toL2CrossDomainMessenger {
+    /// @notice Emitted whenever a message is sent to a destination
+    /// @param destination  Chain ID of the destination chain.
+    /// @param target       Target contract or wallet address.
+    /// @param messageNonce Nonce associated with the messsage sent
+    /// @param sender       Address initiating this message call
+    /// @param message      Message payload to call target with.
+    event SentMessage(
+        uint256 indexed destination,
+        address indexed target,
+        uint256 indexed messageNonce,
+        address sender,
+        bytes message
+    );
+
+    /// @notice Mapping of message hashes to boolean receipt values. Note that a message will only
+    ///         be present in this mapping if it has successfully been relayed on this chain, and
+    ///         can therefore not be relayed again.
+    /// @param _msgHash message hash to check.
+    /// @return Returns true if the message corresponding to the `_msgHash` was successfully relayed.
+    function successfulMessages(bytes32 _msgHash) external view returns (bool);
+
+    /// @notice Retrieves the next message nonce. Message version will be added to the upper two
+    ///         bytes of the message nonce. Message version allows us to treat messages as having
+    ///         different structures.
+    /// @return Nonce of the next message to be sent, with added message version.
+    function messageNonce() external view returns (uint256);
+
+    /// @notice Retrieves the sender of the current cross domain message.
+    /// @return sender_ Address of the sender of the current cross domain message.
+    function crossDomainMessageSender() external view returns (address sender_);
+
+    /// @notice Retrieves the source of the current cross domain message.
+    /// @return source_ Chain ID of the source of the current cross domain message.
+    function crossDomainMessageSource() external view returns (uint256 source_);
+
+    /// @notice Sends a message to some target address on a destination chain. Note that if the call
+    ///         always reverts, then the message will be unrelayable, and any ETH sent will be
+    ///         permanently locked. The same will occur if the target on the other chain is
+    ///         considered unsafe (see the _isUnsafeTarget() function).
+    /// @param _destination Chain ID of the destination chain.
+    /// @param _target      Target contract or wallet address.
+    /// @param _message     Message to trigger the target address with.
+    /// @return msgHash_ The hash of the message being sent, which can be used for tracking whether
+    ///                  the message has successfully been relayed.
+    function sendMessage(
+        uint256 _destination,
+        address _target,
+        bytes calldata _message
+    ) external returns (bytes32 msgHash_);
+
+    /// @notice Relays a message that was sent by the other CrossDomainMessenger contract. Can only
+    ///         be executed via cross-chain call from the other messenger OR if the message was
+    ///         already received once and is currently being replayed.
+    /// @param _id          Identifier of the SentMessage event to be relayed
+    /// @param _sentMessage Message payload of the `SentMessage` event
+    function relayMessage(
+        ICrossL2Inbox.Identifier calldata _id,
+        bytes calldata _sentMessage
+    ) external payable;
+}

package/contracts/isms/hook/SuperchainIsm.sol

@@ -0,0 +1,91 @@
+// SPDX-License-Identifier: MIT OR Apache-2.0
+pragma solidity >=0.8.0;
+
+/*@@@@@@@       @@@@@@@@@
+ @@@@@@@@@       @@@@@@@@@
+  @@@@@@@@@       @@@@@@@@@
+   @@@@@@@@@       @@@@@@@@@
+    @@@@@@@@@@@@@@@@@@@@@@@@@
+     @@@@@  HYPERLANE  @@@@@@@
+    @@@@@@@@@@@@@@@@@@@@@@@@@
+   @@@@@@@@@       @@@@@@@@@
+  @@@@@@@@@       @@@@@@@@@
+ @@@@@@@@@       @@@@@@@@@
+@@@@@@@@@       @@@@@@@@*/
+
+// ============ Internal Imports ============
+import {IInterchainSecurityModule} from "../../interfaces/IInterchainSecurityModule.sol";
+import {TypeCasts} from "../../libs/TypeCasts.sol";
+import {Message} from "../../libs/Message.sol";
+import {AbstractMessageIdAuthorizedIsm} from "./AbstractMessageIdAuthorizedIsm.sol";
+
+// ============ External Imports ============
+
+import {IL2toL2CrossDomainMessenger} from "../../interfaces/optimism/IL2toL2CrossDomainMessenger.sol";
+import {ICrossL2Inbox} from "../../interfaces/optimism/ICrossL2Inbox.sol";
+import {Address} from "@openzeppelin/contracts/utils/Address.sol";
+
+/**
+ * @title SuperchainISM
+ * @notice Uses the native Optimism bridge to verify interchain messages from L2 to L1.
+ */
+contract SuperchainISM is AbstractMessageIdAuthorizedIsm {
+    using TypeCasts for address;
+    using Message for bytes;
+
+    // ============ Constants ============
+
+    // module type for the ISM
+    uint8 public constant moduleType =
+        uint8(IInterchainSecurityModule.Types.SUPERCHAIN);
+    // L2toL2CrossDomainMessenger contract
+    IL2toL2CrossDomainMessenger immutable messenger;
+
+    // ============ Constructor ============
+
+    constructor(address _messenger) {
+        messenger = IL2toL2CrossDomainMessenger(_messenger);
+        require(
+            Address.isContract(_messenger),
+            "SuperchainISM: invalid L2toL2CrossDomainMessenger contract"
+        );
+    }
+
+    // ============ External Functions ============
+
+    /// @inheritdoc IInterchainSecurityModule
+    function verify(
+        bytes calldata metadata,
+        bytes calldata message
+    ) external override returns (bool) {
+        bool verified = isVerified(message);
+        if (!verified) {
+            _verifyWithMessenger(metadata, message);
+            require(isVerified(message), "SuperchainIsm: message not verified");
+        }
+        return true;
+    }
+
+    // ============ Internal function ============
+
+    /**
+     * @notice Verify message directly using the portal.finalizeWithdrawal function.
+     * @dev This is a fallback in case the message is not verified by the stateful verify function first.
+     */
+    function _verifyWithMessenger(
+        bytes calldata metadata,
+        bytes memory
+    ) internal {
+        (ICrossL2Inbox.Identifier memory _id, bytes memory _sentMessage) = abi
+            .decode(metadata, (ICrossL2Inbox.Identifier, bytes));
+        messenger.relayMessage(_id, _sentMessage);
+    }
+
+    /// @inheritdoc AbstractMessageIdAuthorizedIsm
+    function _isAuthorized() internal view override returns (bool) {
+        return
+            msg.sender == address(messenger) &&
+            messenger.crossDomainMessageSender() ==
+            TypeCasts.bytes32ToAddress(authorizedHook);
+    }
+}

package/contracts/mock/MockOptimism.sol

@@ -4,7 +4,10 @@ pragma solidity ^0.8.0;
 import {CallLib} from "../middleware/libs/Call.sol";
 import {TypeCasts} from "../libs/TypeCasts.sol";
 import {ICrossDomainMessenger} from "../interfaces/optimism/ICrossDomainMessenger.sol";
+import {IL2toL2CrossDomainMessenger} from "../interfaces/optimism/IL2toL2CrossDomainMessenger.sol";
+import {ICrossL2Inbox} from "../interfaces/optimism/ICrossL2Inbox.sol";
 import {IOptimismPortal} from "../interfaces/optimism/IOptimismPortal.sol";
+import {Address} from "@openzeppelin/contracts/utils/Address.sol";
 
 // for both L1 and L2
 contract MockOptimismMessenger is ICrossDomainMessenger {
@@ -59,3 +62,73 @@ contract MockOptimismPortal is IOptimismPortal {
         CallLib.call(call);
     }
 }
+
+contract MockL2toL2CrossDomainMessenger is IL2toL2CrossDomainMessenger {
+    uint256 public messageNonce;
+    bool passMessages = true;
+    address originCaller;
+
+    function encodeCall(
+        address _originCaller,
+        address target,
+        bytes calldata call
+    ) public view returns (bytes memory) {
+        return abi.encode(_originCaller, target, call);
+    }
+
+    function sendMessage(
+        uint256 _destination,
+        address _target,
+        bytes calldata _message
+    ) external returns (bytes32 msgHash_) {}
+
+    /// @notice Relays a message that was sent by the other CrossDomainMessenger contract. Can only
+    ///         be executed via cross-chain call from the other messenger OR if the message was
+    ///         already received once and is currently being replayed.
+    /// @param _id          Identifier of the SentMessage event to be relayed
+    /// @param _sentMessage Message payload of the `SentMessage` event
+    function relayMessage(
+        ICrossL2Inbox.Identifier calldata _id,
+        bytes calldata _sentMessage
+    ) external payable {
+        require(
+            passMessages,
+            "MockL2toL2CrossDomainMessenger: passMessages is false"
+        );
+        (address _originCaller, address target, bytes memory call) = abi.decode(
+            _sentMessage,
+            (address, address, bytes)
+        );
+        originCaller = _originCaller;
+        Address.functionCall(target, call);
+    }
+
+    /// @notice Mapping of message hashes to boolean receipt values. Note that a message will only
+    ///         be present in this mapping if it has successfully been relayed on this chain, and
+    ///         can therefore not be relayed again.
+    /// @param _msgHash message hash to check.
+    /// @return Returns true if the message corresponding to the `_msgHash` was successfully relayed.
+    function successfulMessages(bytes32 _msgHash) external view returns (bool) {
+        return true;
+    }
+
+    /// @notice Retrieves the sender of the current cross domain message.
+    /// @return sender_ Address of the sender of the current cross domain message.
+    function crossDomainMessageSender()
+        external
+        view
+        returns (address sender_)
+    {
+        return originCaller;
+    }
+
+    /// @notice Retrieves the source of the current cross domain message.
+    /// @return source_ Chain ID of the source of the current cross domain message.
+    function crossDomainMessageSource()
+        external
+        view
+        returns (uint256 source_)
+    {
+        return 0;
+    }
+}