@hyperlane-xyz/core 1.5.4-beta0 → 1.5.5-beta0

package/contracts/hooks/aggregation/ERC5164Hook.sol

@@ -0,0 +1,63 @@
+// SPDX-License-Identifier: MIT OR Apache-2.0
+pragma solidity >=0.8.0;
+
+/*@@@@@@@       @@@@@@@@@
+ @@@@@@@@@       @@@@@@@@@
+  @@@@@@@@@       @@@@@@@@@
+   @@@@@@@@@       @@@@@@@@@
+    @@@@@@@@@@@@@@@@@@@@@@@@@
+     @@@@@  HYPERLANE  @@@@@@@
+    @@@@@@@@@@@@@@@@@@@@@@@@@
+   @@@@@@@@@       @@@@@@@@@
+  @@@@@@@@@       @@@@@@@@@
+ @@@@@@@@@       @@@@@@@@@
+@@@@@@@@@       @@@@@@@@*/
+
+// ============ Internal Imports ============
+import {TypeCasts} from "../../libs/TypeCasts.sol";
+import {IPostDispatchHook} from "../../interfaces/hooks/IPostDispatchHook.sol";
+import {IMessageDispatcher} from "../../interfaces/hooks/IMessageDispatcher.sol";
+import {AbstractMessageIdAuthHook} from "../libs/AbstractMessageIdAuthHook.sol";
+
+// ============ External Imports ============
+import {Address} from "@openzeppelin/contracts/utils/Address.sol";
+
+/**
+ * @title 5164MessageHook
+ * @notice Message hook to inform the 5164 ISM of messages published through
+ * any of the 5164 adapters.
+ */
+contract ERC5164Hook is AbstractMessageIdAuthHook {
+    IMessageDispatcher public immutable dispatcher;
+
+    constructor(
+        address _mailbox,
+        uint32 _destinationDomain,
+        address _ism,
+        address _dispatcher
+    ) AbstractMessageIdAuthHook(_mailbox, _destinationDomain, _ism) {
+        require(
+            Address.isContract(_dispatcher),
+            "ERC5164Hook: invalid dispatcher"
+        );
+        dispatcher = IMessageDispatcher(_dispatcher);
+    }
+
+    function _quoteDispatch(bytes calldata, bytes calldata)
+        internal
+        pure
+        override
+        returns (uint256)
+    {
+        revert("not implemented");
+    }
+
+    function _sendMessageId(
+        bytes calldata,
+        /* metadata */
+        bytes memory payload
+    ) internal override {
+        require(msg.value == 0, "ERC5164Hook: no value allowed");
+        dispatcher.dispatchMessage(destinationDomain, ism, payload);
+    }
+}

package/contracts/hooks/aggregation/StaticAggregationHook.sol

@@ -0,0 +1,68 @@
+// SPDX-License-Identifier: MIT OR Apache-2.0
+pragma solidity >=0.8.0;
+
+/*@@@@@@@       @@@@@@@@@
+ @@@@@@@@@       @@@@@@@@@
+  @@@@@@@@@       @@@@@@@@@
+   @@@@@@@@@       @@@@@@@@@
+    @@@@@@@@@@@@@@@@@@@@@@@@@
+     @@@@@  HYPERLANE  @@@@@@@
+    @@@@@@@@@@@@@@@@@@@@@@@@@
+   @@@@@@@@@       @@@@@@@@@
+  @@@@@@@@@       @@@@@@@@@
+ @@@@@@@@@       @@@@@@@@@
+@@@@@@@@@       @@@@@@@@*/
+
+import {StandardHookMetadata} from "../libs/StandardHookMetadata.sol";
+import {AbstractPostDispatchHook} from "../libs/AbstractPostDispatchHook.sol";
+import {IPostDispatchHook} from "../../interfaces/hooks/IPostDispatchHook.sol";
+import {MetaProxy} from "../../libs/MetaProxy.sol";
+
+contract StaticAggregationHook is AbstractPostDispatchHook {
+    using StandardHookMetadata for bytes;
+
+    // ============ External functions ============
+
+    /// @inheritdoc AbstractPostDispatchHook
+    function _postDispatch(bytes calldata metadata, bytes calldata message)
+        internal
+        override
+    {
+        address[] memory _hooks = hooks(message);
+        uint256 count = _hooks.length;
+        for (uint256 i = 0; i < count; i++) {
+            uint256 quote = IPostDispatchHook(_hooks[i]).quoteDispatch(
+                metadata,
+                message
+            );
+
+            IPostDispatchHook(_hooks[i]).postDispatch{value: quote}(
+                metadata,
+                message
+            );
+        }
+    }
+
+    /// @inheritdoc AbstractPostDispatchHook
+    function _quoteDispatch(bytes calldata metadata, bytes calldata message)
+        internal
+        view
+        override
+        returns (uint256)
+    {
+        address[] memory _hooks = hooks(message);
+        uint256 count = _hooks.length;
+        uint256 total = 0;
+        for (uint256 i = 0; i < count; i++) {
+            total += IPostDispatchHook(_hooks[i]).quoteDispatch(
+                metadata,
+                message
+            );
+        }
+        return total;
+    }
+
+    function hooks(bytes calldata) public pure returns (address[] memory) {
+        return abi.decode(MetaProxy.metadata(), (address[]));
+    }
+}

