@hyperlane-xyz/core 1.5.3 → 1.5.5-beta0

package/contracts/hooks/libs/AbstractPostDispatchHook.sol

@@ -0,0 +1,91 @@
+// SPDX-License-Identifier: MIT OR Apache-2.0
+pragma solidity >=0.8.0;
+
+/*@@@@@@@       @@@@@@@@@
+ @@@@@@@@@       @@@@@@@@@
+  @@@@@@@@@       @@@@@@@@@
+   @@@@@@@@@       @@@@@@@@@
+    @@@@@@@@@@@@@@@@@@@@@@@@@
+     @@@@@  HYPERLANE  @@@@@@@
+    @@@@@@@@@@@@@@@@@@@@@@@@@
+   @@@@@@@@@       @@@@@@@@@
+  @@@@@@@@@       @@@@@@@@@
+ @@@@@@@@@       @@@@@@@@@
+@@@@@@@@@       @@@@@@@@*/
+
+// ============ Internal Imports ============
+import {StandardHookMetadata} from "./StandardHookMetadata.sol";
+import {IPostDispatchHook} from "../../interfaces/hooks/IPostDispatchHook.sol";
+
+/**
+ * @title AbstractPostDispatch
+ * @notice Abstract post dispatch hook supporting the current global hook metadata variant.
+ */
+abstract contract AbstractPostDispatchHook is IPostDispatchHook {
+    using StandardHookMetadata for bytes;
+
+    // ============ External functions ============
+
+    /// @inheritdoc IPostDispatchHook
+    function supportsMetadata(bytes calldata metadata)
+        public
+        pure
+        virtual
+        override
+        returns (bool)
+    {
+        return
+            metadata.length == 0 ||
+            metadata.variant() == StandardHookMetadata.VARIANT;
+    }
+
+    /// @inheritdoc IPostDispatchHook
+    function postDispatch(bytes calldata metadata, bytes calldata message)
+        external
+        payable
+        override
+    {
+        require(
+            supportsMetadata(metadata),
+            "AbstractPostDispatchHook: invalid metadata variant"
+        );
+        _postDispatch(metadata, message);
+    }
+
+    /// @inheritdoc IPostDispatchHook
+    function quoteDispatch(bytes calldata metadata, bytes calldata message)
+        public
+        view
+        override
+        returns (uint256)
+    {
+        require(
+            supportsMetadata(metadata),
+            "AbstractPostDispatchHook: invalid metadata variant"
+        );
+        return _quoteDispatch(metadata, message);
+    }
+
+    // ============ Internal functions ============
+
+    /**
+     * @notice Post dispatch hook implementation.
+     * @param metadata The metadata of the message being dispatched.
+     * @param message The message being dispatched.
+     */
+    function _postDispatch(bytes calldata metadata, bytes calldata message)
+        internal
+        virtual;
+
+    /**
+     * @notice Quote dispatch hook implementation.
+     * @param metadata The metadata of the message being dispatched.
+     * @param message The message being dispatched.
+     * @return The quote for the dispatch.
+     */
+    function _quoteDispatch(bytes calldata metadata, bytes calldata message)
+        internal
+        view
+        virtual
+        returns (uint256);
+}

package/contracts/hooks/libs/StandardHookMetadata.sol

