@hyperlane-xyz/core 3.11.0 → 3.12.0

package/contracts/avs/HyperlaneServiceManager.sol

@@ -0,0 +1,297 @@
+// SPDX-License-Identifier: MIT OR Apache-2.0
+pragma solidity >=0.8.0;
+
+/*@@@@@@@       @@@@@@@@@
+ @@@@@@@@@       @@@@@@@@@
+  @@@@@@@@@       @@@@@@@@@
+   @@@@@@@@@       @@@@@@@@@
+    @@@@@@@@@@@@@@@@@@@@@@@@@
+     @@@@@  HYPERLANE  @@@@@@@
+    @@@@@@@@@@@@@@@@@@@@@@@@@
+   @@@@@@@@@       @@@@@@@@@
+  @@@@@@@@@       @@@@@@@@@
+ @@@@@@@@@       @@@@@@@@@
+@@@@@@@@@       @@@@@@@@*/
+
+// ============ Internal Imports ============
+import {Enrollment, EnrollmentStatus, EnumerableMapEnrollment} from "../libs/EnumerableMapEnrollment.sol";
+import {IAVSDirectory} from "../interfaces/avs/vendored/IAVSDirectory.sol";
+import {IRemoteChallenger} from "../interfaces/avs/IRemoteChallenger.sol";
+import {ISlasher} from "../interfaces/avs/vendored/ISlasher.sol";
+import {ECDSAServiceManagerBase} from "./ECDSAServiceManagerBase.sol";
+
+contract HyperlaneServiceManager is ECDSAServiceManagerBase {
+    // ============ Libraries ============
+
+    using EnumerableMapEnrollment for EnumerableMapEnrollment.AddressToEnrollmentMap;
+
+    // ============ Public Storage ============
+
+    // Slasher contract responsible for slashing operators
+    // @dev slasher needs to be updated once slashing is implemented
+    ISlasher internal slasher;
+
+    // ============ Events ============
+
+    /**
+     * @notice Emitted when an operator is enrolled in a challenger
+     * @param operator The address of the operator
+     * @param challenger The address of the challenger
+     */
+    event OperatorEnrolledToChallenger(
+        address operator,
+        IRemoteChallenger challenger
+    );
+
+    /**
+     * @notice Emitted when an operator is queued for unenrollment from a challenger
+     * @param operator The address of the operator
+     * @param challenger The address of the challenger
+     * @param unenrollmentStartBlock The block number at which the unenrollment was queued
+     * @param challengeDelayBlocks The number of blocks to wait before unenrollment is complete
+     */
+    event OperatorQueuedUnenrollmentFromChallenger(
+        address operator,
+        IRemoteChallenger challenger,
+        uint256 unenrollmentStartBlock,
+        uint256 challengeDelayBlocks
+    );
+
+    /**
+     * @notice Emitted when an operator is unenrolled from a challenger
+     * @param operator The address of the operator
+     * @param challenger The address of the challenger
+     * @param unenrollmentEndBlock The block number at which the unenrollment was completed
+     */
+    event OperatorUnenrolledFromChallenger(
+        address operator,
+        IRemoteChallenger challenger,
+        uint256 unenrollmentEndBlock
+    );
+
+    // ============ Internal Storage ============
+
+    // Mapping of operators to challengers they are enrolled in (enumerable required for remove-all)
+    mapping(address => EnumerableMapEnrollment.AddressToEnrollmentMap)
+        internal enrolledChallengers;
+
+    // ============ Modifiers ============
+
+    // Only allows the challenger the operator is enrolled in to call the function
+    modifier onlyEnrolledChallenger(address operator) {
+        (bool exists, ) = enrolledChallengers[operator].tryGet(msg.sender);
+        require(
+            exists,
+            "HyperlaneServiceManager: Operator not enrolled in challenger"
+        );
+        _;
+    }
+
+    // ============ Constructor ============
+
+    constructor(
+        address _avsDirectory,
+        address _stakeRegistry,
+        address _paymentCoordinator,
+        address _delegationManager
+    )
+        ECDSAServiceManagerBase(
+            _avsDirectory,
+            _stakeRegistry,
+            _paymentCoordinator,
+            _delegationManager
+        )
+    {}
+
+    /**
+     * @notice Initializes the HyperlaneServiceManager contract with the owner address
+     */
+    function initialize(address _owner) public initializer {
+        __ServiceManagerBase_init(_owner);
+    }
+
+    // ============ External Functions ============
+
+    /**
+     * @notice Enrolls as an operator into a list of challengers
+     * @param _challengers The list of challengers to enroll into
+     */
+    function enrollIntoChallengers(
+        IRemoteChallenger[] memory _challengers
+    ) external {
+        for (uint256 i = 0; i < _challengers.length; i++) {
+            enrollIntoChallenger(_challengers[i]);
+        }
+    }
+
+    /**
+     * @notice starts an operator for unenrollment from a list of challengers
+     * @param _challengers The list of challengers to unenroll from
+     */
+    function startUnenrollment(
+        IRemoteChallenger[] memory _challengers
+    ) external {
+        for (uint256 i = 0; i < _challengers.length; i++) {
+            startUnenrollment(_challengers[i]);
+        }
+    }
+
+    /**
+     * @notice Completes the unenrollment of an operator from a list of challengers
+     * @param _challengers The list of challengers to unenroll from
+     */
+    function completeUnenrollment(address[] memory _challengers) external {
+        _completeUnenrollment(msg.sender, _challengers);
+    }
+
+    /**
+     * @notice Sets the slasher contract responsible for slashing operators
+     * @param _slasher The address of the slasher contract
+     */
+    function setSlasher(ISlasher _slasher) external onlyOwner {
+        slasher = _slasher;
+    }
+
+    /**
+     * @notice returns the status of a challenger an operator is enrolled in
+     * @param _operator The address of the operator
+     * @param _challenger specified IRemoteChallenger contract
+     */
+    function getChallengerEnrollment(
+        address _operator,
+        IRemoteChallenger _challenger
+    ) external view returns (Enrollment memory enrollment) {
+        return enrolledChallengers[_operator].get(address(_challenger));
+    }
+
+    /**
+     * @notice forwards a call to the Slasher contract to freeze an operator
+     * @param operator The address of the operator to freeze.
+     * @dev only the enrolled challengers can call this function
+     */
+    function freezeOperator(
+        address operator
+    ) external virtual onlyEnrolledChallenger(operator) {
+        slasher.freezeOperator(operator);
+    }
+
+    // ============ Public Functions ============
+
+    /**
+     * @notice returns the list of challengers an operator is enrolled in
+     * @param _operator The address of the operator
+     */
+    function getOperatorChallengers(
+        address _operator
+    ) public view returns (address[] memory) {
+        return enrolledChallengers[_operator].keys();
+    }
+
+    /**
+     * @notice Enrolls as an operator into a single challenger
+     * @param challenger The challenger to enroll into
+     */
+    function enrollIntoChallenger(IRemoteChallenger challenger) public {
+        require(
+            enrolledChallengers[msg.sender].set(
+                address(challenger),
+                Enrollment(EnrollmentStatus.ENROLLED, 0)
+            )
+        );
+        emit OperatorEnrolledToChallenger(msg.sender, challenger);
+    }
+
+    /**
+     * @notice starts an operator for unenrollment from a challenger
+     * @param challenger The challenger to unenroll from
+     */
+    function startUnenrollment(IRemoteChallenger challenger) public {
+        (bool exists, Enrollment memory enrollment) = enrolledChallengers[
+            msg.sender
+        ].tryGet(address(challenger));
+        require(
+            exists && enrollment.status == EnrollmentStatus.ENROLLED,
+            "HyperlaneServiceManager: challenger isn't enrolled"
+        );
+
+        enrolledChallengers[msg.sender].set(
+            address(challenger),
+            Enrollment(
+                EnrollmentStatus.PENDING_UNENROLLMENT,
+                uint248(block.number)
+            )
+        );
+        emit OperatorQueuedUnenrollmentFromChallenger(
+            msg.sender,
+            challenger,
+            block.number,
+            challenger.challengeDelayBlocks()
+        );
+    }
+
+    /**
+     * @notice Completes the unenrollment of an operator from a challenger
+     * @param challenger The challenger to unenroll from
+     */
+    function completeUnenrollment(address challenger) public {
+        _completeUnenrollment(msg.sender, challenger);
+    }
+
+    // ============ Internal Functions ============
+
+    /**
+     * @notice Completes the unenrollment of an operator from a list of challengers
+     * @param operator The address of the operator
+     * @param _challengers The list of challengers to unenroll from
+     */
+    function _completeUnenrollment(
+        address operator,
+        address[] memory _challengers
+    ) internal {
+        for (uint256 i = 0; i < _challengers.length; i++) {
+            _completeUnenrollment(operator, _challengers[i]);
+        }
+    }
+
+    /**
+     * @notice Completes the unenrollment of an operator from a challenger
+     * @param operator The address of the operator
+     * @param _challenger The challenger to unenroll from
+     */
+    function _completeUnenrollment(
+        address operator,
+        address _challenger
+    ) internal {
+        IRemoteChallenger challenger = IRemoteChallenger(_challenger);
+        (bool exists, Enrollment memory enrollment) = enrolledChallengers[
+            operator
+        ].tryGet(address(challenger));
+
+        require(
+            exists &&
+                enrollment.status == EnrollmentStatus.PENDING_UNENROLLMENT &&
+                block.number >=
+                enrollment.unenrollmentStartBlock +
+                    challenger.challengeDelayBlocks(),
+            "HyperlaneServiceManager: Invalid unenrollment"
+        );
+
+        enrolledChallengers[operator].remove(address(challenger));
+        emit OperatorUnenrolledFromChallenger(
+            operator,
+            challenger,
+            block.number
+        );
+    }
+
+    /// @inheritdoc ECDSAServiceManagerBase
+    function _deregisterOperatorFromAVS(
+        address operator
+    ) internal virtual override {
+        address[] memory challengers = getOperatorChallengers(operator);
+        _completeUnenrollment(operator, challengers);
+
+        IAVSDirectory(avsDirectory).deregisterOperatorFromAVS(operator);
+        emit OperatorDeregisteredFromAVS(operator);
+    }
+}