package/contracts/hooks/aggregation/StaticAggregationHookFactory.sol

@@ -0,0 +1,29 @@
+// SPDX-License-Identifier: MIT OR Apache-2.0
+pragma solidity >=0.8.0;
+
+/*@@@@@@@       @@@@@@@@@
+ @@@@@@@@@       @@@@@@@@@
+  @@@@@@@@@       @@@@@@@@@
+   @@@@@@@@@       @@@@@@@@@
+    @@@@@@@@@@@@@@@@@@@@@@@@@
+     @@@@@  HYPERLANE  @@@@@@@
+    @@@@@@@@@@@@@@@@@@@@@@@@@
+   @@@@@@@@@       @@@@@@@@@
+  @@@@@@@@@       @@@@@@@@@
+ @@@@@@@@@       @@@@@@@@@
+@@@@@@@@@       @@@@@@@@*/
+
+// ============ Internal Imports ============
+import {StaticAggregationHook} from "./StaticAggregationHook.sol";
+import {StaticAddressSetFactory} from "../../libs/StaticAddressSetFactory.sol";
+
+contract StaticAggregationHookFactory is StaticAddressSetFactory {
+    function _deployImplementation()
+        internal
+        virtual
+        override
+        returns (address)
+    {
+        return address(new StaticAggregationHook());
+    }
+}

package/contracts/hooks/igp/InterchainGasPaymaster.sol