@@ -0,0 +1,160 @@
+// SPDX-License-Identifier: MIT OR Apache-2.0
+pragma solidity >=0.8.0;
+
+/*@@@@@@@       @@@@@@@@@
+ @@@@@@@@@       @@@@@@@@@
+  @@@@@@@@@       @@@@@@@@@
+   @@@@@@@@@       @@@@@@@@@
+    @@@@@@@@@@@@@@@@@@@@@@@@@
+     @@@@@  HYPERLANE  @@@@@@@
+    @@@@@@@@@@@@@@@@@@@@@@@@@
+   @@@@@@@@@       @@@@@@@@@
+  @@@@@@@@@       @@@@@@@@@
+ @@@@@@@@@       @@@@@@@@@
+@@@@@@@@@       @@@@@@@@*/
+
+/**
+ * Format of metadata:
+ *
+ * [0:1] variant
+ * [2:33] msg.value
+ * [34:65] Gas limit for message (IGP)
+ * [66:85] Refund address for message (IGP)
+ * [86:] Custom metadata
+ */
+library StandardHookMetadata {
+    uint8 private constant VARIANT_OFFSET = 0;
+    uint8 private constant MSG_VALUE_OFFSET = 2;
+    uint8 private constant GAS_LIMIT_OFFSET = 34;
+    uint8 private constant REFUND_ADDRESS_OFFSET = 66;
+    uint256 private constant MIN_METADATA_LENGTH = 86;
+
+    uint16 public constant VARIANT = 1;
+
+    /**
+     * @notice Returns the variant of the metadata.
+     * @param _metadata ABI encoded global hook metadata.
+     * @return variant of the metadata as uint8.
+     */
+    function variant(bytes calldata _metadata) internal pure returns (uint16) {
+        if (_metadata.length < VARIANT_OFFSET + 2) return 0;
+        return uint16(bytes2(_metadata[VARIANT_OFFSET:VARIANT_OFFSET + 2]));
+    }
+
+    /**
+     * @notice Returns the specified value for the message.
+     * @param _metadata ABI encoded global hook metadata.
+     * @param _default Default fallback value.
+     * @return Value for the message as uint256.
+     */
+    function msgValue(bytes calldata _metadata, uint256 _default)
+        internal
+        pure
+        returns (uint256)
+    {
+        if (_metadata.length < MSG_VALUE_OFFSET + 32) return _default;
+        return
+            uint256(bytes32(_metadata[MSG_VALUE_OFFSET:MSG_VALUE_OFFSET + 32]));
+    }
+
+    /**
+     * @notice Returns the specified gas limit for the message.
+     * @param _metadata ABI encoded global hook metadata.
+     * @param _default Default fallback gas limit.
+     * @return Gas limit for the message as uint256.
+     */
+    function gasLimit(bytes calldata _metadata, uint256 _default)
+        internal
+        pure
+        returns (uint256)
+    {
+        if (_metadata.length < GAS_LIMIT_OFFSET + 32) return _default;
+        return
+            uint256(bytes32(_metadata[GAS_LIMIT_OFFSET:GAS_LIMIT_OFFSET + 32]));
+    }
+
+    /**
+     * @notice Returns the specified refund address for the message.
+     * @param _metadata ABI encoded global hook metadata.
+     * @param _default Default fallback refund address.
+     * @return Refund address for the message as address.
+     */
+    function refundAddress(bytes calldata _metadata, address _default)
+        internal
+        pure
+        returns (address)
+    {
+        if (_metadata.length < REFUND_ADDRESS_OFFSET + 20) return _default;
+        return
+            address(
+                bytes20(
+                    _metadata[REFUND_ADDRESS_OFFSET:REFUND_ADDRESS_OFFSET + 20]
+                )
+            );
+    }
+
+    /**
+     * @notice Returns the specified refund address for the message.
+     * @param _metadata ABI encoded global hook metadata.
+     * @return Refund address for the message as address.
+     */
+    function getCustomMetadata(bytes calldata _metadata)
+        internal
+        pure
+        returns (bytes calldata)
+    {
+        if (_metadata.length < MIN_METADATA_LENGTH) return _metadata[0:0];
+        return _metadata[MIN_METADATA_LENGTH:];
+    }
+
+    /**
+     * @notice Formats the specified gas limit and refund address into global hook metadata.
+     * @param _msgValue msg.value for the message.
+     * @param _gasLimit Gas limit for the message.
+     * @param _refundAddress Refund address for the message.
+     * @param _customMetadata Additional metadata to include in the global hook metadata.
+     * @return ABI encoded global hook metadata.
+     */
+    function formatMetadata(
+        uint256 _msgValue,
+        uint256 _gasLimit,
+        address _refundAddress,
+        bytes memory _customMetadata
+    ) internal pure returns (bytes memory) {
+        return
+            abi.encodePacked(
+                VARIANT,
+                _msgValue,
+                _gasLimit,
+                _refundAddress,
+                _customMetadata
+            );
+    }
+
+    /**
+     * @notice Formats the specified gas limit and refund address into global hook metadata.
+     * @param _msgValue msg.value for the message.
+     * @return ABI encoded global hook metadata.
+     */
+    function formatMetadata(uint256 _msgValue)
+        internal
+        view
+        returns (bytes memory)
+    {
+        return formatMetadata(_msgValue, uint256(0), msg.sender, "");
+    }
+
+    /**
+     * @notice Formats the specified gas limit and refund address into global hook metadata.
+     * @param _gasLimit Gas limit for the message.
+     * @param _refundAddress Refund address for the message.
+     * @return ABI encoded global hook metadata.
+     */
+    function formatMetadata(uint256 _gasLimit, address _refundAddress)
+        internal
+        pure
+        returns (bytes memory)
+    {
+        return formatMetadata(uint256(0), _gasLimit, _refundAddress, "");
+    }
+}