package/contracts/hooks/PolygonPosHook.sol

@@ -0,0 +1,83 @@
+// SPDX-License-Identifier: MIT OR Apache-2.0
+pragma solidity >=0.8.0;
+
+/*@@@@@@@       @@@@@@@@@
+ @@@@@@@@@       @@@@@@@@@
+  @@@@@@@@@       @@@@@@@@@
+   @@@@@@@@@       @@@@@@@@@
+    @@@@@@@@@@@@@@@@@@@@@@@@@
+     @@@@@  HYPERLANE  @@@@@@@
+    @@@@@@@@@@@@@@@@@@@@@@@@@
+   @@@@@@@@@       @@@@@@@@@
+  @@@@@@@@@       @@@@@@@@@
+ @@@@@@@@@       @@@@@@@@@
+@@@@@@@@@       @@@@@@@@*/
+
+// ============ Internal Imports ============
+import {AbstractMessageIdAuthHook} from "./libs/AbstractMessageIdAuthHook.sol";
+import {StandardHookMetadata} from "./libs/StandardHookMetadata.sol";
+import {TypeCasts} from "../libs/TypeCasts.sol";
+import {Message} from "../libs/Message.sol";
+import {IPostDispatchHook} from "../interfaces/hooks/IPostDispatchHook.sol";
+
+// ============ External Imports ============
+import {FxBaseRootTunnel} from "fx-portal/contracts/tunnel/FxBaseRootTunnel.sol";
+import {Address} from "@openzeppelin/contracts/utils/Address.sol";
+
+/**
+ * @title PolygonPosHook
+ * @notice Message hook to inform the PolygonPosIsm of messages published through
+ * the native PoS bridge.
+ */
+contract PolygonPosHook is AbstractMessageIdAuthHook, FxBaseRootTunnel {
+    using StandardHookMetadata for bytes;
+
+    // ============ Constructor ============
+
+    constructor(
+        address _mailbox,
+        uint32 _destinationDomain,
+        bytes32 _ism,
+        address _cpManager,
+        address _fxRoot
+    )
+        AbstractMessageIdAuthHook(_mailbox, _destinationDomain, _ism)
+        FxBaseRootTunnel(_cpManager, _fxRoot)
+    {
+        require(
+            Address.isContract(_cpManager),
+            "PolygonPosHook: invalid cpManager contract"
+        );
+        require(
+            Address.isContract(_fxRoot),
+            "PolygonPosHook: invalid fxRoot contract"
+        );
+    }
+
+    // ============ Internal functions ============
+    function _quoteDispatch(
+        bytes calldata,
+        bytes calldata
+    ) internal pure override returns (uint256) {
+        return 0;
+    }
+
+    /// @inheritdoc AbstractMessageIdAuthHook
+    function _sendMessageId(
+        bytes calldata metadata,
+        bytes memory payload
+    ) internal override {
+        require(
+            metadata.msgValue(0) == 0,
+            "PolygonPosHook: does not support msgValue"
+        );
+        require(msg.value == 0, "PolygonPosHook: does not support msgValue");
+        _sendMessageToChild(payload);
+    }
+
+    bytes public latestData;
+
+    function _processMessageFromChild(bytes memory data) internal override {
+        latestData = data;
+    }
+}