@@ -0,0 +1,323 @@
+// SPDX-License-Identifier: MIT OR Apache-2.0
+pragma solidity >=0.8.0;
+
+/*@@@@@@@       @@@@@@@@@
+ @@@@@@@@@       @@@@@@@@@
+  @@@@@@@@@       @@@@@@@@@
+   @@@@@@@@@       @@@@@@@@@
+    @@@@@@@@@@@@@@@@@@@@@@@@@
+     @@@@@  HYPERLANE  @@@@@@@
+    @@@@@@@@@@@@@@@@@@@@@@@@@
+   @@@@@@@@@       @@@@@@@@@
+  @@@@@@@@@       @@@@@@@@@
+ @@@@@@@@@       @@@@@@@@@
+@@@@@@@@@       @@@@@@@@*/
+
+// ============ Internal Imports ============
+import {Message} from "../../libs/Message.sol";
+import {StandardHookMetadata} from "../libs/StandardHookMetadata.sol";
+import {IGasOracle} from "../../interfaces/IGasOracle.sol";
+import {IInterchainGasPaymaster} from "../../interfaces/IInterchainGasPaymaster.sol";
+import {IPostDispatchHook} from "../../interfaces/hooks/IPostDispatchHook.sol";
+import {AbstractPostDispatchHook} from "../libs/AbstractPostDispatchHook.sol";
+import {Indexed} from "../../libs/Indexed.sol";
+
+// ============ External Imports ============
+import {Strings} from "@openzeppelin/contracts/utils/Strings.sol";
+import {Address} from "@openzeppelin/contracts/utils/Address.sol";
+import {OwnableUpgradeable} from "@openzeppelin/contracts-upgradeable/access/OwnableUpgradeable.sol";
+
+/**
+ * @title InterchainGasPaymaster
+ * @notice Manages payments on a source chain to cover gas costs of relaying
+ * messages to destination chains and includes the gas overhead per destination
+ * @dev The intended use of this contract is to store overhead gas amounts for destination
+ * domains, e.g. Mailbox and ISM gas usage, such that users of this IGP are only required
+ * to specify the gas amount used by their own applications.
+ */
+contract InterchainGasPaymaster is
+    IInterchainGasPaymaster,
+    AbstractPostDispatchHook,
+    IGasOracle,
+    Indexed,
+    OwnableUpgradeable
+{
+    using Address for address payable;
+    using Message for bytes;
+    using StandardHookMetadata for bytes;
+    // ============ Constants ============
+
+    /// @notice The scale of gas oracle token exchange rates.
+    uint256 internal constant TOKEN_EXCHANGE_RATE_SCALE = 1e10;
+    /// @notice default for user call if metadata not provided
+    uint256 internal immutable DEFAULT_GAS_USAGE = 50_000;
+
+    // ============ Public Storage ============
+
+    /// @notice Destination domain => gas oracle and overhead gas amount.
+    mapping(uint32 => DomainGasConfig) public destinationGasConfigs;
+
+    /// @notice The benficiary that can receive native tokens paid into this contract.
+    address public beneficiary;
+
+    // ============ Events ============
+
+    /**
+     * @notice Emitted when the gas oracle for a remote domain is set.
+     * @param remoteDomain The remote domain.
+     * @param gasOracle The gas oracle.
+     * @param gasOverhead The destination gas overhead.
+     */
+    event DestinationGasConfigSet(
+        uint32 remoteDomain,
+        address gasOracle,
+        uint96 gasOverhead
+    );
+
+    /**
+     * @notice Emitted when the beneficiary is set.
+     * @param beneficiary The new beneficiary.
+     */
+    event BeneficiarySet(address beneficiary);
+
+    struct DomainGasConfig {
+        IGasOracle gasOracle;
+        uint96 gasOverhead;
+    }
+
+    struct GasParam {
+        uint32 remoteDomain;
+        DomainGasConfig config;
+    }
+
+    // ============ External Functions ============
+
+    /**
+     * @param _owner The owner of the contract.
+     * @param _beneficiary The beneficiary.
+     */
+    function initialize(address _owner, address _beneficiary)
+        public
+        initializer
+    {
+        __Ownable_init();
+        _transferOwnership(_owner);
+        _setBeneficiary(_beneficiary);
+    }
+
+    /**
+     * @notice Transfers the entire native token balance to the beneficiary.
+     * @dev The beneficiary must be able to receive native tokens.
+     */
+    function claim() external {
+        // Transfer the entire balance to the beneficiary.
+        (bool success, ) = beneficiary.call{value: address(this).balance}("");
+        require(success, "IGP: claim failed");
+    }
+
+    /**
+     * @notice Sets the gas oracles for remote domains specified in the config array.
+     * @param _configs An array of configs including the remote domain and gas oracles to set.
+     */
+    function setDestinationGasConfigs(GasParam[] calldata _configs)
+        external
+        onlyOwner
+    {
+        uint256 _len = _configs.length;
+        for (uint256 i = 0; i < _len; i++) {
+            _setDestinationGasConfig(
+                _configs[i].remoteDomain,
+                _configs[i].config.gasOracle,
+                _configs[i].config.gasOverhead
+            );
+        }
+    }
+
+    /**
+     * @notice Sets the beneficiary.
+     * @param _beneficiary The new beneficiary.
+     */
+    function setBeneficiary(address _beneficiary) external onlyOwner {
+        _setBeneficiary(_beneficiary);
+    }
+
+    // ============ Public Functions ============
+
+    /**
+     * @notice Deposits msg.value as a payment for the relaying of a message
+     * to its destination chain.
+     * @dev Overpayment will result in a refund of native tokens to the _refundAddress.
+     * Callers should be aware that this may present reentrancy issues.
+     * @param _messageId The ID of the message to pay for.
+     * @param _destinationDomain The domain of the message's destination chain.
+     * @param _gasLimit The amount of destination gas to pay for.
+     * @param _refundAddress The address to refund any overpayment to.
+     */
+    function payForGas(
+        bytes32 _messageId,
+        uint32 _destinationDomain,
+        uint256 _gasLimit,
+        address _refundAddress
+    ) public payable override {
+        uint256 _requiredPayment = quoteGasPayment(
+            _destinationDomain,
+            _gasLimit
+        );
+        require(
+            msg.value >= _requiredPayment,
+            "IGP: insufficient interchain gas payment"
+        );
+        uint256 _overpayment = msg.value - _requiredPayment;
+        if (_overpayment > 0) {
+            require(_refundAddress != address(0), "no refund address");
+            payable(_refundAddress).sendValue(_overpayment);
+        }
+
+        emit GasPayment(
+            _messageId,
+            _destinationDomain,
+            _gasLimit,
+            _requiredPayment
+        );
+    }
+
+    /**
+     * @notice Quotes the amount of native tokens to pay for interchain gas.
+     * @param _destinationDomain The domain of the message's destination chain.
+     * @param _gasLimit The amount of destination gas to pay for.
+     * @return The amount of native tokens required to pay for interchain gas.
+     */
+    function quoteGasPayment(uint32 _destinationDomain, uint256 _gasLimit)
+        public
+        view
+        virtual
+        override
+        returns (uint256)
+    {
+        // Get the gas data for the destination domain.
+        (
+            uint128 _tokenExchangeRate,
+            uint128 _gasPrice
+        ) = getExchangeRateAndGasPrice(_destinationDomain);
+
+        // The total cost quoted in destination chain's native token.
+        uint256 _destinationGasCost = _gasLimit * uint256(_gasPrice);
+
+        // Convert to the local native token.
+        return
+            (_destinationGasCost * _tokenExchangeRate) /
+            TOKEN_EXCHANGE_RATE_SCALE;
+    }
+
+    /**
+     * @notice Gets the token exchange rate and gas price from the configured gas oracle
+     * for a given destination domain.
+     * @param _destinationDomain The destination domain.
+     * @return tokenExchangeRate The exchange rate of the remote native token quoted in the local native token.
+     * @return gasPrice The gas price on the remote chain.
+     */
+    function getExchangeRateAndGasPrice(uint32 _destinationDomain)
+        public
+        view
+        override
+        returns (uint128 tokenExchangeRate, uint128 gasPrice)
+    {
+        IGasOracle _gasOracle = destinationGasConfigs[_destinationDomain]
+            .gasOracle;
+
+        require(
+            address(_gasOracle) != address(0),
+            string.concat(
+                "Configured IGP doesn't support domain ",
+                Strings.toString(_destinationDomain)
+            )
+        );
+
+        return _gasOracle.getExchangeRateAndGasPrice(_destinationDomain);
+    }
+
+    /**
+     * @notice Returns the stored destinationGasOverhead added to the _gasLimit.
+     * @dev If there is no stored destinationGasOverhead, 0 is used. This is useful in the case
+     *      the ISM deployer wants to subsidize the overhead gas cost. Then, can specify the gas oracle
+     *      they want to use with the destination domain, but set the overhead to 0.
+     * @param _destinationDomain The domain of the message's destination chain.
+     * @param _gasLimit The amount of destination gas to pay for. This is only for application gas usage as
+     *      the gas usage for the mailbox and the ISM is already accounted in the DomainGasConfig.gasOverhead
+     */
+    function destinationGasLimit(uint32 _destinationDomain, uint256 _gasLimit)
+        public
+        view
+        returns (uint256)
+    {
+        return
+            uint256(destinationGasConfigs[_destinationDomain].gasOverhead) +
+            _gasLimit;
+    }
+
+    // ============ Internal Functions ============
+
+    /// @inheritdoc AbstractPostDispatchHook
+    function _postDispatch(bytes calldata metadata, bytes calldata message)
+        internal
+        override
+    {
+        payForGas(
+            message.id(),
+            message.destination(),
+            destinationGasLimit(
+                message.destination(),
+                metadata.gasLimit(DEFAULT_GAS_USAGE)
+            ),
+            metadata.refundAddress(message.senderAddress())
+        );
+    }
+
+    /// @inheritdoc AbstractPostDispatchHook
+    function _quoteDispatch(bytes calldata metadata, bytes calldata message)
+        internal
+        view
+        override
+        returns (uint256)
+    {
+        return
+            quoteGasPayment(
+                message.destination(),
+                destinationGasLimit(
+                    message.destination(),
+                    metadata.gasLimit(DEFAULT_GAS_USAGE)
+                )
+            );
+    }
+
+    /**
+     * @notice Sets the beneficiary.
+     * @param _beneficiary The new beneficiary.
+     */
+    function _setBeneficiary(address _beneficiary) internal {
+        beneficiary = _beneficiary;
+        emit BeneficiarySet(_beneficiary);
+    }
+
+    /**
+     * @notice Sets the gas oracle and destination gas overhead for a remote domain.
+     * @param _remoteDomain The remote domain.
+     * @param _gasOracle The gas oracle.
+     * @param _gasOverhead The destination gas overhead.
+     */
+    function _setDestinationGasConfig(
+        uint32 _remoteDomain,
+        IGasOracle _gasOracle,
+        uint96 _gasOverhead
+    ) internal {
+        destinationGasConfigs[_remoteDomain] = DomainGasConfig(
+            _gasOracle,
+            _gasOverhead
+        );
+        emit DestinationGasConfigSet(
+            _remoteDomain,
+            address(_gasOracle),
+            _gasOverhead
+        );
+    }
+}