package/contracts/hooks/routing/DestinationRecipientRoutingHook.sol

@@ -0,0 +1,54 @@
+// SPDX-License-Identifier: MIT OR Apache-2.0
+pragma solidity >=0.8.0;
+
+/*@@@@@@@       @@@@@@@@@
+ @@@@@@@@@       @@@@@@@@@
+  @@@@@@@@@       @@@@@@@@@
+   @@@@@@@@@       @@@@@@@@@
+    @@@@@@@@@@@@@@@@@@@@@@@@@
+     @@@@@  HYPERLANE  @@@@@@@
+    @@@@@@@@@@@@@@@@@@@@@@@@@
+   @@@@@@@@@       @@@@@@@@@
+  @@@@@@@@@       @@@@@@@@@
+ @@@@@@@@@       @@@@@@@@@
+@@@@@@@@@       @@@@@@@@*/
+
+import {Message} from "../../libs/Message.sol";
+import {IPostDispatchHook} from "../../interfaces/hooks/IPostDispatchHook.sol";
+import {DomainRoutingHook} from "./DomainRoutingHook.sol";
+
+contract DestinationRecipientRoutingHook is DomainRoutingHook {
+    using Message for bytes;
+
+    /// @notice destination => recipient =>custom hook
+    mapping(uint32 => mapping(bytes32 => address)) public customHooks;
+
+    constructor(address mailbox, address owner)
+        DomainRoutingHook(mailbox, owner)
+    {}
+
+    function _postDispatch(bytes calldata metadata, bytes calldata message)
+        internal
+        override
+    {
+        address customHookPreset = customHooks[message.destination()][
+            message.recipient()
+        ];
+        if (customHookPreset != address(0)) {
+            IPostDispatchHook(customHookPreset).postDispatch{value: msg.value}(
+                metadata,
+                message
+            );
+        } else {
+            super._postDispatch(metadata, message);
+        }
+    }
+
+    function configCustomHook(
+        uint32 destinationDomain,
+        bytes32 recipient,
+        address hook
+    ) external onlyOwner {
+        customHooks[destinationDomain][recipient] = hook;
+    }
+}

package/contracts/hooks/routing/DomainRoutingHook.sol

