@hyperlane-xyz/core 1.5.8 → 3.0.0-beta0

package/contracts/client/MailboxClient.sol

@@ -0,0 +1,140 @@
+// SPDX-License-Identifier: MIT OR Apache-2.0
+pragma solidity >=0.6.11;
+
+// ============ Internal Imports ============
+import {IMailbox} from "../interfaces/IMailbox.sol";
+import {IPostDispatchHook} from "../interfaces/hooks/IPostDispatchHook.sol";
+import {IInterchainSecurityModule} from "../interfaces/IInterchainSecurityModule.sol";
+import {Message} from "../libs/Message.sol";
+
+// ============ External Imports ============
+import {Address} from "@openzeppelin/contracts/utils/Address.sol";
+import {OwnableUpgradeable} from "@openzeppelin/contracts-upgradeable/access/OwnableUpgradeable.sol";
+
+abstract contract MailboxClient is OwnableUpgradeable {
+    using Message for bytes;
+
+    IMailbox public immutable mailbox;
+
+    uint32 public immutable localDomain;
+
+    IPostDispatchHook public hook;
+
+    IInterchainSecurityModule public interchainSecurityModule;
+
+    // ============ Modifiers ============
+    modifier onlyContract(address _contract) {
+        require(
+            Address.isContract(_contract),
+            "MailboxClient: invalid mailbox"
+        );
+        _;
+    }
+
+    modifier onlyContractOrNull(address _contract) {
+        require(
+            Address.isContract(_contract) || _contract == address(0),
+            "MailboxClient: invalid contract setting"
+        );
+        _;
+    }
+
+    /**
+     * @notice Only accept messages from an Hyperlane Mailbox contract
+     */
+    modifier onlyMailbox() {
+        require(
+            msg.sender == address(mailbox),
+            "MailboxClient: sender not mailbox"
+        );
+        _;
+    }
+
+    constructor(address _mailbox) onlyContract(_mailbox) {
+        mailbox = IMailbox(_mailbox);
+        localDomain = mailbox.localDomain();
+        _transferOwnership(msg.sender);
+    }
+
+    /**
+     * @notice Sets the address of the application's custom hook.
+     * @param _hook The address of the hook contract.
+     */
+    function setHook(address _hook) public onlyContractOrNull(_hook) onlyOwner {
+        hook = IPostDispatchHook(_hook);
+    }
+
+    /**
+     * @notice Sets the address of the application's custom interchain security module.
+     * @param _module The address of the interchain security module contract.
+     */
+    function setInterchainSecurityModule(address _module)
+        public
+        onlyContractOrNull(_module)
+        onlyOwner
+    {
+        interchainSecurityModule = IInterchainSecurityModule(_module);
+    }
+
+    // ======== Initializer =========
+    function _MailboxClient_initialize(
+        address _hook,
+        address _interchainSecurityModule,
+        address _owner
+    ) internal onlyInitializing {
+        __Ownable_init();
+        setHook(_hook);
+        setInterchainSecurityModule(_interchainSecurityModule);
+        _transferOwnership(_owner);
+    }
+
+    function _isLatestDispatched(bytes32 id) internal view returns (bool) {
+        return mailbox.latestDispatchedId() == id;
+    }
+
+    function _metadata(
+        uint32 /*_destinationDomain*/
+    ) internal view virtual returns (bytes memory) {
+        return "";
+    }
+
+    function _dispatch(
+        uint32 _destinationDomain,
+        bytes32 _recipient,
+        bytes memory _messageBody
+    ) internal virtual returns (bytes32) {
+        return
+            _dispatch(_destinationDomain, _recipient, msg.value, _messageBody);
+    }
+
+    function _dispatch(
+        uint32 _destinationDomain,
+        bytes32 _recipient,
+        uint256 _value,
+        bytes memory _messageBody
+    ) internal virtual returns (bytes32) {
+        return
+            mailbox.dispatch{value: _value}(
+                _destinationDomain,
+                _recipient,
+                _messageBody,
+                _metadata(_destinationDomain),
+                hook
+            );
+    }
+
+    function _quoteDispatch(
+        uint32 _destinationDomain,
+        bytes32 _recipient,
+        bytes memory _messageBody
+    ) internal view virtual returns (uint256) {
+        return
+            mailbox.quoteDispatch(
+                _destinationDomain,
+                _recipient,
+                _messageBody,
+                _metadata(_destinationDomain),
+                hook
+            );
+    }
+}

