@hyperlane-xyz/core 3.8.0 → 3.8.2

package/contracts/hooks/layer-zero/LayerZeroV1Hook.sol

@@ -0,0 +1,118 @@
+// SPDX-License-Identifier: MIT
+pragma solidity >=0.8.0;
+
+/*@@@@@@@       @@@@@@@@@
+ @@@@@@@@@       @@@@@@@@@
+  @@@@@@@@@       @@@@@@@@@
+   @@@@@@@@@       @@@@@@@@@
+    @@@@@@@@@@@@@@@@@@@@@@@@@
+     @@@@@  HYPERLANE  @@@@@@@
+    @@@@@@@@@@@@@@@@@@@@@@@@@
+   @@@@@@@@@       @@@@@@@@@
+  @@@@@@@@@       @@@@@@@@@
+ @@@@@@@@@       @@@@@@@@@
+@@@@@@@@@       @@@@@@@@*/
+import {ILayerZeroEndpoint} from "@layerzerolabs/lz-evm-v1-0.7/contracts/interfaces/ILayerZeroEndpoint.sol";
+import {Message} from "../../libs/Message.sol";
+import {TypeCasts} from "../../libs/TypeCasts.sol";
+import {MailboxClient} from "../../client/MailboxClient.sol";
+import {Indexed} from "../../libs/Indexed.sol";
+import {IPostDispatchHook} from "../../interfaces/hooks/IPostDispatchHook.sol";
+import {AbstractPostDispatchHook} from "../libs/AbstractPostDispatchHook.sol";
+import {StandardHookMetadata} from "../libs/StandardHookMetadata.sol";
+
+struct LayerZeroMetadata {
+    /// @dev the destination chain identifier
+    uint16 dstChainId;
+    /// @dev the user app address on this EVM chain. Contract address that calls Endpoint.send(). Used for LZ user app config lookup
+    address userApplication;
+    /// @dev if the source transaction is cheaper than the amount of value passed, refund the additional amount to this address
+    address refundAddress;
+    /// @dev the custom message to send over LayerZero
+    bytes payload;
+    /// @dev the address on destination chain (in bytes). A 40 length byte with remote and local addresses concatenated.
+    bytes destination;
+    /// @dev  parameters for the adapter service, e.g. send some dust native token to dstChain
+    bytes adapterParam;
+}
+
+contract LayerZeroV1Hook is AbstractPostDispatchHook, MailboxClient {
+    using StandardHookMetadata for bytes;
+    using Message for bytes;
+    using TypeCasts for bytes32;
+
+    ILayerZeroEndpoint public immutable lZEndpoint;
+
+    constructor(address _mailbox, address _lZEndpoint) MailboxClient(_mailbox) {
+        lZEndpoint = ILayerZeroEndpoint(_lZEndpoint);
+    }
+
+    // ============ External Functions ============
+
+    /// @inheritdoc IPostDispatchHook
+    function hookType() external pure override returns (uint8) {
+        return uint8(IPostDispatchHook.Types.LAYER_ZERO_V1);
+    }
+
+    /// @inheritdoc AbstractPostDispatchHook
+    function _postDispatch(
+        bytes calldata metadata,
+        bytes calldata message
+    ) internal virtual override {
+        // ensure hook only dispatches messages that are dispatched by the mailbox
+        bytes32 id = message.id();
+        require(_isLatestDispatched(id), "message not dispatched by mailbox");
+
+        bytes calldata lZMetadata = metadata.getCustomMetadata();
+        LayerZeroMetadata memory layerZeroMetadata = parseLzMetadata(
+            lZMetadata
+        );
+        lZEndpoint.send{value: msg.value}(
+            layerZeroMetadata.dstChainId,
+            layerZeroMetadata.destination,
+            layerZeroMetadata.payload,
+            payable(layerZeroMetadata.refundAddress),
+            address(0), // _zroPaymentAddress is hardcoded to addr(0) because zro tokens should not be directly accepted
+            layerZeroMetadata.adapterParam
+        );
+    }
+
+    /// @inheritdoc AbstractPostDispatchHook
+    function _quoteDispatch(
+        bytes calldata metadata,
+        bytes calldata
+    ) internal view virtual override returns (uint256 nativeFee) {
+        bytes calldata lZMetadata = metadata.getCustomMetadata();
+        LayerZeroMetadata memory layerZeroMetadata = parseLzMetadata(
+            lZMetadata
+        );
+        (nativeFee, ) = lZEndpoint.estimateFees(
+            layerZeroMetadata.dstChainId,
+            layerZeroMetadata.userApplication,
+            layerZeroMetadata.payload,
+            false, // _payInZRO is hardcoded to false because zro tokens should not be directly accepted
+            layerZeroMetadata.adapterParam
+        );
+    }
+
+    /**
+     * @notice Formats LayerZero metadata using default abi encoding
+     * @param layerZeroMetadata LayerZero specific metadata
+     * @return ABI encoded metadata
+     */
+    function formatLzMetadata(
+        LayerZeroMetadata calldata layerZeroMetadata
+    ) public pure returns (bytes memory) {
+        return abi.encode(layerZeroMetadata);
+    }
+
+    /**
+     * @notice Decodes LayerZero metadata. Should be used after formatLzMetadata()
+     * @param lZMetadata ABI encoded metadata
+     */
+    function parseLzMetadata(
+        bytes calldata lZMetadata
+    ) public pure returns (LayerZeroMetadata memory parsedLayerZeroMetadata) {
+        (parsedLayerZeroMetadata) = abi.decode(lZMetadata, (LayerZeroMetadata));
+    }
+}