@@ -0,0 +1,106 @@
+// SPDX-License-Identifier: MIT
+pragma solidity >=0.8.0;
+
+/*@@@@@@@       @@@@@@@@@
+ @@@@@@@@@       @@@@@@@@@
+  @@@@@@@@@       @@@@@@@@@
+   @@@@@@@@@       @@@@@@@@@
+    @@@@@@@@@@@@@@@@@@@@@@@@@
+     @@@@@  HYPERLANE  @@@@@@@
+    @@@@@@@@@@@@@@@@@@@@@@@@@
+   @@@@@@@@@       @@@@@@@@@
+  @@@@@@@@@       @@@@@@@@@
+ @@@@@@@@@       @@@@@@@@@
+@@@@@@@@@       @@@@@@@@*/
+
+// ============ Internal Imports ============
+import {StandardHookMetadata} from "../libs/StandardHookMetadata.sol";
+import {AbstractPostDispatchHook} from "../libs/AbstractPostDispatchHook.sol";
+import {MailboxClient} from "../../client/MailboxClient.sol";
+import {Message} from "../../libs/Message.sol";
+import {IPostDispatchHook} from "../../interfaces/hooks/IPostDispatchHook.sol";
+
+// ============ External Imports ============
+import {Strings} from "@openzeppelin/contracts/utils/Strings.sol";
+
+/**
+ * @title DomainRoutingHook
+ * @notice Delegates to a hook based on the destination domain of the message.
+ */
+contract DomainRoutingHook is AbstractPostDispatchHook, MailboxClient {
+    using Strings for uint32;
+    using Message for bytes;
+
+    struct HookConfig {
+        uint32 destination;
+        address hook;
+    }
+
+    mapping(uint32 => IPostDispatchHook) public hooks;
+
+    constructor(address _mailbox, address _owner) MailboxClient(_mailbox) {
+        _transferOwnership(_owner);
+    }
+
+    function setHook(uint32 destination, address hook) public onlyOwner {
+        hooks[destination] = IPostDispatchHook(hook);
+    }
+
+    function setHooks(HookConfig[] calldata configs) external onlyOwner {
+        for (uint256 i = 0; i < configs.length; i++) {
+            setHook(configs[i].destination, configs[i].hook);
+        }
+    }
+
+    function supportsMetadata(bytes calldata)
+        public
+        pure
+        virtual
+        override
+        returns (bool)
+    {
+        // routing hook does not care about metadata shape
+        return true;
+    }
+
+    // ============ Internal Functions ============
+
+    /// @inheritdoc AbstractPostDispatchHook
+    function _postDispatch(bytes calldata metadata, bytes calldata message)
+        internal
+        virtual
+        override
+    {
+        _getConfiguredHook(message).postDispatch{value: msg.value}(
+            metadata,
+            message
+        );
+    }
+
+    /// @inheritdoc AbstractPostDispatchHook
+    function _quoteDispatch(bytes calldata metadata, bytes calldata message)
+        internal
+        view
+        virtual
+        override
+        returns (uint256)
+    {
+        return _getConfiguredHook(message).quoteDispatch(metadata, message);
+    }
+
+    function _getConfiguredHook(bytes calldata message)
+        internal
+        view
+        virtual
+        returns (IPostDispatchHook hook)
+    {
+        hook = hooks[message.destination()];
+        require(
+            address(hook) != address(0),
+            string.concat(
+                "No hook configured for destination: ",
+                message.destination().toString()
+            )
+        );
+    }
+}

package/contracts/hooks/routing/FallbackDomainRoutingHook.sol

@@ -0,0 +1,52 @@
+// SPDX-License-Identifier: MIT OR Apache-2.0
+pragma solidity >=0.8.0;
+
+/*@@@@@@@       @@@@@@@@@
+ @@@@@@@@@       @@@@@@@@@
+  @@@@@@@@@       @@@@@@@@@
+   @@@@@@@@@       @@@@@@@@@
+    @@@@@@@@@@@@@@@@@@@@@@@@@
+     @@@@@  HYPERLANE  @@@@@@@
+    @@@@@@@@@@@@@@@@@@@@@@@@@
+   @@@@@@@@@       @@@@@@@@@
+  @@@@@@@@@       @@@@@@@@@
+ @@@@@@@@@       @@@@@@@@@
+@@@@@@@@@       @@@@@@@@*/
+
+import {IPostDispatchHook} from "../../interfaces/hooks/IPostDispatchHook.sol";
+import {IMailbox} from "../../interfaces/IMailbox.sol";
+import {DomainRoutingHook} from "./DomainRoutingHook.sol";
+import {Message} from "../../libs/Message.sol";
+
+/**
+ * @title FallbackDomainRoutingHook
+ * @notice Delegates to a hook based on the destination domain of the message.
+ * If no hook is configured for the destination domain, delegates to a fallback hook.
+ */
+contract FallbackDomainRoutingHook is DomainRoutingHook {
+    using Message for bytes;
+
+    IPostDispatchHook public immutable fallbackHook;
+
+    constructor(
+        address _mailbox,
+        address _owner,
+        address _fallback
+    ) DomainRoutingHook(_mailbox, _owner) {
+        fallbackHook = IPostDispatchHook(_fallback);
+    }
+
+    // ============ Internal Functions ============
+
+    function _getConfiguredHook(bytes calldata message)
+        internal
+        view
+        override
+        returns (IPostDispatchHook hook)
+    {
+        hook = hooks[message.destination()];
+        if (address(hook) == address(0)) {
+            hook = fallbackHook;
+        }
+    }
+}