package/contracts/interfaces/avs/IRemoteChallenger.sol

@@ -0,0 +1,24 @@
+// SPDX-License-Identifier: MIT OR Apache-2.0
+pragma solidity >=0.8.0;
+
+/*@@@@@@@       @@@@@@@@@
+ @@@@@@@@@       @@@@@@@@@
+  @@@@@@@@@       @@@@@@@@@
+   @@@@@@@@@       @@@@@@@@@
+    @@@@@@@@@@@@@@@@@@@@@@@@@
+     @@@@@  HYPERLANE  @@@@@@@
+    @@@@@@@@@@@@@@@@@@@@@@@@@
+   @@@@@@@@@       @@@@@@@@@
+  @@@@@@@@@       @@@@@@@@@
+ @@@@@@@@@       @@@@@@@@@
+@@@@@@@@@       @@@@@@@@*/
+
+interface IRemoteChallenger {
+    /// @notice Returns the number of blocks that must be mined before a challenge can be handled
+    /// @return The number of blocks that must be mined before a challenge can be handled
+    function challengeDelayBlocks() external view returns (uint256);
+
+    /// @notice Handles a challenge for an operator
+    /// @param operator The address of the operator
+    function handleChallenge(address operator) external;
+}

package/contracts/interfaces/avs/vendored/IAVSDirectory.sol