package/contracts/client/Router.sol

@@ -0,0 +1,204 @@
+// SPDX-License-Identifier: MIT OR Apache-2.0
+pragma solidity >=0.6.11;
+
+// ============ Internal Imports ============
+import {IMessageRecipient} from "../interfaces/IMessageRecipient.sol";
+import {IPostDispatchHook} from "../interfaces/hooks/IPostDispatchHook.sol";
+import {IInterchainSecurityModule} from "../interfaces/IInterchainSecurityModule.sol";
+import {MailboxClient} from "./MailboxClient.sol";
+import {EnumerableMapExtended} from "../libs/EnumerableMapExtended.sol";
+import {StandardHookMetadata} from "../hooks/libs/StandardHookMetadata.sol";
+
+// ============ External Imports ============
+import {Strings} from "@openzeppelin/contracts/utils/Strings.sol";
+
+abstract contract Router is MailboxClient, IMessageRecipient {
+    using EnumerableMapExtended for EnumerableMapExtended.UintToBytes32Map;
+    using Strings for uint32;
+
+    // ============ Mutable Storage ============
+    EnumerableMapExtended.UintToBytes32Map internal _routers;
+
+    uint256[48] private __GAP; // gap for upgrade safety
+
+    constructor(address _mailbox) MailboxClient(_mailbox) {}
+
+    // ============ External functions ============
+    function domains() external view returns (uint32[] memory) {
+        return _routers.uint32Keys();
+    }
+
+    /**
+     * @notice Returns the address of the Router contract for the given domain
+     * @param _domain The remote domain ID.
+     * @dev Returns 0 address if no router is enrolled for the given domain
+     * @return router The address of the Router contract for the given domain
+     */
+    function routers(uint32 _domain) public view virtual returns (bytes32) {
+        (, bytes32 _router) = _routers.tryGet(_domain);
+        return _router;
+    }
+
+    /**
+     * @notice Unregister the domain
+     * @param _domain The domain of the remote Application Router
+     */
+    function unenrollRemoteRouter(uint32 _domain) external virtual onlyOwner {
+        _unenrollRemoteRouter(_domain);
+    }
+
+    /**
+     * @notice Register the address of a Router contract for the same Application on a remote chain
+     * @param _domain The domain of the remote Application Router
+     * @param _router The address of the remote Application Router
+     */
+    function enrollRemoteRouter(uint32 _domain, bytes32 _router)
+        external
+        virtual
+        onlyOwner
+    {
+        _enrollRemoteRouter(_domain, _router);
+    }
+
+    /**
+     * @notice Batch version of `enrollRemoteRouter`
+     * @param _domains The domains of the remote Application Routers
+     * @param _addresses The addresses of the remote Application Routers
+     */
+    function enrollRemoteRouters(
+        uint32[] calldata _domains,
+        bytes32[] calldata _addresses
+    ) external virtual onlyOwner {
+        require(_domains.length == _addresses.length, "!length");
+        uint256 length = _domains.length;
+        for (uint256 i = 0; i < length; i += 1) {
+            _enrollRemoteRouter(_domains[i], _addresses[i]);
+        }
+    }
+
+    /**
+     * @notice Batch version of `unenrollRemoteRouter`
+     * @param _domains The domains of the remote Application Routers
+     */
+    function unenrollRemoteRouters(uint32[] calldata _domains)
+        external
+        virtual
+        onlyOwner
+    {
+        uint256 length = _domains.length;
+        for (uint256 i = 0; i < length; i += 1) {
+            _unenrollRemoteRouter(_domains[i]);
+        }
+    }
+
+    /**
+     * @notice Handles an incoming message
+     * @param _origin The origin domain
+     * @param _sender The sender address
+     * @param _message The message
+     */
+    function handle(
+        uint32 _origin,
+        bytes32 _sender,
+        bytes calldata _message
+    ) external payable virtual override onlyMailbox {
+        bytes32 _router = _mustHaveRemoteRouter(_origin);
+        require(_router == _sender, "Enrolled router does not match sender");
+        _handle(_origin, _sender, _message);
+    }
+
+    // ============ Virtual functions ============
+    function _handle(
+        uint32 _origin,
+        bytes32 _sender,
+        bytes calldata _message
+    ) internal virtual;
+
+    // ============ Internal functions ============
+
+    /**
+     * @notice Set the router for a given domain
+     * @param _domain The domain
+     * @param _address The new router
+     */
+    function _enrollRemoteRouter(uint32 _domain, bytes32 _address)
+        internal
+        virtual
+    {
+        _routers.set(_domain, _address);
+    }
+
+    /**
+     * @notice Remove the router for a given domain
+     * @param _domain The domain
+     */
+    function _unenrollRemoteRouter(uint32 _domain) internal virtual {
+        require(_routers.remove(_domain), _domainNotFoundError(_domain));
+    }
+
+    /**
+     * @notice Return true if the given domain / router is the address of a remote Application Router
+     * @param _domain The domain of the potential remote Application Router
+     * @param _address The address of the potential remote Application Router
+     */
+    function _isRemoteRouter(uint32 _domain, bytes32 _address)
+        internal
+        view
+        returns (bool)
+    {
+        return routers(_domain) == _address;
+    }
+
+    /**
+     * @notice Assert that the given domain has a Application Router registered and return its address
+     * @param _domain The domain of the chain for which to get the Application Router
+     * @return _router The address of the remote Application Router on _domain
+     */
+    function _mustHaveRemoteRouter(uint32 _domain)
+        internal
+        view
+        returns (bytes32)
+    {
+        (bool contained, bytes32 _router) = _routers.tryGet(_domain);
+        require(contained, _domainNotFoundError(_domain));
+        return _router;
+    }
+
+    function _domainNotFoundError(uint32 _domain)
+        internal
+        pure
+        returns (string memory)
+    {
+        return
+            string.concat(
+                "No router enrolled for domain: ",
+                _domain.toString()
+            );
+    }
+
+    function _dispatch(uint32 _destinationDomain, bytes memory _messageBody)
+        internal
+        virtual
+        returns (bytes32)
+    {
+        return _dispatch(_destinationDomain, msg.value, _messageBody);
+    }
+
+    function _dispatch(
+        uint32 _destinationDomain,
+        uint256 _value,
+        bytes memory _messageBody
+    ) internal virtual returns (bytes32) {
+        bytes32 _router = _mustHaveRemoteRouter(_destinationDomain);
+        return
+            super._dispatch(_destinationDomain, _router, _value, _messageBody);
+    }
+
+    function _quoteDispatch(
+        uint32 _destinationDomain,
+        bytes memory _messageBody
+    ) internal view virtual returns (uint256) {
+        bytes32 _router = _mustHaveRemoteRouter(_destinationDomain);
+        return super._quoteDispatch(_destinationDomain, _router, _messageBody);
+    }
+}