package/contracts/hooks/layer-zero/LayerZeroV2Hook.sol

@@ -0,0 +1,135 @@
+// SPDX-License-Identifier: MIT
+pragma solidity >=0.8.0;
+
+/*@@@@@@@       @@@@@@@@@
+ @@@@@@@@@       @@@@@@@@@
+  @@@@@@@@@       @@@@@@@@@
+   @@@@@@@@@       @@@@@@@@@
+    @@@@@@@@@@@@@@@@@@@@@@@@@
+     @@@@@  HYPERLANE  @@@@@@@
+    @@@@@@@@@@@@@@@@@@@@@@@@@
+   @@@@@@@@@       @@@@@@@@@
+  @@@@@@@@@       @@@@@@@@@
+ @@@@@@@@@       @@@@@@@@@
+@@@@@@@@@       @@@@@@@@*/
+import {MessagingParams, MessagingFee, ILayerZeroEndpointV2} from "@layerzerolabs/lz-evm-protocol-v2/contracts/interfaces/ILayerZeroEndpointV2.sol";
+import {Message} from "../../libs/Message.sol";
+import {TypeCasts} from "../../libs/TypeCasts.sol";
+import {Indexed} from "../../libs/Indexed.sol";
+import {IPostDispatchHook} from "../../interfaces/hooks/IPostDispatchHook.sol";
+import {AbstractMessageIdAuthHook} from "../libs/AbstractMessageIdAuthHook.sol";
+import {StandardHookMetadata} from "../libs/StandardHookMetadata.sol";
+
+struct LayerZeroV2Metadata {
+    /// @dev the endpoint Id. prev dstChainId
+    uint32 eid;
+    /// @dev if the source transaction is cheaper than the amount of value passed, refund the additional amount to this address
+    address refundAddress;
+    /// @dev  parameters for the adapter service, e.g. send some dust native token to dstChain. prev adapterParam
+    bytes options;
+}
+
+contract LayerZeroV2Hook is AbstractMessageIdAuthHook {
+    using StandardHookMetadata for bytes;
+    using Message for bytes;
+    using TypeCasts for bytes32;
+
+    ILayerZeroEndpointV2 public immutable lZEndpoint;
+
+    /// @dev offset for Layer Zero metadata parsing
+    uint8 constant EID_OFFSET = 0;
+    uint8 constant REFUND_ADDRESS_OFFSET = 4;
+    uint8 constant OPTIONS_OFFSET = 24;
+
+    constructor(
+        address _mailbox,
+        uint32 _destinationDomain,
+        bytes32 _ism,
+        address _lZEndpoint
+    ) AbstractMessageIdAuthHook(_mailbox, _destinationDomain, _ism) {
+        lZEndpoint = ILayerZeroEndpointV2(_lZEndpoint);
+    }
+
+    // ============ External Functions ============
+
+    /// @inheritdoc AbstractMessageIdAuthHook
+    function _sendMessageId(
+        bytes calldata metadata,
+        bytes memory payload
+    ) internal override {
+        bytes calldata lZMetadata = metadata.getCustomMetadata();
+        (
+            uint32 eid,
+            address refundAddress,
+            bytes memory options
+        ) = parseLzMetadata(lZMetadata);
+
+        // Build and send message
+        MessagingParams memory msgParams = MessagingParams(
+            eid,
+            ism,
+            payload,
+            options,
+            false // payInLzToken
+        );
+        lZEndpoint.send{value: msg.value}(msgParams, refundAddress);
+    }
+
+    /// @dev payInZRO is hardcoded to false because zro tokens should not be directly accepted
+    function _quoteDispatch(
+        bytes calldata metadata,
+        bytes calldata message
+    ) internal view virtual override returns (uint256) {
+        bytes calldata lZMetadata = metadata.getCustomMetadata();
+        (uint32 eid, , bytes memory options) = parseLzMetadata(lZMetadata);
+
+        // Build and quote message
+        MessagingParams memory msgParams = MessagingParams(
+            eid,
+            message.recipient(),
+            message.body(),
+            options,
+            false // payInLzToken
+        );
+        MessagingFee memory msgFee = lZEndpoint.quote(
+            msgParams,
+            message.senderAddress()
+        );
+
+        return msgFee.nativeFee;
+    }
+
+    /**
+     * @notice Formats LayerZero metadata using default abi encoding
+     * @param layerZeroMetadata LayerZero specific metadata
+     * @return ABI encoded metadata
+     */
+    function formatLzMetadata(
+        LayerZeroV2Metadata calldata layerZeroMetadata
+    ) public pure returns (bytes memory) {
+        return
+            abi.encodePacked(
+                layerZeroMetadata.eid,
+                layerZeroMetadata.refundAddress,
+                layerZeroMetadata.options
+            );
+    }
+
+    /**
+     * @notice Decodes LayerZero metadata. Should be used after formatLzMetadata()
+     * @param lZMetadata ABI encoded metadata
+     */
+    function parseLzMetadata(
+        bytes calldata lZMetadata
+    )
+        public
+        pure
+        returns (uint32 eid, address refundAddress, bytes memory options)
+    {
+        eid = uint32(bytes4(lZMetadata[EID_OFFSET:REFUND_ADDRESS_OFFSET]));
+        refundAddress = address(
+            bytes20(lZMetadata[REFUND_ADDRESS_OFFSET:OPTIONS_OFFSET])
+        );
+        options = lZMetadata[OPTIONS_OFFSET:];
+    }
+}