@@ -0,0 +1,24 @@
+// SPDX-License-Identifier: BUSL-1.1
+pragma solidity >=0.8.0;
+
+import "./ISignatureUtils.sol";
+
+/// part of mock interfaces for vendoring necessary Eigenlayer contracts for the hyperlane AVS
+/// @author Layr Labs, Inc.
+interface IAVSDirectory is ISignatureUtils {
+    enum OperatorAVSRegistrationStatus {
+        UNREGISTERED,
+        REGISTERED
+    }
+
+    event AVSMetadataURIUpdated(address indexed avs, string metadataURI);
+
+    function registerOperatorToAVS(
+        address operator,
+        ISignatureUtils.SignatureWithSaltAndExpiry memory operatorSignature
+    ) external;
+
+    function deregisterOperatorFromAVS(address operator) external;
+
+    function updateAVSMetadataURI(string calldata metadataURI) external;
+}

package/contracts/interfaces/avs/vendored/IDelegationManager.sol

@@ -0,0 +1,32 @@
+// SPDX-License-Identifier: BUSL-1.1
+pragma solidity >=0.8.0;
+
+import {IStrategy} from "./IStrategy.sol";
+
+/**
+ * @title DelegationManager
+ * @author Layr Labs, Inc.
+ * @notice Terms of Service: https://docs.eigenlayer.xyz/overview/terms-of-service
+ * @notice  This is the contract for delegation in EigenLayer. The main functionalities of this contract are
+ * - enabling anyone to register as an operator in EigenLayer
+ * - allowing operators to specify parameters related to stakers who delegate to them
+ * - enabling any staker to delegate its stake to the operator of its choice (a given staker can only delegate to a single operator at a time)
+ * - enabling a staker to undelegate its assets from the operator it is delegated to (performed as part of the withdrawal process, initiated through the StrategyManager)
+ */
+interface IDelegationManager {
+    struct OperatorDetails {
+        address earningsReceiver;
+        address delegationApprover;
+        uint32 stakerOptOutWindowBlocks;
+    }
+
+    function registerAsOperator(
+        OperatorDetails calldata registeringOperatorDetails,
+        string calldata metadataURI
+    ) external;
+
+    function getOperatorShares(
+        address operator,
+        IStrategy[] memory strategies
+    ) external view returns (uint256[] memory);
+}