package/contracts/hooks/MerkleTreeHook.sol

@@ -0,0 +1,87 @@
+// SPDX-License-Identifier: MIT
+pragma solidity >=0.8.0;
+
+/*@@@@@@@       @@@@@@@@@
+ @@@@@@@@@       @@@@@@@@@
+  @@@@@@@@@       @@@@@@@@@
+   @@@@@@@@@       @@@@@@@@@
+    @@@@@@@@@@@@@@@@@@@@@@@@@
+     @@@@@  HYPERLANE  @@@@@@@
+    @@@@@@@@@@@@@@@@@@@@@@@@@
+   @@@@@@@@@       @@@@@@@@@
+  @@@@@@@@@       @@@@@@@@@
+ @@@@@@@@@       @@@@@@@@@
+@@@@@@@@@       @@@@@@@@*/
+
+import {MerkleLib} from "../libs/Merkle.sol";
+import {Message} from "../libs/Message.sol";
+import {MailboxClient} from "../client/MailboxClient.sol";
+import {Indexed} from "../libs/Indexed.sol";
+import {IPostDispatchHook} from "../interfaces/hooks/IPostDispatchHook.sol";
+import {AbstractPostDispatchHook} from "./libs/AbstractPostDispatchHook.sol";
+import {StandardHookMetadata} from "./libs/StandardHookMetadata.sol";
+
+contract MerkleTreeHook is AbstractPostDispatchHook, MailboxClient, Indexed {
+    using Message for bytes;
+    using MerkleLib for MerkleLib.Tree;
+    using StandardHookMetadata for bytes;
+
+    // An incremental merkle tree used to store outbound message IDs.
+    MerkleLib.Tree internal _tree;
+
+    event InsertedIntoTree(bytes32 messageId, uint32 index);
+
+    constructor(address _mailbox) MailboxClient(_mailbox) {}
+
+    // count cannot exceed 2**TREE_DEPTH, see MerkleLib.sol
+    function count() public view returns (uint32) {
+        return uint32(_tree.count);
+    }
+
+    function root() public view returns (bytes32) {
+        return _tree.root();
+    }
+
+    function tree() public view returns (MerkleLib.Tree memory) {
+        return _tree;
+    }
+
+    function latestCheckpoint() external view returns (bytes32, uint32) {
+        return (root(), count() - 1);
+    }
+
+    // ============ External Functions ============
+
+    /// @inheritdoc IPostDispatchHook
+    function hookType() external pure override returns (uint8) {
+        return uint8(IPostDispatchHook.Types.MERKLE_TREE);
+    }
+
+    // ============ Internal Functions ============
+
+    /// @inheritdoc AbstractPostDispatchHook
+    function _postDispatch(
+        bytes calldata,
+        /*metadata*/
+        bytes calldata message
+    ) internal override {
+        require(msg.value == 0, "MerkleTreeHook: no value expected");
+
+        // ensure messages which were not dispatched are not inserted into the tree
+        bytes32 id = message.id();
+        require(_isLatestDispatched(id), "message not dispatching");
+
+        uint32 index = count();
+        _tree.insert(id);
+        emit InsertedIntoTree(id, index);
+    }
+
+    /// @inheritdoc AbstractPostDispatchHook
+    function _quoteDispatch(
+        bytes calldata,
+        /*metadata*/
+        bytes calldata /*message*/
+    ) internal pure override returns (uint256) {
+        return 0;
+    }
+}