package/contracts/hooks/libs/AbstractMessageIdAuthHook.sol

@@ -78,6 +78,10 @@ abstract contract AbstractMessageIdAuthHook is
             message.destination() == destinationDomain,
             "AbstractMessageIdAuthHook: invalid destination domain"
         );
+        require(
+            metadata.msgValue(0) < 2 ** 255,
+            "AbstractMessageIdAuthHook: msgValue must be less than 2 ** 255"
+        );
         bytes memory payload = abi.encodeCall(
             AbstractMessageIdAuthorizedIsm.verifyMessageId,
             id

package/contracts/interfaces/hooks/IPostDispatchHook.sol

@@ -23,7 +23,8 @@ interface IPostDispatchHook {
         FALLBACK_ROUTING,
         ID_AUTH_ISM,
         PAUSABLE,
-        PROTOCOL_FEE
+        PROTOCOL_FEE,
+        LAYER_ZERO_V1
     }
 
     /**

package/contracts/isms/hook/AbstractMessageIdAuthorizedIsm.sol

@@ -99,7 +99,7 @@ abstract contract AbstractMessageIdAuthorizedIsm is
      * @dev Only callable by the authorized hook.
      * @param messageId Hyperlane Id of the message.
      */
-    function verifyMessageId(bytes32 messageId) external payable virtual {
+    function verifyMessageId(bytes32 messageId) public payable virtual {
         require(
             _isAuthorized(),
             "AbstractMessageIdAuthorizedIsm: sender is not the hook"

package/contracts/isms/hook/layer-zero/LayerZeroV2Ism.sol

@@ -0,0 +1,114 @@
+// SPDX-License-Identifier: MIT OR Apache-2.0
+pragma solidity >=0.8.0;
+
+/*@@@@@@@       @@@@@@@@@
+ @@@@@@@@@       @@@@@@@@@
+  @@@@@@@@@       @@@@@@@@@
+   @@@@@@@@@       @@@@@@@@@
+    @@@@@@@@@@@@@@@@@@@@@@@@@
+     @@@@@  HYPERLANE  @@@@@@@
+    @@@@@@@@@@@@@@@@@@@@@@@@@
+   @@@@@@@@@       @@@@@@@@@
+  @@@@@@@@@       @@@@@@@@@
+ @@@@@@@@@       @@@@@@@@@
+@@@@@@@@@       @@@@@@@@*/
+
+// ============ Internal Imports ============
+
+import {IInterchainSecurityModule} from "../../../interfaces/IInterchainSecurityModule.sol";
+import {Message} from "../../../libs/Message.sol";
+import {TypeCasts} from "../../../libs/TypeCasts.sol";
+import {AbstractMessageIdAuthorizedIsm} from "../AbstractMessageIdAuthorizedIsm.sol";
+
+// ============ External Imports ============
+import {Origin} from "@layerzerolabs/lz-evm-protocol-v2/contracts/interfaces/ILayerZeroEndpointV2.sol";
+
+/**
+ * @title LayerZeroV2Ism
+ * @notice Uses LayerZero V2 deliver and verify a messages Id
+ */
+contract LayerZeroV2Ism is AbstractMessageIdAuthorizedIsm {
+    using Message for bytes;
+    using TypeCasts for bytes32;
+
+    // Layerzero endpoint address
+    address public immutable endpoint;
+
+    // ============ Constants ============
+
+    uint8 public constant moduleType =
+        uint8(IInterchainSecurityModule.Types.NULL);
+
+    // @dev the offset of msg.data where the function parameters (as bytes) begins. 4 bytes is always used when encoding the function selector
+    uint8 constant FUNC_SELECTOR_OFFSET = 4;
+
+    // @dev the offset of msg.data where Origin.sender begins. 32 is always used since calldata comes in 32 bytes.
+    uint8 constant ORIGIN_SENDER_OFFSET = FUNC_SELECTOR_OFFSET + 32;
+
+    // ============ Constructor ============
+    constructor(address _endpoint) {
+        require(
+            _endpoint != address(0),
+            "LayerZeroV2Ism: invalid authorized endpoint"
+        );
+        endpoint = _endpoint;
+    }
+
+    /**
+     * @notice Entry point for receiving msg/packet from the LayerZero endpoint.
+     * @param _lzMessage The payload of the received message.
+     * @dev Authorization verifcation is done within verifyMessageId() -> _isAuthorized()
+     */
+    function lzReceive(
+        Origin calldata,
+        bytes32,
+        bytes calldata _lzMessage,
+        address,
+        bytes calldata
+    ) external payable {
+        verifyMessageId(_messageId(_lzMessage));
+    }
+
+    // ============ Internal function ============
+
+    /**
+     * @notice Slices the messageId from the message delivered from LayerZeroV2Hook
+     * @dev message is created as abi.encodeCall(AbstractMessageIdAuthorizedIsm.verifyMessageId, id)
+     * @dev _message will be 36 bytes (4 bytes for function selector, and 32 bytes for messageId)
+     */
+    function _messageId(
+        bytes calldata _message
+    ) internal pure returns (bytes32) {
+        return bytes32(_message[FUNC_SELECTOR_OFFSET:]);
+    }
+
+    /**
+     * @notice Validates criterias to verify a message
+     * @dev this is called by AbstractMessageIdAuthorizedIsm.verifyMessageId
+     * @dev parses msg.value to get parameters from lzReceive()
+     */
+    function _isAuthorized() internal view override returns (bool) {
+        require(_isAuthorizedHook(), "LayerZeroV2Ism: hook is not authorized");
+
+        require(
+            _isAuthorizedEndPoint(),
+            "LayerZeroV2Ism: endpoint is not authorized"
+        );
+
+        return true;
+    }
+
+    /**
+     * @notice check if origin.sender is the authorized hook
+     */
+    function _isAuthorizedHook() internal view returns (bool) {
+        return bytes32(msg.data[ORIGIN_SENDER_OFFSET:]) == authorizedHook;
+    }
+
+    /**
+     * @notice check if LayerZero endpoint is authorized
+     */
+    function _isAuthorizedEndPoint() internal view returns (bool) {
+        return msg.sender == endpoint;
+    }
+}

package/contracts/test/ERC20Test.sol

@@ -19,4 +19,12 @@ contract ERC20Test is ERC20 {
     function decimals() public view override returns (uint8) {
         return _decimals;
     }
+
+    function mint(uint256 amount) public {
+        _mint(msg.sender, amount);
+    }
+
+    function mintTo(address account, uint256 amount) public {
+        _mint(account, amount);
+    }
 }

package/contracts/test/ERC4626/ERC4626Test.sol

@@ -0,0 +1,13 @@
+// SPDX-License-Identifier: Apache-2.0
+pragma solidity >=0.8.0;
+import "@openzeppelin/contracts/token/ERC20/extensions/ERC4626.sol";
+import "@openzeppelin/contracts/token/ERC20/ERC20.sol";
+import "@openzeppelin/contracts/interfaces/IERC20.sol";
+
+contract ERC4626Test is ERC4626 {
+    constructor(
+        address _asset,
+        string memory _name,
+        string memory _symbol
+    ) ERC4626(IERC20(_asset)) ERC20(_name, _symbol) {}
+}

package/contracts/test/TestLayerZeroTreasury.sol

@@ -0,0 +1,15 @@
+// SPDX-License-Identifier: UNLICENSED
+
+pragma solidity ^0.8.0;
+
+import {Ownable} from "@openzeppelin/contracts/access/Ownable.sol";
+
+contract LayerZeroTreasuryMock is Ownable {
+    function withdraw() external onlyOwner {
+        //withdraw
+    }
+
+    function withdrawAlt() external onlyOwner {
+        //withdraw token
+    }
+}

package/contracts/token/HypERC20Collateral.sol

@@ -37,7 +37,7 @@ contract HypERC20Collateral is TokenRouter {
      */
     function _transferFromSender(
         uint256 _amount
-    ) internal override returns (bytes memory) {
+    ) internal virtual override returns (bytes memory) {
         wrappedToken.safeTransferFrom(msg.sender, address(this), _amount);
         return bytes(""); // no metadata
     }

package/contracts/token/HypERC20CollateralVaultDeposit.sol

@@ -0,0 +1,82 @@
+// SPDX-License-Identifier: Apache-2.0
+pragma solidity >=0.8.0;
+import "@openzeppelin/contracts/token/ERC20/extensions/ERC4626.sol";
+import {HypERC20Collateral} from "./HypERC20Collateral.sol";
+
+/**
+ * @title Hyperlane ERC20 Token Collateral with deposits collateral to a vault
+ * @author ltyu
+ */
+contract HypERC20CollateralVaultDeposit is HypERC20Collateral {
+    // Address of the ERC4626 compatible vault
+    ERC4626 public immutable vault;
+
+    // Internal balance of total asset deposited
+    uint256 public assetDeposited;
+
+    event ExcessSharesSwept(uint256 amount, uint256 assetsRedeemed);
+
+    constructor(
+        ERC4626 _vault,
+        address _mailbox
+    ) HypERC20Collateral(_vault.asset(), _mailbox) {
+        vault = _vault;
+        wrappedToken.approve(address(vault), type(uint256).max);
+    }
+
+    /**
+     * @dev Transfers `_amount` of `wrappedToken` from `msg.sender` to this contract, and deposit into vault
+     * @inheritdoc HypERC20Collateral
+     */
+    function _transferFromSender(
+        uint256 _amount
+    ) internal override returns (bytes memory metadata) {
+        metadata = super._transferFromSender(_amount);
+        _depositIntoVault(_amount);
+    }
+
+    /**
+     * @dev Deposits into the vault and increment assetDeposited
+     * @param _amount amount to deposit into vault
+     */
+    function _depositIntoVault(uint256 _amount) internal {
+        assetDeposited += _amount;
+        vault.deposit(_amount, address(this));
+    }
+
+    /**
+     * @dev Transfers `_amount` of `wrappedToken` from this contract to `_recipient`, and withdraws from vault
+     * @inheritdoc HypERC20Collateral
+     */
+    function _transferTo(
+        address _recipient,
+        uint256 _amount,
+        bytes calldata
+    ) internal virtual override {
+        _withdrawFromVault(_amount, _recipient);
+    }
+
+    /**
+     * @dev Withdraws from the vault and decrement assetDeposited
+     * @param _amount amount to withdraw from vault
+     * @param _recipient address to deposit withdrawn underlying to
+     */
+    function _withdrawFromVault(uint256 _amount, address _recipient) internal {
+        assetDeposited -= _amount;
+        vault.withdraw(_amount, _recipient, address(this));
+    }
+
+    /**
+     * @notice Allows the owner to redeem excess shares
+     */
+    function sweep() external onlyOwner {
+        uint256 excessShares = vault.maxRedeem(address(this)) -
+            vault.convertToShares(assetDeposited);
+        uint256 assetsRedeemed = vault.redeem(
+            excessShares,
+            owner(),
+            address(this)
+        );
+        emit ExcessSharesSwept(excessShares, assetsRedeemed);
+    }
+}

package/dist/@layerzerolabs/index.d.ts

@@ -0,0 +1,5 @@
+import type * as lzEvmProtocolV2 from "./lz-evm-protocol-v2";
+export type { lzEvmProtocolV2 };
+import type * as lzEvmV107 from "./lz-evm-v1-0.7";
+export type { lzEvmV107 };
+//# sourceMappingURL=index.d.ts.map

package/dist/@layerzerolabs/index.d.ts.map

@@ -0,0 +1 @@
+{"version":3,"file":"index.d.ts","sourceRoot":"","sources":["../../types/@layerzerolabs/index.ts"],"names":[],"mappings":"AAGA,OAAO,KAAK,KAAK,eAAe,MAAM,sBAAsB,CAAC;AAC7D,YAAY,EAAE,eAAe,EAAE,CAAC;AAChC,OAAO,KAAK,KAAK,SAAS,MAAM,iBAAiB,CAAC;AAClD,YAAY,EAAE,SAAS,EAAE,CAAC"}

package/dist/@layerzerolabs/index.js

@@ -0,0 +1,3 @@
+"use strict";
+Object.defineProperty(exports, "__esModule", { value: true });
+//# sourceMappingURL=index.js.map

package/dist/@layerzerolabs/index.js.map

@@ -0,0 +1 @@
+{"version":3,"file":"index.js","sourceRoot":"","sources":["../../types/@layerzerolabs/index.ts"],"names":[],"mappings":""}

package/dist/@layerzerolabs/lz-evm-protocol-v2/contracts/index.d.ts

@@ -0,0 +1,3 @@
+import type * as interfaces from "./interfaces";
+export type { interfaces };
+//# sourceMappingURL=index.d.ts.map

package/dist/@layerzerolabs/lz-evm-protocol-v2/contracts/index.d.ts.map

@@ -0,0 +1 @@
+{"version":3,"file":"index.d.ts","sourceRoot":"","sources":["../../../../types/@layerzerolabs/lz-evm-protocol-v2/contracts/index.ts"],"names":[],"mappings":"AAGA,OAAO,KAAK,KAAK,UAAU,MAAM,cAAc,CAAC;AAChD,YAAY,EAAE,UAAU,EAAE,CAAC"}

package/dist/@layerzerolabs/lz-evm-protocol-v2/contracts/index.js

@@ -0,0 +1,3 @@
+"use strict";
+Object.defineProperty(exports, "__esModule", { value: true });
+//# sourceMappingURL=index.js.map

package/dist/@layerzerolabs/lz-evm-protocol-v2/contracts/index.js.map

@@ -0,0 +1 @@
+{"version":3,"file":"index.js","sourceRoot":"","sources":["../../../../types/@layerzerolabs/lz-evm-protocol-v2/contracts/index.ts"],"names":[],"mappings":""}