package/contracts/interfaces/avs/vendored/IECDSAStakeRegistryEventsAndErrors.sol

@@ -0,0 +1,99 @@
+// SPDX-License-Identifier: MIT
+pragma solidity ^0.8.12;
+
+import {IStrategy} from "./IStrategy.sol";
+
+struct StrategyParams {
+    IStrategy strategy; // The strategy contract reference
+    uint96 multiplier; // The multiplier applied to the strategy
+}
+
+struct Quorum {
+    StrategyParams[] strategies; // An array of strategy parameters to define the quorum
+}
+
+/// part of mock interfaces for vendoring necessary Eigenlayer contracts for the hyperlane AVS
+/// @author Layr Labs, Inc.
+interface IECDSAStakeRegistryEventsAndErrors {
+    /// @notice Emitted when the system registers an operator
+    /// @param _operator The address of the registered operator
+    /// @param _avs The address of the associated AVS
+    event OperatorRegistered(address indexed _operator, address indexed _avs);
+
+    /// @notice Emitted when the system deregisters an operator
+    /// @param _operator The address of the deregistered operator
+    /// @param _avs The address of the associated AVS
+    event OperatorDeregistered(address indexed _operator, address indexed _avs);
+
+    /// @notice Emitted when the system updates the quorum
+    /// @param _old The previous quorum configuration
+    /// @param _new The new quorum configuration
+    event QuorumUpdated(Quorum _old, Quorum _new);
+
+    /// @notice Emitted when the weight to join the operator set updates
+    /// @param _old The previous minimum weight
+    /// @param _new The new minimumWeight
+    event MinimumWeightUpdated(uint256 _old, uint256 _new);
+
+    /// @notice Emitted when the weight required to be an operator changes
+    /// @param oldMinimumWeight The previous weight
+    /// @param newMinimumWeight The updated weight
+    event UpdateMinimumWeight(
+        uint256 oldMinimumWeight,
+        uint256 newMinimumWeight
+    );
+
+    /// @notice Emitted when the system updates an operator's weight
+    /// @param _operator The address of the operator updated
+    /// @param oldWeight The operator's weight before the update
+    /// @param newWeight The operator's weight after the update
+    event OperatorWeightUpdated(
+        address indexed _operator,
+        uint256 oldWeight,
+        uint256 newWeight
+    );
+
+    /// @notice Emitted when the system updates the total weight
+    /// @param oldTotalWeight The total weight before the update
+    /// @param newTotalWeight The total weight after the update
+    event TotalWeightUpdated(uint256 oldTotalWeight, uint256 newTotalWeight);
+
+    /// @notice Emits when setting a new threshold weight.
+    event ThresholdWeightUpdated(uint256 _thresholdWeight);
+
+    /// @notice Indicates when the lengths of the signers array and signatures array do not match.
+    error LengthMismatch();
+
+    /// @notice Indicates encountering an invalid length for the signers or signatures array.
+    error InvalidLength();
+
+    /// @notice Indicates encountering an invalid signature.
+    error InvalidSignature();
+
+    /// @notice Thrown when the threshold update is greater than BPS
+    error InvalidThreshold();
+
+    /// @notice Thrown when missing operators in an update
+    error MustUpdateAllOperators();
+
+    /// @notice Indicates operator weights were out of sync and the signed weight exceed the total
+    error InvalidSignedWeight();
+
+    /// @notice Indicates the total signed stake fails to meet the required threshold.
+    error InsufficientSignedStake();
+
+    /// @notice Indicates an individual signer's weight fails to meet the required threshold.
+    error InsufficientWeight();
+
+    /// @notice Indicates the quorum is invalid
+    error InvalidQuorum();
+
+    /// @notice Indicates the system finds a list of items unsorted
+    error NotSorted();
+
+    /// @notice Thrown when registering an already registered operator
+    error OperatorAlreadyRegistered();
+
+    /// @notice Thrown when de-registering or updating the stake for an unregistered operator
+    error OperatorNotRegistered();
+}