package/contracts/hooks/igp/StorageGasOracle.sol

@@ -0,0 +1,105 @@
+// SPDX-License-Identifier: MIT OR Apache-2.0
+pragma solidity >=0.8.0;
+
+// ============ Internal Imports ============
+import {IGasOracle} from "../../interfaces/IGasOracle.sol";
+
+// ============ External Imports ============
+import {Ownable} from "@openzeppelin/contracts/access/Ownable.sol";
+
+/**
+ * @notice A gas oracle that uses data stored within the contract.
+ * @dev This contract is intended to be owned by an address that will
+ * update the stored remote gas data.
+ */
+contract StorageGasOracle is IGasOracle, Ownable {
+    // ============ Public Storage ============
+
+    /// @notice Keyed by remote domain, gas data on that remote domain.
+    mapping(uint32 => IGasOracle.RemoteGasData) public remoteGasData;
+
+    // ============ Events ============
+
+    /**
+     * @notice Emitted when an entry in `remoteGasData` is set.
+     * @param remoteDomain The remote domain in which the gas data was set for.
+     * @param tokenExchangeRate The exchange rate of the remote native token quoted in the local native token.
+     * @param gasPrice The gas price on the remote chain.
+     */
+    event RemoteGasDataSet(
+        uint32 indexed remoteDomain,
+        uint128 tokenExchangeRate,
+        uint128 gasPrice
+    );
+
+    struct RemoteGasDataConfig {
+        uint32 remoteDomain;
+        uint128 tokenExchangeRate;
+        uint128 gasPrice;
+    }
+
+    // ============ External Functions ============
+
+    /**
+     * @notice Returns the stored `remoteGasData` for the `_destinationDomain`.
+     * @param _destinationDomain The destination domain.
+     * @return tokenExchangeRate The exchange rate of the remote native token quoted in the local native token.
+     * @return gasPrice The gas price on the remote chain.
+     */
+    function getExchangeRateAndGasPrice(uint32 _destinationDomain)
+        external
+        view
+        override
+        returns (uint128 tokenExchangeRate, uint128 gasPrice)
+    {
+        // Intentionally allow unset / zero values
+        IGasOracle.RemoteGasData memory _data = remoteGasData[
+            _destinationDomain
+        ];
+        return (_data.tokenExchangeRate, _data.gasPrice);
+    }
+
+    /**
+     * @notice Sets the remote gas data for many remotes at a time.
+     * @param _configs The configs to use when setting the remote gas data.
+     */
+    function setRemoteGasDataConfigs(RemoteGasDataConfig[] calldata _configs)
+        external
+        onlyOwner
+    {
+        uint256 _len = _configs.length;
+        for (uint256 i = 0; i < _len; i++) {
+            _setRemoteGasData(_configs[i]);
+        }
+    }
+
+    /**
+     * @notice Sets the remote gas data using the values in `_config`.
+     * @param _config The config to use when setting the remote gas data.
+     */
+    function setRemoteGasData(RemoteGasDataConfig calldata _config)
+        external
+        onlyOwner
+    {
+        _setRemoteGasData(_config);
+    }
+
+    // ============ Internal functions ============
+
+    /**
+     * @notice Sets the remote gas data using the values in `_config`.
+     * @param _config The config to use when setting the remote gas data.
+     */
+    function _setRemoteGasData(RemoteGasDataConfig calldata _config) internal {
+        remoteGasData[_config.remoteDomain] = IGasOracle.RemoteGasData({
+            tokenExchangeRate: _config.tokenExchangeRate,
+            gasPrice: _config.gasPrice
+        });
+
+        emit RemoteGasDataSet(
+            _config.remoteDomain,
+            _config.tokenExchangeRate,
+            _config.gasPrice
+        );
+    }
+}