package/contracts/hooks/OPStackHook.sol

@@ -0,0 +1,86 @@
+// SPDX-License-Identifier: MIT OR Apache-2.0
+pragma solidity >=0.8.0;
+
+/*@@@@@@@       @@@@@@@@@
+ @@@@@@@@@       @@@@@@@@@
+  @@@@@@@@@       @@@@@@@@@
+   @@@@@@@@@       @@@@@@@@@
+    @@@@@@@@@@@@@@@@@@@@@@@@@
+     @@@@@  HYPERLANE  @@@@@@@
+    @@@@@@@@@@@@@@@@@@@@@@@@@
+   @@@@@@@@@       @@@@@@@@@
+  @@@@@@@@@       @@@@@@@@@
+ @@@@@@@@@       @@@@@@@@@
+@@@@@@@@@       @@@@@@@@*/
+
+// ============ Internal Imports ============
+import {AbstractMessageIdAuthHook} from "./libs/AbstractMessageIdAuthHook.sol";
+import {StandardHookMetadata} from "./libs/StandardHookMetadata.sol";
+import {TypeCasts} from "../libs/TypeCasts.sol";
+import {Message} from "../libs/Message.sol";
+import {IPostDispatchHook} from "../interfaces/hooks/IPostDispatchHook.sol";
+
+// ============ External Imports ============
+import {ICrossDomainMessenger} from "../interfaces/optimism/ICrossDomainMessenger.sol";
+import {Address} from "@openzeppelin/contracts/utils/Address.sol";
+
+/**
+ * @title OPStackHook
+ * @notice Message hook to inform the OPStackIsm of messages published through
+ * the native OPStack bridge.
+ * @notice This works only for L1 -> L2 messages.
+ */
+contract OPStackHook is AbstractMessageIdAuthHook {
+    using StandardHookMetadata for bytes;
+
+    // ============ Constants ============
+
+    /// @notice messenger contract specified by the rollup
+    ICrossDomainMessenger public immutable l1Messenger;
+
+    // Gas limit for sending messages to L2
+    // First 1.92e6 gas is provided by Optimism, see more here:
+    // https://community.optimism.io/docs/developers/bridge/messaging/#for-l1-%E2%87%92-l2-transactions
+    uint32 internal constant GAS_LIMIT = 1_920_000;
+
+    // ============ Constructor ============
+
+    constructor(
+        address _mailbox,
+        uint32 _destinationDomain,
+        bytes32 _ism,
+        address _l1Messenger
+    ) AbstractMessageIdAuthHook(_mailbox, _destinationDomain, _ism) {
+        require(
+            Address.isContract(_l1Messenger),
+            "OPStackHook: invalid messenger"
+        );
+        l1Messenger = ICrossDomainMessenger(_l1Messenger);
+    }
+
+    // ============ Internal functions ============
+    function _quoteDispatch(bytes calldata, bytes calldata)
+        internal
+        pure
+        override
+        returns (uint256)
+    {
+        return 0; // gas subsidized by the L2
+    }
+
+    /// @inheritdoc AbstractMessageIdAuthHook
+    function _sendMessageId(bytes calldata metadata, bytes memory payload)
+        internal
+        override
+    {
+        require(
+            metadata.msgValue(0) < 2**255,
+            "OPStackHook: msgValue must be less than 2 ** 255"
+        );
+        l1Messenger.sendMessage{value: metadata.msgValue(0)}(
+            TypeCasts.bytes32ToAddress(ism),
+            payload,
+            GAS_LIMIT
+        );
+    }
+}