package/contracts/interfaces/avs/vendored/IPaymentCoordinator.sol

@@ -0,0 +1,46 @@
+// SPDX-License-Identifier: BUSL-1.1
+pragma solidity >=0.8.0;
+
+import {IERC20} from "@openzeppelin/contracts/token/ERC20/IERC20.sol";
+import "./IStrategy.sol";
+
+/**
+ * @title Interface for the `IPaymentCoordinator` contract.
+ * @author Layr Labs, Inc.
+ * @notice Terms of Service: https://docs.eigenlayer.xyz/overview/terms-of-service
+ * @notice Allows AVSs to make "Range Payments", which get distributed amongst the AVSs' confirmed
+ * Operators and the Stakers delegated to those Operators.
+ * Calculations are performed based on the completed Range Payments, with the results posted in
+ * a Merkle root against which Stakers & Operators can make claims.
+ */
+interface IPaymentCoordinator {
+    /// STRUCTS ///
+    struct StrategyAndMultiplier {
+        IStrategy strategy;
+        // weight used to compare shares in multiple strategies against one another
+        uint96 multiplier;
+    }
+
+    struct RangePayment {
+        // Strategies & relative weights of shares in the strategies
+        StrategyAndMultiplier[] strategiesAndMultipliers;
+        IERC20 token;
+        uint256 amount;
+        uint64 startTimestamp;
+        uint64 duration;
+    }
+
+    /// EXTERNAL FUNCTIONS ///
+
+    /**
+     * @notice Creates a new range payment on behalf of an AVS, to be split amongst the
+     * set of stakers delegated to operators who are registered to the `avs`
+     * @param rangePayments The range payments being created
+     * @dev Expected to be called by the ServiceManager of the AVS on behalf of which the payment is being made
+     * @dev The duration of the `rangePayment` cannot exceed `MAX_PAYMENT_DURATION`
+     * @dev The tokens are sent to the `claimingManager` contract
+     * @dev This function will revert if the `rangePayment` is malformed,
+     * e.g. if the `strategies` and `weights` arrays are of non-equal lengths
+     */
+    function payForRange(RangePayment[] calldata rangePayments) external;
+}

package/contracts/interfaces/avs/vendored/IServiceManager.sol

@@ -0,0 +1,28 @@
+// SPDX-License-Identifier: BUSL-1.1
+pragma solidity >=0.8.0;
+
+import {IPaymentCoordinator} from "./IPaymentCoordinator.sol";
+import {IServiceManagerUI} from "./IServiceManagerUI.sol";
+
+/**
+ * @title Minimal interface for a ServiceManager-type contract that forms the single point for an AVS to push updates to EigenLayer
+ * @author Layr Labs, Inc.
+ */
+interface IServiceManager is IServiceManagerUI {
+    /**
+     * @notice Creates a new range payment on behalf of an AVS, to be split amongst the
+     * set of stakers delegated to operators who are registered to the `avs`.
+     * Note that the owner calling this function must have approved the tokens to be transferred to the ServiceManager
+     * and of course has the required balances.
+     * @param rangePayments The range payments being created
+     * @dev Expected to be called by the ServiceManager of the AVS on behalf of which the payment is being made
+     * @dev The duration of the `rangePayment` cannot exceed `paymentCoordinator.MAX_PAYMENT_DURATION()`
+     * @dev The tokens are sent to the `PaymentCoordinator` contract
+     * @dev Strategies must be in ascending order of addresses to check for duplicates
+     * @dev This function will revert if the `rangePayment` is malformed,
+     * e.g. if the `strategies` and `weights` arrays are of non-equal lengths
+     */
+    function payForRange(
+        IPaymentCoordinator.RangePayment[] calldata rangePayments
+    ) external;
+}