package/contracts/hooks/libs/AbstractMessageIdAuthHook.sol

@@ -0,0 +1,90 @@
+// SPDX-License-Identifier: MIT OR Apache-2.0
+pragma solidity >=0.8.0;
+
+/*@@@@@@@       @@@@@@@@@
+ @@@@@@@@@       @@@@@@@@@
+  @@@@@@@@@       @@@@@@@@@
+   @@@@@@@@@       @@@@@@@@@
+    @@@@@@@@@@@@@@@@@@@@@@@@@
+     @@@@@  HYPERLANE  @@@@@@@
+    @@@@@@@@@@@@@@@@@@@@@@@@@
+   @@@@@@@@@       @@@@@@@@@
+  @@@@@@@@@       @@@@@@@@@
+ @@@@@@@@@       @@@@@@@@@
+@@@@@@@@@       @@@@@@@@*/
+
+// ============ Internal Imports ============
+import {AbstractPostDispatchHook} from "./AbstractPostDispatchHook.sol";
+import {AbstractMessageIdAuthorizedIsm} from "../../isms/hook/AbstractMessageIdAuthorizedIsm.sol";
+import {TypeCasts} from "../../libs/TypeCasts.sol";
+import {Message} from "../../libs/Message.sol";
+import {StandardHookMetadata} from "./StandardHookMetadata.sol";
+import {MailboxClient} from "../../client/MailboxClient.sol";
+
+/**
+ * @title AbstractMessageIdAuthHook
+ * @notice Message hook to inform an Abstract Message ID ISM of messages published through
+ * a third-party bridge.
+ */
+abstract contract AbstractMessageIdAuthHook is
+    AbstractPostDispatchHook,
+    MailboxClient
+{
+    using StandardHookMetadata for bytes;
+    using Message for bytes;
+
+    // ============ Constants ============
+
+    // address for ISM to verify messages
+    address public immutable ism;
+    // Domain of chain on which the ISM is deployed
+    uint32 public immutable destinationDomain;
+
+    // ============ Constructor ============
+
+    constructor(
+        address _mailbox,
+        uint32 _destinationDomain,
+        address _ism
+    ) MailboxClient(_mailbox) {
+        require(_ism != address(0), "AbstractMessageIdAuthHook: invalid ISM");
+        require(
+            _destinationDomain != 0,
+            "AbstractMessageIdAuthHook: invalid destination domain"
+        );
+        ism = _ism;
+        destinationDomain = _destinationDomain;
+    }
+
+    // ============ Internal functions ============
+
+    /// @inheritdoc AbstractPostDispatchHook
+    function _postDispatch(bytes calldata metadata, bytes calldata message)
+        internal
+        override
+    {
+        bytes32 id = message.id();
+        require(
+            _isLatestDispatched(id),
+            "AbstractMessageIdAuthHook: message not latest dispatched"
+        );
+        require(
+            message.destination() == destinationDomain,
+            "AbstractMessageIdAuthHook: invalid destination domain"
+        );
+        bytes memory payload = abi.encodeCall(
+            AbstractMessageIdAuthorizedIsm.verifyMessageId,
+            id
+        );
+        _sendMessageId(metadata, payload);
+    }
+
+    /**
+     * @notice Send a message to the ISM.
+     * @param metadata The metadata for the hook caller
+     * @param payload The payload for call to the ISM
+     */
+    function _sendMessageId(bytes calldata metadata, bytes memory payload)
+        internal
+        virtual;
+}