package/contracts/interfaces/IInterchainGasPaymaster.sol

@@ -10,11 +10,13 @@ interface IInterchainGasPaymaster {
     /**
      * @notice Emitted when a payment is made for a message's gas costs.
      * @param messageId The ID of the message to pay for.
+     * @param destinationDomain The domain of the destination chain.
      * @param gasAmount The amount of destination gas paid for.
      * @param payment The amount of native tokens paid.
      */
     event GasPayment(
         bytes32 indexed messageId,
+        uint32 indexed destinationDomain,
         uint256 gasAmount,
         uint256 payment
     );

package/contracts/interfaces/IMailbox.sol

@@ -2,6 +2,7 @@
 pragma solidity >=0.8.0;
 
 import {IInterchainSecurityModule} from "./IInterchainSecurityModule.sol";
+import {IPostDispatchHook} from "./hooks/IPostDispatchHook.sol";
 
 interface IMailbox {
     // ============ Events ============
@@ -49,23 +50,58 @@ interface IMailbox {
 
     function defaultIsm() external view returns (IInterchainSecurityModule);
 
+    function defaultHook() external view returns (IPostDispatchHook);
+
+    function latestDispatchedId() external view returns (bytes32);
+
     function dispatch(
-        uint32 _destinationDomain,
-        bytes32 _recipientAddress,
-        bytes calldata _messageBody
-    ) external returns (bytes32);
+        uint32 destinationDomain,
+        bytes32 recipientAddress,
+        bytes calldata messageBody
+    ) external payable returns (bytes32 messageId);
 
-    function process(bytes calldata _metadata, bytes calldata _message)
-        external;
+    function quoteDispatch(
+        uint32 destinationDomain,
+        bytes32 recipientAddress,
+        bytes calldata messageBody
+    ) external view returns (uint256 fee);
 
-    function count() external view returns (uint32);
+    function dispatch(
+        uint32 destinationDomain,
+        bytes32 recipientAddress,
+        bytes calldata body,
+        bytes calldata defaultHookMetadata
+    ) external payable returns (bytes32 messageId);
 
-    function root() external view returns (bytes32);
+    function quoteDispatch(
+        uint32 destinationDomain,
+        bytes32 recipientAddress,
+        bytes calldata messageBody,
+        bytes calldata defaultHookMetadata
+    ) external view returns (uint256 fee);
 
-    function latestCheckpoint() external view returns (bytes32, uint32);
+    function dispatch(
+        uint32 destinationDomain,
+        bytes32 recipientAddress,
+        bytes calldata body,
+        bytes calldata customHookMetadata,
+        IPostDispatchHook customHook
+    ) external payable returns (bytes32 messageId);
+
+    function quoteDispatch(
+        uint32 destinationDomain,
+        bytes32 recipientAddress,
+        bytes calldata messageBody,
+        bytes calldata customHookMetadata,
+        IPostDispatchHook customHook
+    ) external view returns (uint256 fee);
+
+    function process(bytes calldata metadata, bytes calldata message)
+        external
+        payable;
 
-    function recipientIsm(address _recipient)
+    function recipientIsm(address recipient)
         external
         view
-        returns (IInterchainSecurityModule);
+        returns (IInterchainSecurityModule module);
 }

package/contracts/interfaces/IMessageRecipient.sol

@@ -6,5 +6,5 @@ interface IMessageRecipient {
         uint32 _origin,
         bytes32 _sender,
         bytes calldata _message
-    ) external;
+    ) external payable;
 }

package/contracts/interfaces/IValidatorAnnounce.sol