package/contracts/hooks/PausableHook.sol

@@ -0,0 +1,61 @@
+// SPDX-License-Identifier: MIT
+pragma solidity >=0.8.0;
+
+/*@@@@@@@       @@@@@@@@@
+ @@@@@@@@@       @@@@@@@@@
+  @@@@@@@@@       @@@@@@@@@
+   @@@@@@@@@       @@@@@@@@@
+    @@@@@@@@@@@@@@@@@@@@@@@@@
+     @@@@@  HYPERLANE  @@@@@@@
+    @@@@@@@@@@@@@@@@@@@@@@@@@
+   @@@@@@@@@       @@@@@@@@@
+  @@@@@@@@@       @@@@@@@@@
+ @@@@@@@@@       @@@@@@@@@
+@@@@@@@@@       @@@@@@@@*/
+
+import {StandardHookMetadata} from "../hooks/libs/StandardHookMetadata.sol";
+import {IPostDispatchHook} from "../interfaces/hooks/IPostDispatchHook.sol";
+import {AbstractPostDispatchHook} from "./libs/AbstractPostDispatchHook.sol";
+
+import {Ownable} from "@openzeppelin/contracts/access/Ownable.sol";
+import {Pausable} from "@openzeppelin/contracts/security/Pausable.sol";
+
+contract PausableHook is AbstractPostDispatchHook, Ownable, Pausable {
+    using StandardHookMetadata for bytes;
+
+    // ============ External functions ============
+
+    function pause() external onlyOwner {
+        _pause();
+    }
+
+    function unpause() external onlyOwner {
+        _unpause();
+    }
+
+    // ============ External Functions ============
+
+    /// @inheritdoc IPostDispatchHook
+    function hookType() external pure override returns (uint8) {
+        return uint8(IPostDispatchHook.Types.PAUSABLE);
+    }
+
+    // ============ Internal functions ============
+
+    /// @inheritdoc AbstractPostDispatchHook
+    function _postDispatch(bytes calldata metadata, bytes calldata message)
+        internal
+        override
+        whenNotPaused
+    {}
+
+    /// @inheritdoc AbstractPostDispatchHook
+    function _quoteDispatch(bytes calldata, bytes calldata)
+        internal
+        pure
+        override
+        returns (uint256)
+    {
+        return 0;
+    }
+}