@@ -2,12 +2,6 @@
 pragma solidity >=0.6.11;
 
 interface IValidatorAnnounce {
-    /// @notice Returns the local domain for validator announcements
-    function localDomain() external view returns (uint32);
-
-    /// @notice Returns the mailbox contract for validator announcements
-    function mailbox() external view returns (address);
-
     /// @notice Returns a list of validators that have made announcements
     function getAnnouncedValidators() external view returns (address[] memory);
 

package/contracts/interfaces/hooks/IPostDispatchHook.sol

@@ -0,0 +1,46 @@
+// SPDX-License-Identifier: MIT OR Apache-2.0
+pragma solidity >=0.8.0;
+
+/*@@@@@@@       @@@@@@@@@
+ @@@@@@@@@       @@@@@@@@@
+  @@@@@@@@@       @@@@@@@@@
+   @@@@@@@@@       @@@@@@@@@
+    @@@@@@@@@@@@@@@@@@@@@@@@@
+     @@@@@  HYPERLANE  @@@@@@@
+    @@@@@@@@@@@@@@@@@@@@@@@@@
+   @@@@@@@@@       @@@@@@@@@
+  @@@@@@@@@       @@@@@@@@@
+ @@@@@@@@@       @@@@@@@@@
+@@@@@@@@@       @@@@@@@@*/
+
+interface IPostDispatchHook {
+    /**
+     * @notice Returns whether the hook supports metadata
+     * @param metadata metadata
+     * @return Whether the hook supports metadata
+     */
+    function supportsMetadata(bytes calldata metadata)
+        external
+        view
+        returns (bool);
+
+    /**
+     * @notice Post action after a message is dispatched via the Mailbox
+     * @param metadata The metadata required for the hook
+     * @param message The message passed from the Mailbox.dispatch() call
+     */
+    function postDispatch(bytes calldata metadata, bytes calldata message)
+        external
+        payable;
+
+    /**
+     * @notice Compute the payment required by the postDispatch call
+     * @param metadata The metadata required for the hook
+     * @param message The message passed from the Mailbox.dispatch() call
+     * @return Quoted payment for the postDispatch call
+     */
+    function quoteDispatch(bytes calldata metadata, bytes calldata message)
+        external
+        view
+        returns (uint256);
+}

package/contracts/interfaces/optimism/ICrossDomainMessenger.sol

@@ -0,0 +1,39 @@
+// SPDX-License-Identifier: MIT
+pragma solidity >=0.8.0;
+
+/**
+ * @title ICrossDomainMessenger interface for bedrock update
+ * @dev eth-optimism's version uses strict 0.8.15 which we don't want to restrict to
+ */
+interface ICrossDomainMessenger {
+    /**
+     * Sends a cross domain message to the target messenger.
+     * @param _target Target contract address.
+     * @param _message Message to send to the target.
+     * @param _gasLimit Gas limit for the provided message.
+     */
+    function sendMessage(
+        address _target,
+        bytes calldata _message,
+        uint32 _gasLimit
+    ) external payable;
+
+    function relayMessage(
+        uint256 _nonce,
+        address _sender,
+        address _target,
+        uint256 _value,
+        uint256 _minGasLimit,
+        bytes calldata _message
+    ) external payable;
+
+    /*************
+     * Variables *
+     *************/
+
+    function xDomainMessageSender() external view returns (address);
+}
+
+interface IL2CrossDomainMessenger is ICrossDomainMessenger {
+    function messageNonce() external view returns (uint256);
+}

package/contracts/isms/NoopIsm.sol

@@ -0,0 +1,17 @@
+// SPDX-License-Identifier: MIT OR Apache-2.0
+pragma solidity >=0.8.0;
+
+import {IInterchainSecurityModule} from "../interfaces/IInterchainSecurityModule.sol";
+
+contract NoopIsm is IInterchainSecurityModule {
+    uint8 public constant override moduleType = uint8(Types.NULL);
+
+    function verify(bytes calldata, bytes calldata)
+        public
+        pure
+        override
+        returns (bool)
+    {
+        return true;
+    }
+}

package/contracts/isms/aggregation/AbstractAggregationIsm.sol

@@ -7,7 +7,7 @@ import {ECDSA} from "@openzeppelin/contracts/utils/cryptography/ECDSA.sol";
 // ============ Internal Imports ============
 import {IInterchainSecurityModule} from "../../interfaces/IInterchainSecurityModule.sol";
 import {IAggregationIsm} from "../../interfaces/isms/IAggregationIsm.sol";
-import {AggregationIsmMetadata} from "../../libs/isms/AggregationIsmMetadata.sol";
+import {AggregationIsmMetadata} from "../../isms/libs/AggregationIsmMetadata.sol";
 
 /**
  * @title AggregationIsm